Update copyright year in Digia's license headers
[qt:qtgraphicaleffects.git] / src / effects / ColorOverlay.qml
1 /****************************************************************************
2 **
3 ** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
4 ** Contact: http://www.qt-project.org/legal
5 **
6 ** This file is part of the Qt Graphical Effects module.
7 **
8 ** $QT_BEGIN_LICENSE:BSD$
9 ** You may use this file under the terms of the BSD license as follows:
10 **
11 ** "Redistribution and use in source and binary forms, with or without
12 ** modification, are permitted provided that the following conditions are
13 ** met:
14 **   * Redistributions of source code must retain the above copyright
15 **     notice, this list of conditions and the following disclaimer.
16 **   * Redistributions in binary form must reproduce the above copyright
17 **     notice, this list of conditions and the following disclaimer in
18 **     the documentation and/or other materials provided with the
19 **     distribution.
20 **   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
21 **     of its contributors may be used to endorse or promote products derived
22 **     from this software without specific prior written permission.
23 **
24 **
25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
36 **
37 ** $QT_END_LICENSE$
38 **
39 ****************************************************************************/
40
41 import QtQuick 2.0
42 import "private"
43
44 /*!
45     \qmltype ColorOverlay
46     \inqmlmodule QtGraphicalEffects 1.0
47     \since QtGraphicalEffects 1.0
48     \inherits QtQuick2::Item
49     \ingroup qtgraphicaleffects-color
50     \brief Alters the colors of the source item by applying an overlay color.
51
52     The effect is similar to what happens when a colorized glass is put on top
53     of a grayscale image. The color for the overlay is given in the RGBA format.
54
55     \table
56     \header
57         \li Source
58         \li Effect applied
59     \row
60         \li \image Original_butterfly.png
61         \li \image ColorOverlay_butterfly.png
62     \endtable
63
64     \section1 Example
65
66     The following example shows how to apply the effect.
67     \snippet ColorOverlay-example.qml example
68
69 */
70 Item {
71     id: rootItem
72
73     /*!
74         This property defines the source item that provides the source pixels
75         for the effect.
76     */
77     property variant source
78
79     /*!
80         This property defines the RGBA color value which is used to colorize the
81         source.
82
83         By default, the property is set to \c "transparent".
84
85         \table
86         \header
87         \li Output examples with different color values
88         \li
89         \li
90         \row
91             \li \image ColorOverlay_color1.png
92             \li \image ColorOverlay_color2.png
93             \li \image ColorOverlay_color3.png
94         \row
95             \li \b { color: #80ff0000 }
96             \li \b { color: #8000ff00 }
97             \li \b { color: #800000ff }
98         \endtable
99
100     */
101     property color color: "transparent"
102
103     /*!
104         This property allows the effect output pixels to be cached in order to
105         improve the rendering performance.
106
107         Every time the source or effect properties are changed, the pixels in
108         the cache must be updated. Memory consumption is increased, because an
109         extra buffer of memory is required for storing the effect output.
110
111         It is recommended to disable the cache when the source or the effect
112         properties are animated.
113
114         By default, the property is set to \c false.
115
116     */
117     property bool cached: false
118
119     SourceProxy {
120         id: sourceProxy
121         input: rootItem.source
122     }
123
124     ShaderEffectSource {
125         id: cacheItem
126         anchors.fill: parent
127         visible: rootItem.cached
128         smooth: true
129         sourceItem: shaderItem
130         live: true
131         hideSource: visible
132     }
133
134     ShaderEffect {
135         id: shaderItem
136         property variant source: sourceProxy.output
137         property color color: rootItem.color
138
139         anchors.fill: parent
140
141         fragmentShader: "
142             varying mediump vec2 qt_TexCoord0;
143             uniform highp float qt_Opacity;
144             uniform lowp sampler2D source;
145             uniform highp vec4 color;
146             void main() {
147                 highp vec4 pixelColor = texture2D(source, qt_TexCoord0);
148                 gl_FragColor = vec4(mix(pixelColor.rgb/max(pixelColor.a, 0.00390625), color.rgb/max(color.a, 0.00390625), color.a) * pixelColor.a, pixelColor.a) * qt_Opacity;
149             }
150         "
151     }
152 }