Removing QtCreator <2.4 .pro file workarounds
[sowatch:sowatch.git] / metawatch / metawatch.pro
1 TARGET = metawatchdriver
2 TEMPLATE = lib
3 CONFIG   += plugin
4 QT       += gui
5
6 # Qt Mobility 1.2
7 maemo5 {
8         CONFIG += mobility12
9 } else {
10         CONFIG += mobility
11 }
12 MOBILITY += connectivity systeminfo
13
14 SOURCES += metawatchplugin.cpp \
15     metawatchsimulatorform.cpp \
16     metawatchsimulator.cpp \
17     metawatchpaintengine.cpp \
18     metawatch.cpp \
19     metawatchdigital.cpp \
20     metawatchanalog.cpp
21
22 HEADERS += metawatchplugin.h \
23     metawatchsimulatorform.h \
24     metawatchsimulator.h \
25     metawatchpaintengine.h \
26     metawatch.h \
27     metawatchdigital.h \
28     metawatchanalog.h
29
30 FORMS += \
31         metawatchsimulatorform.ui
32
33 res_files.files += res/graphics res/fonts
34 qml_files.files += qml/com
35
36 win32:CONFIG(release, debug|release): LIBS += -L$$OUT_PWD/../libsowatch/release/ -lsowatch
37 else:win32:CONFIG(debug, debug|release): LIBS += -L$$OUT_PWD/../libsowatch/debug/ -lsowatch
38 else:symbian: LIBS += -lsowatch
39 else:unix: LIBS += -L$$OUT_PWD/../libsowatch/ -lsowatch
40
41 INCLUDEPATH += $$PWD/../libsowatch
42 DEPENDPATH += $$PWD/../libsowatch
43
44 symbian {
45     MMP_RULES += EXPORTUNFROZEN
46     TARGET.UID3 = 0xE4DC26B0
47     TARGET.CAPABILITY = 
48     TARGET.EPOCALLOWDLLDATA = 1
49         addFiles.sources = metawatchdriver.dll
50     addFiles.path = !:/sys/bin
51     DEPLOYMENT += addFiles
52 }
53
54 unix:!symbian {
55         !isEmpty(MEEGO_VERSION_MAJOR)|maemo5 {
56                 QMAKE_RPATHDIR += /opt/sowatch/lib
57                 target.path = /opt/sowatch/lib/drivers
58                 res_files.path = /opt/sowatch/share/metawatch
59                 qml_files.path = /opt/sowatch/qml
60     } else {
61                 target.path = /usr/lib/sowatch/drivers
62                 res_files.path = /usr/share/sowatch/metawatch
63                 qml_files.path = /usr/share/sowatch/qml
64     }
65         INSTALLS += target res_files qml_files
66 }