v2.4.8 -> v2.4.8.1
[opensuse:kernel.git] / arch / arm / kernel / head-armv.S
1 /*
2  *  linux/arch/arm/kernel/head-armv.S
3  *
4  *  Copyright (C) 1994-1999 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  *
10  *  32-bit kernel startup code for all architectures
11  */
12 #include <linux/config.h>
13 #include <linux/linkage.h>
14
15 #include <asm/assembler.h>
16 #include <asm/mach-types.h>
17 #include <asm/mach/arch.h>
18
19 #define K(a,b,c)        ((a) << 24 | (b) << 12 | (c))
20
21 /*
22  * We place the page tables 16K below TEXTADDR.  Therefore, we must make sure
23  * that TEXTADDR is correctly set.  Currently, we expect the least significant
24  * "short" to be 0x8000, but we could probably relax this restriction to
25  * TEXTADDR > PAGE_OFFSET + 0x4000
26  *
27  * Note that swapper_pg_dir is the virtual address of the page tables, and
28  * pgtbl gives us a position-independent reference to these tables.  We can
29  * do this because stext == TEXTADDR
30  *
31  * swapper_pg_dir, pgtbl and krnladr are all closely related.
32  */
33 #if (TEXTADDR & 0xffff) != 0x8000
34 #error TEXTADDR must start at 0xXXXX8000
35 #endif
36
37                 .globl  SYMBOL_NAME(swapper_pg_dir)
38                 .equ    SYMBOL_NAME(swapper_pg_dir), TEXTADDR - 0x4000
39
40                 .macro  pgtbl, reg, rambase
41                 adr     \reg, stext
42                 sub     \reg, \reg, #0x4000
43                 .endm
44
45 /*
46  * Since the page table is closely related to the kernel start address, we
47  * can convert the page table base address to the base address of the section
48  * containing both.
49  */
50                 .macro  krnladr, rd, pgtable, rambase
51                 bic     \rd, \pgtable, #0x000ff000
52                 .endm
53
54 /*
55  *  Kernel startup entry point.
56  *
57  * The rules are:
58  *  r0      - should be 0
59  *  r1      - unique architecture number
60  *  MMU     - off
61  *  I-cache - on or off
62  *  D-cache - off
63  *
64  * See linux/arch/arm/tools/mach-types for the complete list of numbers
65  * for r1.
66  */
67                 .section ".text.init",#alloc,#execinstr
68                 .type   stext, #function
69 ENTRY(stext)
70                 mov     r12, r0
71 /*
72  * NOTE!  Any code which is placed here should be done for one of
73  * the following reasons:
74  *
75  *  1. Compatability with old production boot firmware (ie, users
76  *     actually have and are booting the kernel with the old firmware)
77  *     and therefore will be eventually removed.
78  *  2. Cover the case when there is no boot firmware.  This is not
79  *     ideal, but in this case, it should ONLY set r0 and r1 to the
80  *     appropriate value.
81  */
82 #if defined(CONFIG_ARCH_NETWINDER)
83 /*
84  * Compatability cruft for old NetWinder NeTTroms.  This
85  * code is currently scheduled for destruction in 2.5.xx
86  */
87                 .rept   8
88                 mov     r0, r0
89                 .endr
90
91                 adr     r2, 1f
92                 ldmdb   r2, {r7, r8}
93                 and     r3, r2, #0xc000
94                 teq     r3, #0x8000
95                 beq     __entry
96                 bic     r3, r2, #0xc000
97                 orr     r3, r3, #0x8000
98                 mov     r0, r3
99                 mov     r4, #64
100                 sub     r5, r8, r7
101                 b       1f
102
103                 .word   _stext
104                 .word   __bss_start
105
106 1:
107                 .rept   4
108                 ldmia   r2!, {r6, r7, r8, r9}
109                 stmia   r3!, {r6, r7, r8, r9}
110                 .endr
111                 subs    r4, r4, #64
112                 bcs     1b
113                 movs    r4, r5
114                 mov     r5, #0
115                 movne   pc, r0
116
117                 mov     r1, #MACH_TYPE_NETWINDER        @ (will go in 2.5)
118                 mov     r12, #2 << 24                   @ scheduled for removal in 2.5.xx
119                 orr     r12, r12, #5 << 12
120 __entry:
121 #endif
122 #if defined(CONFIG_ARCH_L7200)
123 /*
124  * FIXME - No bootloader, so manually set 'r1' with our architecture number.
125  */
126                 mov     r1, #MACH_TYPE_L7200
127 #endif
128
129                 mov     r0, #F_BIT | I_BIT | MODE_SVC   @ make sure svc mode
130                 msr     cpsr_c, r0                      @ and all irqs disabled
131                 bl      __lookup_processor_type
132                 teq     r10, #0                         @ invalid processor?
133                 moveq   r0, #'p'                        @ yes, error 'p'
134                 beq     __error
135                 bl      __lookup_architecture_type
136                 teq     r7, #0                          @ invalid architecture?
137                 moveq   r0, #'a'                        @ yes, error 'a'
138                 beq     __error
139                 bl      __create_page_tables
140                 adr     lr, __ret                       @ return address
141                 add     pc, r10, #12                    @ initialise processor
142                                                         @ (return control reg)
143
144                 .type   __switch_data, %object
145 __switch_data:  .long   __mmap_switched
146                 .long   SYMBOL_NAME(compat)
147                 .long   SYMBOL_NAME(__bss_start)
148                 .long   SYMBOL_NAME(_end)
149                 .long   SYMBOL_NAME(processor_id)
150                 .long   SYMBOL_NAME(__machine_arch_type)
151                 .long   SYMBOL_NAME(cr_alignment)
152                 .long   SYMBOL_NAME(init_task_union)+8192
153
154                 .type   __ret, %function
155 __ret:          ldr     lr, __switch_data
156                 mcr     p15, 0, r0, c1, c0
157                 mov     r0, r0
158                 mov     r0, r0
159                 mov     r0, r0
160                 mov     pc, lr
161
162                 /*
163                  * This code follows on after the page
164                  * table switch and jump above.
165                  *
166                  * r0  = processor control register
167                  * r1  = machine ID
168                  * r9  = processor ID
169                  */
170                 .align  5
171 __mmap_switched:
172                 adr     r3, __switch_data + 4
173                 ldmia   r3, {r2, r4, r5, r6, r7, r8, sp}@ r2 = compat
174                                                         @ sp = stack pointer
175                 str     r12, [r2]
176
177                 mov     fp, #0                          @ Clear BSS (and zero fp)
178 1:              cmp     r4, r5
179                 strcc   fp, [r4],#4
180                 bcc     1b
181
182                 str     r9, [r6]                        @ Save processor ID
183                 str     r1, [r7]                        @ Save machine type
184 #ifdef CONFIG_ALIGNMENT_TRAP
185                 orr     r0, r0, #2                      @ ...........A.
186 #endif
187                 bic     r2, r0, #2                      @ Clear 'A' bit
188                 stmia   r8, {r0, r2}                    @ Save control register values
189                 b       SYMBOL_NAME(start_kernel)
190
191
192
193 /*
194  * Setup the initial page tables.  We only setup the barest
195  * amount which are required to get the kernel running, which
196  * generally means mapping in the kernel code.
197  *
198  * We only map in 4MB of RAM, which should be sufficient in
199  * all cases.
200  *
201  * r5 = physical address of start of RAM
202  * r6 = physical IO address
203  * r7 = byte offset into page tables for IO
204  * r8 = page table flags
205  */
206 __create_page_tables:
207                 pgtbl   r4, r5                          @ page table address
208
209                 /*
210                  * Clear the 16K level 1 swapper page table
211                  */
212                 mov     r0, r4
213                 mov     r3, #0
214                 add     r2, r0, #0x4000
215 1:              str     r3, [r0], #4
216                 str     r3, [r0], #4
217                 str     r3, [r0], #4
218                 str     r3, [r0], #4
219                 teq     r0, r2
220                 bne     1b
221
222                 /*
223                  * Create identity mapping for first MB of kernel to
224                  * cater for the MMU enable.  This identity mapping
225                  * will be removed by paging_init()
226                  */
227                 krnladr r2, r4, r5                      @ start of kernel
228                 add     r3, r8, r2                      @ flags + kernel base
229                 str     r3, [r4, r2, lsr #18]           @ identity mapping
230
231                 /*
232                  * Now setup the pagetables for our kernel direct
233                  * mapped region.  We round TEXTADDR down to the
234                  * nearest megabyte boundary.
235                  */
236                 add     r0, r4, #(TEXTADDR & 0xff000000) >> 18 @ start of kernel
237                 bic     r2, r3, #0x00f00000
238                 str     r2, [r0]                        @ PAGE_OFFSET + 0MB
239                 add     r0, r0, #(TEXTADDR & 0x00f00000) >> 18
240                 str     r3, [r0], #4                    @ KERNEL + 0MB
241                 add     r3, r3, #1 << 20
242                 str     r3, [r0], #4                    @ KERNEL + 1MB
243                 add     r3, r3, #1 << 20
244                 str     r3, [r0], #4                    @ KERNEL + 2MB
245                 add     r3, r3, #1 << 20
246                 str     r3, [r0], #4                    @ KERNEL + 3MB
247
248                 /*
249                  * Ensure that the first section of RAM is present.
250                  * we assume that:
251                  *  1. the RAM is aligned to a 128MB boundary
252                  *  2. the kernel is executing in the same 128MB chunk
253                  *     as the start of RAM.
254                  */
255                 bic     r0, r0, #0x07f00000 >> 18       @ round down
256                 and     r2, r5, #0xf8000000             @ round down
257                 add     r3, r8, r2                      @ flags + rambase
258                 str     r3, [r0]
259
260                 bic     r8, r8, #0x0c                   @ turn off cacheable
261                                                         @ and bufferable bits
262 #ifdef CONFIG_DEBUG_LL
263                 /*
264                  * Map in IO space for serial debugging.
265                  * This allows debug messages to be output
266                  * via a serial console before paging_init.
267                  */
268                 add     r0, r4, r7
269                 rsb     r3, r7, #0x4000 @ PTRS_PER_PGD*sizeof(long)
270                 cmp     r3, #0x0800
271                 addge   r2, r0, #0x0800
272                 addlt   r2, r0, r3
273                 orr     r3, r6, r8
274 1:              str     r3, [r0], #4
275                 add     r3, r3, #1 << 20
276                 teq     r0, r2
277                 bne     1b
278 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
279                 /*
280                  * If we're using the NetWinder, we need to map in
281                  * the 16550-type serial port for the debug messages
282                  */
283                 teq     r1, #MACH_TYPE_NETWINDER
284                 teqne   r1, #MACH_TYPE_CATS
285                 bne     1f
286                 add     r0, r4, #0x3fc0
287                 mov     r3, #0x7c000000
288                 orr     r3, r3, r8
289                 str     r3, [r0], #4
290                 add     r3, r3, #1 << 20
291                 str     r3, [r0], #4
292 1:
293 #endif
294 #endif
295 #ifdef CONFIG_ARCH_RPC
296                 /*
297                  * Map in screen at 0x02000000 & SCREEN2_BASE
298                  * Similar reasons here - for debug.  This is
299                  * only for Acorn RiscPC architectures.
300                  */
301                 add     r0, r4, #0x80                   @ 02000000
302                 mov     r3, #0x02000000
303                 orr     r3, r3, r8
304                 str     r3, [r0]
305                 add     r0, r4, #0x3600                 @ d8000000
306                 str     r3, [r0]
307 #endif
308                 mov     pc, lr
309
310
311
312 /*
313  * Exception handling.  Something went wrong and we can't
314  * proceed.  We ought to tell the user, but since we
315  * don't have any guarantee that we're even running on
316  * the right architecture, we do virtually nothing.
317  * r0 = ascii error character:
318  *      a = invalid architecture
319  *      p = invalid processor
320  *      i = invalid calling convention
321  *
322  * Generally, only serious errors cause this.
323  */
324 __error:
325 #ifdef CONFIG_DEBUG_LL
326                 mov     r8, r0                          @ preserve r0
327                 adr     r0, err_str
328                 bl      printascii
329                 mov     r0, r8
330                 bl      printch
331 #endif
332 #ifdef CONFIG_ARCH_RPC
333 /*
334  * Turn the screen red on a error - RiscPC only.
335  */
336                 mov     r0, #0x02000000
337                 mov     r3, #0x11
338                 orr     r3, r3, r3, lsl #8
339                 orr     r3, r3, r3, lsl #16
340                 str     r3, [r0], #4
341                 str     r3, [r0], #4
342                 str     r3, [r0], #4
343                 str     r3, [r0], #4
344 #endif
345 1:              mov     r0, r0
346                 b       1b
347
348 #ifdef CONFIG_DEBUG_LL
349 err_str:        .asciz  "\nError: "
350                 .align
351 #endif
352
353 /*
354  * Read processor ID register (CP#15, CR0), and look up in the linker-built
355  * supported processor list.  Note that we can't use the absolute addresses
356  * for the __proc_info lists since we aren't running with the MMU on
357  * (and therefore, we are not in the correct address space).  We have to
358  * calculate the offset.
359  *
360  * Returns:
361  *      r5, r6, r7 corrupted
362  *      r8  = page table flags
363  *      r9  = processor ID
364  *      r10 = pointer to processor structure
365  */
366 __lookup_processor_type:
367                 adr     r5, 2f
368                 ldmia   r5, {r7, r9, r10}
369                 sub     r5, r5, r10                     @ convert addresses
370                 add     r7, r7, r5                      @ to our address space
371                 add     r10, r9, r5
372                 mrc     p15, 0, r9, c0, c0              @ get processor id
373 1:              ldmia   r10, {r5, r6, r8}               @ value, mask, mmuflags
374                 and     r6, r6, r9                      @ mask wanted bits
375                 teq     r5, r6
376                 moveq   pc, lr
377                 add     r10, r10, #36                   @ sizeof(proc_info_list)
378                 cmp     r10, r7
379                 blt     1b
380                 mov     r10, #0                         @ unknown processor
381                 mov     pc, lr
382
383 /*
384  * Look in include/asm-arm/procinfo.h and arch/arm/kernel/arch.[ch] for
385  * more information about the __proc_info and __arch_info structures.
386  */
387 2:              .long   __proc_info_end
388                 .long   __proc_info_begin
389                 .long   2b
390                 .long   __arch_info_begin
391                 .long   __arch_info_end
392
393 /*
394  * Lookup machine architecture in the linker-build list of architectures.
395  * Note that we can't use the absolute addresses for the __arch_info
396  * lists since we aren't running with the MMU on (and therefore, we are
397  * not in the correct address space).  We have to calculate the offset.
398  *
399  *  r1 = machine architecture number
400  * Returns:
401  *  r2, r3, r4 corrupted
402  *  r5 = physical start address of RAM
403  *  r6 = physical address of IO
404  *  r7 = byte offset into page tables for IO
405  */
406 __lookup_architecture_type:
407                 adr     r4, 2b
408                 ldmia   r4, {r2, r3, r5, r6, r7}        @ throw away r2, r3
409                 sub     r5, r4, r5                      @ convert addresses
410                 add     r4, r6, r5                      @ to our address space
411                 add     r7, r7, r5
412 1:              ldr     r5, [r4]                        @ get machine type
413                 teq     r5, r1
414                 beq     2f
415                 add     r4, r4, #SIZEOF_MACHINE_DESC
416                 cmp     r4, r7
417                 blt     1b
418                 mov     r7, #0                          @ unknown architecture
419                 mov     pc, lr
420 2:              ldmib   r4, {r5, r6, r7}                @ found, get results
421                 mov     r7, r7, lsr #18                 @ pagetable byte offset
422                 mov     pc, lr