Allow expectations to suppress data sorting
[openmx:openmx.git] / acsite.m4
1 AC_DEFUN([AX_GCC_VERSION], [
2   GCC_VERSION=""
3   AX_GCC_OPTION([-dumpversion],[],[],[
4     ax_gcc_version_option=yes
5   ],[
6     ax_gcc_version_option=no
7   ])
8   AS_IF([test "x$GCC" = "xyes"],[
9     AS_IF([test "x$ax_gcc_version_option" != "no"],[
10       AC_CACHE_CHECK([gcc version],[ax_cv_gcc_version],[
11         ax_cv_gcc_version="`$CC -dumpversion`"
12         AS_IF([test "x$ax_cv_gcc_version" = "x"],[
13           ax_cv_gcc_version=""
14         ])
15       ])
16       GCC_VERSION=$ax_cv_gcc_version
17     ])
18   ])
19   AC_SUBST([GCC_VERSION])
20 ])
21
22 AC_DEFUN([AX_GCC_OPTION], [
23   AC_REQUIRE([AC_PROG_CC])
24
25   AC_MSG_CHECKING([if gcc accepts $1 option])
26
27   AS_IF([ test "x$GCC" = "xyes" ],[
28     AS_IF([ test -z "$3" ],[
29       ax_gcc_option_test="int main()
30 {
31         return 0;
32 }"
33     ],[
34       ax_gcc_option_test="$3"
35     ])
36
37     # Dump the test program to file
38     cat <<EOF > conftest.c
39 $ax_gcc_option_test
40 EOF
41
42     # Dump back the file to the log, useful for debugging purposes
43     AC_TRY_COMMAND(cat conftest.c 1>&AS_MESSAGE_LOG_FD)
44
45     AS_IF([ AC_TRY_COMMAND($CC $2 $1 -c conftest.c 1>&AS_MESSAGE_LOG_FD) ],[
46                 AC_MSG_RESULT([yes])
47         $4
48     ],[
49                 AC_MSG_RESULT([no])
50         $5
51     ])
52   ],[
53     AC_MSG_RESULT([no gcc available])
54   ])
55 ])
56
57 AC_DEFUN([AX_C_CHECK_FLAG],[
58   AC_PREREQ([2.61])
59   AC_REQUIRE([AC_PROG_CC])
60   AC_REQUIRE([AC_PROG_SED])
61
62   flag=`echo "$1" | $SED 'y% .=/+-(){}<>:*,%_______________%'`
63
64   AC_CACHE_CHECK([whether the C compiler accepts the $1 flag],
65     [ax_cv_c_check_flag_$flag],[
66
67     AC_LANG_PUSH([C])
68
69     save_CFLAGS="$CFLAGS"
70     CFLAGS="$CFLAGS $1"
71     AC_COMPILE_IFELSE([
72       AC_LANG_PROGRAM([$2],[$3])
73     ],[
74       eval "ax_cv_c_check_flag_$flag=yes"
75     ],[
76       eval "ax_cv_c_check_flag_$flag=no"
77     ])
78
79     CFLAGS="$save_CFLAGS"
80
81     AC_LANG_POP
82
83   ])
84
85   AS_IF([eval "test \"`echo '$ax_cv_c_check_flag_'$flag`\" = yes"],[
86     :
87     $4
88   ],[
89     :
90     $5
91   ])
92 ])
93
94