Replace win32-g++ with mingw scope
[qt:qtsvg.git] / src / svg / svg.pro
1 TARGET     = QtSvg
2 QT         = core-private gui-private
3 qtHaveModule(widgets): QT += widgets-private
4
5 DEFINES   += QT_NO_USING_NAMESPACE
6 win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x66000000
7 solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2
8
9 QMAKE_DOCS = $$PWD/doc/qtsvg.qdocconf
10 load(qt_module)
11
12 HEADERS += \
13     qsvggraphics_p.h        \
14     qsvghandler_p.h         \
15     qsvgnode_p.h            \
16     qsvgstructure_p.h       \
17     qsvgstyle_p.h           \
18     qsvgfont_p.h            \
19     qsvgtinydocument_p.h    \
20     qsvgrenderer.h          \
21     qsvgwidget.h            \
22     qgraphicssvgitem.h      \
23     qsvggenerator.h \
24     qtsvgglobal.h
25
26
27 SOURCES += \
28     qsvggraphics.cpp        \
29     qsvghandler.cpp         \
30     qsvgnode.cpp            \
31     qsvgstructure.cpp       \
32     qsvgstyle.cpp           \
33     qsvgfont.cpp            \
34     qsvgtinydocument.cpp    \
35     qsvgrenderer.cpp        \
36     qsvgwidget.cpp          \
37     qgraphicssvgitem.cpp    \
38     qsvggenerator.cpp
39
40 wince*: {
41     SOURCES += \
42         qsvgfunctions_wince.cpp
43     HEADERS += \
44         qsvgfunctions_wince_p.h
45 }
46
47 contains(QT_CONFIG, system-zlib) {
48     if(unix|mingw):          LIBS_PRIVATE += -lz
49     else:                    LIBS += zdll.lib
50 } else {
51     git_build: \
52         INCLUDEPATH += $$[QT_INSTALL_HEADERS/get]/QtZlib
53     else: \
54         INCLUDEPATH += $$[QT_INSTALL_HEADERS/src]/QtZlib
55 }
56
57 ANDROID_LIB_DEPENDENCIES = \
58     lib/libQt5Xml.so
59
60 ANDROID_BUNDLED_FILES += \
61     lib/libQt5Xml.so