Assistant: Fix static linking on Windows.
[qt:qttools.git] / src / assistant / assistant / assistant.pro
1 TEMPLATE = app
2 LANGUAGE = C++
3 TARGET = assistant
4 DESTDIR = $$QT.help.bins
5 qtHaveModule(webkitwidgets):!contains(QT_CONFIG, static) {
6     QT += webkitwidgets
7 } else {
8     DEFINES += QT_NO_WEBKIT
9 }
10 !build_pass:contains(QT_CONFIG, build_all): CONFIG += release
11 QT += widgets network help sql help
12 qtHaveModule(printsupport): QT += printsupport
13 PROJECTNAME = Assistant
14
15 include(../../shared/fontpanel/fontpanel.pri)
16
17 QMAKE_DOCS = $$PWD/doc/qtassistant.qdocconf
18
19 HEADERS += aboutdialog.h \
20     bookmarkdialog.h \
21     bookmarkfiltermodel.h \
22     bookmarkitem.h \
23     bookmarkmanager.h \
24     bookmarkmanagerwidget.h \
25     bookmarkmodel.h \
26     centralwidget.h \
27     cmdlineparser.h \
28     contentwindow.h \
29     findwidget.h \
30     filternamedialog.h \
31     helpenginewrapper.h \
32     helpviewer.h \
33     helpviewer_p.h \
34     indexwindow.h \
35     installdialog.h \
36     mainwindow.h \
37     preferencesdialog.h \
38     qtdocinstaller.h \
39     remotecontrol.h \
40     searchwidget.h \
41     topicchooser.h \
42     tracer.h \
43     xbelsupport.h \
44     ../shared/collectionconfiguration.h \
45     openpagesmodel.h \
46     globalactions.h \
47     openpageswidget.h \
48     openpagesmanager.h \
49     openpagesswitcher.h
50 win32:HEADERS += remotecontrol_win.h
51
52 SOURCES += aboutdialog.cpp \
53     bookmarkdialog.cpp \
54     bookmarkfiltermodel.cpp \
55     bookmarkitem.cpp \
56     bookmarkmanager.cpp \
57     bookmarkmanagerwidget.cpp \
58     bookmarkmodel.cpp \
59     centralwidget.cpp \
60     cmdlineparser.cpp \
61     contentwindow.cpp \
62     findwidget.cpp \
63     filternamedialog.cpp \
64     helpenginewrapper.cpp \
65     helpviewer.cpp \
66     indexwindow.cpp \
67     installdialog.cpp \
68     main.cpp \
69     mainwindow.cpp \
70     preferencesdialog.cpp \
71     qtdocinstaller.cpp \
72     remotecontrol.cpp \
73     searchwidget.cpp \
74     topicchooser.cpp \
75     xbelsupport.cpp \
76     ../shared/collectionconfiguration.cpp \
77     openpagesmodel.cpp \
78     globalactions.cpp \
79     openpageswidget.cpp \
80     openpagesmanager.cpp \
81     openpagesswitcher.cpp
82 qtHaveModule(webkitwidgets):!contains(QT_CONFIG, static) {
83     SOURCES += helpviewer_qwv.cpp
84 } else {
85     SOURCES += helpviewer_qtb.cpp
86 }
87
88 FORMS += bookmarkdialog.ui \
89     bookmarkmanagerwidget.ui \
90     bookmarkwidget.ui \
91     filternamedialog.ui \
92     installdialog.ui \
93     preferencesdialog.ui \
94     topicchooser.ui
95
96 RESOURCES += assistant.qrc \
97     assistant_images.qrc
98
99 win32 {
100     !wince*:LIBS += -lshell32
101     RC_FILE = assistant.rc
102 }
103
104 mac {
105     ICON = assistant.icns
106     TARGET = Assistant
107     QMAKE_INFO_PLIST = Info_mac.plist
108 }
109
110 contains(SQLPLUGINS, sqlite):QTPLUGIN += qsqlite
111
112 target.path=$$[QT_INSTALL_BINS]
113 INSTALLS += target