Merge remote-tracking branch 'origin/4.7' into qt-4.8-from-4.7
[qt:qt.git] / src / s60installs / s60installs.pro
1 # Use subdirs template to suppress generation of unnecessary files
2 TEMPLATE = subdirs
3
4 symbian: {
5     load(data_caging_paths)
6
7     SUBDIRS=
8     # WARNING: Changing TARGET name will break Symbian SISX upgrade functionality
9     # DO NOT TOUCH TARGET VARIABLE IF YOU ARE NOT SURE WHAT YOU ARE DOING
10     TARGET = "Qt$${QT_LIBINFIX}"
11
12     isEmpty(QT_LIBINFIX) {
13         TARGET.UID3 = 0x2001e61c
14     } else {
15         # Always use experimental UID for infixed configuration to avoid UID clash
16         TARGET.UID3 = 0xe001e61c
17     }
18     VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
19
20     DESTDIR = $$QMAKE_LIBDIR_QT
21
22     qtlibraries.files = \
23         $$QMAKE_LIBDIR_QT/QtCore$${QT_LIBINFIX}.dll \
24         $$QMAKE_LIBDIR_QT/QtXml$${QT_LIBINFIX}.dll \
25         $$QMAKE_LIBDIR_QT/QtGui$${QT_LIBINFIX}.dll \
26         $$QMAKE_LIBDIR_QT/QtNetwork$${QT_LIBINFIX}.dll \
27         $$QMAKE_LIBDIR_QT/QtTest$${QT_LIBINFIX}.dll \
28         $$QMAKE_LIBDIR_QT/QtSql$${QT_LIBINFIX}.dll
29
30     symbian-abld|symbian-sbsv2 {
31         pluginLocations = $${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)
32         bearerPluginLocation = $${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)
33         bearerStubZ = $${EPOCROOT}$${HW_ZDIR}$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin
34         BLD_INF_RULES.prj_exports += \
35             "qsymbianbearer.qtplugin /$${HW_ZDIR}$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin" \
36             "qsymbianbearer.qtplugin /epoc32/winscw/c$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin"
37     } else {
38         pluginLocations = $$QT_BUILD_TREE/plugins/s60
39         bearerPluginLocation = $$QT_BUILD_TREE/plugins/bearer
40         bearerStubZ = $${PWD}/qsymbianbearer.qtplugin
41     }
42
43     contains(S60_VERSION, 5.0) {
44         qts60plugindeployment = \
45             "IF package(0x2003A678) OR package(0x20022E6D)" \
46             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
47             "ELSEIF package(0x1028315F)" \
48             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}_3_2.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
49             "ELSE" \
50             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
51             "ENDIF" \
52             "   \"$$bearerStubZ\" - \"c:$$replace(QT_PLUGINS_BASE_DIR,/,\\)\\bearer\\qsymbianbearer$${QT_LIBINFIX}.qtplugin\""
53         qtlibraries.pkg_postrules += qts60plugindeployment
54     } else {
55         # No need to deploy plugins for older platform versions when building on Symbian3 or later
56         bearer_plugin.files = $$QT_BUILD_TREE/plugins/bearer/qsymbianbearer$${QT_LIBINFIX}.dll
57         bearer_plugin.path = c:$$QT_PLUGINS_BASE_DIR/bearer
58         DEPLOYMENT += bearer_plugin
59     }
60
61     qtlibraries.path = c:/sys/bin
62
63     vendorinfo = \
64         "; Localised Vendor name" \
65         "%{\"Nokia\"}" \
66         " " \
67         "; Unique Vendor name" \
68         ":\"Nokia, Qt\"" \
69         " "
70
71
72     qtlibraries.pkg_prerules = vendorinfo
73     qtlibraries.pkg_prerules += "; Dependencies of Qt libraries"
74
75     # It is expected that Symbian^3 and newer phones will have sufficiently new OpenC already installed
76     contains(S60_VERSION, 5.0) {
77         qtlibraries.pkg_prerules += "(0x20013851), 1, 5, 1, {\"PIPS Installer\"}"
78         contains(QT_CONFIG, openssl) | contains(QT_CONFIG, openssl-linked) {
79             qtlibraries.pkg_prerules += "(0x200110CB), 1, 5, 1, {\"Open C LIBSSL Common\"}"
80         }
81         contains(CONFIG, stl) {
82             qtlibraries.pkg_prerules += "(0x2000F866), 1, 0, 0, {\"Standard C++ Library Common\"}"
83         }
84     }
85     qtlibraries.pkg_prerules += "(0x2002af5f), 0, 5, 0, {\"sqlite3\"}"
86
87     !contains(QT_CONFIG, no-jpeg): imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qjpeg$${QT_LIBINFIX}.dll
88     !contains(QT_CONFIG, no-gif):  imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qgif$${QT_LIBINFIX}.dll
89     !contains(QT_CONFIG, no-mng):  imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qmng$${QT_LIBINFIX}.dll
90     !contains(QT_CONFIG, no-tiff): imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qtiff$${QT_LIBINFIX}.dll
91     !contains(QT_CONFIG, no-ico):  imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qico$${QT_LIBINFIX}.dll
92     imageformats_plugins.path = c:$$QT_PLUGINS_BASE_DIR/imageformats
93
94     codecs_plugins.files = $$QT_BUILD_TREE/plugins/codecs/qcncodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qjpcodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qtwcodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qkrcodecs$${QT_LIBINFIX}.dll
95     codecs_plugins.path = c:$$QT_PLUGINS_BASE_DIR/codecs
96
97     contains(QT_CONFIG, phonon-backend) {
98         phonon_backend_plugins.files += $$QT_BUILD_TREE/plugins/phonon_backend/phonon_mmf$${QT_LIBINFIX}.dll
99
100         phonon_backend_plugins.path = c:$$QT_PLUGINS_BASE_DIR/phonon_backend
101         DEPLOYMENT += phonon_backend_plugins
102     }
103
104     # Support backup & restore for Qt libraries
105     qtbackup.files = backup_registration.xml
106     qtbackup.path = c:/private/10202d56/import/packages/$$replace(TARGET.UID3, 0x,)
107
108     DEPLOYMENT += qtlibraries \
109                   qtbackup \
110                   imageformats_plugins \
111                   codecs_plugins \
112                   graphicssystems_plugins
113
114     contains(QT_CONFIG, svg): {
115        qtlibraries.files += $$QMAKE_LIBDIR_QT/QtSvg$${QT_LIBINFIX}.dll
116        imageformats_plugins.files += $$QT_BUILD_TREE/plugins/imageformats/qsvg$${QT_LIBINFIX}.dll
117        iconengines_plugins.files = $$QT_BUILD_TREE/plugins/iconengines/qsvgicon$${QT_LIBINFIX}.dll
118        iconengines_plugins.path = c:$$QT_PLUGINS_BASE_DIR/iconengines
119        DEPLOYMENT += iconengines_plugins
120     }
121
122     contains(QT_CONFIG, phonon): {
123        qtlibraries.files += $$QMAKE_LIBDIR_QT/phonon$${QT_LIBINFIX}.dll
124     }
125
126     contains(QT_CONFIG, script): {
127         qtlibraries.files += $$QMAKE_LIBDIR_QT/QtScript$${QT_LIBINFIX}.dll
128     }
129
130     contains(QT_CONFIG, xmlpatterns): {
131        qtlibraries.files += $$QMAKE_LIBDIR_QT/QtXmlPatterns$${QT_LIBINFIX}.dll
132     }
133
134     contains(QT_CONFIG, declarative): {
135         qtlibraries.files += $$QMAKE_LIBDIR_QT/QtDeclarative$${QT_LIBINFIX}.dll
136
137         folderlistmodelImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/folderlistmodel/qmlfolderlistmodelplugin$${QT_LIBINFIX}.dll
138         gesturesImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/gestures/qmlgesturesplugin$${QT_LIBINFIX}.dll
139         particlesImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/particles/qmlparticlesplugin$${QT_LIBINFIX}.dll
140         shadersImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/shaders/qmlshadersplugin$${QT_LIBINFIX}.dll
141
142         folderlistmodelImport.sources += $$QT_SOURCE_TREE/src/imports/folderlistmodel/qmldir
143         gesturesImport.sources += $$QT_SOURCE_TREE/src/imports/gestures/qmldir
144         particlesImport.sources += $$QT_SOURCE_TREE/src/imports/particles/qmldir
145         shadersImport.sources += $$QT_SOURCE_TREE/src/imports/shaders/qmldir
146
147         folderlistmodelImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/folderlistmodel
148         gesturesImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/gestures
149         particlesImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/particles
150         shadersImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/shaders
151
152         DEPLOYMENT += folderlistmodelImport gesturesImport particlesImport shadersImport
153     }
154
155     graphicssystems_plugins.path = c:$$QT_PLUGINS_BASE_DIR/graphicssystems
156     contains(QT_CONFIG, openvg) {
157         qtlibraries.files += $$QMAKE_LIBDIR_QT/QtOpenVG$${QT_LIBINFIX}.dll
158         graphicssystems_plugins.files += $$QT_BUILD_TREE/plugins/graphicssystems/qvggraphicssystem$${QT_LIBINFIX}.dll
159     }
160
161     contains(QT_CONFIG, opengl) {
162         qtlibraries.files += $$QMAKE_LIBDIR_QT/QtOpenGL$${QT_LIBINFIX}.dll
163         graphicssystems_plugins.files += $$QT_BUILD_TREE/plugins/graphicssystems/qglgraphicssystem$${QT_LIBINFIX}.dll
164     }
165
166     contains(QT_CONFIG, multimedia){
167         qtlibraries.files += $$QMAKE_LIBDIR_QT/QtMultimedia$${QT_LIBINFIX}.dll
168     }
169
170     BLD_INF_RULES.prj_exports += "qt.iby $$CORE_MW_LAYER_IBY_EXPORT_PATH(qt.iby)"
171 }