add --re= and --im= command line arguments; add pure-data output (commented out)
[maximus:gmndl.git] / gmndl.hs
1 {-
2
3     gmndl -- Mandelbrot Set explorer
4     Copyright (C) 2010  Claude Heiland-Allen <claudiusmaximus@goto10.org>
5
6     This program is free software; you can redistribute it and/or modify
7     it under the terms of the GNU General Public License as published by
8     the Free Software Foundation; either version 2 of the License, or
9     (at your option) any later version.
10
11     This program is distributed in the hope that it will be useful,
12     but WITHOUT ANY WARRANTY; without even the implied warranty of
13     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14     GNU General Public License for more details.
15
16     You should have received a copy of the GNU General Public License along
17     with this program; if not, write to the Free Software Foundation, Inc.,
18     51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19
20 -}
21
22 module Main (main) where
23
24 import Control.Concurrent (forkIO, newEmptyMVar, takeMVar, putMVar)
25 import GHC.Conc (forkOnIO, numCapabilities)
26 import Control.Monad (forever)
27
28 -- some simple helpers
29 import Data.List (isPrefixOf) --, intersperse)
30 --import Data.Ratio (denominator)
31
32 -- the dependency on mtl is just for this!
33 import Control.Monad.Trans (liftIO)
34
35 -- the main program thread needs to store some thread-local state
36 import Data.IORef (newIORef, readIORef, writeIORef)
37
38 -- build the interface with GTK to allow more fancy controls later
39 import Graphics.UI.Gtk
40
41 -- use OpenGL to display frequently update images on a textured quad
42 import Graphics.UI.Gtk.OpenGL
43 import qualified Graphics.Rendering.OpenGL as GL
44 import Graphics.Rendering.OpenGL (($=))
45
46 -- need a hack to ensure correct qd operation
47 import Numeric.QD.QuadDouble (QuadDouble())
48 import Numeric.QD.FPU.Raw (fpu_fix_start)
49 import Foreign (nullPtr)
50
51 import System.IO (hSetBuffering, stdout, BufferMode(LineBuffering))
52
53 -- mu-atom properties
54 import Calculate
55 import qualified Image
56 import MuAtom (muAtom)
57
58 -- the state we need for everything
59 data GMNDL
60   = Invalid
61   | GMNDL
62       { center :: Complex QuadDouble
63       , zoom :: Int
64       , image :: Image.Image
65       , stop :: IO ()
66       }
67
68 -- command line arguments: currently only initial window dimensions
69 data Args = Args{ aWidth :: Int, aHeight :: Int, aRe :: QuadDouble, aIm :: QuadDouble }
70
71 -- and the defaults are suitable for PAL DVD rendering, if that should
72 -- come to pass in the future
73 defaultArgs :: Args
74 defaultArgs = Args{ aWidth = 788, aHeight = 576, aRe = 0, aIm = 0 }
75
76 -- braindead argument parser: latest argument takes priority
77 -- probably should use Monoid instances for this stuff
78 combineArgs :: Args -> String -> Args
79 combineArgs a0 s
80   | "--width="  `isPrefixOf` s = a0{ aWidth  = read $ "--width="  `dropPrefix` s }
81   | "-w="       `isPrefixOf` s = a0{ aWidth  = read $ "-w="       `dropPrefix` s }
82   | "--height=" `isPrefixOf` s = a0{ aHeight = read $ "--height=" `dropPrefix` s }
83   | "-h="       `isPrefixOf` s = a0{ aHeight = read $ "-h="       `dropPrefix` s }
84   | "--re="     `isPrefixOf` s = a0{ aRe = convert (read $ "--re=" `dropPrefix` s :: Double) }
85   | "--im="     `isPrefixOf` s = a0{ aIm = convert (read $ "--im=" `dropPrefix` s :: Double) }
86   | otherwise = a0
87
88 -- this is a bit silly, especially with the duplicated string literals..
89 dropPrefix :: String -> String -> String
90 dropPrefix p s = drop (length p) s
91
92 -- the main program!
93 main :: IO ()
94 main = do
95   hSetBuffering stdout LineBuffering
96   args <- foldl combineArgs defaultArgs `fmap` unsafeInitGUIForThreadedRTS
97   let width = aWidth args
98       height = aHeight args
99       rng = ((0, 0), (height - 1, width - 1))
100   _ <- initGL
101   -- dirty hack to set FPU control words as recommended by libqd docs
102   -- because it relies on 64bit doubles and some FPU use 80bits inside
103   mapM_ (flip forkOnIO $ fpu_fix_start nullPtr) [ 0 .. numCapabilities - 1 ]
104   glconfig <- glConfigNew [ GLModeRGBA, GLModeDouble ]
105   canvas <- glDrawingAreaNew glconfig
106   widgetSetSizeRequest canvas width height
107   window <- windowNew
108   eventb <- eventBoxNew
109   vbox <- vBoxNew False 0
110   status <- vBoxNew False 0
111   statusRe <- entryNew
112   statusIm <- entryNew
113   statusZo <- entryNew
114   ratios <- entryNew
115   boxPackStart vbox eventb PackGrow 0
116   boxPackStart vbox status PackGrow 0
117   boxPackStart vbox ratios PackGrow 0
118   boxPackStart status statusRe PackGrow 0
119   boxPackStart status statusIm PackGrow 0
120   boxPackStart status statusZo PackGrow 0
121   let -- update the status bar
122       updateStatus re im zo = do
123         entrySetText statusRe (reshow $ show re) -- toStringExp 50 re)
124         entrySetText statusIm (reshow $ show im) -- toStringExp 50 im)
125         entrySetText statusZo (show zo)
126   set window [ containerBorderWidth := 0, containerChild := vbox, windowResizable := False ]
127   set eventb [ containerBorderWidth := 0, containerChild := canvas ]
128   -- initial state is invalid because...
129   sR <- newIORef Invalid
130   let -- restart the renderer
131       restart :: IO ()
132       restart = do
133         g <- readIORef sR
134         stop g
135         Image.clear (image g)
136         stop' <- renderer rng (Image.plot (image g)) (center g) (zoom g)
137         writeIORef sR $! g{ stop = stop' }
138         let re :+ im = center g
139         updateStatus re im (zoom g)
140   -- ...need to initialize OpenGL stuff etc in this callback
141   _ <- onRealize canvas $ {-# SCC "cbRz" #-} withGLDrawingArea canvas $ \_ -> do
142     GL.matrixMode $= GL.Projection
143     GL.loadIdentity
144     GL.ortho 0.0 1.0 0.0 1.0 (-1.0) 1.0
145     GL.drawBuffer $= GL.BackBuffers
146     GL.texture GL.Texture2D $= GL.Enabled
147     i <- Image.new width height
148     writeIORef sR $! GMNDL{ image = i, center = aRe args :+ aIm args, zoom = zoom0, stop = return () }
149     restart
150   -- when the mouse button is pressed, center and zoom in or out
151   _ <- eventb `on` buttonPressEvent $ {-# SCC "cbEv" #-} tryEvent $ do
152     b <- eventButton
153     (x, y) <- eventCoordinates
154     liftIO $ do
155       g <- readIORef sR
156       let w2 = fromIntegral width  / 2
157           h2 = fromIntegral height / 2
158           p  = convert x :+ convert (-y)
159           s  = convert ((1/2)^^zoom g :: Double) :+ 0
160           c  = center g + (p - (w2 :+ (-h2))) * s
161           zoom' = zoom g + delta
162           delta | b == LeftButton = 1
163                 | b == RightButton = -1
164                 | otherwise = 0
165       writeIORef sR $! g{ center = c, zoom = zoom' }
166       restart
167   -- when typing in the coordinate boxes, zoom to the new place
168   _ <- statusRe `onEntryActivate` do
169     s <- entryGetText statusRe
170     liftIO $ do
171       g <- readIORef sR
172       let re = convert (read s :: Double) -- stringToMPFR Near 512 10 s
173           _ :+ im = center g
174       writeIORef sR $! g{ center = re :+ im }
175       restart
176   _ <- statusIm `onEntryActivate` do
177     s <- entryGetText statusIm
178     liftIO $ do
179       g <- readIORef sR
180       let im = convert (read s :: Double) -- stringToMPFR Near 512 10 s
181           re :+ _ = center g
182       writeIORef sR $! g{ center = re :+ im }
183       restart
184   _ <- statusZo `onEntryActivate` do
185     s <- entryGetText statusZo
186     liftIO $ do
187       g <- readIORef sR
188       let zo = read s
189       writeIORef sR $! g{ zoom = zo }
190       restart
191   -- when pressing return in the ratios list, zoom to that mu-atom
192   muQueue <- newEmptyMVar
193   _ <- forkIO . forever $ do
194     qs <- takeMVar muQueue
195     let (cr, ci, radius, _period) = muAtom qs
196         zoom' = floor ((logBase 2 . fromIntegral $ width `min` height) - (logBase 2 . convert $ radius) - 2 :: Double)
197     cr `seq` ci `seq` zoom' `seq` postGUISync $ do
198       g <- readIORef sR
199       if isNaN cr || isNaN ci
200         then writeIORef sR $! g{ center = c0, zoom = zoom0 }
201         else writeIORef sR $! g{ center = cr :+ ci, zoom = zoom' }
202       _ <- ratios `widgetSetSensitive` True
203       -- toPureData zoom' ci cr (map denominator qs)
204       restart
205   _ <- ratios `onEntryActivate` do
206     s <- entryGetText ratios
207     case rationalize s of
208       Nothing -> return ()
209       Just qs -> do
210         _ <- ratios `widgetSetSensitive` False
211         g <- readIORef sR
212         stop g
213         putMVar muQueue qs
214   -- time to draw the image: upload to the texture and draw a quad
215   _ <- onExpose canvas $ {-# SCC "cbEx" #-} \_ -> do
216     withGLDrawingArea canvas $ \glwindow -> do
217       GMNDL{ image = i } <- readIORef sR
218       Image.upload i
219       Image.draw i
220       glDrawableSwapBuffers glwindow
221     return True
222   -- need an exit strategy
223   _ <- onDestroy window mainQuit
224   -- make sure the expose callback gets called regularly (5fps)
225   _ <- timeoutAdd (widgetQueueDraw canvas >> return True) 200
226 --  _ <- timeoutAdd (do { GMNDL{ image = i } <- readIORef sR ; Image.putPPM i ; return True }) 200
227   -- and we're off!
228   widgetShowAll window
229   mainGUI
230
231 -- initial center coordinates
232 -- using the maximum precision available from the start for this makes
233 -- sure that nothing weird happens when precision gets close to the edge
234 c0 :: Complex QuadDouble
235 c0 = 0
236
237 -- initial zoom level
238 -- neighbouring pixel are 2^(-zoom) units apart
239 -- the initial zoom level should probably depend on initial image size
240 zoom0 :: Int
241 zoom0 = 7
242
243 -- convert scientific notation like "-4.12345600000000e-03"
244 -- into human-readable numbers like "-0.004123456"
245 -- do it by string manipulation as QuadDouble has a lot of precision
246 -- and the show instance for QuadDouble gives the problematic form...
247 reshow :: String -> String
248 reshow s =
249   let (front, rear') = break (=='e') s
250       (sign, mantissa) = case front of
251                           '-':m -> (True, m)
252                           m -> (False, m)
253       (big, dotsmall) = break (=='.') mantissa
254       small = case dotsmall of
255         '.':small' -> small'
256         small' -> small'
257       expo = case rear' of
258         'e':rear -> read (dropWhile (=='+') rear) + length big
259         _ -> 0
260       digits = if expo < 0  then "0." ++ replicate (-expo) '0' ++ big ++ small
261                             else let (x,y) = splitAt expo (big ++ small)
262                                  in  case x of
263                                       [] -> "0." ++ y
264                                       x' -> x' ++ "." ++ y
265   in  reverse . dropWhile (=='.') . dropWhile (=='0') . reverse . (if sign then ('-':) else id) $ digits
266
267 -- convert a string of space separated fractions into rationals
268 -- moreover ensure that they are all in 0<q<1
269 rationalize :: String -> Maybe [Rational]
270 rationalize s =
271   let f '/' = '%'
272       f  c  = c
273       r t = case reads t of
274         [(q, "")] | 0 < q && q < 1 -> Just q
275         _ -> Nothing
276   in  mapM r . words . map f $ s
277
278 {-
279 -- export parameters to Pure-data FUDI format
280 toPureData zo im re cascade
281   | isNaN im || isNaN re = return ()
282   | otherwise = putStrLn $ "zoom " ++ show zo ++ " ; im " ++ f im ++ " ; re " ++ f re ++ " ; cascade " ++ unwords (map show cascade) ++ " ;"
283   where
284     f x | x < 0     = concatMap (\d -> " -" ++ [d]) . take 16 . filter (`elem` ['0' .. '9']) . reshow . show $ x
285         | otherwise = concatMap (\d -> "  " ++ [d]) . take 16 . filter (`elem` ['0' .. '9']) . reshow . show $ x
286 -}