tests: add test for JPEG decoding.
[vaapi:halleys-gstreamer-vaapi.git] / configure.ac
1 # gstreamer-vaapi package version number
2 m4_define([gst_vaapi_major_version], [0])
3 m4_define([gst_vaapi_minor_version], [3])
4 m4_define([gst_vaapi_micro_version], [8])
5 m4_define([gst_vaapi_pre_version],   [1])
6 m4_define([gst_vaapi_version],
7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
8 m4_if(gst_vaapi_pre_version, [0], [], [
9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
10 ])
11
12 # glib version number
13 m4_define([glib_major_version], [2])
14 m4_define([glib_minor_version], [5])
15 m4_define([glib_micro_version], [2])
16 m4_define([glib_major_minor_version],
17           [glib_major_version.glib_minor_version])
18 m4_define([glib_version],
19           [glib_major_version.glib_minor_version.glib_micro_version])
20
21 # gst version number
22 m4_define([gst_major_version], [0])
23 m4_define([gst_minor_version], [10])
24 m4_define([gst_micro_version], [14])
25 m4_define([gst_major_minor_version],
26           [gst_major_version.gst_minor_version])
27 m4_define([gst_version],
28           [gst_major_version.gst_minor_version.gst_micro_version])
29
30 # gst plugins-base version number
31 m4_define([gst_plugins_base_major_version], [0])
32 m4_define([gst_plugins_base_minor_version], [10])
33 m4_define([gst_plugins_base_micro_version], [31])
34 m4_define([gst_plugins_base_version],
35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
36
37 # VA-API minimum version number
38 m4_define([va_api_x11_version], [0.31.0])
39 m4_define([va_api_glx_version], [0.32.0])
40
41 # gst plugins-bad version number
42 m4_define([gst_plugins_bad_major_version], [0])
43 m4_define([gst_plugins_bad_minor_version], [10])
44 m4_define([gst_plugins_bad_micro_version], [22])
45 m4_define([gst_plugins_bad_version],
46           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
47
48 # libva package version number
49 m4_define([libva_x11_package_version], [1.0.3])
50 m4_define([libva_glx_package_version], [1.0.9])
51
52 # gtk-doc version number
53 # XXX: introspection annotations require gtk-doc >= 1.12
54 m4_define([gtkdoc_major_version], [1])
55 m4_define([gtkdoc_minor_version], [9])
56 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
57
58 AC_PREREQ([2.58])
59 AC_INIT([gst_vaapi], [gst_vaapi_version],
60     [gwenole.beauchesne@intel.com],
61     [gstreamer-vaapi])
62
63 AC_CONFIG_HEADERS([config.h])
64 AC_CONFIG_SRCDIR([Makefile.am])
65 AC_CONFIG_MACRO_DIR([m4])
66 AC_CONFIG_AUX_DIR([build-aux])
67
68 AC_CANONICAL_TARGET
69
70 AM_INIT_AUTOMAKE
71
72 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
73 AC_SUBST(TODAY)
74
75 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
76 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
77
78 LIBVA_PACKAGE_VERSION=libva_x11_package_version
79 AC_SUBST(LIBVA_PACKAGE_VERSION)
80
81 dnl Versions for GStreamer and plugins-base
82 GST_MAJORMINOR=gst_major_minor_version
83 GST_VERSION_REQUIRED=gst_version
84 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
85 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
86 AC_SUBST(GST_MAJORMINOR)
87 AC_SUBST(GST_VERSION_REQUIRED)
88 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
89
90 dnl Use pretty build output with automake >= 1.11
91 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
92   AM_DEFAULT_VERBOSITY=1
93   AC_SUBST(AM_DEFAULT_VERBOSITY)
94 ])
95
96 dnl Check for tools
97 AC_PROG_CC
98 AM_PROG_CC_C_O
99 AC_PROG_LIBTOOL
100
101 AC_ARG_ENABLE(glx,
102     AS_HELP_STRING([--enable-glx],
103                    [enable OpenGL/X11 @<:@default=yes@:>@]),
104     [], [enable_glx="yes"])
105
106 AC_ARG_ENABLE(vaapi-glx,
107     AS_HELP_STRING([--enable-vaapi-glx],
108                    [enable VA/GLX extensions @<:@default=yes@:>@]),
109     [], [enable_vaapi_glx="yes"])
110
111 AC_ARG_ENABLE(vaapisink-glx,
112     AS_HELP_STRING([--enable-vaapisink-glx],
113                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
114     [], [enable_vaapisink_glx="no"])
115
116 AC_ARG_ENABLE(ffmpeg,
117     AS_HELP_STRING([--enable-ffmpeg],
118                    [enable bitstream parsing from FFmpeg @<:@default=no@:>@]),
119     [], [enable_ffmpeg="no"])
120
121 AC_ARG_ENABLE(codecparsers,
122     AS_HELP_STRING([--enable-codecparsers],
123                    [enable adhoc bitstream parsers from GStreamer @<:@default=yes@:>@]),
124     [], [enable_codecparsers="yes"])
125
126 dnl Check for basic libraries
127 AC_CHECK_LIB(m, tan)
128
129 dnl Check for Gtk doc
130 GTKDOC_VERSION=gtkdoc_version
131 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
132 m4_ifdef([GTK_DOC_CHECK], [
133 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
134 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
135 AC_SUBST(GTKDOC_VERSION)
136
137 dnl Check for GLib
138 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= glib_version])
139
140 dnl Check for GStreamer
141 PKG_CHECK_MODULES([GST],
142     [gstreamer-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
143 )
144
145 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
146     saved_CFLAGS="$CFLAGS"
147     CFLAGS="$CFLAGS $GST_CFLAGS"
148     saved_LIBS="$LIBS"
149     LIBS="$LIBS $GST_LIBS"
150     AC_COMPILE_IFELSE(
151         [AC_LANG_PROGRAM(
152             [[#include <gst/base/gstbasesink.h>]],
153             [[GstBaseSinkClass klass; klass.query = NULL;]])],
154         [ac_cv_have_gst_base_sink_query="yes"],
155         [ac_cv_have_gst_base_sink_query="no"]
156     )
157     CFLAGS="$saved_CFLAGS"
158     LIBS="$saved_LIBS"
159 ])
160 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
161     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
162 fi
163
164 dnl Check for GStreamer plugins-base
165 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
166     [gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
167 )
168
169 V=`$PKG_CONFIG --modversion gstreamer-plugins-base-$GST_MAJORMINOR`
170 GST_PLUGINS_BASE_MAJOR_VERSION=`echo "$V" | cut -d'.' -f1`
171 GST_PLUGINS_BASE_MINOR_VERSION=`echo "$V" | cut -d'.' -f2`
172 GST_PLUGINS_BASE_MICRO_VERSION=`echo "$V" | cut -d'.' -f3`
173 AC_SUBST(GST_PLUGINS_BASE_MAJOR_VERSION)
174 AC_SUBST(GST_PLUGINS_BASE_MINOR_VERSION)
175 AC_SUBST(GST_PLUGINS_BASE_MICRO_VERSION)
176
177 dnl Check for GStreamer base
178 PKG_CHECK_MODULES([GST_BASE],
179     [gstreamer-base-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
180 )
181
182 dnl Check for GStreamer video
183 PKG_CHECK_MODULES([GST_VIDEO],
184     [gstreamer-video-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
185 )
186
187 AC_CACHE_CHECK([for GstVideoOverlayComposition],
188     ac_cv_have_gst_video_overlay_composition, [
189     saved_CFLAGS="$CFLAGS"
190     CFLAGS="$CFLAGS $GST_CFLAGS"
191     saved_LIBS="$LIBS"
192     LIBS="$LIBS $GST_LIBS"
193     AC_COMPILE_IFELSE(
194         [AC_LANG_PROGRAM(
195             [[#include <gst/video/video-overlay-composition.h>]],
196             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
197         [ac_cv_have_gst_video_overlay_composition="yes"],
198         [ac_cv_have_gst_video_overlay_composition="no"]
199     )
200     CFLAGS="$saved_CFLAGS"
201     LIBS="$saved_LIBS"
202 ])
203 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
204     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
205 fi
206
207 dnl Check for GStreamer basevideo
208 PKG_CHECK_MODULES([GST_BASEVIDEO],
209     [gstreamer-basevideo-$GST_MAJORMINOR >= $GST_PLUGINS_BAD_VERSION_REQUIRED]
210 )
211
212 dnl Check for GStreamer codec parsers
213 USE_CODEC_PARSERS=0
214 if test "$enable_codecparsers" = "yes"; then
215 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
216     [gstreamer-codecparsers-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED],
217     [enable_codecparsers="yes" USE_CODEC_PARSERS=1],
218     [enable_codecparsers="no"  USE_CODEC_PARSERS=0]
219 )
220 fi
221
222 AC_DEFINE_UNQUOTED(USE_CODEC_PARSERS, $USE_CODEC_PARSERS,
223     [Defined to 1 if GStreamer codec parsers are used])
224 AM_CONDITIONAL(USE_CODEC_PARSERS, test $USE_CODEC_PARSERS -eq 1)
225
226 USE_LOCAL_CODEC_PARSERS=0
227 if test "$enable_codecparsers" = "yes"; then
228 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
229     ac_cv_have_gst_h264_slice_hdr_epb_count, [
230     saved_CFLAGS="$CFLAGS"
231     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
232     saved_LIBS="$LIBS"
233     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
234     AC_COMPILE_IFELSE(
235         [AC_LANG_PROGRAM(
236             [[#include <gst/codecparsers/gsth264parser.h>]],
237             [[GstH264SliceHdr slice_hdr;
238               slice_hdr.n_emulation_prevention_bytes = 0;]])],
239         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
240         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
241     )
242     CFLAGS="$saved_CFLAGS"
243     LIBS="$saved_LIBS"
244 ])
245
246 AC_CACHE_CHECK([for JPEG parser],
247     ac_cv_have_gst_jpeg_parser, [
248     saved_CFLAGS="$CFLAGS"
249     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
250     saved_LIBS="$LIBS"
251     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
252     AC_TRY_COMPILE(
253         [#include <gst/codecparsers/gstjpegparser.h>],
254         [GstJpegImage jpeg_image;],
255         [ac_cv_have_gst_jpeg_parser="yes"],
256         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
257     )
258     CFLAGS="$saved_CFLAGS"
259     LIBS="$saved_LIBS"
260 ])
261 fi
262
263 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
264     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
265         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
266 fi
267
268 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
269     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
270         [Defined to 1 if JPEG parser exists.])
271 fi
272 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
273
274 dnl Check for GStreamer interfaces
275 PKG_CHECK_MODULES([GST_INTERFACES],
276     [gstreamer-interfaces-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
277 )
278
279 dnl GST_ALL_LDFLAGS:
280 dnl LDFLAGS really should only contain flags, not libs - they get added before
281 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
282 GST_ALL_LDFLAGS="-no-undefined"
283 AC_SUBST(GST_ALL_LDFLAGS)
284
285 dnl GST_PLUGIN_LDFLAGS:
286 dnl this really should only contain flags, not libs - they get added before
287 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
288 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
289 AC_SUBST(GST_PLUGIN_LDFLAGS)
290
291 dnl Check for the GStreamer plugins directory
292 AC_MSG_CHECKING([for GStreamer plugins directory])
293 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
294 if test -z "$GST_PLUGINS_DIR"; then
295     echo "FAIL FAIL FAIL"
296     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
297 fi
298 AC_MSG_RESULT([$GST_PLUGINS_DIR])
299 plugindir="$GST_PLUGINS_DIR"
300 AC_SUBST(plugindir)
301
302 dnl Check for X11
303 PKG_CHECK_MODULES(X11, [x11])
304
305 dnl Check for OpenGL
306 USE_GLX=1
307 if test "$enable_glx" != "yes"; then
308     USE_GLX=0
309 fi
310 GLX_CFLAGS=""
311 GLX_LIBS=""
312 AC_CHECK_HEADERS([GL/gl.h GL/glext.h GL/glx.h], [], [USE_GLX=0], [
313 #ifdef HAVE_GL_GL_H
314 # include <GL/gl.h>
315 #endif
316 ])
317 AC_CHECK_LIB(GL, glXCreateContext, [GLX_LIBS="-lGL"], [USE_GLX=0])
318 AC_SUBST(GLX_CFLAGS)
319 AC_SUBST(GLX_LIBS)
320
321 dnl Check for VA-API
322 LIBVA_PKGNAME="libva"
323 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME])
324 AC_SUBST(LIBVA_PKGNAME)
325
326 dnl ... original VA-API 0.29
327 AC_CACHE_CHECK([for old VA-API 0.29],
328     ac_cv_have_vaapi_old, [
329     saved_CFLAGS="$CFLAGS"
330     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
331     saved_LIBS="$LIBS"
332     LIBS="$LIBS $LIBVA_LIBS"
333     AC_LINK_IFELSE(
334         [AC_LANG_PROGRAM(
335             [[#include <va_x11.h>]],
336             [[vaGetDisplay(NULL)]])],
337         [ac_cv_have_vaapi_old="yes"],
338         [ac_cv_have_vaapi_old="no"]
339     )
340     CFLAGS="$saved_CFLAGS"
341     LIBS="$saved_LIBS"
342 ])
343 if test "$ac_cv_have_vaapi_old" = "yes"; then
344     LIBVA_EXTRA_CFLAGS="$LIBVA_CFLAGS -DGST_VAAPI_USE_OLD_VAAPI_0_29"
345 fi
346
347 dnl ... VA-API >= 0.31 or -sds
348 LIBVA_X11_PKGNAME="libva-x11"
349 PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME],
350     [ac_cv_have_vaapi_x11="yes"],
351     [ac_cv_have_vaapi_x11="no"]
352 )
353 if test "$ac_cv_have_vaapi_x11" = "no"; then
354     if test "$ac_cv_have_vaapi_old" = "yes"; then
355         LIBVA_X11_PKGNAME="libva"
356         CFLAGS="$CFLAGS $LIBVA_EXTRA_CFLAGS"
357         LIBS="$LIBS $LIBVA_EXTRA_LIBS"
358     else
359         AC_MSG_ERROR([could not find VA-API])
360     fi
361 fi
362 AC_SUBST(LIBVA_X11_PKGNAME)
363
364 dnl ... VA-API >= 0.31 or -sds (VA/GLX extensions)
365 USE_VAAPI_GLX=0
366 if test $USE_GLX -eq 1; then
367     if test "$enable_vaapi_glx" = "yes"; then
368         LIBVA_GLX_PKGNAME="libva-glx"
369         PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME],
370             [ac_cv_have_vaapi_glx="yes" USE_VAAPI_GLX=1],
371             [ac_cv_have_vaapi_glx="no"]
372         )
373     fi
374     if test $USE_VAAPI_GLX -eq 0; then
375         AC_MSG_WARN([VA/GLX not found or disabled. Fallbacking to TFP+FBO])
376         LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"
377     fi
378 fi
379 AC_SUBST(LIBVA_GLX_PKGNAME)
380
381 AC_SUBST(LIBVA_EXTRA_CFLAGS)
382 AC_SUBST(LIBVA_EXTRA_LIBS)
383
384 dnl Check for JPEG decoding API (0.32.1+)
385 USE_JPEG_DECODER=0
386 if test "$enable_codecparsers" = "yes"; then
387 AC_CACHE_CHECK([for JPEG decoding API],
388     ac_cv_have_jpeg_decoding_api, [
389     saved_CFLAGS="$CFLAGS"
390     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
391     saved_LIBS="$LIBS"
392     LIBS="$CFLAGS $LIBVA_LIBS"
393     AC_COMPILE_IFELSE(
394         [AC_LANG_PROGRAM(
395             [[#include <va/va.h>]],
396             [[VAPictureParameterBufferJPEGBaseline pic_param;
397               VASliceParameterBufferJPEGBaseline slice_param;
398               VAHuffmanTableBufferJPEGBaseline huffman_table;
399               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
400         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
401         [ac_cv_have_jpeg_decoding_api="no"]
402     )
403     CFLAGS="$saved_CFLAGS"
404     LIBS="$saved_LIBS"
405 ])
406 fi
407
408 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
409     [Defined to 1 if JPEG decoder is used])
410 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
411
412 dnl Check for OpenGL support to vaapisink
413 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
414     USE_VAAPISINK_GLX=1
415 else
416     USE_VAAPISINK_GLX=0
417 fi
418
419 dnl Check for FFmpeg
420 USE_FFMPEG=0
421 if test "$enable_ffmpeg" = "yes"; then
422 PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec],
423     [enable_ffmpeg="yes" USE_FFMPEG=1],
424     [enable_ffmpeg="no"  USE_FFMPEG=0]
425 )
426 fi
427 if test "$enable_ffmpeg" = "yes"; then
428 AC_CHECK_HEADERS([libavcodec/avcodec.h ffmpeg/avcodec.h])
429 AC_CHECK_HEADERS([libavcodec/vaapi.h ffmpeg/vaapi.h],
430     [break],
431     [enable_ffmpeg="no"  USE_FFMPEG=0]
432 )
433 fi
434
435 if test "$enable_ffmpeg:$enable_codecparsers" = "no:no"; then
436     AC_MSG_ERROR([Found neither suitable FFmpeg with VA-API support nor GStreamer bitstream parsers])
437 fi
438
439 AC_DEFINE_UNQUOTED(USE_FFMPEG, $USE_FFMPEG,
440     [Defined to 1 if FFmpeg is used])
441 AM_CONDITIONAL(USE_FFMPEG, test $USE_FFMPEG -eq 1)
442
443 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
444     [Defined to 1 if GLX is enabled])
445 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
446
447 AC_DEFINE_UNQUOTED(USE_VAAPI_GLX, $USE_VAAPI_GLX,
448     [Defined to 1 if VA/GLX is enabled])
449 AM_CONDITIONAL(USE_VAAPI_GLX, test $USE_VAAPI_GLX -eq 1)
450
451 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
452     [Defined to 1 to enable GLX support to vaapisink])
453 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
454
455 VA_VERSION=`$PKG_CONFIG --modversion libva`
456 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
457 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
458 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
459 VA_VERSION_STR="$VA_VERSION"
460
461 pkgconfigdir=${libdir}/pkgconfig
462 AC_SUBST(pkgconfigdir)
463
464 AC_CONFIG_FILES([
465     Makefile
466     debian.upstream/Makefile
467     debian.upstream/changelog
468     debian.upstream/control
469     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
470 debian.upstream/gstreamer-vaapi.install.in
471     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
472 debian.upstream/gstreamer-vaapi-doc.install.in
473     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
474 debian.upstream/libgstvaapi.install.in
475     debian.upstream/libgstvaapi-dev.install
476     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
477 debian.upstream/libgstvaapi-x11.install.in
478     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
479 debian.upstream/libgstvaapi-glx.install.in
480     docs/Makefile
481     docs/reference/Makefile
482     docs/reference/libs/Makefile
483     docs/reference/libs/libs-docs.xml
484     docs/reference/plugins/Makefile
485     docs/reference/plugins/plugins-docs.xml
486     gst-libs/Makefile
487     gst-libs/gst/Makefile
488     gst-libs/gst/gstutils_version.h
489     gst-libs/gst/codecparsers/Makefile
490     gst-libs/gst/vaapi/Makefile
491     pkgconfig/Makefile
492     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
493 pkgconfig/gstreamer-vaapi.pc.in
494     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
495 pkgconfig/gstreamer-vaapi-glx.pc.in
496     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
497 pkgconfig/gstreamer-vaapi-x11.pc.in
498     gst/Makefile
499     gst/vaapi/Makefile
500     tests/Makefile
501 ])
502 AC_OUTPUT
503
504 dnl Print summary
505 yesno() {
506     test $1 -eq 1 && echo yes || echo no
507 }
508
509 echo
510 echo $PACKAGE configuration summary:
511 echo
512 echo VA-API version ................... : $VA_VERSION_STR
513 echo GLX support ...................... : $(yesno $USE_GLX)
514 echo VA/GLX support ................... : $(yesno $USE_VAAPI_GLX)
515 echo VaapiSink/GL ..................... : $(yesno $USE_VAAPISINK_GLX)
516 echo FFmpeg bitstream parsers ......... : $(yesno $USE_FFMPEG)
517 echo GStreamer bitstream parsers ...... : $(yesno $USE_CODEC_PARSERS)
518 echo