Change default linux backends when dbus is not present
[qt:qtsystems.git] / src / serviceframework / ipc / ipc.pri
1 INCLUDEPATH += ipc
2 win32 {
3     INCLUDEPATH += .
4 }
5
6 QT += core-private
7
8 isEmpty(SFW_BACKEND) {
9     contains(QT_CONFIG,dbus) {
10         SFW_BACKEND = dbus
11     } else {
12         linux {
13             SFW_BACKEND = unix
14         } else {
15             SFW_BACKEND = localsocket
16         }
17     }
18 }
19
20 equals(SFW_BACKEND,unix) {
21     DEFINES += SFW_USE_UNIX_BACKEND
22     PRIVATE_HEADERS += ipc/qremoteserviceregister_unix_p.h \
23         ipc/objectendpoint_p.h
24     SOURCES += ipc/qremoteserviceregister_unix_p.cpp \
25         ipc/objectendpoint.cpp
26 } else:equals(SFW_BACKEND,dbus) {
27     DEFINES += SFW_USE_DBUS_BACKEND
28     QT_FOR_PRIVATE += dbus \
29         network
30     PRIVATE_HEADERS += ipc/qremoteserviceregister_dbus_p.h \
31         ipc/objectendpoint_dbus_p.h \
32         ipc/qservicemetaobject_dbus_p.h
33     SOURCES += ipc/qremoteserviceregister_dbus_p.cpp \
34         ipc/objectendpoint_dbus.cpp \
35         ipc/qservicemetaobject_dbus.cpp
36 } else:equals(SFW_BACKEND,localsocket) {
37     DEFINES += SFW_USE_LOCALSOCKET_BACKEND
38     QT_FOR_PRIVATE += network
39     PRIVATE_HEADERS += ipc/qremoteserviceregister_ls_p.h \
40         ipc/objectendpoint_p.h
41     SOURCES += ipc/qremoteserviceregister_ls_p.cpp \
42         ipc/objectendpoint.cpp
43 } else {
44     error("Unkown SFW_BACKEND $$SFW_BACKEND")
45 }
46
47 PRIVATE_HEADERS += ipc/qslotinvoker_p.h \
48     ipc/qsignalintercepter_p.h \
49     ipc/instancemanager_p.h \
50     ipc/qservicepackage_p.h \
51     ipc/proxyobject_p.h \
52     ipc/ipcendpoint_p.h \
53     ipc/qremoteserviceregister_p.h \
54     ipc/qremoteserviceregisterentry_p.h
55
56 SOURCES += ipc/qslotinvoker.cpp \
57     ipc/qsignalintercepter.cpp \
58     ipc/instancemanager.cpp \
59     ipc/qservicepackage.cpp \
60     ipc/proxyobject.cpp \
61     ipc/ipcendpoint.cpp \
62     ipc/qremoteserviceregister_p.cpp
63
64 OTHER_FILES += \
65     ipc/json-schema.txt