New: MImSubViewOverride to track MAttributeExtension for enable-all-subviews override
[maliit:fw.git] / maliit-framework.pro
1 include(./config.pri)
2
3 !isEmpty(HELP) {
4     # Output help
5     help_string = \
6         Important build options: \
7         \\n\\t M_IM_PREFIX : Install prefix (default: /usr) \
8         \\n\\t M_IM_INSTALL_{BIN,LIBS,HEADERS,SCHEMAS,DOCS} : Install prefix for specific types of files \
9         \\nRecognised CONFIG flags: \
10         \\n\\t enable-legacy : Build in legacy mode (for meego-im ABI/API compatability) \
11         \\n\\t enable-meegotouch : Link input context to libmeegotouch for a MApplicationPage hack \
12         \\n\\t enable-contextkit : Build contextkit support (for monitoring hardware keyboard status) \
13         \\n\\t notests : Do not build tests \
14         \\n\\t nodoc : Do not build documentation \
15         \\n\\t only-libmaliit : Only build libmaliit \
16         \\n\\t external-libmaliit : Use external libmaliit (do not build libmaliit) \
17         \\n\\t disable-gtk-cache-update : Do not update GTK2/3 input method caches \
18         \\nInfluential environment variables: \
19         \\n\\t GCONF_CONFIG_SOURCE : Specify custom gconf source2 \
20         \\nExamples: \
21         \\n\\t qmake \
22         \\n\\t qmake M_IM_PREFIX=/usr M_IM_INSTALL_LIBS=/usr/lib64 CONFIG+=enable-legacy CONFIG+=notests \
23
24     !build_pass:system(echo -e \"$$help_string\")
25 } else {
26     config_string = Tip: Run qmake HELP=1 for a list of all supported build options
27
28     !build_pass:system(echo -e \"$$config_string\")
29 }
30
31 CONFIG += ordered
32 TEMPLATE = subdirs
33
34 !only-libmaliit {
35     SUBDIRS = src passthroughserver
36     TARGET = meego-im-uiserver
37 }
38
39 external-libmaliit {
40     only-libmaliit:error("CONFIG options only-libmaliit and external-libmaliit does not make sense together!")
41     !system(pkg-config --exists maliit-1.0):error("Could not find maliit-1.0")
42 } else {
43     SUBDIRS += maliit
44 }
45
46 !only-libmaliit {
47     SUBDIRS += common input-context gtk-input-context input-method-quick examples
48
49     !nodoc {
50         SUBDIRS += doc
51     }
52
53     !notests {
54         SUBDIRS += tests
55     }
56 }
57
58 !system(pkg-config --exists dbus-glib-1 dbus-1 gconf-2.0):error("Could not find dbus-glib-1 dbus-1 gconf-2.0")
59
60 QMAKE_EXTRA_TARGETS += check-xml
61 check-xml.target = check-xml
62 check-xml.CONFIG = recursive
63
64 QMAKE_EXTRA_TARGETS += check
65 check.target = check
66 check.CONFIG = recursive
67
68 OTHER_FILES += NEWS README