linuxport: Merging in the fruits of my labors (Python VFS)
[xbmc:xbmc-antiquated.git] / xbmc / lib / libPython / Python / Grammar / Grammar
1 # Grammar for Python
2
3 # Note:  Changing the grammar specified in this file will most likely
4 #        require corresponding changes in the parser module
5 #        (../Modules/parsermodule.c).  If you can't make the changes to
6 #        that module yourself, please co-ordinate the required changes
7 #        with someone who can; ask around on python-dev for help.  Fred
8 #        Drake <fdrake@acm.org> will probably be listening there.
9
10 # Commands for Kees Blom's railroad program
11 #diagram:token NAME
12 #diagram:token NUMBER
13 #diagram:token STRING
14 #diagram:token NEWLINE
15 #diagram:token ENDMARKER
16 #diagram:token INDENT
17 #diagram:output\input python.bla
18 #diagram:token DEDENT
19 #diagram:output\textwidth 20.04cm\oddsidemargin  0.0cm\evensidemargin 0.0cm
20 #diagram:rules
21
22 # Start symbols for the grammar:
23 #       single_input is a single interactive statement;
24 #       file_input is a module or sequence of commands read from an input file;
25 #       eval_input is the input for the eval() and input() functions.
26 # NB: compound_stmt in single_input is followed by extra NEWLINE!
27 single_input: NEWLINE | simple_stmt | compound_stmt NEWLINE
28 file_input: (NEWLINE | stmt)* ENDMARKER
29 eval_input: testlist NEWLINE* ENDMARKER
30
31 decorator: '@' dotted_name [ '(' [arglist] ')' ] NEWLINE
32 decorators: decorator+
33 funcdef: [decorators] 'def' NAME parameters ':' suite
34 parameters: '(' [varargslist] ')'
35 varargslist: (fpdef ['=' test] ',')* ('*' NAME [',' '**' NAME] | '**' NAME) | fpdef ['=' test] (',' fpdef ['=' test])* [',']
36 fpdef: NAME | '(' fplist ')'
37 fplist: fpdef (',' fpdef)* [',']
38
39 stmt: simple_stmt | compound_stmt
40 simple_stmt: small_stmt (';' small_stmt)* [';'] NEWLINE
41 small_stmt: expr_stmt | print_stmt  | del_stmt | pass_stmt | flow_stmt | import_stmt | global_stmt | exec_stmt | assert_stmt
42 expr_stmt: testlist (augassign testlist | ('=' testlist)*)
43 augassign: '+=' | '-=' | '*=' | '/=' | '%=' | '&=' | '|=' | '^=' | '<<=' | '>>=' | '**=' | '//='
44 # For normal assignments, additional restrictions enforced by the interpreter
45 print_stmt: 'print' ( [ test (',' test)* [','] ] | '>>' test [ (',' test)+ [','] ] )
46 del_stmt: 'del' exprlist
47 pass_stmt: 'pass'
48 flow_stmt: break_stmt | continue_stmt | return_stmt | raise_stmt | yield_stmt
49 break_stmt: 'break'
50 continue_stmt: 'continue'
51 return_stmt: 'return' [testlist]
52 yield_stmt: 'yield' testlist
53 raise_stmt: 'raise' [test [',' test [',' test]]]
54 import_stmt: import_name | import_from
55 import_name: 'import' dotted_as_names
56 import_from: 'from' dotted_name 'import' ('*' | '(' import_as_names ')' | import_as_names)
57 import_as_name: NAME [NAME NAME]
58 dotted_as_name: dotted_name [NAME NAME]
59 import_as_names: import_as_name (',' import_as_name)* [',']
60 dotted_as_names: dotted_as_name (',' dotted_as_name)*
61 dotted_name: NAME ('.' NAME)*
62 global_stmt: 'global' NAME (',' NAME)*
63 exec_stmt: 'exec' expr ['in' test [',' test]]
64 assert_stmt: 'assert' test [',' test]
65
66 compound_stmt: if_stmt | while_stmt | for_stmt | try_stmt | funcdef | classdef
67 if_stmt: 'if' test ':' suite ('elif' test ':' suite)* ['else' ':' suite]
68 while_stmt: 'while' test ':' suite ['else' ':' suite]
69 for_stmt: 'for' exprlist 'in' testlist ':' suite ['else' ':' suite]
70 try_stmt: ('try' ':' suite (except_clause ':' suite)+ #diagram:break
71            ['else' ':' suite] | 'try' ':' suite 'finally' ':' suite)
72 # NB compile.c makes sure that the default except clause is last
73 except_clause: 'except' [test [',' test]]
74 suite: simple_stmt | NEWLINE INDENT stmt+ DEDENT
75
76 test: and_test ('or' and_test)* | lambdef
77 and_test: not_test ('and' not_test)*
78 not_test: 'not' not_test | comparison
79 comparison: expr (comp_op expr)*
80 comp_op: '<'|'>'|'=='|'>='|'<='|'<>'|'!='|'in'|'not' 'in'|'is'|'is' 'not'
81 expr: xor_expr ('|' xor_expr)*
82 xor_expr: and_expr ('^' and_expr)*
83 and_expr: shift_expr ('&' shift_expr)*
84 shift_expr: arith_expr (('<<'|'>>') arith_expr)*
85 arith_expr: term (('+'|'-') term)*
86 term: factor (('*'|'/'|'%'|'//') factor)*
87 factor: ('+'|'-'|'~') factor | power
88 power: atom trailer* ['**' factor]
89 atom: '(' [testlist_gexp] ')' | '[' [listmaker] ']' | '{' [dictmaker] '}' | '`' testlist1 '`' | NAME | NUMBER | STRING+
90 listmaker: test ( list_for | (',' test)* [','] )
91 testlist_gexp: test ( gen_for | (',' test)* [','] )
92 lambdef: 'lambda' [varargslist] ':' test
93 trailer: '(' [arglist] ')' | '[' subscriptlist ']' | '.' NAME
94 subscriptlist: subscript (',' subscript)* [',']
95 subscript: '.' '.' '.' | test | [test] ':' [test] [sliceop]
96 sliceop: ':' [test]
97 exprlist: expr (',' expr)* [',']
98 testlist: test (',' test)* [',']
99 testlist_safe: test [(',' test)+ [',']]
100 dictmaker: test ':' test (',' test ':' test)* [',']
101
102 classdef: 'class' NAME ['(' testlist ')'] ':' suite
103
104 arglist: (argument ',')* (argument [',']| '*' test [',' '**' test] | '**' test)
105 argument: test [gen_for] | test '=' test ['(' gen_for ')'] # Really [keyword '='] test
106
107 list_iter: list_for | list_if
108 list_for: 'for' exprlist 'in' testlist_safe [list_iter]
109 list_if: 'if' test [list_iter]
110
111 gen_iter: gen_for | gen_if
112 gen_for: 'for' exprlist 'in' test [gen_iter]
113 gen_if: 'if' test [gen_iter]
114
115 testlist1: test (',' test)*
116
117 # not used in grammar, but may appear in "node" passed from Parser to Compiler
118 encoding_decl: NAME