Merge bk://linux.bkbits.net/linux-2.5
[opensuse:kernel.git] / arch / ia64 / kernel / gate.S
1 /*
2  * This file contains the code that gets mapped at the upper end of each task's text
3  * region.  For now, it contains the signal trampoline code only.
4  *
5  * Copyright (C) 1999-2001 Hewlett-Packard Co
6  *      David Mosberger-Tang <davidm@hpl.hp.com>
7  */
8
9 #include <asm/asmmacro.h>
10 #include <asm/offsets.h>
11 #include <asm/sigcontext.h>
12 #include <asm/system.h>
13 #include <asm/unistd.h>
14 #include <asm/page.h>
15
16         .section .text.gate,"ax"
17
18 #       define ARG0_OFF         (16 + IA64_SIGFRAME_ARG0_OFFSET)
19 #       define ARG1_OFF         (16 + IA64_SIGFRAME_ARG1_OFFSET)
20 #       define ARG2_OFF         (16 + IA64_SIGFRAME_ARG2_OFFSET)
21 #       define SIGHANDLER_OFF   (16 + IA64_SIGFRAME_HANDLER_OFFSET)
22 #       define SIGCONTEXT_OFF   (16 + IA64_SIGFRAME_SIGCONTEXT_OFFSET)
23
24 #       define FLAGS_OFF        IA64_SIGCONTEXT_FLAGS_OFFSET
25 #       define CFM_OFF          IA64_SIGCONTEXT_CFM_OFFSET
26 #       define FR6_OFF          IA64_SIGCONTEXT_FR6_OFFSET
27 #       define BSP_OFF          IA64_SIGCONTEXT_AR_BSP_OFFSET
28 #       define RNAT_OFF         IA64_SIGCONTEXT_AR_RNAT_OFFSET
29 #       define UNAT_OFF         IA64_SIGCONTEXT_AR_UNAT_OFFSET
30 #       define FPSR_OFF         IA64_SIGCONTEXT_AR_FPSR_OFFSET
31 #       define PR_OFF           IA64_SIGCONTEXT_PR_OFFSET
32 #       define RP_OFF           IA64_SIGCONTEXT_B0_OFFSET
33 #       define SP_OFF           IA64_SIGCONTEXT_R12_OFFSET
34 #       define RBS_BASE_OFF     IA64_SIGCONTEXT_RBS_BASE_OFFSET
35 #       define LOADRS_OFF       IA64_SIGCONTEXT_LOADRS_OFFSET
36 #       define base0            r2
37 #       define base1            r3
38         /*
39          * When we get here, the memory stack looks like this:
40          *
41          *   +===============================+
42          *   |                               |
43          *   //     struct sigframe          //
44          *   |                               |
45          *   +-------------------------------+ <-- sp+16
46          *   |      16 byte of scratch       |
47          *   |            space              |
48          *   +-------------------------------+ <-- sp
49          *
50          * The register stack looks _exactly_ the way it looked at the time the signal
51          * occurred.  In other words, we're treading on a potential mine-field: each
52          * incoming general register may be a NaT value (including sp, in which case the
53          * process ends up dying with a SIGSEGV).
54          *
55          * The first thing need to do is a cover to get the registers onto the backing
56          * store.  Once that is done, we invoke the signal handler which may modify some
57          * of the machine state.  After returning from the signal handler, we return
58          * control to the previous context by executing a sigreturn system call.  A signal
59          * handler may call the rt_sigreturn() function to directly return to a given
60          * sigcontext.  However, the user-level sigreturn() needs to do much more than
61          * calling the rt_sigreturn() system call as it needs to unwind the stack to
62          * restore preserved registers that may have been saved on the signal handler's
63          * call stack.
64          */
65
66 GLOBAL_ENTRY(ia64_sigtramp)
67         // describe the state that is active when we get here:
68         .prologue
69         .unwabi @svr4, 's'              // mark this as a sigtramp handler (saves scratch regs)
70         .savesp ar.unat, UNAT_OFF+SIGCONTEXT_OFF
71         .savesp ar.fpsr, FPSR_OFF+SIGCONTEXT_OFF
72         .savesp pr, PR_OFF+SIGCONTEXT_OFF
73         .savesp rp, RP_OFF+SIGCONTEXT_OFF
74         .vframesp SP_OFF+SIGCONTEXT_OFF
75         .body
76
77         .label_state 1
78
79         adds base0=SIGHANDLER_OFF,sp
80         adds base1=RBS_BASE_OFF+SIGCONTEXT_OFF,sp
81         br.call.sptk.many rp=1f
82 1:
83         ld8 r17=[base0],(ARG0_OFF-SIGHANDLER_OFF)       // get pointer to signal handler's plabel
84         ld8 r15=[base1]                                 // get address of new RBS base (or NULL)
85         cover                           // push args in interrupted frame onto backing store
86         ;;
87         cmp.ne p8,p0=r15,r0             // do we need to switch the rbs?
88         mov.m r9=ar.bsp                 // fetch ar.bsp
89         .spillsp.p p8, ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
90 (p8)    br.cond.spnt setup_rbs          // yup -> (clobbers r14, r15, and r16)
91 back_from_setup_rbs:
92
93         .spillreg ar.pfs, r8
94         alloc r8=ar.pfs,0,0,3,0         // get CFM0, EC0, and CPL0 into r8
95         ld8 out0=[base0],16             // load arg0 (signum)
96         adds base1=(ARG1_OFF-(RBS_BASE_OFF+SIGCONTEXT_OFF)),base1
97         ;;
98         ld8 out1=[base1]                // load arg1 (siginfop)
99         ld8 r10=[r17],8                 // get signal handler entry point
100         ;;
101         ld8 out2=[base0]                // load arg2 (sigcontextp)
102         ld8 gp=[r17]                    // get signal handler's global pointer
103
104         adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
105         ;;
106         .spillsp ar.bsp, BSP_OFF+SIGCONTEXT_OFF
107         st8 [base0]=r9,(CFM_OFF-BSP_OFF)        // save sc_ar_bsp
108         dep r8=0,r8,38,26                       // clear EC0, CPL0 and reserved bits
109         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
110         ;;
111         .spillsp ar.pfs, CFM_OFF
112         st8 [base0]=r8                          // save CFM0
113         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
114         ;;
115         stf.spill [base0]=f6,32
116         stf.spill [base1]=f7,32
117         ;;
118         stf.spill [base0]=f8,32
119         stf.spill [base1]=f9,32
120         mov b6=r10
121         ;;
122         stf.spill [base0]=f10,32
123         stf.spill [base1]=f11,32
124         ;;
125         stf.spill [base0]=f12,32
126         stf.spill [base1]=f13,32
127         ;;
128         stf.spill [base0]=f14,32
129         stf.spill [base1]=f15,32
130         br.call.sptk.many rp=b6                 // call the signal handler
131 .ret0:  adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
132         ;;
133         ld8 r15=[base0],(CFM_OFF-BSP_OFF)       // fetch sc_ar_bsp and advance to CFM_OFF
134         mov r14=ar.bsp
135         ;;
136         ld8 r8=[base0]                          // restore (perhaps modified) CFM0, EC0, and CPL0
137         cmp.ne p8,p0=r14,r15                    // do we need to restore the rbs?
138 (p8)    br.cond.spnt restore_rbs                // yup -> (clobbers r14 and r16)
139         ;;
140 back_from_restore_rbs:
141         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
142         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
143         ;;
144         ldf.fill f6=[base0],32
145         ldf.fill f7=[base1],32
146         ;;
147         ldf.fill f8=[base0],32
148         ldf.fill f9=[base1],32
149         ;;
150         ldf.fill f10=[base0],32
151         ldf.fill f11=[base1],32
152         ;;
153         ldf.fill f12=[base0],32
154         ldf.fill f13=[base1],32
155         ;;
156         ldf.fill f14=[base0],32
157         ldf.fill f15=[base1],32
158         mov r15=__NR_rt_sigreturn
159         break __BREAK_SYSCALL
160
161         .body
162         .copy_state 1
163 setup_rbs:
164         mov ar.rsc=0                            // put RSE into enforced lazy mode
165         ;;
166         .save ar.rnat, r16
167         mov r16=ar.rnat                         // save RNaT before switching backing store area
168         adds r14=(RNAT_OFF+SIGCONTEXT_OFF),sp
169
170         mov ar.bspstore=r15                     // switch over to new register backing store area
171         ;;
172         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
173         st8 [r14]=r16                           // save sc_ar_rnat
174         adds r14=(LOADRS_OFF+SIGCONTEXT_OFF),sp
175
176         mov.m r16=ar.bsp                        // sc_loadrs <- (new bsp - new bspstore) << 16
177         ;;
178         invala
179         sub r15=r16,r15
180         ;;
181         shl r15=r15,16
182         ;;
183         st8 [r14]=r15                           // save sc_loadrs
184         mov ar.rsc=0xf                          // set RSE into eager mode, pl 3
185         br.cond.sptk back_from_setup_rbs
186
187         .prologue
188         .copy_state 1
189         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
190         .body
191 restore_rbs:
192         alloc r2=ar.pfs,0,0,0,0                 // alloc null frame
193         adds r16=(LOADRS_OFF+SIGCONTEXT_OFF),sp
194         ;;
195         ld8 r14=[r16]
196         adds r16=(RNAT_OFF+SIGCONTEXT_OFF),sp
197         ;;
198         mov ar.rsc=r14                          // put RSE into enforced lazy mode
199         ld8 r14=[r16]                           // get new rnat
200         ;;
201         loadrs                                  // restore dirty partition
202         ;;
203         mov ar.bspstore=r15                     // switch back to old register backing store area
204         ;;
205         mov ar.rnat=r14                         // restore RNaT
206         mov ar.rsc=0xf                          // (will be restored later on from sc_ar_rsc)
207         // invala not necessary as that will happen when returning to user-mode
208         br.cond.sptk back_from_restore_rbs
209 END(ia64_sigtramp)