Remove sqlite3_selfsigned.sis as it is no longer usable or needed.
[qt:qt.git] / src / s60installs / s60installs.pro
1 # Use subdirs template to suppress generation of unnecessary files
2 TEMPLATE = subdirs
3
4 symbian: {
5     load(data_caging_paths)
6
7     SUBDIRS=
8     # WARNING: Changing TARGET name will break Symbian SISX upgrade functionality
9     # DO NOT TOUCH TARGET VARIABLE IF YOU ARE NOT SURE WHAT YOU ARE DOING
10     TARGET = "Qt$${QT_LIBINFIX}"
11
12     isEmpty(QT_LIBINFIX) {
13         TARGET.UID3 = 0x2001E61C
14
15         # Sqlite3 is expected to be already found on phone if infixed configuration is built.
16         # It is also expected that devices newer than those based on S60 5.0 all have sqlite3.dll.
17         contains(S60_VERSION, 3.1)|contains(S60_VERSION, 3.2)|contains(S60_VERSION, 5.0) {
18             BLD_INF_RULES.prj_exports += \
19                 "sqlite3.sis /epoc32/data/qt/sis/sqlite3.sis"
20             symbian-abld|symbian-sbsv2 {
21                 sqlitedeployment = \
22                     "; Deploy sqlite onto phone that does not have it already" \
23                     "@\"$${EPOCROOT}epoc32/data/qt/sis/sqlite3.sis\", (0x2002af5f)"
24             } else {
25                 sqlitedeployment = \
26                     "; Deploy sqlite onto phone that does not have it already" \
27                     "@\"$${PWD}/sqlite3.sis\", (0x2002af5f)"
28             }
29             qtlibraries.pkg_postrules += sqlitedeployment
30         }
31     } else {
32         # Always use experimental UID for infixed configuration to avoid UID clash
33         TARGET.UID3 = 0xE001E61C
34     }
35     VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
36
37     DESTDIR = $$QMAKE_LIBDIR_QT
38
39     qtlibraries.sources = \
40         $$QMAKE_LIBDIR_QT/QtCore$${QT_LIBINFIX}.dll \
41         $$QMAKE_LIBDIR_QT/QtXml$${QT_LIBINFIX}.dll \
42         $$QMAKE_LIBDIR_QT/QtGui$${QT_LIBINFIX}.dll \
43         $$QMAKE_LIBDIR_QT/QtNetwork$${QT_LIBINFIX}.dll \
44         $$QMAKE_LIBDIR_QT/QtTest$${QT_LIBINFIX}.dll \
45         $$QMAKE_LIBDIR_QT/QtSql$${QT_LIBINFIX}.dll
46
47     symbian-abld|symbian-sbsv2 {
48         pluginLocations = $${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)
49         bearerPluginLocation = $${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)
50         bearerStubZ = $${EPOCROOT}$${HW_ZDIR}$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin
51         BLD_INF_RULES.prj_exports += \
52             "qsymbianbearer.qtplugin /$${HW_ZDIR}$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin" \
53             "qsymbianbearer.qtplugin /epoc32/winscw/c$${QT_PLUGINS_BASE_DIR}/bearer/qsymbianbearer$${QT_LIBINFIX}.qtplugin"
54     } else {
55         pluginLocations = $$QT_BUILD_TREE/plugins/s60
56         bearerPluginLocation = $$QT_BUILD_TREE/plugins/bearer
57         bearerStubZ = $${PWD}/qsymbianbearer.qtplugin
58     }
59
60     contains(S60_VERSION, 3.1)|contains(S60_VERSION, 3.2)|contains(S60_VERSION, 5.0) {
61         qts60plugindeployment = \
62             "IF package(0x20022E6D)" \
63             "   \"$$pluginLocations/qts60plugin_5_0$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0$${QT_LIBINFIX}.dll\"" \
64             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
65             "ELSEIF package(0x1028315F)" \
66             "   \"$$pluginLocations/qts60plugin_5_0$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0$${QT_LIBINFIX}.dll\"" \
67             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}_3_2.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
68             "ELSEIF package(0x102752AE)" \
69             "   \"$$pluginLocations/qts60plugin_3_2$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_3_2$${QT_LIBINFIX}.dll\"" \
70             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}_3_2.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
71             "ELSEIF package(0x102032BE)" \
72             "   \"$$pluginLocations/qts60plugin_3_1$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_3_1$${QT_LIBINFIX}.dll\"" \
73             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}_3_1.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
74             "ELSE" \
75             "   \"$$pluginLocations/qts60plugin_5_0$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0$${QT_LIBINFIX}.dll\"" \
76             "   \"$$bearerPluginLocation/qsymbianbearer$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qsymbianbearer$${QT_LIBINFIX}.dll\"" \
77             "ENDIF" \
78             "   \"$$bearerStubZ\" - \"c:$$replace(QT_PLUGINS_BASE_DIR,/,\\)\\bearer\\qsymbianbearer$${QT_LIBINFIX}.qtplugin\"
79     } else {
80         # No need to deploy plugins for older platform versions when building on Symbian3 or later
81         qts60plugindeployment = \
82             "   \"$$pluginLocations/qts60plugin_5_0$${QT_LIBINFIX}.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0$${QT_LIBINFIX}.dll\""
83
84         bearer_plugin.sources = $$QT_BUILD_TREE/plugins/bearer/qsymbianbearer$${QT_LIBINFIX}.dll
85         bearer_plugin.path = c:$$QT_PLUGINS_BASE_DIR/bearer
86         DEPLOYMENT += bearer_plugin
87     }
88
89     qtlibraries.pkg_postrules += qts60plugindeployment
90
91     qtlibraries.path = c:/sys/bin
92
93     vendorinfo = \
94         "; Localised Vendor name" \
95         "%{\"Nokia, Qt\"}" \
96         " " \
97         "; Unique Vendor name" \
98         ":\"Nokia, Qt\"" \
99         " "
100
101
102     qtlibraries.pkg_prerules = vendorinfo
103     qtlibraries.pkg_prerules += "; Dependencies of Qt libraries"
104
105     # It is expected that Symbian^3 and newer phones will have sufficiently new OpenC already installed
106     contains(S60_VERSION, 3.1)|contains(S60_VERSION, 3.2)|contains(S60_VERSION, 5.0) {
107         qtlibraries.pkg_prerules += "(0x20013851), 1, 5, 1, {\"PIPS Installer\"}"
108         contains(QT_CONFIG, openssl) | contains(QT_CONFIG, openssl-linked) {
109             qtlibraries.pkg_prerules += "(0x200110CB), 1, 5, 1, {\"Open C LIBSSL Common\"}"
110         }
111         contains(CONFIG, stl) {
112             qtlibraries.pkg_prerules += "(0x2000F866), 1, 0, 0, {\"Standard C++ Library Common\"}"
113         }
114     }
115     qtlibraries.pkg_prerules += "(0x2002af5f), 0, 5, 0, {\"sqlite3\"}"
116
117     !contains(QT_CONFIG, no-jpeg): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qjpeg$${QT_LIBINFIX}.dll
118     !contains(QT_CONFIG, no-gif):  imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qgif$${QT_LIBINFIX}.dll
119     !contains(QT_CONFIG, no-mng):  imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qmng$${QT_LIBINFIX}.dll
120     !contains(QT_CONFIG, no-tiff): imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qtiff$${QT_LIBINFIX}.dll
121     !contains(QT_CONFIG, no-ico):  imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qico$${QT_LIBINFIX}.dll
122     imageformats_plugins.path = c:$$QT_PLUGINS_BASE_DIR/imageformats
123
124     codecs_plugins.sources = $$QT_BUILD_TREE/plugins/codecs/qcncodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qjpcodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qtwcodecs$${QT_LIBINFIX}.dll $$QT_BUILD_TREE/plugins/codecs/qkrcodecs$${QT_LIBINFIX}.dll
125     codecs_plugins.path = c:$$QT_PLUGINS_BASE_DIR/codecs
126
127     contains(QT_CONFIG, phonon-backend) {
128         phonon_backend_plugins.sources += $$QT_BUILD_TREE/plugins/phonon_backend/phonon_mmf$${QT_LIBINFIX}.dll
129
130         phonon_backend_plugins.path = c:$$QT_PLUGINS_BASE_DIR/phonon_backend
131         DEPLOYMENT += phonon_backend_plugins
132     }
133
134     # Support backup & restore for Qt libraries
135     qtbackup.sources = backup_registration.xml
136     qtbackup.path = c:/private/10202D56/import/packages/$$replace(TARGET.UID3, 0x,)
137
138     DEPLOYMENT += qtlibraries \
139                   qtbackup \
140                   imageformats_plugins \
141                   codecs_plugins \
142                   graphicssystems_plugins
143
144     contains(QT_CONFIG, svg): {
145        qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtSvg$${QT_LIBINFIX}.dll
146        imageformats_plugins.sources += $$QT_BUILD_TREE/plugins/imageformats/qsvg$${QT_LIBINFIX}.dll
147        iconengines_plugins.sources = $$QT_BUILD_TREE/plugins/iconengines/qsvgicon$${QT_LIBINFIX}.dll
148        iconengines_plugins.path = c:$$QT_PLUGINS_BASE_DIR/iconengines
149        DEPLOYMENT += iconengines_plugins
150     }
151
152     contains(QT_CONFIG, phonon): {
153        qtlibraries.sources += $$QMAKE_LIBDIR_QT/phonon$${QT_LIBINFIX}.dll
154     }
155
156     contains(QT_CONFIG, script): {
157         qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtScript$${QT_LIBINFIX}.dll
158     }
159
160     contains(QT_CONFIG, xmlpatterns): {
161        qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtXmlPatterns$${QT_LIBINFIX}.dll
162     }
163
164     contains(QT_CONFIG, declarative): {
165         qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtDeclarative$${QT_LIBINFIX}.dll
166
167         folderlistmodelImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/folderlistmodel/qmlfolderlistmodelplugin$${QT_LIBINFIX}.dll
168         gesturesImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/gestures/qmlgesturesplugin$${QT_LIBINFIX}.dll
169         particlesImport.sources = $$QT_BUILD_TREE/imports/Qt/labs/particles/qmlparticlesplugin$${QT_LIBINFIX}.dll
170
171         folderlistmodelImport.sources += $$QT_SOURCE_TREE/src/imports/folderlistmodel/qmldir
172         gesturesImport.sources += $$QT_SOURCE_TREE/src/imports/gestures/qmldir
173         particlesImport.sources += $$QT_SOURCE_TREE/src/imports/particles/qmldir
174
175         folderlistmodelImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/folderlistmodel
176         gesturesImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/gestures
177         particlesImport.path = c:$$QT_IMPORTS_BASE_DIR/Qt/labs/particles
178
179         DEPLOYMENT += folderlistmodelImport gesturesImport particlesImport
180     }
181
182     graphicssystems_plugins.path = c:$$QT_PLUGINS_BASE_DIR/graphicssystems
183     contains(QT_CONFIG, openvg) {
184         qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtOpenVG$${QT_LIBINFIX}.dll
185         graphicssystems_plugins.sources += $$QT_BUILD_TREE/plugins/graphicssystems/qvggraphicssystem$${QT_LIBINFIX}.dll
186         # OpenVG requires Symbian^3 or later
187         pkg_platform_dependencies = \
188             "[0x20022E6D],0,0,0,{\"S60ProductID\"}" \
189             "[0x20032DE7],0,0,0,{\"S60ProductID\"}"
190     }
191
192     contains(QT_CONFIG, opengl) {
193         qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtOpenGL$${QT_LIBINFIX}.dll
194         graphicssystems_plugins.sources += $$QT_BUILD_TREE/plugins/graphicssystems/qglgraphicssystem$${QT_LIBINFIX}.dll
195     }
196
197     contains(QT_CONFIG, multimedia){
198         qtlibraries.sources += $$QMAKE_LIBDIR_QT/QtMultimedia$${QT_LIBINFIX}.dll
199     }
200
201     BLD_INF_RULES.prj_exports += "qt.iby $$CORE_MW_LAYER_IBY_EXPORT_PATH(qt.iby)"
202 }