Build Bluetooth and NFC only for Blackberry
[qt:qtconnectivity.git] / src / nfc / nfc.pro
1 TARGET = QtNfc
2 QT = core
3
4 load(qt_module)
5
6 QMAKE_DOCS = $$PWD/doc/qtnfc.qdocconf
7 OTHER_FILES += doc/src/*.qdoc   # show .qdoc files in Qt Creator
8
9 PUBLIC_HEADERS += \
10     qnfcglobal.h \
11     qnearfieldmanager.h \
12     qnearfieldtarget.h \
13     qndefrecord.h \
14     qndefnfctextrecord.h \
15     qndefmessage.h \
16     qndeffilter.h \
17     qndefnfcurirecord.h \
18     qqmlndefrecord.h \
19     qndefnfcsmartposterrecord.h
20
21 PRIVATE_HEADERS += \
22     qllcpsocket_p.h \
23     qllcpserver_p.h \
24     qndefrecord_p.h \
25     qnearfieldtarget_p.h \
26     qnearfieldmanager_p.h \
27     qnearfieldtagtype1_p.h \
28     qnearfieldtagtype2_p.h \
29     qnearfieldtagtype3_p.h \
30     qnearfieldtagtype4_p.h \
31     qtlv_p.h \
32     qndefnfcsmartposterrecord_p.h
33
34 SOURCES += \
35     qnearfieldmanager.cpp \
36     qnearfieldtarget.cpp \
37     qndefrecord.cpp \
38     qndefnfctextrecord.cpp \
39     qndefmessage.cpp \
40     qndeffilter.cpp \
41     qndefnfcurirecord.cpp \
42     qnearfieldtagtype1.cpp \
43     qnearfieldtagtype2.cpp \
44     qnearfieldtagtype3.cpp \
45     qllcpsocket.cpp \
46     qnearfieldtagtype4.cpp \
47     qtlv.cpp \
48     qllcpserver.cpp \
49     qqmlndefrecord.cpp \
50     qndefnfcsmartposterrecord.cpp
51
52 CONFIG(blackberry) {
53     NFC_BACKEND_AVAILABLE = yes
54     DEFINES += QNX_NFC #QQNXNFC_DEBUG
55
56     LIBS_PRIVATE += -lnfc
57
58     PRIVATE_HEADERS += \
59         qllcpserver_qnx_p.h \
60         qllcpsocket_qnx_p.h \
61         qnearfieldmanager_qnx_p.h \
62         qnx/qnxnfcmanager_p.h \
63         qnearfieldtarget_qnx_p.h \
64         qnx/qnxnfceventfilter_p.h
65
66     SOURCES += \
67         qllcpserver_qnx_p.cpp \
68         qllcpsocket_qnx_p.cpp \
69         qnearfieldmanager_qnx.cpp \
70         qnx/qnxnfcmanager.cpp \
71         qnx/qnxnfceventfilter.cpp
72 }
73
74 simulator {
75     NFC_BACKEND_AVAILABLE = yes
76
77     QT *= gui
78
79     PRIVATE_HEADERS += \
80         qnearfieldmanagervirtualbase_p.h \
81         qnearfieldmanager_simulator_p.h \
82         qllcpsocket_simulator_p.h \
83         qllcpserver_simulator_p.h
84
85     SOURCES += \
86         qnearfieldmanagervirtualbase.cpp \
87         qnearfieldmanager_simulator.cpp \
88         qllcpsocket_simulator_p.cpp \
89         qllcpserver_simulator_p.cpp
90 }
91
92 isEmpty(NFC_BACKEND_AVAILABLE) {
93     message("Unsupported NFC platform, will not build a working QtNfc library.")
94
95     PRIVATE_HEADERS += \
96         qllcpsocket_p_p.h \
97         qllcpserver_p_p.h \
98         qnearfieldmanagerimpl_p.h
99
100     SOURCES += \
101         qllcpsocket_p.cpp \
102         qllcpserver_p.cpp \
103         qnearfieldmanagerimpl_p.cpp
104 }
105
106 HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS