bump required Qt version in the cmakelists
[phonon:phonon.git] / CMakeLists.txt
1 project(Phonon)
2
3 cmake_minimum_required(VERSION 2.6.2 FATAL_ERROR)
4
5 # CMP0002: we have multiple targets with the same name for the unit tests
6 cmake_policy(SET CMP0002 OLD)
7
8 # enable unit tests
9 option(PHONON_BUILD_TESTS "Build the tests")
10
11 if (PHONON_BUILD_TESTS)
12     enable_testing()
13 endif (PHONON_BUILD_TESTS)
14
15 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
16
17 include(PhononMacros)
18
19 include(MacroLogFeature)
20 include(MacroOptionalFindPackage)
21
22 set(QT_MIN_VERSION 4.6.0)
23 find_package(Qt4 REQUIRED)
24 if (NOT QT_QTDBUS_FOUND)
25    message(STATUS "Warning: Phonon won't be compiled with DBus support.")
26 endif(NOT QT_QTDBUS_FOUND)
27
28 find_package(Automoc4 REQUIRED)
29 include (CheckCXXCompilerFlag)
30 include (MacroEnsureVersion)
31
32 if (NOT AUTOMOC4_VERSION)
33    set(AUTOMOC4_VERSION "0.9.83")
34 endif (NOT AUTOMOC4_VERSION)
35 macro_ensure_version("0.9.86" "${AUTOMOC4_VERSION}" _automoc4_version_ok)
36 if (NOT _automoc4_version_ok)
37    message(FATAL_ERROR "Your version of automoc4 is too old. You have ${AUTOMOC4_VERSION}, you need at least 0.9.86")
38 endif (NOT _automoc4_version_ok)
39
40 if (CMAKE_COMPILER_IS_GNUCXX)
41    set (KDE4_ENABLE_EXCEPTIONS -fexceptions)
42    # Select flags.
43    set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g")
44    set(CMAKE_CXX_FLAGS_RELEASE        "-O2 -DNDEBUG -DQT_NO_DEBUG")
45    set(CMAKE_CXX_FLAGS_DEBUG          "-g -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
46    set(CMAKE_CXX_FLAGS_DEBUGFULL      "-g3 -fno-inline")
47    set(CMAKE_CXX_FLAGS_PROFILE        "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
48    set(CMAKE_C_FLAGS_RELWITHDEBINFO   "-O2 -g")
49    set(CMAKE_C_FLAGS_RELEASE          "-O2 -DNDEBUG -DQT_NO_DEBUG")
50    set(CMAKE_C_FLAGS_DEBUG            "-g -O2 -fno-reorder-blocks -fno-schedule-insns -fno-inline")
51    set(CMAKE_C_FLAGS_DEBUGFULL        "-g3 -fno-inline")
52    set(CMAKE_C_FLAGS_PROFILE          "-g3 -fno-inline -ftest-coverage -fprofile-arcs")
53
54    if (CMAKE_SYSTEM_NAME MATCHES Linux)
55      set ( CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wno-long-long -std=iso9899:1990 -Wundef -Wcast-align -Werror-implicit-function-declaration -Wchar-subscripts -Wall -W -Wpointer-arith -Wwrite-strings -Wformat-security -Wmissing-format-attribute -fno-common")
56      set ( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -ansi -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wpointer-arith -Wformat-security -fno-exceptions -fno-check-new -fno-common")
57      add_definitions (-D_BSD_SOURCE -DQT_NO_EXCEPTIONS)
58    endif (CMAKE_SYSTEM_NAME MATCHES Linux)
59
60    # gcc under Windows
61    if (MINGW)
62       set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--export-all-symbols -Wl,--disable-auto-import")
63       set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--export-all-symbols -Wl,--disable-auto-import")
64
65       # we always link against the release version of QT with mingw
66       # (even for debug builds). So we need to define QT_NO_DEBUG
67       # or else QPluginLoader rejects plugins because it thinks
68       # they're built against the wrong QT.
69       add_definitions(-DQT_NO_DEBUG)
70    endif (MINGW)
71
72    if (QT_USE_FRAMEWORKS)
73      set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -F${QT_LIBRARY_DIR}")
74    endif (QT_USE_FRAMEWORKS)
75
76    check_cxx_compiler_flag(-fPIE HAVE_FPIE_SUPPORT)
77    if(KDE4_ENABLE_FPIE)
78        if(HAVE_FPIE_SUPPORT)
79         set (KDE4_CXX_FPIE_FLAGS "-fPIE")
80         set (KDE4_PIE_LDFLAGS "-pie")
81        else(HAVE_FPIE_SUPPORT)
82         message(STATUS "Your compiler doesn't support PIE flag")
83        endif(HAVE_FPIE_SUPPORT)
84    endif(KDE4_ENABLE_FPIE)
85
86    check_cxx_compiler_flag(-Woverloaded-virtual __KDE_HAVE_W_OVERLOADED_VIRTUAL)
87    if(__KDE_HAVE_W_OVERLOADED_VIRTUAL)
88        set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Woverloaded-virtual")
89    endif(__KDE_HAVE_W_OVERLOADED_VIRTUAL)
90
91    # visibility support
92    check_cxx_compiler_flag(-fvisibility=hidden __KDE_HAVE_GCC_VISIBILITY)
93    set( __KDE_HAVE_GCC_VISIBILITY ${__KDE_HAVE_GCC_VISIBILITY} CACHE BOOL "GCC support for hidden visibility")
94
95    # get the gcc version
96    exec_program(${CMAKE_C_COMPILER} ARGS --version OUTPUT_VARIABLE _gcc_version_info)
97
98    string (REGEX MATCH "[345]\\.[0-9]\\.[0-9]" _gcc_version "${_gcc_version_info}")
99    # gcc on mac just reports: "gcc (GCC) 3.3 20030304 ..." without the patch level, handle this here:
100    if (NOT _gcc_version)
101       string (REGEX REPLACE ".*\\(GCC\\).* ([34]\\.[0-9]) .*" "\\1.0" _gcc_version "${_gcc_version_info}")
102    endif (NOT _gcc_version)
103
104    macro_ensure_version("4.1.0" "${_gcc_version}" GCC_IS_NEWER_THAN_4_1)
105    macro_ensure_version("4.2.0" "${_gcc_version}" GCC_IS_NEWER_THAN_4_2)
106    macro_ensure_version("4.3.0" "${_gcc_version}" GCC_IS_NEWER_THAN_4_3)
107
108    # save a little by making local statics not threadsafe
109    # ### do not enable it for older compilers, see
110    # ### http://gcc.gnu.org/bugzilla/show_bug.cgi?id=31806
111    if (GCC_IS_NEWER_THAN_4_3)
112        set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
113    endif (GCC_IS_NEWER_THAN_4_3)
114
115    set(_GCC_COMPILED_WITH_BAD_ALLOCATOR FALSE)
116    if (GCC_IS_NEWER_THAN_4_1)
117       exec_program(${CMAKE_C_COMPILER} ARGS -v OUTPUT_VARIABLE _gcc_alloc_info)
118       string(REGEX MATCH "(--enable-libstdcxx-allocator=mt)" _GCC_COMPILED_WITH_BAD_ALLOCATOR "${_gcc_alloc_info}")
119    endif (GCC_IS_NEWER_THAN_4_1)
120
121    if (__KDE_HAVE_GCC_VISIBILITY AND GCC_IS_NEWER_THAN_4_1 AND NOT _GCC_COMPILED_WITH_BAD_ALLOCATOR AND NOT WIN32)
122       set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
123       set (KDE4_C_FLAGS "-fvisibility=hidden")
124       # check that Qt defines Q_DECL_EXPORT as __attribute__ ((visibility("default")))
125       # if it doesn't and KDE compiles with hidden default visibiltiy plugins will break
126       set(_source "#include <QtCore/QtGlobal>\n int main()\n {\n #ifdef QT_VISIBILITY_AVAILABLE \n return 0;\n #else \n return 1; \n #endif \n }\n")
127       set(_source_file ${CMAKE_BINARY_DIR}/CMakeTmp/check_qt_visibility.cpp)
128       file(WRITE "${_source_file}" "${_source}")
129       set(_include_dirs "-DINCLUDE_DIRECTORIES:STRING=${QT_INCLUDES}")
130
131       try_run(_run_result _compile_result ${CMAKE_BINARY_DIR} ${_source_file} CMAKE_FLAGS "${_include_dirs}")
132
133       if(NOT _compile_result)
134          message(FATAL_ERROR "Could not compile simple test program:\n ${_source}")
135       endif(NOT _compile_result)
136       if(_run_result)
137          message(FATAL_ERROR "Qt compiled without support for -fvisibility=hidden. This will break plugins and linking of some applications. Please fix your Qt installation.")
138       endif(_run_result)
139
140       if (GCC_IS_NEWER_THAN_4_2)
141           set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
142       endif (GCC_IS_NEWER_THAN_4_2)
143    else (__KDE_HAVE_GCC_VISIBILITY AND GCC_IS_NEWER_THAN_4_1 AND NOT _GCC_COMPILED_WITH_BAD_ALLOCATOR AND NOT WIN32)
144       set (__KDE_HAVE_GCC_VISIBILITY 0)
145    endif (__KDE_HAVE_GCC_VISIBILITY AND GCC_IS_NEWER_THAN_4_1 AND NOT _GCC_COMPILED_WITH_BAD_ALLOCATOR AND NOT WIN32)
146
147 endif (CMAKE_COMPILER_IS_GNUCXX)
148
149 set(CMAKE_INCLUDE_CURRENT_DIR ON)
150 set(CMAKE_INCLUDE_DIRECTORIES_PROJECT_BEFORE ON)
151 set(CMAKE_COLOR_MAKEFILE ON)
152
153 set(PHONON_LIB_MAJOR_VERSION "4")
154 set(PHONON_LIB_MINOR_VERSION "4")
155 set(PHONON_LIB_PATCH_VERSION "1")
156 set(PHONON_LIB_VERSION "${PHONON_LIB_MAJOR_VERSION}.4.0")
157 set(PHONON_LIB_SOVERSION ${PHONON_LIB_MAJOR_VERSION})
158
159 add_definitions(${QT_DEFINITIONS})
160 remove_definitions(-DQT3_SUPPORT_WARNINGS -DQT3_SUPPORT)
161 if(MSVC)
162   add_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS )
163 endif(MSVC)
164
165 # for including config.h and for includes like <kparts/foo.h>
166 include_directories(${QT_INCLUDES} ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/includes ${CMAKE_CURRENT_SOURCE_DIR}/phonon ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/phonon)
167
168 macro(_SET_FANCY _var _value _comment)
169    if (KDESupport_SOURCE_DIR)
170       # when building inside kdesupport other subprojects write crap into our variables
171       set(${_var} "${_value}")
172    else (KDESupport_SOURCE_DIR)
173       if (NOT DEFINED ${_var})
174          set(${_var} "${_value}")
175       else (NOT DEFINED ${_var})
176          set(${_var} "${${_var}}" CACHE PATH "${_comment}")
177       endif (NOT DEFINED ${_var})
178    endif (KDESupport_SOURCE_DIR)
179 endmacro(_SET_FANCY)
180
181 set(LIB_SUFFIX "" CACHE STRING "Define suffix of directory name (32/64)" )
182
183 if (WIN32)
184     _set_fancy(EXEC_INSTALL_PREFIX         "."                                     "Base directory for executables and libraries")
185 else(WIN32)
186     _set_fancy(EXEC_INSTALL_PREFIX         "${CMAKE_INSTALL_PREFIX}"              "Base directory for executables and libraries")
187 endif(WIN32)
188 _set_fancy(SHARE_INSTALL_PREFIX        "${EXEC_INSTALL_PREFIX}/share"             "Base directory for files which go to share/")
189 _set_fancy(INCLUDE_INSTALL_DIR         "${EXEC_INSTALL_PREFIX}/include"           "The subdirectory to the header prefix")
190 _set_fancy(BIN_INSTALL_DIR             "${EXEC_INSTALL_PREFIX}/bin"                "The install dir for executables (default ${EXEC_INSTALL_PREFIX}/bin)")
191 _set_fancy(LIB_INSTALL_DIR             "${EXEC_INSTALL_PREFIX}/lib${LIB_SUFFIX}"   "The subdirectory relative to the install prefix where libraries will be installed (default is ${EXEC_INSTALL_PREFIX}/lib${LIB_SUFFIX})")
192 _set_fancy(PLUGIN_INSTALL_DIR          "${LIB_INSTALL_DIR}/kde4"                   "The subdirectory relative to the install prefix where plugins will be installed (default is ${LIB_INSTALL_DIR}/kde4)")
193 _set_fancy(ICON_INSTALL_DIR            "${SHARE_INSTALL_PREFIX}/icons"             "The icon install dir (default ${SHARE_INSTALL_PREFIX}/share/icons/)")
194 _set_fancy(SERVICES_INSTALL_DIR        "${SHARE_INSTALL_PREFIX}/kde4/services"     "The install dir for service (desktop, protocol, ...) files")
195 _set_fancy(DBUS_INTERFACES_INSTALL_DIR "${SHARE_INSTALL_PREFIX}/dbus-1/interfaces" "The dbus interfaces install dir (default: ${SHARE_INSTALL_PREFIX}/dbus-1/interfaces)")
196 _set_fancy(DBUS_SERVICES_INSTALL_DIR   "${SHARE_INSTALL_PREFIX}/dbus-1/services"   "The dbus services install dir (default: ${SHARE_INSTALL_PREFIX}/dbus-1/services)")
197
198 set(INSTALL_TARGETS_DEFAULT_ARGS  RUNTIME DESTINATION "${BIN_INSTALL_DIR}"
199                                   LIBRARY DESTINATION "${LIB_INSTALL_DIR}"
200                                   ARCHIVE DESTINATION "${LIB_INSTALL_DIR}" COMPONENT Devel )
201
202 # on the Mac support an extra install directory for application bundles
203 if(APPLE)
204    set(INSTALL_TARGETS_DEFAULT_ARGS  ${INSTALL_TARGETS_DEFAULT_ARGS}
205                                      BUNDLE DESTINATION "${BUNDLE_INSTALL_DIR}" )
206         set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS   "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS}   -flat_namespace -undefined dynamic_lookup")
207         set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -flat_namespace -undefined dynamic_lookup")
208 endif(APPLE)
209
210 if (CMAKE_SYSTEM_NAME MATCHES Linux)
211    if (CMAKE_COMPILER_IS_GNUCXX)
212       set ( CMAKE_SHARED_LINKER_FLAGS "-Wl,--fatal-warnings -Wl,--no-undefined -lc ${CMAKE_SHARED_LINKER_FLAGS}")
213       set ( CMAKE_MODULE_LINKER_FLAGS "-Wl,--fatal-warnings -Wl,--no-undefined -lc ${CMAKE_MODULE_LINKER_FLAGS}")
214
215       set ( CMAKE_SHARED_LINKER_FLAGS "-Wl,--enable-new-dtags ${CMAKE_SHARED_LINKER_FLAGS}")
216       set ( CMAKE_MODULE_LINKER_FLAGS "-Wl,--enable-new-dtags ${CMAKE_MODULE_LINKER_FLAGS}")
217       set ( CMAKE_EXE_LINKER_FLAGS "-Wl,--enable-new-dtags ${CMAKE_EXE_LINKER_FLAGS}")
218
219       # we profile...
220       if(CMAKE_BUILD_TYPE_TOLOWER MATCHES profile)
221         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
222         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
223       endif(CMAKE_BUILD_TYPE_TOLOWER MATCHES profile)
224    endif (CMAKE_COMPILER_IS_GNUCXX)
225    if (CMAKE_C_COMPILER MATCHES "icc")
226       set ( CMAKE_SHARED_LINKER_FLAGS "-Wl,--fatal-warnings -Wl,--no-undefined -lc ${CMAKE_SHARED_LINKER_FLAGS}")
227       set ( CMAKE_MODULE_LINKER_FLAGS "-Wl,--fatal-warnings -Wl,--no-undefined -lc ${CMAKE_MODULE_LINKER_FLAGS}")
228    endif (CMAKE_C_COMPILER MATCHES "icc")
229 endif (CMAKE_SYSTEM_NAME MATCHES Linux)
230
231 set(PHONON_LIBS phonon ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
232 if(QT_QTDBUS_FOUND)
233     list(APPEND PHONON_LIBS phonon ${QT_QTDBUS_LIBRARY})
234 endif(QT_QTDBUS_FOUND)
235
236 set(EXECUTABLE_OUTPUT_PATH ${Phonon_BINARY_DIR}/bin)
237 if (WIN32)
238    set(LIBRARY_OUTPUT_PATH ${EXECUTABLE_OUTPUT_PATH})
239 else (WIN32)
240    set(LIBRARY_OUTPUT_PATH ${Phonon_BINARY_DIR}/lib)
241 endif (WIN32)
242
243 if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_C_COMPILER MATCHES "icc")
244    set ( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wnon-virtual-dtor -Wno-long-long -ansi -Wundef -Wcast-align -Wchar-subscripts -Wall -W -Wpointer-arith -Wformat-security -fno-check-new -fno-common")
245 endif (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_C_COMPILER MATCHES "icc")
246
247 # Set up RPATH handling, so the libs are found if they are installed to a non-standard location.
248 # By default cmake builds the targets with full RPATH to everything in the build directory,
249 # but then removes the RPATH when installing.
250 # These two options below make it set the RPATH of the installed targets to all
251 # RPATH directories outside the current CMAKE_BINARY_DIR and also the library 
252 # install directory. Alex
253 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH  TRUE)
254 set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}" )
255
256 if(APPLE)
257    set(CMAKE_INSTALL_NAME_DIR ${LIB_INSTALL_DIR})
258 endif(APPLE)
259
260
261 add_subdirectory(phonon)
262 add_subdirectory(includes)
263 if (Q_WS_MAC AND BUILD_PHONON_QT7)
264   add_subdirectory(qt7)
265 endif (Q_WS_MAC AND BUILD_PHONON_QT7)
266 if (Q_WS_WIN)
267    add_subdirectory(ds9)
268 endif (Q_WS_WIN)
269
270 if (Q_WS_X11)
271    add_subdirectory(gstreamer)
272    add_subdirectory(xine)
273 endif (Q_WS_X11)
274
275 if(NOT WIN32) # pkgconfig file
276    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/phonon.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/phonon.pc @ONLY)
277    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/phonon.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig)
278 endif(NOT WIN32)
279
280 macro_display_feature_log()