initial commit
[freebsd-arm:freebsd-arm.git] / boot / i386 / zfsboot / zfsldr.S
1 /*
2  * Copyright (c) 1998 Robert Nordier
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms are freely
6  * permitted provided that the above copyright notice and this
7  * paragraph and the following disclaimer are duplicated in all
8  * such forms.
9  *
10  * This software is provided "AS IS" and without any express or
11  * implied warranties, including, without limitation, the implied
12  * warranties of merchantability and fitness for a particular
13  * purpose.
14  *
15  * $FreeBSD$
16  */
17
18 /* Memory Locations */
19                 .set MEM_REL,0x700              # Relocation address
20                 .set MEM_ARG,0x900              # Arguments
21                 .set MEM_ORG,0x7c00             # Origin
22                 .set MEM_BUF,0x8000             # Load area
23                 .set MEM_BTX,0x9000             # BTX start
24                 .set MEM_JMP,0x9010             # BTX entry point
25                 .set MEM_USR,0xa000             # Client start
26                 .set BDA_BOOT,0x472             # Boot howto flag
27         
28 /* Partition Constants */
29                 .set PRT_OFF,0x1be              # Partition offset
30                 .set PRT_NUM,0x4                # Partitions
31                 .set PRT_BSD,0xa5               # Partition type
32
33 /* Flag Bits */
34                 .set FL_PACKET,0x80             # Packet mode
35
36 /* Misc. Constants */
37                 .set SIZ_PAG,0x1000             # Page size
38                 .set SIZ_SEC,0x200              # Sector size
39
40                 .set NSECT,0x40
41                 .globl start
42                 .globl xread
43                 .code16
44
45 start:          jmp main                        # Start recognizably
46
47 /*
48  * This is the start of a standard BIOS Parameter Block (BPB). Most bootable
49  * FAT disks have this at the start of their MBR. While normal BIOS's will
50  * work fine without this section, IBM's El Torito emulation "fixes" up the
51  * BPB by writing into the memory copy of the MBR. Rather than have data
52  * written into our xread routine, we'll define a BPB to work around it.
53  * The data marked with (T) indicates a field required for a ThinkPad to
54  * recognize the disk and (W) indicates fields written from IBM BIOS code.
55  * The use of the BPB is based on what OpenBSD and NetBSD implemented in
56  * their boot code but the required fields were determined by trial and error.
57  *
58  * Note: If additional space is needed in boot1, one solution would be to
59  * move the "prompt" message data (below) to replace the OEM ID.
60  */
61                 .org 0x03, 0x00
62 oemid:          .space 0x08, 0x00       # OEM ID
63
64                 .org 0x0b, 0x00
65 bpb:            .word   512             # sector size (T)
66                 .byte   0               # sectors/clustor
67                 .word   0               # reserved sectors
68                 .byte   0               # number of FATs
69                 .word   0               # root entries
70                 .word   0               # small sectors
71                 .byte   0               # media type (W)
72                 .word   0               # sectors/fat
73                 .word   18              # sectors per track (T)
74                 .word   2               # number of heads (T)
75                 .long   0               # hidden sectors (W)
76                 .long   0               # large sectors
77
78                 .org 0x24, 0x00
79 ebpb:           .byte   0               # BIOS physical drive number (W)
80
81                 .org 0x25,0x90
82 /*
83  * Trampoline used by boot2 to call read to read data from the disk via
84  * the BIOS.  Call with:
85  *
86  * %ecx:%eax    - long    - LBA to read in
87  * %es:(%bx)    - caddr_t - buffer to read data into
88  * %dl          - byte    - drive to read from
89  * %dh          - byte    - num sectors to read
90  */
91
92 xread:          push %ss                        # Address
93                 pop %ds                         #  data
94 /*
95  * Setup an EDD disk packet and pass it to read
96  */
97 xread.1:        pushl %ecx                      # Starting absolute block
98                 pushl %eax                      #  block number
99                 push %es                        # Address of
100                 push %bx                        #  transfer buffer
101                 xor %ax,%ax                     # Number of
102                 movb %dh,%al                    #  blocks to
103                 push %ax                        #  transfer
104                 push $0x10                      # Size of packet
105                 mov %sp,%bp                     # Packet pointer
106                 callw read                      # Read from disk
107                 lea 0x10(%bp),%sp               # Clear stack
108                 lret                            # To far caller
109 /*
110  * Load the rest of boot2 and BTX up, copy the parts to the right locations,
111  * and start it all up.
112  */
113
114 /*
115  * Setup the segment registers to flat addressing (segment 0) and setup the
116  * stack to end just below the start of our code.
117  */
118 main:           cld                             # String ops inc
119                 xor %cx,%cx                     # Zero
120                 mov %cx,%es                     # Address
121                 mov %cx,%ds                     #  data
122                 mov %cx,%ss                     # Set up
123                 mov $start,%sp                  #  stack
124 /*
125  * Relocate ourself to MEM_REL.  Since %cx == 0, the inc %ch sets
126  * %cx == 0x100.
127  */
128                 mov %sp,%si                     # Source
129                 mov $MEM_REL,%di                # Destination
130                 incb %ch                        # Word count
131                 rep                             # Copy
132                 movsw                           #  code
133 /*
134  * If we are on a hard drive, then load the MBR and look for the first
135  * FreeBSD slice.  We use the fake partition entry below that points to
136  * the MBR when we call nread.  The first pass looks for the first active
137  * FreeBSD slice.  The second pass looks for the first non-active FreeBSD
138  * slice if the first one fails.
139  */
140                 mov $part4,%si                  # Partition
141                 cmpb $0x80,%dl                  # Hard drive?
142                 jb main.4                       # No
143                 movb $0x1,%dh                   # Block count
144                 callw nread                     # Read MBR
145                 mov $0x1,%cx                    # Two passes
146 main.1:         mov $MEM_BUF+PRT_OFF,%si        # Partition table
147                 movb $0x1,%dh                   # Partition
148 main.2:         cmpb $PRT_BSD,0x4(%si)          # Our partition type?
149                 jne main.3                      # No
150                 jcxz main.5                     # If second pass
151                 testb $0x80,(%si)               # Active?
152                 jnz main.5                      # Yes
153 main.3:         add $0x10,%si                   # Next entry
154                 incb %dh                        # Partition
155                 cmpb $0x1+PRT_NUM,%dh           # In table?
156                 jb main.2                       # Yes
157                 dec %cx                         # Do two
158                 jcxz main.1                     #  passes
159 /*
160  * If we get here, we didn't find any FreeBSD slices at all, so print an
161  * error message and die.
162  */
163                 mov $msg_part,%si               # Message
164                 jmp error                       # Error
165 /*
166  * Floppies use partition 0 of drive 0.
167  */
168 main.4:         xor %dx,%dx                     # Partition:drive
169
170 /*
171  * Ok, we have a slice and drive in %dx now, so use that to locate and
172  * load boot2.  %si references the start of the slice we are looking
173  * for, so go ahead and load up the 64 sectors starting at sector 1024
174  * (i.e. after the two vdev labels).  We don't have do anything fancy
175  * here to allow for an extra copy of boot1 and a partition table
176  * (compare to this section of the UFS bootstrap) so we just load it
177  * all at 0x8000. The first part of boot2 is BTX, which wants to run
178  * at 0x9000. The boot2.bin binary starts right after the end of BTX,
179  * so we have to figure out where the start of it is and then move the
180  * binary to 0xc000. After we have moved the client, we relocate BTX
181  * itself to 0x9000 - doing it in this order means that none of the
182  * memcpy regions overlap which would corrupt the copy.  Normally, BTX
183  * clients start at MEM_USR, or 0xa000, but when we use btxld to
184  * create boot2, we use an entry point of 0x2000.  That entry point is
185  * relative to MEM_USR; thus boot2.bin starts at 0xc000.
186  *
187  * The load area and the target area for the client overlap so we have
188  * to use a decrementing string move. We also play segment register
189  * games with the destination address for the move so that the client
190  * can be larger than 16k (which would overflow the zero segment since
191  * the client starts at 0xc000). Relocating BTX is easy since the load
192  * area and target area do not overlap.
193  */
194 main.5:         mov %dx,MEM_ARG                 # Save args
195                 movb $NSECT,%dh                 # Sector count
196                 movl $1024,%eax                 # Offset to boot2
197                 callw nread.1                   # Read disk
198 main.6:         mov $MEM_BUF,%si                # BTX (before reloc)
199                 mov 0xa(%si),%bx                # Get BTX length and set
200                 mov $NSECT*SIZ_SEC-1,%di        # Size of load area (less one)
201                 mov %di,%si                     # End of load
202                 add $MEM_BUF,%si                #  area
203                 sub %bx,%di                     # End of client, 0xc000 rel
204                 mov %di,%cx                     # Size of
205                 inc %cx                         #  client
206                 mov $(MEM_USR+2*SIZ_PAG)>>4,%dx # Segment
207                 mov %dx,%es                     #   addressing 0xc000
208                 std                             # Move with decrement
209                 rep                             # Relocate
210                 movsb                           #  client
211                 mov %ds,%dx                     # Back to
212                 mov %dx,%es                     #  zero segment
213                 mov $MEM_BUF,%si                # BTX (before reloc)
214                 mov $MEM_BTX,%di                # BTX
215                 mov %bx,%cx                     # Get BTX length
216                 cld                             # Increment this time
217                 rep                             # Relocate
218                 movsb                           #  BTX
219
220 /*
221  * Enable A20 so we can access memory above 1 meg.
222  * Use the zero-valued %cx as a timeout for embedded hardware which do not
223  * have a keyboard controller.
224  */
225 seta20:         cli                             # Disable interrupts
226 seta20.1:       dec %cx                         # Timeout?
227                 jz seta20.3                     # Yes
228                 inb $0x64,%al                   # Get status
229                 testb $0x2,%al                  # Busy?
230                 jnz seta20.1                    # Yes
231                 movb $0xd1,%al                  # Command: Write
232                 outb %al,$0x64                  #  output port
233 seta20.2:       inb $0x64,%al                   # Get status
234                 testb $0x2,%al                  # Busy?
235                 jnz seta20.2                    # Yes
236                 movb $0xdf,%al                  # Enable
237                 outb %al,$0x60                  #  A20
238 seta20.3:       sti                             # Enable interrupts
239
240                 jmp start+MEM_JMP-MEM_ORG       # Start BTX
241
242
243 /*
244  * Trampoline used to call read from within boot1.
245  */
246 nread:          xor %eax,%eax                   # Sector offset in partition
247 nread.1:        mov $MEM_BUF,%bx                # Transfer buffer
248                 xor %ecx,%ecx                   # Get
249                 addl 0x8(%si),%eax              #  LBA
250                 adc $0,%ecx
251                 push %cs                        # Read from
252                 callw xread.1                   #  disk
253                 jnc return                      # If success, return
254                 mov $msg_read,%si               # Otherwise, set the error
255                                                 #  message and fall through to
256                                                 #  the error routine
257 /*
258  * Print out the error message pointed to by %ds:(%si) followed
259  * by a prompt, wait for a keypress, and then reboot the machine.
260  */
261 error:          callw putstr                    # Display message
262                 mov $prompt,%si                 # Display
263                 callw putstr                    #  prompt
264                 xorb %ah,%ah                    # BIOS: Get
265                 int $0x16                       #  keypress
266                 movw $0x1234, BDA_BOOT          # Do a warm boot
267                 ljmp $0xffff,$0x0               # reboot the machine
268 /*
269  * Display a null-terminated string using the BIOS output.
270  */
271 putstr.0:       mov $0x7,%bx                    # Page:attribute
272                 movb $0xe,%ah                   # BIOS: Display
273                 int $0x10                       #  character
274 putstr:         lodsb                           # Get char
275                 testb %al,%al                   # End of string?
276                 jne putstr.0                    # No
277
278 /*
279  * Overused return code.  ereturn is used to return an error from the
280  * read function.  Since we assume putstr succeeds, we (ab)use the
281  * same code when we return from putstr.
282  */
283 ereturn:        movb $0x1,%ah                   # Invalid
284                 stc                             #  argument
285 return:         retw                            # To caller
286 /*
287  * Reads sectors from the disk.  If EDD is enabled, then check if it is
288  * installed and use it if it is.  If it is not installed or not enabled, then
289  * fall back to using CHS.  Since we use a LBA, if we are using CHS, we have to
290  * fetch the drive parameters from the BIOS and divide it out ourselves.
291  * Call with:
292  *
293  * %dl  - byte     - drive number
294  * stack - 10 bytes - EDD Packet
295  */
296 read:           testb $FL_PACKET,%cs:MEM_REL+flags-start # LBA support enabled?
297                 jz read.1                       # No, use CHS
298                 cmpb $0x80,%dl                  # Hard drive?
299                 jb read.1                       # No, use CHS
300                 mov $0x55aa,%bx                 # Magic
301                 push %dx                        # Save
302                 movb $0x41,%ah                  # BIOS: Check
303                 int $0x13                       #  extensions present
304                 pop %dx                         # Restore
305                 jc read.1                       # If error, use CHS
306                 cmp $0xaa55,%bx                 # Magic?
307                 jne read.1                      # No, so use CHS
308                 testb $0x1,%cl                  # Packet interface?
309                 jz read.1                       # No, so use CHS
310                 mov %bp,%si                     # Disk packet
311                 movb $0x42,%ah                  # BIOS: Extended
312                 int $0x13                       #  read
313                 retw                            # To caller
314 #if 0   
315 read.1:         push %dx                        # Save
316                 movb $0x8,%ah                   # BIOS: Get drive
317                 int $0x13                       #  parameters
318                 movb %dh,%ch                    # Max head number
319                 pop %dx                         # Restore
320                 jc return                       # If error
321                 andb $0x3f,%cl                  # Sectors per track
322                 jz ereturn                      # If zero
323                 cli                             # Disable interrupts
324                 mov 0x8(%bp),%eax               # Get LBA
325                 push %dx                        # Save
326                 movzbl %cl,%ebx                 # Divide by
327                 xor %edx,%edx                   #  sectors
328                 div %ebx                        #  per track
329                 movb %ch,%bl                    # Max head number
330                 movb %dl,%ch                    # Sector number
331                 inc %bx                         # Divide by
332                 xorb %dl,%dl                    #  number
333                 div %ebx                        #  of heads
334                 movb %dl,%bh                    # Head number
335                 pop %dx                         # Restore
336                 cmpl $0x3ff,%eax                # Cylinder number supportable?
337                 sti                             # Enable interrupts
338                 ja ereturn                      # No, return an error
339                 xchgb %al,%ah                   # Set up cylinder
340                 rorb $0x2,%al                   #  number
341                 orb %ch,%al                     # Merge
342                 inc %ax                         #  sector
343                 xchg %ax,%cx                    #  number
344                 movb %bh,%dh                    # Head number
345                 subb %ah,%al                    # Sectors this track
346                 mov 0x2(%bp),%ah                # Blocks to read
347                 cmpb %ah,%al                    # To read
348                 jb read.2                       #  this
349 #ifdef  TRACK_AT_A_TIME
350                 movb %ah,%al                    #  track
351 #else
352                 movb $1,%al                     #  one sector
353 #endif
354 read.2:         mov $0x5,%di                    # Try count
355 read.3:         les 0x4(%bp),%bx                # Transfer buffer
356                 push %ax                        # Save
357                 movb $0x2,%ah                   # BIOS: Read
358                 int $0x13                       #  from disk
359                 pop %bx                         # Restore
360                 jnc read.4                      # If success
361                 dec %di                         # Retry?
362                 jz read.6                       # No
363                 xorb %ah,%ah                    # BIOS: Reset
364                 int $0x13                       #  disk system
365                 xchg %bx,%ax                    # Block count
366                 jmp read.3                      # Continue
367 read.4:         movzbw %bl,%ax                  # Sectors read
368                 add %ax,0x8(%bp)                # Adjust
369                 jnc read.5                      #  LBA,
370                 incw 0xa(%bp)                   #  transfer
371 read.5:         shlb %bl                        #  buffer
372                 add %bl,0x5(%bp)                #  pointer,
373                 sub %al,0x2(%bp)                #  block count
374                 ja read.1                       # If not done
375 read.6:         retw                            # To caller
376 #else
377 read.1:         mov $msg_chs,%si
378                 jmp error
379 msg_chs:        .asciz "CHS not supported"
380 #endif
381
382 /* Messages */
383
384 msg_read:       .asciz "Read"
385 msg_part:       .asciz "Boot"
386
387 prompt:         .asciz " error\r\n"
388
389 flags:          .byte FLAGS                     # Flags
390
391                 .org PRT_OFF,0x90
392
393 /* Partition table */
394
395                 .fill 0x30,0x1,0x0
396 part4:          .byte 0x80, 0x00, 0x01, 0x00
397                 .byte 0xa5, 0xfe, 0xff, 0xff
398                 .byte 0x00, 0x00, 0x00, 0x00
399                 .byte 0x50, 0xc3, 0x00, 0x00    # 50000 sectors long, bleh
400
401                 .word 0xaa55                    # Magic number