projects.pro

   1 #####################################################################
   2 # Main projectfile
   3 #####################################################################
   4
   5 CONFIG += ordered
   6 TEMPLATE = subdirs
   7
   8 cross_compile: CONFIG += nostrip
   9
  10 isEmpty(QT_BUILD_PARTS) { #defaults
  11     symbian|integrity {
  12        QT_BUILD_PARTS = libs tools examples demos
  13     } else {
  14        QT_BUILD_PARTS = libs tools examples demos docs translations
  15     }
  16 } else { #make sure the order makes sense
  17    contains(QT_BUILD_PARTS, translations) {
  18        QT_BUILD_PARTS -= translations
  19        QT_BUILD_PARTS = translations $$QT_BUILD_PARTS
  20    }
  21    contains(QT_BUILD_PARTS, tools) {
  22        QT_BUILD_PARTS -= tools
  23        QT_BUILD_PARTS = tools $$QT_BUILD_PARTS
  24    }
  25    contains(QT_BUILD_PARTS, libs) {
  26        QT_BUILD_PARTS -= libs
  27        QT_BUILD_PARTS = libs $$QT_BUILD_PARTS
  28    }
  29    contains(QT_BUILD_PARTS, qmake) {
  30        QT_BUILD_PARTS -= qmake
  31        QT_BUILD_PARTS = qmake $$QT_BUILD_PARTS
  32    }
  33 }
  34
  35 #process the projects
  36 for(PROJECT, $$list($$lower($$unique(QT_BUILD_PARTS)))) {
  37     isEqual(PROJECT, tools) {
  38        SUBDIRS += tools
  39     } else:isEqual(PROJECT, examples) {
  40        SUBDIRS += examples
  41     } else:isEqual(PROJECT, demos) {
  42        SUBDIRS += demos
  43     } else:isEqual(PROJECT, libs) {
  44        include(src/src.pro)
  45     } else:isEqual(PROJECT, docs) {
  46        contains(QT_BUILD_PARTS, tools):include(doc/doc.pri)
  47     } else:isEqual(PROJECT, translations) {
  48        !contains(QT_BUILD_PARTS, tools):!wince*:SUBDIRS += tools/linguist/lrelease
  49        SUBDIRS += translations
  50     } else:isEqual(PROJECT, qmake) {
  51 #      SUBDIRS += qmake
  52     } else {
  53        message(Unknown PROJECT: $$PROJECT)
  54     }
  55 }
  56
  57 !symbian: confclean.depends += clean
  58 confclean.commands =
  59 unix:!symbian {
  60   confclean.commands += (cd config.tests/unix/stl && $(MAKE) distclean); \
  61                         (cd config.tests/unix/endian && $(MAKE) distclean); \
  62                         (cd config.tests/unix/ipv6 && $(MAKE) distclean); \
  63                         (cd config.tests/unix/largefile && $(MAKE) distclean); \
  64                         (cd config.tests/unix/ptrsize && $(MAKE) distclean); \
  65                         (cd config.tests/x11/notype && $(MAKE) distclean); \
  66                         (cd config.tests/unix/getaddrinfo && $(MAKE) distclean); \
  67                         (cd config.tests/unix/cups && $(MAKE) distclean); \
  68                         (cd config.tests/unix/psql && $(MAKE) distclean); \
  69                         (cd config.tests/unix/mysql && $(MAKE) distclean); \
  70                         (cd config.tests/unix/mysql_r && $(MAKE) distclean); \
  71                         (cd config.tests/unix/nis && $(MAKE) distclean); \
  72                         (cd config.tests/unix/nix && $(MAKE) distclean); \
  73                         (cd config.tests/unix/iodbc && $(MAKE) distclean); \
  74                         (cd config.tests/unix/odbc && $(MAKE) distclean); \
  75                         (cd config.tests/unix/oci && $(MAKE) distclean); \
  76                         (cd config.tests/unix/tds && $(MAKE) distclean); \
  77                         (cd config.tests/unix/db2 && $(MAKE) distclean); \
  78                         (cd config.tests/unix/ibase && $(MAKE) distclean); \
  79                         (cd config.tests/unix/ipv6ifname && $(MAKE) distclean); \
  80                         (cd config.tests/unix/zlib && $(MAKE) distclean); \
  81                         (cd config.tests/unix/libmng && $(MAKE) distclean); \
  82                         (cd config.tests/unix/sqlite2 && $(MAKE) distclean); \
  83                         (cd config.tests/unix/libjpeg && $(MAKE) distclean); \
  84                         (cd config.tests/unix/libpng && $(MAKE) distclean); \
  85                         (cd config.tests/x11/xcursor && $(MAKE) distclean); \
  86                         (cd config.tests/x11/xrender && $(MAKE) distclean); \
  87                         (cd config.tests/x11/xrandr && $(MAKE) distclean); \
  88                         (cd config.tests/x11/xkb && $(MAKE) distclean); \
  89                         (cd config.tests/x11/xinput && $(MAKE) distclean); \
  90                         (cd config.tests/x11/fontconfig && $(MAKE) distclean); \
  91                         (cd config.tests/x11/xinerama && $(MAKE) distclean); \
  92                         (cd config.tests/x11/sm && $(MAKE) distclean); \
  93                         (cd config.tests/x11/xshape && $(MAKE) distclean); \
  94                         (cd config.tests/x11/opengl && $(MAKE) distclean); \
  95                         $(DEL_FILE) config.tests/.qmake.cache; \
  96                         $(DEL_FILE) src/corelib/global/qconfig.h; \
  97                         $(DEL_FILE) src/corelib/global/qconfig.cpp; \
  98                         $(DEL_FILE) mkspecs/qconfig.pri; \
  99                         $(DEL_FILE) .qmake.cache; \
 100                         (cd qmake && $(MAKE) distclean);
 101 }
 102 win32 {
 103   confclean.commands += -$(DEL_FILE) src\\corelib\\global\\qconfig.h $$escape_expand(\\n\\t) \
 104                         -$(DEL_FILE) src\\corelib\\global\\qconfig.cpp $$escape_expand(\\n\\t) \
 105                         -$(DEL_FILE) mkspecs\\qconfig.pri $$escape_expand(\\n\\t) \
 106                         -$(DEL_FILE) .qmake.cache $$escape_expand(\\n\\t) \
 107                         (cd qmake && $(MAKE) distclean)
 108 }
 109 symbian {
 110   confclean.depends += distclean
 111   contains(QMAKE_HOST.os, "Windows") {
 112     confclean.commands += \
 113             (cd src\\tools\\moc && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 114             (cd src\\tools\\rcc && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 115             (cd src\\tools\\uic && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 116             -$(DEL_FILE) src\\corelib\\global\\qconfig.h $$escape_expand(\\n\\t) \
 117             -$(DEL_FILE) src\\corelib\\global\\qconfig.cpp $$escape_expand(\\n\\t) \
 118             -$(DEL_FILE) mkspecs\\qconfig.pri $$escape_expand(\\n\\t) \
 119             -$(DEL_FILE) .qmake.cache $$escape_expand(\\n\\t) \
 120             (cd qmake && $(MAKE) distclean)
 121   } else {
 122     confclean.commands += \
 123             (cd src/tools/moc && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 124             (cd src/tools/rcc && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 125             (cd src/tools/uic && $(MAKE) distclean) $$escape_expand(\\n\\t) \
 126             -$(DEL_FILE) src/corelib/global/qconfig.h $$escape_expand(\\n\\t) \
 127             -$(DEL_FILE) src/corelib/global/qconfig.cpp $$escape_expand(\\n\\t) \
 128             -$(DEL_FILE) mkspecs/qconfig.pri $$escape_expand(\\n\\t) \
 129             -$(DEL_FILE) .qmake.cache $$escape_expand(\\n\\t) \
 130             (cd qmake && $(MAKE) distclean)
 131   }
 132 }
 133 QMAKE_EXTRA_TARGETS += confclean
 134 qmakeclean.commands += (cd qmake && $(MAKE) clean)
 135 QMAKE_EXTRA_TARGETS += qmakeclean
 136 CLEAN_DEPS += qmakeclean
 137
 138 CONFIG -= qt
 139
 140 ### installations ####
 141
 142 #qmake
 143 qmake.path=$$[QT_INSTALL_BINS]
 144 equals(QMAKE_HOST.os, Windows) {
 145    qmake.files=$$QT_BUILD_TREE/bin/qmake.exe
 146 } else {
 147    qmake.files=$$QT_BUILD_TREE/bin/qmake
 148 }
 149 INSTALLS += qmake
 150
 151 #mkspecs
 152 mkspecs.path=$$[QT_INSTALL_DATA]/mkspecs
 153 mkspecs.files=$$QT_BUILD_TREE/mkspecs/qconfig.pri $$files($$QT_SOURCE_TREE/mkspecs/*)
 154 mkspecs.files -= $$QT_SOURCE_TREE/mkspecs/modules
 155 unix {
 156    DEFAULT_QMAKESPEC = $$QMAKESPEC
 157    DEFAULT_QMAKESPEC ~= s,^.*mkspecs/,,g
 158
 159    # When cross-compiling on a Unix-like environment in a Windows host
 160    # we let the default mkspecs be copied to the target directory, instead
 161    # of being symlinked.
 162    !contains(QMAKE_HOST.os, Windows): mkspecs.commands += $(DEL_FILE) $(INSTALL_ROOT)$$mkspecs.path/default; $(SYMLINK) $$DEFAULT_QMAKESPEC $(INSTALL_ROOT)$$mkspecs.path/default
 163    mkspecs.files -= $$QT_SOURCE_TREE/mkspecs/default
 164 }
 165 win32:!equals(QT_BUILD_TREE, $$QT_SOURCE_TREE) {
 166     # When shadow building on Windows, the default mkspec only exists in the build tree.
 167     mkspecs.files += $$QT_BUILD_TREE/mkspecs/default
 168 }
 169 INSTALLS += mkspecs
 170
 171 false:macx { #mac install location
 172     macdocs.files = $$htmldocs.files
 173     macdocs.path = /Developer/Documentation/Qt
 174     INSTALLS += macdocs
 175 }
 176