need to recursively chown TOPDIR
[opensuse:build.git] / substitutedeps
1 #!/usr/bin/perl -w
2
3 BEGIN {
4   unshift @INC, ($::ENV{'BUILD_DIR'} || '/usr/lib/build');
5 }
6
7 use strict;
8
9 use Build;
10
11 sub expand {
12   my ($config, $str) = @_;
13   my @xspec;
14   my %cf = %$config;
15   $cf{'save_expanded'} = 1;
16   Build::Rpm::parse(\%cf, [ "$str" ], \@xspec);
17   return @xspec && ref($xspec[0]) ? $xspec[0]->[1] : '';
18 }
19
20 my ($dist, $buildroot, $rpmdeps, $archs, $configdir, $release, $changelog);
21
22 while (@ARGV)  {
23   if ($ARGV[0] eq '--root') {
24     shift @ARGV;
25     $buildroot = shift @ARGV;
26     next;
27   }
28   if ($ARGV[0] eq '--dist') {
29     shift @ARGV;
30     $dist = shift @ARGV;
31     next;
32   }
33   if ($ARGV[0] eq '--archpath') {
34     shift @ARGV;
35     $archs = shift @ARGV;
36     next;
37   }
38   if ($ARGV[0] eq '--configdir') {
39     shift @ARGV;
40     $configdir = shift @ARGV;
41     next;
42   }
43   if ($ARGV[0] eq '--release') {
44     shift @ARGV;
45     $release = shift @ARGV;
46     next;
47   }
48   if ($ARGV[0] eq '--changelog') {
49     shift @ARGV;
50     $changelog = shift @ARGV;
51     next;
52   }
53   last;
54 }
55 die("Usage: substitutedeps --dist <dist> --archpath <archpath> [--configdir <configdir>] <specin> <specout>\n") unless @ARGV == 2;
56 my $spec = $ARGV[0];
57 my $specdir = $spec;
58 $specdir =~ s/[^\/]*$//;
59 $specdir = "./" if $specdir eq '';
60
61 my $newspec = $ARGV[1];
62
63 my $cf = Build::read_config_dist($dist, $archs, $configdir);
64 $cf->{'warnings'} = 1;
65
66 #######################################################################
67
68 my $xspec = [];
69 my $d = Build::parse($cf, $spec, $xspec) || {};
70 my @sdeps = @{$d->{'deps'} || []};
71 my @neg = map {substr($_, 1)} grep {/^-/} @{$d->{'deps'} || []};
72 my %neg = map {$_ => 1} @neg;
73 @sdeps = grep {!$neg{$_}} @sdeps;
74 @sdeps = Build::do_subst($cf, @sdeps);
75 @sdeps = grep {!$neg{$_}} @sdeps;
76 my %sdeps = map {$_ => 1} @sdeps;
77
78 open(F, '>', $newspec) || die("$newspec: $!\n");
79
80 my $used;
81 my $inchangelog = 0;
82 my $mainpkg = '';
83 my $pkg;
84
85 for my $l (@$xspec) {
86   $used = 1;
87   if (ref($l)) {
88     if (!defined($l->[1])) {
89       $used = 0;
90       $l = $l->[0];
91     } else {
92       $l = $l->[1];
93     }
94   }
95
96   if ($inchangelog) {
97     $inchangelog = 0 if $l =~ /^\s*%[^%]/;
98     next if $inchangelog;
99   }
100   if ($changelog && ($l =~ /\s*\%changelog\b/)) {
101     $inchangelog = 1;
102     next;
103   }
104
105   if ($l =~ /^Name\s*:\s*(\S+)/i) {
106     $pkg = $mainpkg = $1 unless $mainpkg;
107   }
108   if ($l =~ /^\s*%package\s+(-n\s+)?(\S+)/) {
109     if ($1) {
110       $pkg = $2;
111     } else {
112       $pkg = "$mainpkg-$2";
113     }
114   }
115
116   if ($l =~ /^Release:/i) {
117     my $oldl = $l;
118     if (defined $release) {
119       if (!($l =~ s/<RELEASE\d*>/$release/g)) {
120         if ($l =~ /<(?:CI_CNT|B_CNT)>/) {
121           # XXX: should pass ci_cnt/b_cnt instead
122           if ($release =~ /(\d+)\.(\d+)$/) {
123             my ($ci, $b) = ($1, $2);
124             $l =~ s/<CI_CNT>/$ci/;
125             $l =~ s/<B_CNT>/$b/;
126           } elsif ($release =~ /(\d+)$/) {
127             my $b = $1;
128             $l =~ s/<B_CNT>/$b/ unless $l =~ s/<CI_CNT>/$b/;
129           }
130         } else {
131           $l =~ s/^(Release:\s*).*/$1$release/i;
132         }
133       }
134     }
135     # this is to be compatible to legacy autobuild.
136     # you can specify a releaseprg in the project configuration,
137     # if your package contains this file it is executed and its
138     # output is used as a release.
139     # use only if you really must.
140     if ($cf->{'releaseprg'} && -f "$specdir$cf->{'releaseprg'}") {
141       my $newl = $l;
142       $newl =~ s/^Release:\s*//;
143       $oldl =~ s/^Release:\s*//;
144       my $project = expand($cf, "%?_project") || 'BUILD_BASENAME';
145       my $arch = expand($cf, "%?_target_cpu") || 'noarch';
146       $::ENV{'BUILD_OLDRELEASE'} = $oldl;
147       my @nl;
148       my $interpreter = "/bin/bash";
149       if (open(RP, '<', "$specdir$cf->{'releaseprg'}")) {
150         @nl = <RP>;
151         close RP;
152         if (@nl && $nl[0] =~ /^#!\s*(\S*)/) {
153           $interpreter = $1;
154         }
155       }
156       if ($buildroot) {
157         my $sd = $specdir;
158         $sd =~ s/^\Q$buildroot\E//;
159         open(RP, "-|", 'chroot', $buildroot, $interpreter, "$sd$cf->{'releaseprg'}", $project, $newl, $pkg, $arch) || die("$cf->{'releaseprg'}: $!\n");
160       } else {
161         open(RP, "-|", $interpreter, "$specdir$cf->{'releaseprg'}", $project, $newl, $pkg, $arch) || die("$cf->{'releaseprg'}: $!\n");
162       }
163       @nl = grep {$_ ne ''} <RP>;
164       if (!close(RP)) {
165         warn("$cf->{'releaseprg'} failed: $?\n");
166       }
167       # and another compatibility hack: if the prg returns pkg:<package>,
168       # the release of the package will be used. yuck...
169       if (@nl && $nl[0] =~ s/^pkg://) {
170         my $relpkg = $nl[0];
171         chomp $relpkg;
172         if ($buildroot) {
173           open(RP, "-|", 'chroot', $buildroot, 'rpm', '-q', '--qf', '%{RELEASE}', $relpkg) || die("rpm: $!\n");
174         } else {
175           open(RP, "-|", 'rpm', '-q', '--qf', '%{RELEASE}', $relpkg) || die("rpm: $!\n");
176         }
177         @nl = grep {$_ ne ''} <RP>;
178         if (!close(RP)) {
179           warn("rpm package query of '$relpkg' failed: $?\n");
180         }
181       }
182       if ($nl[0]) {
183         chomp $nl[0];
184         $l =~ s/^(Release:\s*).*/$1$nl[0]/i;
185         if (defined $release) {
186           if (!($l =~ s/<RELEASE\d*>/$release/g)) {
187             if ($l =~ /<(?:CI_CNT|B_CNT)>/) {
188               # XXX: should pass ci_cnt/b_cnt instead
189               if ($release =~ /(\d+)\.(\d+)$/) {
190                 my ($ci, $b) = ($1, $2);
191                 $l =~ s/<CI_CNT>/$ci/;
192                 $l =~ s/<B_CNT>/$b/;
193               } elsif ($release =~ /(\d+)$/) {
194                 my $b = $1;
195                 $l =~ s/<B_CNT>/$b/ unless $l =~ s/<CI_CNT>/$b/;
196               }
197             }
198           }
199         }
200       }
201     }
202     # all compat stuff done. we return to your scheduled program
203   }
204
205   if (!$used || ($l !~ /^(?:Build)?Requires:/i)) {
206     print F "$l\n";
207     next;
208   }
209
210   my $isbuildrequires = 0;
211   $isbuildrequires = 1 if $l =~ /^BuildRequires:/i;
212   my $r = $l;
213   $r =~ s/^[^:]*:\s*//;
214   my @deps = $r =~ /([^\s\[,]+)(\s+[<=>]+\s+[^\s\[,]+)?[\s,]*/g;
215   my @ndeps = ();
216   my $replace = 0;
217   my @f2 = Build::do_subst_vers($cf, @deps);
218   my %f2 = @f2;
219   if ($isbuildrequires) {
220     delete $f2{$_} for @neg;
221     delete $f2{$_} for grep {/^-/} keys %f2;
222   }
223   while (@deps) {
224     my ($pack, $vers) = splice(@deps, 0, 2);
225     $vers = '' unless defined $vers;
226     if (($isbuildrequires && $sdeps{$pack}) || exists($f2{$pack})) {
227       push @ndeps, "$pack$vers";
228       delete $f2{$pack};
229     } else {
230       $replace = 1;
231     }
232   }
233   if (%f2) {
234     while (@f2) {
235       my ($pack, $vers) = splice(@f2, 0, 2);
236       next unless exists $f2{$pack};
237       $vers = '' unless defined $vers;
238       push @ndeps, "$pack$vers";
239     }
240     $replace = 1
241   }
242   if ($replace) {
243     $l =~ /^(.*?:\s*)/;
244     print F $1.join(' ', @ndeps)."\n" if @ndeps;
245   } else {
246     print F "$l\n";
247   }
248 }
249
250 if ($changelog) {
251   print F "%changelog\n";
252   if (open(CF, '<', $changelog)) {
253     while(<CF>) {
254       print F $_;
255     }
256     close CF;
257   }
258 }
259
260 close(F) || die("close: $!\n");
261
262 exit(0);