SIM Application Toolkit: build system
[meego-ux:meego-app-satk.git] / meego-app-satk.pro
1 # ---- Include
2 include(common.pri)
3
4
5 # ---- Configuration
6
7 QT += core gui declarative
8 CONFIG += qdbus
9
10 TARGET = satk
11 TEMPLATE = app
12 target.path=/usr/bin
13 INSTALLS=target
14
15
16 # ---- Generated DBus Interfaces
17
18 !exists(modemif.h) {
19     system(qdbusxml2cpp -v -c ModemIf -p modemif.h:modemif.cpp -i ofonodbustypes.h interfaces/org.ofono.Modem.xml)
20 }
21 !exists(mgrif.h) {
22     system(qdbusxml2cpp -v -c MgrIf -p mgrif.h:mgrif.cpp -i ofonodbustypes.h interfaces/org.ofono.Manager.xml)
23 }
24 !exists(simif.h) {
25     system(qdbusxml2cpp -v -c SimIf -p simif.h:simif.cpp interfaces/org.ofono.SimManager.xml)
26 }
27 !exists(stkif.h) {
28     system(qdbusxml2cpp -v -c StkIf -p stkif.h:stkif.cpp interfaces/org.ofono.SimToolkit.xml)
29 }
30 !exists(stkagentifadaptor.h) {
31     system(qdbusxml2cpp -v -c StkAgentIfAdaptor -a stkagentifadaptor.h:stkagentifadaptor.cpp -i ofonodbustypes.h interfaces/org.ofono.SimToolkitAgent.xml)
32 }
33
34
35 # ---- Sources
36
37 SOURCES += \
38     *.cpp
39
40 HEADERS += \
41     *.h
42
43 OTHER_FILES += \
44     *.js \
45     *.qml \
46     interfaces/*.xml
47
48 RESOURCES += \
49     *.qrc
50
51
52 # ---- Installation
53
54 desktop.files += *.desktop
55 desktop.path += $$INSTALL_ROOT/usr/share/applications
56
57 pixmaps.files += *.xpm *.png
58 pixmaps.path += $$INSTALL_ROOT/usr/share/pixmaps
59
60 INSTALLS += pixmaps desktop
61
62
63 # ---- Distribution
64
65 TRANSLATIONS += *.qml
66
67 PROJECT_NAME = meego-app-satk
68
69 dist.commands += rm -fR $${PROJECT_NAME}-$${VERSION} &&
70 dist.commands += git clone . $${PROJECT_NAME}-$${VERSION} &&
71 dist.commands += rm -fR $${PROJECT_NAME}-$${VERSION}/.git &&
72 dist.commands += rm -f $${PROJECT_NAME}-$${VERSION}/.gitignore &&
73 dist.commands += mkdir -p $${PROJECT_NAME}-$${VERSION}/ts &&
74 dist.commands += lupdate $${TRANSLATIONS} -ts $${PROJECT_NAME}-$${VERSION}/ts/$${PROJECT_NAME}.ts &&
75 dist.commands += tar jcpf $${PROJECT_NAME}-$${VERSION}.tar.bz2 $${PROJECT_NAME}-$${VERSION} &&
76 dist.commands += rm -fR $${PROJECT_NAME}-$${VERSION} &&
77 dist.commands += echo; echo Created $${PROJECT_NAME}-$${VERSION}.tar.bz2
78 QMAKE_EXTRA_TARGETS += dist