New: Introduce runQuery variants that accept a custom QSparqlConnection
[qtcontacts-tracker:hasselmms-qtcontacts-tracker.git] / libqtcontacts-tracker.pro
1 CONFIG += ordered
2 TEMPLATE = subdirs
3
4 SUBDIRS = src tests benchmarks tools
5
6 OTHER_FILES += configure Doxyfile FUTURE HACKING EXPECTFAIL
7 OTHER_FILES += debian/changelog debian/control debian/rules
8 OTHER_FILES += meego/qtcontacts-tracker.spec
9
10 # =================================================================================================
11 # Pretend to build API documentation
12 # =================================================================================================
13
14 apidocs.target = docs/html/index.html
15 apidocs.commands = doxygen $$PWD/Doxyfile
16 apidocs.depends = Doxyfile src/*/*.cpp src/*/*.h
17 docs.depends = apidocs
18
19 QMAKE_EXTRA_TARGETS += apidocs docs
20
21 # =================================================================================================
22 # Generate HTML reports from a previous gcov run
23 # =================================================================================================
24
25 coverage-html.commands = $$PWD/tests/gcov-summary.sh lcov docs/coverage
26
27 QMAKE_EXTRA_TARGETS += coverage-html
28 QMAKE_CLEAN += gcov.analysis gcov.analysis.summary
29
30 # =================================================================================================
31 # Remove output of configure script on "make distclean"
32 # =================================================================================================
33
34 confclean.commands = $(DEL_FILE) $$TOP_BUILDDIR/.qmake.cache
35 distclean.depends = confclean
36
37 QMAKE_EXTRA_TARGETS += confclean distclean
38
39 # =================================================================================================
40 # Run configure script when building the project from tools like QtCreator
41 # =================================================================================================
42
43 isEmpty(CONFIGURED):system('$$PWD/configure')
44
45 confstamp.target = configure-stamp .qmake.cache
46 confstamp.commands = $$PWD/configure $$CONFIGURE_FLAGS
47 confstamp.depends = $$PWD/configure
48
49 QMAKE_EXTRA_TARGETS += confstamp