updated to QextMDI-1.0.0
[kdevelop:kdevelop.git] / libtool.m4.in
1 ## libtool.m4 - Configure libtool for the target system. -*-Shell-script-*-
2 ## Copyright (C) 1996-2000 Free Software Foundation, Inc.
3 ## Originally by Gordon Matzigkeit <gord@gnu.ai.mit.edu>, 1996
4 ##
5 ## This program is free software; you can redistribute it and/or modify
6 ## it under the terms of the GNU General Public License as published by
7 ## the Free Software Foundation; either version 2 of the License, or
8 ## (at your option) any later version.
9 ##
10 ## This program is distributed in the hope that it will be useful, but
11 ## WITHOUT ANY WARRANTY; without even the implied warranty of
12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13 ## General Public License for more details.
14 ##
15 ## You should have received a copy of the GNU General Public License
16 ## along with this program; if not, write to the Free Software
17 ## Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
18 ##
19 ## As a special exception to the GNU General Public License, if you
20 ## distribute this file as part of a program that contains a
21 ## configuration script generated by Autoconf, you may include it under
22 ## the same distribution terms that you use for the rest of that program.
23
24 # serial 42 AC_PROG_LIBTOOL
25 AC_DEFUN(AC_PROG_LIBTOOL,
26 [AC_REQUIRE([AC_LIBTOOL_SETUP])dnl
27
28 # Save cache, so that ltconfig can load it
29 AC_CACHE_SAVE
30
31 # Actually configure libtool.  ac_aux_dir is where install-sh is found.
32 AR="$AR" CC="$CC" CFLAGS="$CFLAGS" CPPFLAGS="$CPPFLAGS" \
33 FILE="$FILE" LD="$LD" LDFLAGS="$LDFLAGS" LIBS="$LIBS" \
34 LN_S="$LN_S" NM="$NM" RANLIB="$RANLIB" STRIP="$STRIP" \
35 AS="$AS" DLLTOOL="$DLLTOOL" OBJDUMP="$OBJDUMP" \
36 objext="$OBJEXT" exeext="$EXEEXT" reload_flag="$reload_flag" \
37 deplibs_check_method="$deplibs_check_method" file_magic_cmd="$file_magic_cmd" \
38 ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/ltconfig --no-reexec \
39 $libtool_flags --no-verify --build="$build" $ac_aux_dir/ltmain.sh $lt_target \
40 || AC_MSG_ERROR([libtool configure failed])
41
42 # Reload cache, that may have been modified by ltconfig
43 AC_CACHE_LOAD
44
45 # This can be used to rebuild libtool when needed
46 LIBTOOL_DEPS="$ac_aux_dir/ltconfig $ac_aux_dir/ltmain.sh"
47
48 # Always use our own libtool.
49 LIBTOOL='$(SHELL) $(top_builddir)/libtool'
50 AC_SUBST(LIBTOOL)dnl
51
52 # Redirect the config.log output again, so that the ltconfig log is not
53 # clobbered by the next message.
54 exec 5>>./config.log
55 ])
56
57 AC_DEFUN(AC_LIBTOOL_SETUP,
58 [AC_PREREQ(2.13)dnl
59 AC_REQUIRE([AC_ENABLE_SHARED])dnl
60 AC_REQUIRE([AC_ENABLE_STATIC])dnl
61 AC_REQUIRE([AC_ENABLE_FAST_INSTALL])dnl
62 AC_REQUIRE([AC_CANONICAL_HOST])dnl
63 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
64 AC_REQUIRE([AC_PROG_CC])dnl
65 AC_REQUIRE([AC_PROG_LD])dnl
66 AC_REQUIRE([AC_PROG_LD_RELOAD_FLAG])dnl
67 AC_REQUIRE([AC_PROG_NM])dnl
68 AC_REQUIRE([AC_PROG_LN_S])dnl
69 AC_REQUIRE([AC_DEPLIBS_CHECK_METHOD])dnl
70 AC_REQUIRE([AC_OBJEXT])dnl
71 AC_REQUIRE([AC_EXEEXT])dnl
72 dnl
73
74 # Only perform the check for file, if the check method requires it
75 case "$deplibs_check_method" in
76 file_magic*)
77   if test "$file_magic_cmd" = '$FILE'; then
78     AC_PATH_FILE
79   fi
80   ;;
81 esac
82
83 case "$target" in
84 NONE) lt_target="$host" ;;
85 *) lt_target="$target" ;;
86 esac
87
88 AC_CHECK_TOOL(RANLIB, ranlib, :)
89 AC_CHECK_TOOL(STRIP, strip, :)
90
91 # Check for any special flags to pass to ltconfig.
92 libtool_flags="--cache-file=$cache_file"
93 test "$enable_shared" = no && libtool_flags="$libtool_flags --disable-shared"
94 test "$enable_static" = no && libtool_flags="$libtool_flags --disable-static"
95 test "$enable_fast_install" = no && libtool_flags="$libtool_flags --disable-fast-install"
96 test "$ac_cv_prog_gcc" = yes && libtool_flags="$libtool_flags --with-gcc"
97 test "$ac_cv_prog_gnu_ld" = yes && libtool_flags="$libtool_flags --with-gnu-ld"
98 ifdef([AC_PROVIDE_AC_LIBTOOL_DLOPEN],
99 [libtool_flags="$libtool_flags --enable-dlopen"])
100 ifdef([AC_PROVIDE_AC_LIBTOOL_WIN32_DLL],
101 [libtool_flags="$libtool_flags --enable-win32-dll"])
102 AC_ARG_ENABLE(libtool-lock,
103   [  --disable-libtool-lock  avoid locking (might break parallel builds)])
104 test "x$enable_libtool_lock" = xno && libtool_flags="$libtool_flags --disable-lock"
105 test x"$silent" = xyes && libtool_flags="$libtool_flags --silent"
106
107 AC_ARG_WITH(pic,
108   [  --with-pic              try to use only PIC/non-PIC objects [default=use both]],
109      pic_mode="$withval", pic_mode=default)
110 test x"$pic_mode" = xyes && libtool_flags="$libtool_flags --prefer-pic"
111 test x"$pic_mode" = xno && libtool_flags="$libtool_flags --prefer-non-pic"
112
113 # Some flags need to be propagated to the compiler or linker for good
114 # libtool support.
115 case "$lt_target" in
116 *-*-irix6*)
117   # Find out which ABI we are using.
118   echo '[#]line __oline__ "configure"' > conftest.$ac_ext
119   if AC_TRY_EVAL(ac_compile); then
120     case "`/usr/bin/file conftest.o`" in
121     *32-bit*)
122       LD="${LD-ld} -32"
123       ;;
124     *N32*)
125       LD="${LD-ld} -n32"
126       ;;
127     *64-bit*)
128       LD="${LD-ld} -64"
129       ;;
130     esac
131   fi
132   rm -rf conftest*
133   ;;
134
135 *-*-sco3.2v5*)
136   # On SCO OpenServer 5, we need -belf to get full-featured binaries.
137   SAVE_CFLAGS="$CFLAGS"
138   CFLAGS="$CFLAGS -belf"
139   AC_CACHE_CHECK([whether the C compiler needs -belf], lt_cv_cc_needs_belf,
140     [AC_TRY_LINK([],[],[lt_cv_cc_needs_belf=yes],[lt_cv_cc_needs_belf=no])])
141   if test x"$lt_cv_cc_needs_belf" != x"yes"; then
142     # this is probably gcc 2.8.0, egcs 1.0 or newer; no need for -belf
143     CFLAGS="$SAVE_CFLAGS"
144   fi
145   ;;
146
147 ifdef([AC_PROVIDE_AC_LIBTOOL_WIN32_DLL],
148 [*-*-cygwin* | *-*-mingw*)
149   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
150   AC_CHECK_TOOL(AS, as, false)
151   AC_CHECK_TOOL(OBJDUMP, objdump, false)
152
153   # recent cygwin and mingw systems supply a stub DllMain which the user
154   # can override, but on older systems we have to supply one
155   AC_CACHE_CHECK([if libtool should supply DllMain function], lt_cv_need_dllmain,
156     [AC_TRY_LINK([],
157       [extern int __attribute__((__stdcall__)) DllMain(void*, int, void*);
158       DllMain (0, 0, 0);],
159       [lt_cv_need_dllmain=no],[lt_cv_need_dllmain=yes])])
160
161   case "$lt_target/$CC" in
162   *-*-cygwin*/gcc*-mno-cygwin*|*-*-mingw*)
163     # old mingw systems require "-dll" to link a DLL, while more recent ones
164     # require "-mdll"
165     SAVE_CFLAGS="$CFLAGS"
166     CFLAGS="$CFLAGS -mdll"
167     AC_CACHE_CHECK([how to link DLLs], lt_cv_cc_dll_switch,
168       [AC_TRY_LINK([], [], [lt_cv_cc_dll_switch=-mdll],[lt_cv_cc_dll_switch=-dll])])
169     CFLAGS="$SAVE_CFLAGS" ;;
170   *-*-cygwin*)
171     # cygwin systems need to pass --dll to the linker, and not link
172     # crt.o which will require a WinMain@16 definition.
173     lt_cv_cc_dll_switch="-Wl,--dll -nostartfiles" ;;
174   esac
175   ;;
176   ])
177 esac
178 ])
179
180 # AC_LIBTOOL_DLOPEN - enable checks for dlopen support
181 AC_DEFUN(AC_LIBTOOL_DLOPEN, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])])
182
183 # AC_LIBTOOL_WIN32_DLL - declare package support for building win32 dll's
184 AC_DEFUN(AC_LIBTOOL_WIN32_DLL, [AC_BEFORE([$0], [AC_LIBTOOL_SETUP])])
185
186 # AC_ENABLE_SHARED - implement the --enable-shared flag
187 # Usage: AC_ENABLE_SHARED[(DEFAULT)]
188 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
189 #   `yes'.
190 AC_DEFUN(AC_ENABLE_SHARED, [dnl
191 define([AC_ENABLE_SHARED_DEFAULT], ifelse($1, no, no, yes))dnl
192 AC_ARG_ENABLE(shared,
193 changequote(<<, >>)dnl
194 <<  --enable-shared[=PKGS]  build shared libraries [default=>>AC_ENABLE_SHARED_DEFAULT],
195 changequote([, ])dnl
196 [p=${PACKAGE-default}
197 case "$enableval" in
198 yes) enable_shared=yes ;;
199 no) enable_shared=no ;;
200 *)
201   enable_shared=no
202   # Look at the argument we got.  We use all the common list separators.
203   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
204   for pkg in $enableval; do
205     if test "X$pkg" = "X$p"; then
206       enable_shared=yes
207     fi
208   done
209   IFS="$ac_save_ifs"
210   ;;
211 esac],
212 enable_shared=AC_ENABLE_SHARED_DEFAULT)dnl
213 ])
214
215 # AC_DISABLE_SHARED - set the default shared flag to --disable-shared
216 AC_DEFUN(AC_DISABLE_SHARED, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
217 AC_ENABLE_SHARED(no)])
218
219 # AC_ENABLE_STATIC - implement the --enable-static flag
220 # Usage: AC_ENABLE_STATIC[(DEFAULT)]
221 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
222 #   `yes'.
223 AC_DEFUN(AC_ENABLE_STATIC, [dnl
224 define([AC_ENABLE_STATIC_DEFAULT], ifelse($1, no, no, yes))dnl
225 AC_ARG_ENABLE(static,
226 changequote(<<, >>)dnl
227 <<  --enable-static[=PKGS]  build static libraries [default=>>AC_ENABLE_STATIC_DEFAULT],
228 changequote([, ])dnl
229 [p=${PACKAGE-default}
230 case "$enableval" in
231 yes) enable_static=yes ;;
232 no) enable_static=no ;;
233 *)
234   enable_static=no
235   # Look at the argument we got.  We use all the common list separators.
236   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
237   for pkg in $enableval; do
238     if test "X$pkg" = "X$p"; then
239       enable_static=yes
240     fi
241   done
242   IFS="$ac_save_ifs"
243   ;;
244 esac],
245 enable_static=AC_ENABLE_STATIC_DEFAULT)dnl
246 ])
247
248 # AC_DISABLE_STATIC - set the default static flag to --disable-static
249 AC_DEFUN(AC_DISABLE_STATIC, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
250 AC_ENABLE_STATIC(no)])
251
252
253 # AC_ENABLE_FAST_INSTALL - implement the --enable-fast-install flag
254 # Usage: AC_ENABLE_FAST_INSTALL[(DEFAULT)]
255 #   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
256 #   `yes'.
257 AC_DEFUN(AC_ENABLE_FAST_INSTALL, [dnl
258 define([AC_ENABLE_FAST_INSTALL_DEFAULT], ifelse($1, no, no, yes))dnl
259 AC_ARG_ENABLE(fast-install,
260 changequote(<<, >>)dnl
261 <<  --enable-fast-install[=PKGS]  optimize for fast installation [default=>>AC_ENABLE_FAST_INSTALL_DEFAULT],
262 changequote([, ])dnl
263 [p=${PACKAGE-default}
264 case "$enableval" in
265 yes) enable_fast_install=yes ;;
266 no) enable_fast_install=no ;;
267 *)
268   enable_fast_install=no
269   # Look at the argument we got.  We use all the common list separators.
270   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
271   for pkg in $enableval; do
272     if test "X$pkg" = "X$p"; then
273       enable_fast_install=yes
274     fi
275   done
276   IFS="$ac_save_ifs"
277   ;;
278 esac],
279 enable_fast_install=AC_ENABLE_FAST_INSTALL_DEFAULT)dnl
280 ])
281
282 # AC_ENABLE_FAST_INSTALL - set the default to --disable-fast-install
283 AC_DEFUN(AC_DISABLE_FAST_INSTALL, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
284 AC_ENABLE_FAST_INSTALL(no)])
285
286
287 # AC_PATH_TOOL_PREFIX - find a file program which can recognise shared library
288 AC_DEFUN(AC_PATH_TOOL_PREFIX,
289 [AC_MSG_CHECKING([for $1])
290 AC_CACHE_VAL(lt_cv_path_FILE,
291 [case "$FILE" in
292   /*)
293   lt_cv_path_FILE="$FILE" # Let the user override the test with a path.
294   ;;
295   ?:/*)
296   ac_cv_path_FILE="$FILE" # Let the user override the test with a dos path.
297   ;;
298   *)
299   ac_save_file="$FILE"
300   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS=":"
301 dnl $ac_dummy forces splitting on constant user-supplied paths.
302 dnl POSIX.2 word splitting is done only on the output of word expansions,
303 dnl not every word.  This closes a longstanding sh security hole.
304   ac_dummy="ifelse([$2], , $PATH, [$2])"
305   for ac_dir in $ac_dummy; do
306     test -z "$ac_dir" && ac_dir=.
307     if test -f $ac_dir/$1; then
308       lt_cv_path_FILE="$ac_dir/$1"
309       if test -n "$file_magic_test_file"; then
310         case "$deplibs_check_method" in
311         "file_magic "*)
312           file_magic_regex="`expr \"$deplibs_check_method\" : \"file_magic \(.*\)\"`"
313           FILE="$lt_cv_path_FILE"
314           if eval $file_magic_cmd \$file_magic_test_file 2> /dev/null |
315             egrep "$file_magic_regex" > /dev/null; then
316             :
317           else
318             cat <<EOF 1>&2
319
320 *** Warning: the command libtool uses to detect shared libraries,
321 *** $file_magic_cmd, produces output that libtool cannot recognize.
322 *** The result is that libtool may fail to recognize shared libraries
323 *** as such.  This will affect the creation of libtool libraries that
324 *** depend on shared libraries, but programs linked with such libtool
325 *** libraries will work regardless of this problem.  Nevertheless, you
326 *** may want to report the problem to your system manager and/or to
327 *** bug-libtool@gnu.org
328
329 EOF
330           fi ;;
331         esac
332       fi
333       break
334     fi
335   done
336   IFS="$ac_save_ifs"
337   FILE="$ac_save_file"
338   ;;
339 esac])
340 FILE="$lt_cv_path_FILE"
341 if test -n "$FILE"; then
342   AC_MSG_RESULT($FILE)
343 else
344   AC_MSG_RESULT(no)
345 fi
346 ])
347
348
349 # AC_PATH_FILE - find a file program which can recognise a shared library
350 AC_DEFUN(AC_PATH_FILE,
351 [AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
352 AC_PATH_TOOL_PREFIX(${ac_tool_prefix}file, /usr/bin:$PATH)
353 if test -z "$lt_cv_path_FILE"; then
354   if test -n "$ac_tool_prefix"; then
355     AC_PATH_TOOL_PREFIX(file, /usr/bin:$PATH)
356   else
357     FILE=:
358   fi
359 fi
360 ])
361
362
363 # AC_PROG_LD - find the path to the GNU or non-GNU linker
364 AC_DEFUN(AC_PROG_LD,
365 [AC_ARG_WITH(gnu-ld,
366 [  --with-gnu-ld           assume the C compiler uses GNU ld [default=no]],
367 test "$withval" = no || with_gnu_ld=yes, with_gnu_ld=no)
368 AC_REQUIRE([AC_PROG_CC])dnl
369 AC_REQUIRE([AC_CANONICAL_HOST])dnl
370 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
371 ac_prog=ld
372 if test "$ac_cv_prog_gcc" = yes; then
373   # Check if gcc -print-prog-name=ld gives a path.
374   AC_MSG_CHECKING([for ld used by GCC])
375   case $lt_target in
376   *-*-mingw*)
377     # gcc leaves a trailing carriage return which upsets mingw
378     ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
379   *)
380     ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
381   esac
382   case "$ac_prog" in
383     # Accept absolute paths.
384 changequote(,)dnl
385     [\\/]* | [A-Za-z]:[\\/]*)
386       re_direlt='/[^/][^/]*/\.\./'
387 changequote([,])dnl
388       # Canonicalize the path of ld
389       ac_prog=`echo $ac_prog| sed 's%\\\\%/%g'`
390       while echo $ac_prog | grep "$re_direlt" > /dev/null 2>&1; do
391         ac_prog=`echo $ac_prog| sed "s%$re_direlt%/%"`
392       done
393       test -z "$LD" && LD="$ac_prog"
394       ;;
395   "")
396     # If it fails, then pretend we aren't using GCC.
397     ac_prog=ld
398     ;;
399   *)
400     # If it is relative, then search for the first ld in PATH.
401     with_gnu_ld=unknown
402     ;;
403   esac
404 elif test "$with_gnu_ld" = yes; then
405   AC_MSG_CHECKING([for GNU ld])
406 else
407   AC_MSG_CHECKING([for non-GNU ld])
408 fi
409 AC_CACHE_VAL(ac_cv_path_LD,
410 [if test -z "$LD"; then
411   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR-:}"
412   for ac_dir in $PATH; do
413     test -z "$ac_dir" && ac_dir=.
414     if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
415       ac_cv_path_LD="$ac_dir/$ac_prog"
416       # Check to see if the program is GNU ld.  I'd rather use --version,
417       # but apparently some GNU ld's only accept -v.
418       # Break only if it was the GNU/non-GNU ld that we prefer.
419       if "$ac_cv_path_LD" -v 2>&1 < /dev/null | egrep '(GNU|with BFD)' > /dev/null; then
420         test "$with_gnu_ld" != no && break
421       else
422         test "$with_gnu_ld" != yes && break
423       fi
424     fi
425   done
426   IFS="$ac_save_ifs"
427 else
428   ac_cv_path_LD="$LD" # Let the user override the test with a path.
429 fi])
430 LD="$ac_cv_path_LD"
431 if test -n "$LD"; then
432   AC_MSG_RESULT($LD)
433 else
434   AC_MSG_RESULT(no)
435 fi
436 test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
437 AC_PROG_LD_GNU
438 ])
439
440 AC_DEFUN(AC_PROG_LD_GNU,
441 [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], ac_cv_prog_gnu_ld,
442 [# I'd rather use --version here, but apparently some GNU ld's only accept -v.
443 if $LD -v 2>&1 </dev/null | egrep '(GNU|with BFD)' 1>&5; then
444   ac_cv_prog_gnu_ld=yes
445 else
446   ac_cv_prog_gnu_ld=no
447 fi])
448 with_gnu_ld=$ac_cv_prog_gnu_ld
449 ])
450
451 # AC_PROG_LD_RELOAD_FLAG - find reload flag for linker
452 #   -- PORTME Some linkers may need a different reload flag.
453 AC_DEFUN(AC_PROG_LD_RELOAD_FLAG,
454 [AC_CACHE_CHECK([for $LD option to reload object files], lt_cv_ld_reload_flag,
455 [lt_cv_ld_reload_flag='-r'])
456 reload_flag=$lt_cv_ld_reload_flag
457 test -n "$reload_flag" && reload_flag=" $reload_flag"
458 ])
459
460 # AC_DEPLIBS_CHECK_METHOD - how to check for library dependencies
461 #  -- PORTME fill in with the dynamic library characteristics
462 AC_DEFUN(AC_DEPLIBS_CHECK_METHOD,
463 [AC_CACHE_CHECK([how to recognise dependant libraries],
464 lt_cv_deplibs_check_method,
465 [lt_cv_file_magic_cmd='$FILE'
466 lt_cv_file_magic_test_file=
467 lt_cv_deplibs_check_method='unknown'
468 # Need to set the preceding variable on all platforms that support
469 # interlibrary dependencies.
470 # 'none' -- dependencies not supported.
471 # `unknown' -- same as none, but documents that we really don't know.
472 # 'pass_all' -- all dependencies passed with no checks.
473 # 'test_compile' -- check by making test program.
474 # 'file_magic [regex]' -- check by looking for files in library path
475 # which responds to the $file_magic_cmd with a given egrep regex.
476 # If you have `file' or equivalent on your system and you're not sure
477 # whether `pass_all' will *always* work, you probably want this one.
478
479 case "$host_os" in
480 aix4* | beos*)
481   lt_cv_deplibs_check_method=pass_all
482   ;;
483
484 bsdi4*)
485   changequote(,)dnl
486   lt_cv_deplibs_check_method='file_magic ELF [0-9][0-9]*-bit [ML]SB (shared object|dynamic lib)'
487   changequote([, ])dnl
488   lt_cv_file_magic_test_file=/shlib/libc.so
489   ;;
490
491 cygwin* | mingw*)
492   lt_cv_deplibs_check_method='file_magic file format pei*-i386(.*architecture: i386)?'
493   lt_cv_file_magic_cmd='${OBJDUMP} -f'
494   ;;
495
496 freebsd*)
497   lt_cv_deplibs_check_method=pass_all
498   ;;
499
500 gnu*)
501   lt_cv_deplibs_check_method=pass_all
502   ;;
503
504 irix5* | irix6*)
505   case "$host_os" in
506   irix5*)
507     # this will be overridden with pass_all, but let us keep it just in case
508     lt_cv_deplibs_check_method="file_magic ELF 32-bit MSB dynamic lib MIPS - version 1"
509     ;;
510   *)
511     case "$LD" in
512     *-32|*"-32 ") libmagic=32-bit;;
513     *-n32|*"-n32 ") libmagic=N32;;
514     *-64|*"-64 ") libmagic=64-bit;;
515     *) libmagic=never-match;;
516     esac
517     # this will be overridden with pass_all, but let us keep it just in case
518     changequote(,)dnl
519     lt_cv_deplibs_check_method="file_magic ELF ${libmagic} MSB mips-[1234] dynamic lib MIPS - version 1"
520     changequote([, ])dnl
521     ;;
522   esac
523   lt_cv_file_magic_test_file=`echo /lib${libsuff}/libc.so*`
524   lt_cv_deplibs_check_method=pass_all
525   ;;
526
527 # This must be Linux ELF.
528 linux-gnu*)
529   case "$host_cpu" in
530   alpha* | i*86 | sparc* )
531     lt_cv_deplibs_check_method=pass_all ;;
532   *)
533     # glibc up to 2.1.1 does not perform some relocations on ARM
534     changequote(,)dnl
535     lt_cv_deplibs_check_method='file_magic ELF [0-9][0-9]*-bit [LM]SB (shared object|dynamic lib )' ;;
536     changequote([, ])dnl
537   esac
538   lt_cv_file_magic_test_file=`echo /lib/libc.so* /lib/libc-*.so`
539   ;;
540
541 osf3* | osf4* | osf5*)
542   # this will be overridden with pass_all, but let us keep it just in case
543   lt_cv_deplibs_check_method='file_magic COFF format alpha shared library'
544   lt_cv_file_magic_test_file=/shlib/libc.so
545   lt_cv_deplibs_check_method=pass_all
546   ;;
547
548 sco3.2v5*)
549   lt_cv_deplibs_check_method=pass_all
550   ;;
551
552 solaris*)
553   lt_cv_deplibs_check_method=pass_all
554   lt_cv_file_magic_test_file=/lib/libc.so
555   ;;
556
557 sysv4 | sysv4.2uw2* | sysv4.3* | sysv5*)
558   case "$host_vendor" in
559   ncr)
560     lt_cv_deplibs_check_method=pass_all
561     ;;
562   motorola)
563     changequote(,)dnl
564     lt_cv_deplibs_check_method='file_magic ELF [0-9][0-9]*-bit [ML]SB (shared object|dynamic lib) M[0-9][0-9]* Version [0-9]'
565     changequote([, ])dnl
566     lt_cv_file_magic_test_file=`echo /usr/lib/libc.so*`
567     ;;
568   esac
569   ;;
570 esac
571 ])
572 file_magic_cmd=$lt_cv_file_magic_cmd
573 deplibs_check_method=$lt_cv_deplibs_check_method
574 ])
575
576
577 # AC_PROG_NM - find the path to a BSD-compatible name lister
578 AC_DEFUN(AC_PROG_NM,
579 [AC_MSG_CHECKING([for BSD-compatible nm])
580 AC_CACHE_VAL(ac_cv_path_NM,
581 [if test -n "$NM"; then
582   # Let the user override the test.
583   ac_cv_path_NM="$NM"
584 else
585   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR-:}"
586   for ac_dir in $PATH /usr/ccs/bin /usr/ucb /bin; do
587     test -z "$ac_dir" && ac_dir=.
588     if test -f $ac_dir/nm || test -f $ac_dir/nm$ac_exeext ; then
589       # Check to see if the nm accepts a BSD-compat flag.
590       # Adding the `sed 1q' prevents false positives on HP-UX, which says:
591       #   nm: unknown option "B" ignored
592       if ($ac_dir/nm -B /dev/null 2>&1 | sed '1q'; exit 0) | egrep /dev/null >/dev/null; then
593         ac_cv_path_NM="$ac_dir/nm -B"
594         break
595       elif ($ac_dir/nm -p /dev/null 2>&1 | sed '1q'; exit 0) | egrep /dev/null >/dev/null; then
596         ac_cv_path_NM="$ac_dir/nm -p"
597         break
598       else
599         ac_cv_path_NM=${ac_cv_path_NM="$ac_dir/nm"} # keep the first match, but
600         continue # so that we can try to find one that supports BSD flags
601       fi
602     fi
603   done
604   IFS="$ac_save_ifs"
605   test -z "$ac_cv_path_NM" && ac_cv_path_NM=nm
606 fi])
607 NM="$ac_cv_path_NM"
608 AC_MSG_RESULT([$NM])
609 ])
610
611 # AC_CHECK_LIBM - check for math library
612 AC_DEFUN(AC_CHECK_LIBM,
613 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
614 LIBM=
615 case "$lt_target" in
616 *-*-beos* | *-*-cygwin*)
617   # These system don't have libm
618   ;;
619 *-ncr-sysv4.3*)
620   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
621   AC_CHECK_LIB(m, main, LIBM="$LIBM -lm")
622   ;;
623 *)
624   AC_CHECK_LIB(m, main, LIBM="-lm")
625   ;;
626 esac
627 ])
628
629 # AC_LIBLTDL_CONVENIENCE[(dir)] - sets LIBLTDL to the link flags for
630 # the libltdl convenience library, adds --enable-ltdl-convenience to
631 # the configure arguments.  Note that LIBLTDL is not AC_SUBSTed, nor
632 # is AC_CONFIG_SUBDIRS called.  If DIR is not provided, it is assumed
633 # to be `${top_builddir}/libltdl'.  Make sure you start DIR with
634 # '${top_builddir}/' (note the single quotes!) if your package is not
635 # flat, and, if you're not using automake, define top_builddir as
636 # appropriate in the Makefiles.
637 AC_DEFUN(AC_LIBLTDL_CONVENIENCE, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
638   case "$enable_ltdl_convenience" in
639   no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;;
640   "") enable_ltdl_convenience=yes
641       ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;;
642   esac
643   LIBLTDL=ifelse($#,1,$1,['${top_builddir}/libltdl'])/libltdlc.la
644   INCLTDL=ifelse($#,1,-I$1,['-I${top_srcdir}/libltdl'])
645 ])
646
647 # AC_LIBLTDL_INSTALLABLE[(dir)] - sets LIBLTDL to the link flags for
648 # the libltdl installable library, and adds --enable-ltdl-install to
649 # the configure arguments.  Note that LIBLTDL is not AC_SUBSTed, nor
650 # is AC_CONFIG_SUBDIRS called.  If DIR is not provided, it is assumed
651 # to be `${top_builddir}/libltdl'.  Make sure you start DIR with
652 # '${top_builddir}/' (note the single quotes!) if your package is not
653 # flat, and, if you're not using automake, define top_builddir as
654 # appropriate in the Makefiles.
655 # In the future, this macro may have to be called after AC_PROG_LIBTOOL.
656 AC_DEFUN(AC_LIBLTDL_INSTALLABLE, [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
657   AC_CHECK_LIB(ltdl, main,
658   [test x"$enable_ltdl_install" != xyes && enable_ltdl_install=no],
659   [if test x"$enable_ltdl_install" = xno; then
660      AC_MSG_WARN([libltdl not installed, but installation disabled])
661    else
662      enable_ltdl_install=yes
663    fi
664   ])
665   if test x"$enable_ltdl_install" = x"yes"; then
666     ac_configure_args="$ac_configure_args --enable-ltdl-install"
667     LIBLTDL=ifelse($#,1,$1,['${top_builddir}/libltdl'])/libltdl.la
668     INCLTDL=ifelse($#,1,-I$1,['-I${top_srcdir}/libltdl'])
669   else
670     ac_configure_args="$ac_configure_args --enable-ltdl-install=no"
671     LIBLTDL="-lltdl"
672     INCLTDL=
673   fi
674 ])
675
676 dnl old names
677 AC_DEFUN(AM_PROG_LIBTOOL, [indir([AC_PROG_LIBTOOL])])dnl
678 AC_DEFUN(AM_ENABLE_SHARED, [indir([AC_ENABLE_SHARED], $@)])dnl
679 AC_DEFUN(AM_ENABLE_STATIC, [indir([AC_ENABLE_STATIC], $@)])dnl
680 AC_DEFUN(AM_DISABLE_SHARED, [indir([AC_DISABLE_SHARED], $@)])dnl
681 AC_DEFUN(AM_DISABLE_STATIC, [indir([AC_DISABLE_STATIC], $@)])dnl
682 AC_DEFUN(AM_PROG_LD, [indir([AC_PROG_LD])])dnl
683 AC_DEFUN(AM_PROG_NM, [indir([AC_PROG_NM])])dnl
684
685 dnl This is just to silence aclocal about the macro not being used
686 ifelse([AC_DISABLE_FAST_INSTALL])dnl