mpeg2: fix PAR calculation from commit 132922d.
[vaapi:gstreamer-vaapi.git] / configure.ac
1 # gstreamer-vaapi package version number
2 m4_define([gst_vaapi_major_version], [0])
3 m4_define([gst_vaapi_minor_version], [4])
4 m4_define([gst_vaapi_micro_version], [1])
5 m4_define([gst_vaapi_pre_version],   [1])
6 m4_define([gst_vaapi_version],
7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
8 m4_if(gst_vaapi_pre_version, [0], [], [
9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
10 ])
11
12 # glib version number
13 m4_define([glib_major_version], [2])
14 m4_define([glib_minor_version], [28])
15 m4_define([glib_micro_version], [0])
16 m4_define([glib_major_minor_version],
17           [glib_major_version.glib_minor_version])
18 m4_define([glib_version],
19           [glib_major_version.glib_minor_version.glib_micro_version])
20
21 # gst version number
22 m4_define([gst_major_version], [0])
23 m4_define([gst_minor_version], [10])
24 m4_define([gst_micro_version], [36])
25 m4_define([gst_major_minor_version],
26           [gst_major_version.gst_minor_version])
27 m4_define([gst_version],
28           [gst_major_version.gst_minor_version.gst_micro_version])
29
30 # gst plugins-base version number
31 m4_define([gst_plugins_base_major_version], [0])
32 m4_define([gst_plugins_base_minor_version], [10])
33 m4_define([gst_plugins_base_micro_version], [31])
34 m4_define([gst_plugins_base_version],
35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
36
37 # gst plugins-bad version number
38 m4_define([gst_plugins_bad_major_version], [0])
39 m4_define([gst_plugins_bad_minor_version], [10])
40 m4_define([gst_plugins_bad_micro_version], [22])
41 m4_define([gst_plugins_bad_version],
42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
43
44 # Wayland minimum version number
45 m4_define([wayland_api_version], [0.95.0])
46
47 # VA-API minimum version number
48 m4_define([va_api_version],     [0.30.4])
49 m4_define([va_api_drm_version], [0.33.0])
50 m4_define([va_api_x11_version], [0.31.0])
51 m4_define([va_api_glx_version], [0.32.0])
52 m4_define([va_api_wld_version], [0.33.0])
53
54 # libva package version number
55 m4_define([libva_drm_package_version], [1.1.0])
56 m4_define([libva_x11_package_version], [1.0.3])
57 m4_define([libva_glx_package_version], [1.0.9])
58 m4_define([libva_wld_package_version], [1.1.0])
59
60 # gtk-doc version number
61 # XXX: introspection annotations require gtk-doc >= 1.12
62 m4_define([gtkdoc_major_version], [1])
63 m4_define([gtkdoc_minor_version], [9])
64 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
65
66 AC_PREREQ([2.58])
67 AC_INIT([gst_vaapi], [gst_vaapi_version],
68     [gwenole.beauchesne@intel.com],
69     [gstreamer-vaapi])
70
71 AC_CONFIG_HEADERS([config.h])
72 AC_CONFIG_SRCDIR([Makefile.am])
73 AC_CONFIG_MACRO_DIR([m4])
74 AC_CONFIG_AUX_DIR([build-aux])
75
76 AC_CANONICAL_TARGET
77
78 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
79
80 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
81 AC_SUBST(TODAY)
82
83 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
84 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
85
86 LIBVA_PACKAGE_VERSION=libva_x11_package_version
87 AC_SUBST(LIBVA_PACKAGE_VERSION)
88
89 WAYLAND_API_VERSION=wayland_api_version
90 AC_SUBST(WAYLAND_API_VERSION)
91
92 dnl Versions for GStreamer and plugins-base
93 GST_MAJORMINOR=gst_major_minor_version
94 GST_VERSION_REQUIRED=gst_version
95 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
96 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
97 AC_SUBST(GST_MAJORMINOR)
98 AC_SUBST(GST_VERSION_REQUIRED)
99 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
100 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
101
102 dnl Use pretty build output with automake >= 1.11
103 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
104   AM_DEFAULT_VERBOSITY=1
105   AC_SUBST(AM_DEFAULT_VERBOSITY)
106 ])
107
108 dnl Check for tools
109 AC_PROG_CC
110 AM_PROG_CC_C_O
111
112 dnl Initialize libtool
113 LT_PREREQ([2.2])
114 LT_INIT
115
116 AC_ARG_ENABLE(drm,
117     AS_HELP_STRING([--enable-drm],
118                    [enable DRM backend @<:@default=yes@:>@]),
119     [], [enable_drm="yes"])
120
121 AC_ARG_ENABLE(x11,
122     AS_HELP_STRING([--enable-x11],
123                    [enable X11 output @<:@default=yes@:>@]),
124     [], [enable_x11="yes"])
125
126 AC_ARG_ENABLE(glx,
127     AS_HELP_STRING([--enable-glx],
128                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
129     [], [enable_glx="yes"])
130
131 AC_ARG_ENABLE(wayland,
132     AC_HELP_STRING([--enable-wayland],
133                    [enable Wayland output @<:@default=yes@:>@]),
134     [], [enable_wayland="yes"])
135
136 dnl Check for basic libraries
137 AC_CHECK_LIB(m, tan)
138
139 dnl Check for Gtk doc
140 GTKDOC_VERSION=gtkdoc_version
141 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
142 m4_ifdef([GTK_DOC_CHECK], [
143 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
144 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
145 AC_SUBST(GTKDOC_VERSION)
146
147 dnl Check for GLib
148 GLIB_VERSION_REQUIRED=glib_version
149 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
150 AC_SUBST(GLIB_VERSION_REQUIRED)
151
152 dnl ---------------------------------------------------------------------------
153 dnl -- GStreamer                                                             --
154 dnl ---------------------------------------------------------------------------
155
156 dnl GStreamer Core
157 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
158 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
159
160 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
161     saved_CFLAGS="$CFLAGS"
162     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
163     saved_LIBS="$LIBS"
164     LIBS="$LIBS $GST_BASE_LIBS"
165     AC_COMPILE_IFELSE(
166         [AC_LANG_PROGRAM(
167             [[#include <gst/base/gstbasesink.h>]],
168             [[GstBaseSinkClass klass; klass.query = NULL;]])],
169         [ac_cv_have_gst_base_sink_query="yes"],
170         [ac_cv_have_gst_base_sink_query="no"]
171     )
172     CFLAGS="$saved_CFLAGS"
173     LIBS="$saved_LIBS"
174 ])
175 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
176     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
177 fi
178
179 dnl GStreamer -base plugins
180 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
181     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
182 PKG_CHECK_MODULES([GST_INTERFACES],
183     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
184
185 dnl ... GstVideoOverlayComposition (gstreamer-video)
186 PKG_CHECK_MODULES([GST_VIDEO],
187     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
188
189 AC_CACHE_CHECK([for GstVideoOverlayComposition],
190     ac_cv_have_gst_video_overlay_composition, [
191     saved_CFLAGS="$CFLAGS"
192     CFLAGS="$CFLAGS $GST_CFLAGS"
193     saved_LIBS="$LIBS"
194     LIBS="$LIBS $GST_LIBS"
195     AC_COMPILE_IFELSE(
196         [AC_LANG_PROGRAM(
197             [[#include <gst/video/video-overlay-composition.h>]],
198             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
199         [ac_cv_have_gst_video_overlay_composition="yes"],
200         [ac_cv_have_gst_video_overlay_composition="no"]
201     )
202     CFLAGS="$saved_CFLAGS"
203     LIBS="$saved_LIBS"
204 ])
205 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
206     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
207 fi
208
209 dnl GStreamer -bad plugins
210 PKG_CHECK_MODULES([GST_BASEVIDEO],
211     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
212
213 dnl ... bitstream parsers
214 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
215     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
216
217 dnl ... MPEG-2 parser, with the required extensions
218 AC_CACHE_CHECK([for MPEG-2 parser],
219     ac_cv_have_gst_mpeg2_parser, [
220     saved_CPPFLAGS="$CPPFLAGS"
221     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
222     saved_LIBS="$LIBS"
223     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
224     AC_COMPILE_IFELSE(
225         [AC_LANG_PROGRAM(
226             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
227             [[GstMpegVideoSequenceHdr seq_hdr;
228               GstMpegVideoSequenceExt seq_ext;
229               GstMpegVideoSequenceDisplayExt seq_dpy;
230               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
231                   &seq_ext, &seq_dpy);]])],
232         [ac_cv_have_gst_mpeg2_parser="yes"],
233         [ac_cv_have_gst_mpeg2_parser="no"]
234     )
235     CPPFLAGS="$saved_CPPFLAGS"
236     LIBS="$saved_LIBS"
237 ])
238 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
239     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
240
241 dnl ... H.264 parser, with the required extensions
242 AC_CACHE_CHECK([for H.264 parser],
243     ac_cv_have_gst_h264_parser, [
244     saved_CPPFLAGS="$CPPFLAGS"
245     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
246     saved_LIBS="$LIBS"
247     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
248     AC_COMPILE_IFELSE(
249         [AC_LANG_PROGRAM(
250             [[#include <gst/codecparsers/gsth264parser.h>]],
251             [[GstH264SliceHdr slice_hdr;
252               GstH264VUIParams vui_params;
253               slice_hdr.n_emulation_prevention_bytes = 0;
254               vui_params.par_n = 0;
255               vui_params.par_d = 0;]])],
256         [ac_cv_have_gst_h264_parser="yes"],
257         [ac_cv_have_gst_h264_parser="no"]
258     )
259     CPPFLAGS="$saved_CPPFLAGS"
260     LIBS="$saved_LIBS"
261 ])
262 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
263     [test "$ac_cv_have_gst_h264_parser" != "yes"])
264
265 dnl ... JPEG parser, not upstream yet
266 AC_CACHE_CHECK([for JPEG parser],
267     ac_cv_have_gst_jpeg_parser, [
268     saved_CPPFLAGS="$CPPFLAGS"
269     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
270     saved_LIBS="$LIBS"
271     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
272     AC_COMPILE_IFELSE(
273         [AC_LANG_PROGRAM(
274             [[#include <gst/codecparsers/gstjpegparser.h>]],
275             [[GstJpegImage jpeg_image;]])],
276         [ac_cv_have_gst_jpeg_parser="yes"],
277         [ac_cv_have_gst_jpeg_parser="no"]
278     )
279     CPPFLAGS="$saved_CPPFLAGS"
280     LIBS="$saved_LIBS"
281 ])
282 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
283     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
284
285 dnl GST_ALL_LDFLAGS:
286 dnl LDFLAGS really should only contain flags, not libs - they get added before
287 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
288 GST_ALL_LDFLAGS="-no-undefined"
289 AC_SUBST(GST_ALL_LDFLAGS)
290
291 dnl GST_PLUGIN_LDFLAGS:
292 dnl this really should only contain flags, not libs - they get added before
293 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
294 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
295 AC_SUBST(GST_PLUGIN_LDFLAGS)
296
297 dnl Check for the GStreamer plugins directory
298 AC_MSG_CHECKING([for GStreamer plugins directory])
299 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
300 if test -z "$GST_PLUGINS_DIR"; then
301     echo "FAIL FAIL FAIL"
302     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
303 fi
304 AC_MSG_RESULT([$GST_PLUGINS_DIR])
305 plugindir="$GST_PLUGINS_DIR"
306 AC_SUBST(plugindir)
307
308 dnl ---------------------------------------------------------------------------
309 dnl -- Renderers                                                             --
310 dnl ---------------------------------------------------------------------------
311
312 dnl Check for DRM/libudev
313 USE_DRM=0
314 if test "$enable_drm" = "yes"; then
315     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
316     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
317
318     if test $USE_DRM -eq 1; then
319         saved_CPPFLAGS="$CPPFLAGS"
320         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
321         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
322         CPPFLAGS="$saved_CPPFLAGS"
323     fi
324 fi
325
326 dnl Check for X11
327 USE_X11=0
328 if test "$enable_x11" = "yes"; then
329     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
330     if test $USE_X11 -eq 1; then
331         saved_CPPFLAGS="$CPPFLAGS"
332         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
333         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
334         CPPFLAGS="$saved_CPPFLAGS"
335     fi
336 fi
337
338 dnl Check for XRandR
339 HAVE_XRANDR=0
340 if test $USE_X11 -eq 1; then
341     HAVE_XRANDR=1
342     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
343     if test $HAVE_XRANDR -eq 1; then
344         saved_CPPFLAGS="$CPPFLAGS"
345         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
346         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
347         CPPFLAGS="$saved_CPPFLAGS"
348     fi
349 fi
350 if test $HAVE_XRANDR -eq 1; then
351     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
352         [Defined to 1 if the XRandR extension exists.])
353 fi
354
355 dnl OpenGL
356 enable_opengl="no"
357 if test "$enable_glx" = "yes"; then
358     enable_opengl="yes"
359 fi
360
361 HAVE_GL=0
362 if test "$enable_opengl" = "yes"; then
363     HAVE_GL=1
364     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
365     saved_CPPFLAGS="$CPPFLAGS"
366     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
367     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
368 #ifdef HAVE_GL_GL_H
369 # include <GL/gl.h>
370 #endif
371     ])
372     CPPFLAGS="$saved_CPPFLAGS"
373 fi
374
375 dnl ... GLX
376 USE_GLX=0
377 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
378     USE_GLX=1
379     saved_CPPFLAGS="$CPPFLAGS"
380     saved_LIBS="$LIBS"
381     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
382     LIBS="$LIBS $GL_LIBS"
383     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
384 #ifdef HAVE_GL_GL_H
385 # include <GL/gl.h>
386 #endif
387     ])
388     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
389     CPPFLAGS="$saved_CPPFLAGS"
390     LIBS="$saved_LIBS"
391 fi
392
393 dnl Check for Wayland
394 USE_WAYLAND=0
395 if test "$enable_wayland" = "yes"; then
396     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
397         [USE_WAYLAND=1], [USE_WAYLAND=0])
398
399     if test $USE_WAYLAND -eq 1; then
400         saved_CPPFLAGS="$CPPFLAGS"
401         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
402         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
403         CPPFLAGS="$saved_CPPFLAGS"
404     fi
405 fi
406
407 dnl ---------------------------------------------------------------------------
408 dnl -- VA-API                                                                --
409 dnl ---------------------------------------------------------------------------
410
411 dnl Core API
412 LIBVA_PKGNAME="libva"
413 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
414 AC_SUBST(LIBVA_PKGNAME)
415
416 VA_VERSION=`$PKG_CONFIG --modversion libva`
417 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
418 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
419 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
420 VA_VERSION_STR="$VA_VERSION"
421
422 dnl VA/DRM API
423 HAVE_VA_DRM=0
424 if test $USE_DRM -eq 1; then
425     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
426         [HAVE_VA_DRM=1], [USE_DRM=0])
427
428     if test $HAVE_VA_DRM -eq 1; then
429         saved_CPPFLAGS="$CPPFLAGS"
430         CPPFLAGS="$LIBVA_DRM_CFLAGS"
431         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
432         CPPFLAGS="$saved_CPPFLAGS"
433     fi
434 fi
435
436 dnl VA/X11 API
437 HAVE_VA_X11=0
438 LIBVA_X11_PKGNAME="libva-x11"
439 if test $USE_X11 -eq 1; then
440     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
441         [HAVE_VA_X11=1], [USE_X11=0])
442 fi
443 AC_SUBST(LIBVA_X11_PKGNAME)
444
445 dnl VA/GLX API
446 HAVE_VA_GLX=0
447 LIBVA_GLX_PKGNAME="libva-glx"
448 if test $USE_GLX -eq 1; then
449     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
450         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
451
452     if test $HAVE_VA_GLX -eq 1; then
453         saved_CPPFLAGS="$CPPFLAGS"
454         CPPFLAGS="$LIBVA_GLX_CFLAGS"
455         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
456         CPPFLAGS="$saved_CPPFLAGS"
457     fi
458 fi
459 AC_SUBST(LIBVA_GLX_PKGNAME)
460
461 dnl Check for JPEG decoding API (0.32.1+)
462 USE_JPEG_DECODER=0
463 AC_CACHE_CHECK([for JPEG decoding API],
464     ac_cv_have_jpeg_decoding_api, [
465     saved_CFLAGS="$CFLAGS"
466     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
467     saved_LIBS="$LIBS"
468     LIBS="$CFLAGS $LIBVA_LIBS"
469     AC_COMPILE_IFELSE(
470         [AC_LANG_PROGRAM(
471             [[#include <va/va.h>]],
472             [[VAPictureParameterBufferJPEGBaseline pic_param;
473               VASliceParameterBufferJPEGBaseline slice_param;
474               VAHuffmanTableBufferJPEGBaseline huffman_table;
475               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
476         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
477         [ac_cv_have_jpeg_decoding_api="no"]
478     )
479     CFLAGS="$saved_CFLAGS"
480     LIBS="$saved_LIBS"
481 ])
482
483 dnl VA/Wayland API
484 if test "$enable_wayland" = "yes"; then
485     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
486         [:], [USE_WAYLAND=0])
487 fi
488
489 dnl ---------------------------------------------------------------------------
490 dnl -- Generate files and summary                                            --
491 dnl ---------------------------------------------------------------------------
492
493 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
494 *:1:*)
495     ;;
496 *)
497     AC_MSG_ERROR([No renderer is enabled])
498     ;;
499 esac
500
501 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
502     [Defined to 1 if JPEG decoder is used])
503 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
504
505 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
506     [Defined to 1 if DRM is enabled])
507 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
508
509 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
510     [Defined to 1 if X11 is enabled])
511 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
512
513 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
514     [Defined to 1 if GLX is enabled])
515 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
516
517 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
518     [Defined to 1 if WAYLAND is enabled])
519 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
520
521 pkgconfigdir=${libdir}/pkgconfig
522 AC_SUBST(pkgconfigdir)
523
524 AC_CONFIG_FILES([
525     Makefile
526     debian.upstream/Makefile
527     debian.upstream/changelog
528     debian.upstream/control
529     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
530 debian.upstream/gstreamer-vaapi-doc.install.in
531     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
532 debian.upstream/gstreamer-vaapi.install.in
533     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
534 debian.upstream/libgstvaapi.install.in
535     debian.upstream/libgstvaapi-dev.install
536     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
537 debian.upstream/libgstvaapi-drm.install.in
538     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
539 debian.upstream/libgstvaapi-glx.install.in
540     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
541 debian.upstream/libgstvaapi-wayland.install.in
542     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
543 debian.upstream/libgstvaapi-x11.install.in
544     docs/Makefile
545     docs/reference/Makefile
546     docs/reference/libs/Makefile
547     docs/reference/libs/libs-docs.xml
548     docs/reference/plugins/Makefile
549     docs/reference/plugins/plugins-docs.xml
550     ext/Makefile
551     gst-libs/Makefile
552     gst-libs/gst/Makefile
553     gst-libs/gst/codecparsers/Makefile
554     gst-libs/gst/vaapi/Makefile
555     gst/Makefile
556     gst/vaapi/Makefile
557     pkgconfig/Makefile
558     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
559 pkgconfig/gstreamer-vaapi.pc.in
560     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
561 pkgconfig/gstreamer-vaapi-drm.pc.in
562     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
563 pkgconfig/gstreamer-vaapi-glx.pc.in
564     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
565 pkgconfig/gstreamer-vaapi-wayland.pc.in
566     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
567 pkgconfig/gstreamer-vaapi-x11.pc.in
568     tests/Makefile
569 ])
570 AC_OUTPUT
571
572 dnl Print summary
573 yesno() {
574     test $1 -eq 1 && echo yes || echo no
575 }
576
577 VIDEO_OUTPUTS=""
578 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
579 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
580 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
581 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
582
583 echo
584 echo $PACKAGE configuration summary:
585 echo
586 echo VA-API version ................... : $VA_VERSION_STR
587 echo Video outputs .................... : $VIDEO_OUTPUTS
588 echo