Changes: adapt reference queries, variable to iri projections in fn:concat no longer...
[qtcontacts-tracker:hasselmms-qtcontacts-tracker.git] / libqtcontacts-tracker.pro
1 CONFIG += ordered
2 TEMPLATE = subdirs
3
4 SUBDIRS = src tests benchmarks tools
5 OTHER_FILES = configure debian/changelog Doxyfile FUTURE HACKING EXPECTFAIL
6
7 # =================================================================================================
8 # Pretend to build API documentation
9 # =================================================================================================
10
11 apidocs.target = docs/html/index.html
12 apidocs.commands = doxygen $$PWD/Doxyfile
13 apidocs.depends = Doxyfile src/*/*.cpp src/*/*.h
14 docs.depends = apidocs
15
16 QMAKE_EXTRA_TARGETS += apidocs docs
17
18 # =================================================================================================
19 # Generate HTML reports from a previous gcov run
20 # =================================================================================================
21
22 coverage-html.commands = $$PWD/tests/gcov-summary.sh lcov docs/coverage
23
24 QMAKE_EXTRA_TARGETS += coverage-html
25 QMAKE_CLEAN += gcov.analysis gcov.analysis.summary
26
27 # =================================================================================================
28 # Update ontology convenience classes
29 # =================================================================================================
30
31 ontologycompiler.Makefile.target = tools/ontologycompiler/Makefile
32 ontologycompiler.Makefile.depends = $$PWD/tools/ontologycompiler/ontologycompiler.pro
33 ontologycompiler.Makefile.commands = qmake -o $$ontologycompiler.Makefile.target $$ontologycompiler.Makefile.depends
34
35 ontologycompiler.target = tools/ontologycompiler/ontologycompiler
36 ontologycompiler.depends = ontologycompiler.Makefile $$PWD/tools/ontologycompiler/*.cpp
37 ontologycompiler.commands = make -C tools/ontologycompiler
38
39 update-ontologies.commands = tools/ontologycompiler/ontologycompiler $$PWD/src/dao
40 update-ontologies.depends = ontologycompiler
41
42 QMAKE_EXTRA_TARGETS += update-ontologies ontologycompiler ontologycompiler.Makefile
43
44 # =================================================================================================
45 # Remove output of configure script on "make distclean"
46 # =================================================================================================
47
48 confclean.commands = $(DEL_FILE) $$TOP_BUILDDIR/.qmake.cache
49 distclean.depends = confclean
50
51 QMAKE_EXTRA_TARGETS += confclean distclean
52
53 # =================================================================================================
54 # Run configure script when building the project from tools like QtCreator
55 # =================================================================================================
56
57 isEmpty(CONFIGURED):system('$$PWD/configure')
58
59 confstamp.target = configure-stamp .qmake.cache
60 confstamp.commands = $$PWD/configure $$CONFIGURE_FLAGS
61 confstamp.depends = $$PWD/configure
62
63 QMAKE_EXTRA_TARGETS += confstamp