configure: drop check for --enable-vaapisink-glx.
[vaapi:yyin2s-gstreamer-vaapi-display.git] / configure.ac
1 # gstreamer-vaapi package version number
2 m4_define([gst_vaapi_major_version], [0])
3 m4_define([gst_vaapi_minor_version], [4])
4 m4_define([gst_vaapi_micro_version], [0])
5 m4_define([gst_vaapi_pre_version],   [1])
6 m4_define([gst_vaapi_version],
7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
8 m4_if(gst_vaapi_pre_version, [0], [], [
9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
10 ])
11
12 # glib version number
13 m4_define([glib_major_version], [2])
14 m4_define([glib_minor_version], [28])
15 m4_define([glib_micro_version], [0])
16 m4_define([glib_major_minor_version],
17           [glib_major_version.glib_minor_version])
18 m4_define([glib_version],
19           [glib_major_version.glib_minor_version.glib_micro_version])
20
21 # gst version number
22 m4_define([gst_major_version], [0])
23 m4_define([gst_minor_version], [10])
24 m4_define([gst_micro_version], [14])
25 m4_define([gst_major_minor_version],
26           [gst_major_version.gst_minor_version])
27 m4_define([gst_version],
28           [gst_major_version.gst_minor_version.gst_micro_version])
29
30 # gst plugins-base version number
31 m4_define([gst_plugins_base_major_version], [0])
32 m4_define([gst_plugins_base_minor_version], [10])
33 m4_define([gst_plugins_base_micro_version], [31])
34 m4_define([gst_plugins_base_version],
35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
36
37 # gst plugins-bad version number
38 m4_define([gst_plugins_bad_major_version], [0])
39 m4_define([gst_plugins_bad_minor_version], [10])
40 m4_define([gst_plugins_bad_micro_version], [22])
41 m4_define([gst_plugins_bad_version],
42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
43
44 # VA-API minimum version number
45 m4_define([va_api_version],     [0.30.4])
46 m4_define([va_api_x11_version], [0.31.0])
47 m4_define([va_api_glx_version], [0.32.0])
48
49 # libva package version number
50 m4_define([libva_x11_package_version], [1.0.3])
51 m4_define([libva_glx_package_version], [1.0.9])
52
53 # gtk-doc version number
54 # XXX: introspection annotations require gtk-doc >= 1.12
55 m4_define([gtkdoc_major_version], [1])
56 m4_define([gtkdoc_minor_version], [9])
57 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
58
59 AC_PREREQ([2.58])
60 AC_INIT([gst_vaapi], [gst_vaapi_version],
61     [gwenole.beauchesne@intel.com],
62     [gstreamer-vaapi])
63
64 AC_CONFIG_HEADERS([config.h])
65 AC_CONFIG_SRCDIR([Makefile.am])
66 AC_CONFIG_MACRO_DIR([m4])
67 AC_CONFIG_AUX_DIR([build-aux])
68
69 AC_CANONICAL_TARGET
70
71 AM_INIT_AUTOMAKE
72
73 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
74 AC_SUBST(TODAY)
75
76 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
77 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
78
79 LIBVA_PACKAGE_VERSION=libva_x11_package_version
80 AC_SUBST(LIBVA_PACKAGE_VERSION)
81
82 dnl Versions for GStreamer and plugins-base
83 GST_MAJORMINOR=gst_major_minor_version
84 GST_VERSION_REQUIRED=gst_version
85 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
86 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
87 AC_SUBST(GST_MAJORMINOR)
88 AC_SUBST(GST_VERSION_REQUIRED)
89 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
90 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
91
92 dnl Use pretty build output with automake >= 1.11
93 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
94   AM_DEFAULT_VERBOSITY=1
95   AC_SUBST(AM_DEFAULT_VERBOSITY)
96 ])
97
98 dnl Check for tools
99 AC_PROG_CC
100 AM_PROG_CC_C_O
101 AC_PROG_LIBTOOL
102
103 AC_ARG_ENABLE(x11,
104     AS_HELP_STRING([--enable-x11],
105                    [enable X11 output @<:@default=yes@:>@]),
106     [], [enable_x11="yes"])
107
108 AC_ARG_ENABLE(glx,
109     AS_HELP_STRING([--enable-glx],
110                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
111     [], [enable_glx="yes"])
112
113 dnl Check for basic libraries
114 AC_CHECK_LIB(m, tan)
115
116 dnl Check for Gtk doc
117 GTKDOC_VERSION=gtkdoc_version
118 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
119 m4_ifdef([GTK_DOC_CHECK], [
120 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
121 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
122 AC_SUBST(GTKDOC_VERSION)
123
124 dnl Check for GLib
125 GLIB_VERSION_REQUIRED=glib_version
126 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
127 AC_SUBST(GLIB_VERSION_REQUIRED)
128
129 dnl ---------------------------------------------------------------------------
130 dnl -- GStreamer                                                             --
131 dnl ---------------------------------------------------------------------------
132
133 dnl GStreamer Core
134 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
135 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
136
137 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
138     saved_CFLAGS="$CFLAGS"
139     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
140     saved_LIBS="$LIBS"
141     LIBS="$LIBS $GST_BASE_LIBS"
142     AC_COMPILE_IFELSE(
143         [AC_LANG_PROGRAM(
144             [[#include <gst/base/gstbasesink.h>]],
145             [[GstBaseSinkClass klass; klass.query = NULL;]])],
146         [ac_cv_have_gst_base_sink_query="yes"],
147         [ac_cv_have_gst_base_sink_query="no"]
148     )
149     CFLAGS="$saved_CFLAGS"
150     LIBS="$saved_LIBS"
151 ])
152 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
153     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
154 fi
155
156 dnl GStreamer -base plugins
157 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
158     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
159 PKG_CHECK_MODULES([GST_INTERFACES],
160     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
161
162 dnl ... GstVideoOverlayComposition (gstreamer-video)
163 PKG_CHECK_MODULES([GST_VIDEO],
164     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
165
166 AC_CACHE_CHECK([for GstVideoOverlayComposition],
167     ac_cv_have_gst_video_overlay_composition, [
168     saved_CFLAGS="$CFLAGS"
169     CFLAGS="$CFLAGS $GST_CFLAGS"
170     saved_LIBS="$LIBS"
171     LIBS="$LIBS $GST_LIBS"
172     AC_COMPILE_IFELSE(
173         [AC_LANG_PROGRAM(
174             [[#include <gst/video/video-overlay-composition.h>]],
175             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
176         [ac_cv_have_gst_video_overlay_composition="yes"],
177         [ac_cv_have_gst_video_overlay_composition="no"]
178     )
179     CFLAGS="$saved_CFLAGS"
180     LIBS="$saved_LIBS"
181 ])
182 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
183     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
184 fi
185
186 dnl GStreamer -bad plugins
187 PKG_CHECK_MODULES([GST_BASEVIDEO],
188     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
189
190 dnl ... bitstream parsers
191 USE_CODEC_PARSERS=1
192 USE_LOCAL_CODEC_PARSERS=0
193
194 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
195     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
196
197 dnl ... 0.10.23 addition, could be implemented otherwise
198 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
199     ac_cv_have_gst_h264_slice_hdr_epb_count, [
200     saved_CFLAGS="$CFLAGS"
201     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
202     saved_LIBS="$LIBS"
203     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
204     AC_COMPILE_IFELSE(
205         [AC_LANG_PROGRAM(
206             [[#include <gst/codecparsers/gsth264parser.h>]],
207             [[GstH264SliceHdr slice_hdr;
208               slice_hdr.n_emulation_prevention_bytes = 0;]])],
209         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
210         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
211     )
212     CFLAGS="$saved_CFLAGS"
213     LIBS="$saved_LIBS"
214 ])
215
216 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
217     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
218         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
219 fi
220
221 dnl ... JPEG parser, not upstream yet
222 AC_CACHE_CHECK([for JPEG parser],
223     ac_cv_have_gst_jpeg_parser, [
224     saved_CFLAGS="$CFLAGS"
225     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
226     saved_LIBS="$LIBS"
227     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
228     AC_COMPILE_IFELSE(
229         [AC_LANG_PROGRAM(
230             [[#include <gst/codecparsers/gstjpegparser.h>]],
231             [[GstJpegImage jpeg_image;]])],
232         [ac_cv_have_gst_jpeg_parser="yes"],
233         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
234     )
235     CFLAGS="$saved_CFLAGS"
236     LIBS="$saved_LIBS"
237 ])
238
239 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
240     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
241         [Defined to 1 if JPEG parser exists.])
242 fi
243 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
244
245 dnl GST_ALL_LDFLAGS:
246 dnl LDFLAGS really should only contain flags, not libs - they get added before
247 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
248 GST_ALL_LDFLAGS="-no-undefined"
249 AC_SUBST(GST_ALL_LDFLAGS)
250
251 dnl GST_PLUGIN_LDFLAGS:
252 dnl this really should only contain flags, not libs - they get added before
253 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
254 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
255 AC_SUBST(GST_PLUGIN_LDFLAGS)
256
257 dnl Check for the GStreamer plugins directory
258 AC_MSG_CHECKING([for GStreamer plugins directory])
259 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
260 if test -z "$GST_PLUGINS_DIR"; then
261     echo "FAIL FAIL FAIL"
262     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
263 fi
264 AC_MSG_RESULT([$GST_PLUGINS_DIR])
265 plugindir="$GST_PLUGINS_DIR"
266 AC_SUBST(plugindir)
267
268 dnl ---------------------------------------------------------------------------
269 dnl -- Renderers                                                             --
270 dnl ---------------------------------------------------------------------------
271
272 dnl Check for X11
273 USE_X11=0
274 if test "$enable_x11" = "yes"; then
275     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
276     if test $USE_X11 -eq 1; then
277         saved_CPPFLAGS="$CPPFLAGS"
278         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
279         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
280         CPPFLAGS="$saved_CPPFLAGS"
281     fi
282 fi
283
284 dnl OpenGL
285 enable_opengl="no"
286 if test "$enable_glx" = "yes"; then
287     enable_opengl="yes"
288 fi
289
290 HAVE_GL=0
291 if test "$enable_opengl" = "yes"; then
292     HAVE_GL=1
293     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
294     saved_CPPFLAGS="$CPPFLAGS"
295     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
296     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
297 #ifdef HAVE_GL_GL_H
298 # include <GL/gl.h>
299 #endif
300     ])
301     CPPFLAGS="$saved_CPPFLAGS"
302 fi
303
304 dnl ... GLX
305 USE_GLX=0
306 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
307     USE_GLX=1
308     saved_CPPFLAGS="$CPPFLAGS"
309     saved_LIBS="$LIBS"
310     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
311     LIBS="$LIBS $GL_LIBS"
312     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
313 #ifdef HAVE_GL_GL_H
314 # include <GL/gl.h>
315 #endif
316     ])
317     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
318     CPPFLAGS="$saved_CPPFLAGS"
319     LIBS="$saved_LIBS"
320 fi
321
322 dnl ---------------------------------------------------------------------------
323 dnl -- VA-API                                                                --
324 dnl ---------------------------------------------------------------------------
325
326 dnl Core API
327 LIBVA_PKGNAME="libva"
328 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
329 AC_SUBST(LIBVA_PKGNAME)
330
331 VA_VERSION=`$PKG_CONFIG --modversion libva`
332 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
333 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
334 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
335 VA_VERSION_STR="$VA_VERSION"
336
337 dnl VA/X11 API
338 HAVE_VA_X11=0
339 LIBVA_X11_PKGNAME="libva-x11"
340 if test $USE_X11 -eq 1; then
341     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
342         [HAVE_VA_X11=1], [USE_X11=0])
343 fi
344 AC_SUBST(LIBVA_X11_PKGNAME)
345
346 dnl VA/GLX API
347 HAVE_VA_GLX=0
348 LIBVA_GLX_PKGNAME="libva-glx"
349 if test $USE_GLX -eq 1; then
350     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
351         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
352
353     if test $HAVE_VA_GLX -eq 1; then
354         saved_CPPFLAGS="$CPPFLAGS"
355         CPPFLAGS="$LIBVA_GLX_CPPFLAGS"
356         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
357         CPPFLAGS="$saved_CPPFLAGS"
358     fi
359 fi
360 AC_SUBST(LIBVA_GLX_PKGNAME)
361
362 dnl Check for JPEG decoding API (0.33+)
363 USE_JPEG_DECODER=0
364 AC_CACHE_CHECK([for JPEG decoding API],
365     ac_cv_have_jpeg_decoding_api, [
366     saved_CFLAGS="$CFLAGS"
367     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
368     saved_LIBS="$LIBS"
369     LIBS="$CFLAGS $LIBVA_LIBS"
370     AC_COMPILE_IFELSE(
371         [AC_LANG_PROGRAM(
372             [[#include <va/va.h>
373               #include <va/va_dec_jpeg.h>]],
374             [[VAPictureParameterBufferJPEG pic_param;
375               VASliceParameterBufferJPEG slice_param;
376               VAHuffmanTableBufferJPEG huffman_table;
377               VAIQMatrixBufferJPEG iq_matrix;]])],
378         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
379         [ac_cv_have_jpeg_decoding_api="no"]
380     )
381     CFLAGS="$saved_CFLAGS"
382     LIBS="$saved_LIBS"
383 ])
384
385 dnl ---------------------------------------------------------------------------
386 dnl -- Generate files and summary                                            --
387 dnl ---------------------------------------------------------------------------
388
389 case ":$USE_X11:$USE_GLX:" in
390 *:1:*)
391     ;;
392 *)
393     AC_MSG_ERROR([No renderer is enabled])
394     ;;
395 esac
396
397 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
398     [Defined to 1 if JPEG decoder is used])
399 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
400
401 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
402     [Defined to 1 if X11 is enabled])
403 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
404
405 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
406     [Defined to 1 if GLX is enabled])
407 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
408
409 pkgconfigdir=${libdir}/pkgconfig
410 AC_SUBST(pkgconfigdir)
411
412 AC_CONFIG_FILES([
413     Makefile
414     debian.upstream/Makefile
415     debian.upstream/changelog
416     debian.upstream/control
417     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
418 debian.upstream/gstreamer-vaapi-doc.install.in
419     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
420 debian.upstream/gstreamer-vaapi.install.in
421     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
422 debian.upstream/libgstvaapi.install.in
423     debian.upstream/libgstvaapi-dev.install
424     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
425 debian.upstream/libgstvaapi-glx.install.in
426     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
427 debian.upstream/libgstvaapi-x11.install.in
428     docs/Makefile
429     docs/reference/Makefile
430     docs/reference/libs/Makefile
431     docs/reference/libs/libs-docs.xml
432     docs/reference/plugins/Makefile
433     docs/reference/plugins/plugins-docs.xml
434     gst-libs/Makefile
435     gst-libs/gst/Makefile
436     gst-libs/gst/codecparsers/Makefile
437     gst-libs/gst/vaapi/Makefile
438     gst/Makefile
439     gst/vaapi/Makefile
440     pkgconfig/Makefile
441     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
442 pkgconfig/gstreamer-vaapi.pc.in
443     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
444 pkgconfig/gstreamer-vaapi-glx.pc.in
445     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
446 pkgconfig/gstreamer-vaapi-x11.pc.in
447     tests/Makefile
448 ])
449 AC_OUTPUT
450
451 dnl Print summary
452 yesno() {
453     test $1 -eq 1 && echo yes || echo no
454 }
455
456 echo
457 echo $PACKAGE configuration summary:
458 echo
459 echo VA-API version ................... : $VA_VERSION_STR
460 echo GLX support ...................... : $(yesno $USE_GLX)
461 echo VA/X11 support ................... : $(yesno $USE_X11)
462 echo VA/GLX support ................... : $(yesno $HAVE_VA_GLX)
463 echo