v2.4.8 -> v2.4.8.1
[opensuse:kernel.git] / arch / arm / kernel / entry-common.S
1 /*
2  *  linux/arch/arm/kernel/entry-common.S
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10 #include <linux/config.h>
11 #include "entry-header.S"
12
13 /* 
14  * We rely on the fact that R0 is at the bottom of the stack (due to
15  * slow/fast restore user regs).
16  */
17 #if S_R0 != 0
18 #error "Please fix"
19 #endif
20
21 /*
22  * Our do_softirq out of line code.  See include/asm-arm/softirq.h for
23  * the calling assembly.
24  */
25         .section ".text.lock","ax"
26 ENTRY(__do_softirq)
27         stmfd   sp!, {r0 - r3, ip, lr}
28         bl      do_softirq
29         ldmfd   sp!, {r0 - r3, ip, pc}
30         .previous
31
32         .align  5
33 /*
34  * This is the fast syscall return path.  We do as little as
35  * possible here, and this includes saving r0 back into the SVC
36  * stack.
37  */
38 ret_fast_syscall:
39         ldr     r1, [tsk, #TSK_NEED_RESCHED]
40         ldr     r2, [tsk, #TSK_SIGPENDING]
41         teq     r1, #0                          @ need_resched || sigpending
42         teqeq   r2, #0
43         bne     slow
44         fast_restore_user_regs
45
46 /*
47  * Ok, we need to do extra processing, enter the slow path.
48  */
49 slow:   str     r0, [sp, #S_R0+S_OFF]!  @ returned r0
50         b       1f
51
52 /*
53  * "slow" syscall return path.  "why" tells us if this was a real syscall.
54  */
55 reschedule:
56         bl      SYMBOL_NAME(schedule)
57 ENTRY(ret_to_user)
58 ret_slow_syscall:
59         ldr     r1, [tsk, #TSK_NEED_RESCHED]
60         ldr     r2, [tsk, #TSK_SIGPENDING]
61 1:      teq     r1, #0                          @ need_resched => schedule()
62         bne     reschedule
63         teq     r2, #0                          @ sigpending => do_signal()
64         blne    __do_signal
65         restore_user_regs
66
67 __do_signal:
68         mov     r0, #0                          @ NULL 'oldset'
69         mov     r1, sp                          @ 'regs'
70         mov     r2, why                         @ 'syscall'
71         b       SYMBOL_NAME(do_signal)          @ note the bl above sets lr
72
73 /*
74  * This is how we return from a fork.  __switch_to will be calling us
75  * with r0 pointing at the previous task that was running (ready for
76  * calling schedule_tail).
77  */
78 ENTRY(ret_from_fork)
79         bl      SYMBOL_NAME(schedule_tail)
80         get_current_task tsk
81         ldr     ip, [tsk, #TSK_PTRACE]          @ check for syscall tracing
82         mov     why, #1
83         tst     ip, #PT_TRACESYS                @ are we tracing syscalls?
84         beq     ret_slow_syscall
85         mov     r1, sp
86         mov     r0, #1                          @ trace exit [IP = 1]
87         bl      SYMBOL_NAME(syscall_trace)
88         b       ret_slow_syscall
89         
90
91 #include "calls.S"
92
93 /*=============================================================================
94  * SWI handler
95  *-----------------------------------------------------------------------------
96  */
97
98         /* If we're optimising for StrongARM the resulting code won't 
99            run on an ARM7 and we can save a couple of instructions.  
100                                                                 --pb */
101 #ifdef CONFIG_CPU_ARM710
102         .macro  arm710_bug_check, instr, temp
103         and     \temp, \instr, #0x0f000000      @ check for SWI
104         teq     \temp, #0x0f000000
105         bne     .Larm700bug
106         .endm
107
108 .Larm700bug:
109         ldr     r0, [sp, #S_PSR]                @ Get calling cpsr
110         sub     lr, lr, #4
111         str     lr, [r8]
112         msr     spsr, r0
113         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
114         mov     r0, r0
115         ldr     lr, [sp, #S_PC]                 @ Get PC
116         add     sp, sp, #S_FRAME_SIZE
117         movs    pc, lr
118 #else
119         .macro  arm710_bug_check, instr, temp
120         .endm
121 #endif
122
123         .align  5
124 ENTRY(vector_swi)
125         save_user_regs
126         mask_pc lr, lr
127         zero_fp
128         ldr     scno, [lr, #-4]                 @ get SWI instruction
129         arm710_bug_check scno, ip
130
131 #ifdef CONFIG_ALIGNMENT_TRAP
132         ldr     ip, __cr_alignment
133         ldr     ip, [ip]
134         mcr     p15, 0, ip, c1, c0              @ update control register
135 #endif
136         enable_irqs ip
137
138         str     r4, [sp, #-S_OFF]!              @ push fifth arg
139
140         get_current_task tsk
141         ldr     ip, [tsk, #TSK_PTRACE]          @ check for syscall tracing
142         bic     scno, scno, #0xff000000         @ mask off SWI op-code
143         eor     scno, scno, #OS_NUMBER << 20    @ check OS number
144         adr     tbl, sys_call_table             @ load syscall table pointer
145         tst     ip, #PT_TRACESYS                @ are we tracing syscalls?
146         bne     __sys_trace
147
148         adrsvc  al, lr, ret_fast_syscall        @ return address
149         cmp     scno, #NR_syscalls              @ check upper syscall limit
150         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
151
152         add     r1, sp, #S_OFF
153 2:      mov     why, #0                         @ no longer a real syscall
154         cmp     scno, #ARMSWI_OFFSET
155         eor     r0, scno, #OS_NUMBER << 20      @ put OS number back
156         bcs     SYMBOL_NAME(arm_syscall)        
157         b       SYMBOL_NAME(sys_ni_syscall)     @ not private func
158
159         /*
160          * This is the really slow path.  We're going to be doing
161          * context switches, and waiting for our parent to respond.
162          */
163 __sys_trace:
164         add     r1, sp, #S_OFF
165         mov     r0, #0                          @ trace entry [IP = 0]
166         bl      SYMBOL_NAME(syscall_trace)
167
168         adrsvc  al, lr, __sys_trace_return      @ return address
169         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
170         cmp     scno, #NR_syscalls              @ check upper syscall limit
171         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
172         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
173         b       2b
174
175 __sys_trace_return:
176         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
177         mov     r1, sp
178         mov     r0, #1                          @ trace exit [IP = 1]
179         bl      SYMBOL_NAME(syscall_trace)
180         b       ret_slow_syscall
181
182         .align  5
183 #ifdef CONFIG_ALIGNMENT_TRAP
184         .type   __cr_alignment, #object
185 __cr_alignment:
186         .word   SYMBOL_NAME(cr_alignment)
187 #endif
188
189         .type   sys_call_table, #object
190 ENTRY(sys_call_table)
191 #include "calls.S"
192
193 /*============================================================================
194  * Special system call wrappers
195  */
196 @ r0 = syscall number
197 @ r5 = syscall table
198                 .type   sys_syscall, #function
199 SYMBOL_NAME(sys_syscall):
200                 eor     scno, r0, #OS_NUMBER << 20
201                 cmp     scno, #NR_syscalls      @ check range
202                 stmleia sp, {r5, r6}            @ shuffle args
203                 movle   r0, r1
204                 movle   r1, r2
205                 movle   r2, r3
206                 movle   r3, r4
207                 ldrle   pc, [tbl, scno, lsl #2]
208                 b       sys_ni_syscall
209
210 sys_fork_wrapper:
211                 add     r0, sp, #S_OFF
212                 b       SYMBOL_NAME(sys_fork)
213
214 sys_vfork_wrapper:
215                 add     r0, sp, #S_OFF
216                 b       SYMBOL_NAME(sys_vfork)
217
218 sys_execve_wrapper:
219                 add     r3, sp, #S_OFF
220                 b       SYMBOL_NAME(sys_execve)
221
222 sys_clone_wapper:
223                 add     r2, sp, #S_OFF
224                 b       SYMBOL_NAME(sys_clone)
225
226 sys_sigsuspend_wrapper:
227                 add     r3, sp, #S_OFF
228                 b       SYMBOL_NAME(sys_sigsuspend)
229
230 sys_rt_sigsuspend_wrapper:
231                 add     r2, sp, #S_OFF
232                 b       SYMBOL_NAME(sys_rt_sigsuspend)
233
234 sys_sigreturn_wrapper:
235                 add     r0, sp, #S_OFF
236                 b       SYMBOL_NAME(sys_sigreturn)
237
238 sys_rt_sigreturn_wrapper:
239                 add     r0, sp, #S_OFF
240                 b       SYMBOL_NAME(sys_rt_sigreturn)
241
242 sys_sigaltstack_wrapper:
243                 ldr     r2, [sp, #S_OFF + S_SP]
244                 b       do_sigaltstack
245
246 /*
247  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
248  * offset, we return EINVAL.
249  */
250 sys_mmap2:
251 #if PAGE_SHIFT > 12
252                 tst     r5, #PGOFF_MASK
253                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
254                 streq   r5, [sp, #4]
255                 beq     do_mmap2
256                 mov     r0, #-EINVAL
257                 RETINSTR(mov,pc, lr)
258 #else
259                 str     r5, [sp, #4]
260                 b       do_mmap2
261 #endif