Improved Random building texturesa - Gabo Huerta
[fg:toms-fgdata.git] / Shaders / urban.frag
1 // -*- mode: C; -*-
2 // Licence: GPL v2
3 // Author: Frederic Bouvier.
4 //  Adapted from the paper by F. Policarpo et al. : Real-time Relief Mapping on Arbitrary Polygonal Surfaces
5 //  Adapted from the paper and sources by M. Drobot in GPU Pro : Quadtree Displacement Mapping with Height Blending
6
7 #version 120
8
9 #extension GL_ATI_shader_texture_lod : enable
10 #extension GL_ARB_shader_texture_lod : enable
11
12 #define TEXTURE_MIP_LEVELS 10
13 #define TEXTURE_PIX_COUNT  1024 //pow(2,TEXTURE_MIP_LEVELS)
14 #define BINARY_SEARCH_COUNT 10
15 #define BILINEAR_SMOOTH_FACTOR 2.0
16
17 varying vec4  rawpos;
18 varying vec4  ecPosition;
19 varying vec3  VNormal;
20 varying vec3  VTangent;
21 //varying vec3  VBinormal;
22 varying vec3  Normal;
23 varying vec4  constantColor;
24
25 uniform sampler3D NoiseTex;
26 uniform sampler2D BaseTex;
27 uniform sampler2D NormalTex;
28 uniform sampler2D QDMTex;
29 uniform float depth_factor;
30 uniform float tile_size;
31 uniform float quality_level;
32 uniform float snowlevel;
33 uniform vec3 night_color;
34 uniform bool random_buildings;
35
36 const float scale = 1.0;
37 int linear_search_steps = 10;
38 int GlobalIterationCount = 0;
39 int gIterationCap = 64;
40
41 ////fog "include" /////
42 uniform int fogType;
43
44 vec3 fog_Func(vec3 color, int type);
45 //////////////////////
46
47 void QDM(inout vec3 p, inout vec3 v)
48 {
49     const int MAX_LEVEL = TEXTURE_MIP_LEVELS;
50     const float NODE_COUNT = TEXTURE_PIX_COUNT;
51     const float TEXEL_SPAN_HALF = 1.0 / NODE_COUNT / 2.0;
52
53     float fDeltaNC = TEXEL_SPAN_HALF * depth_factor;
54
55     vec3 p2 = p;
56     float level = MAX_LEVEL;
57     vec2 dirSign = (sign(v.xy) + 1.0) * 0.5;
58     GlobalIterationCount = 0;
59     float d = 0.0;
60
61     while (level >= 0.0 && GlobalIterationCount < gIterationCap)
62     {
63         vec4 uv = vec4(p2.xyz, level);
64         d = texture2DLod(QDMTex, uv.xy, uv.w).w;
65
66         if (d > p2.z)
67         {
68             //predictive point of ray traversal
69             vec3 tmpP2 = p + v * d;
70
71             //current node count
72             float nodeCount = pow(2.0, (MAX_LEVEL - level));
73             //current and predictive node ID
74             vec4 nodeID = floor(vec4(p2.xy, tmpP2.xy)*nodeCount);
75
76             //check if we are crossing the current cell
77             if (nodeID.x != nodeID.z || nodeID.y != nodeID.w)
78             {
79                 //calculate distance to nearest bound
80                 vec2 a = p2.xy - p.xy;
81                 vec2 p3 = (nodeID.xy + dirSign) / nodeCount;
82                 vec2 b = p3.xy - p.xy;
83
84                 vec2 dNC = (b.xy * p2.z) / a.xy;
85                 //take the nearest cell
86                 d = min(d,min(dNC.x, dNC.y))+fDeltaNC;
87
88                 level++;
89             }
90             p2 = p + v * d;
91         }
92         level--;
93         GlobalIterationCount++;
94     }
95
96     //
97     // Manual Bilinear filtering
98     //
99     float rayLength =  length(p2.xy - p.xy) + fDeltaNC;
100
101     float dA = p2.z * (rayLength - BILINEAR_SMOOTH_FACTOR * TEXEL_SPAN_HALF) / rayLength;
102     float dB = p2.z * (rayLength + BILINEAR_SMOOTH_FACTOR * TEXEL_SPAN_HALF) / rayLength;
103
104     vec4 p2a = vec4(p + v * dA, 0.0);
105     vec4 p2b = vec4(p + v * dB, 0.0);
106     dA = texture2DLod(NormalTex, p2a.xy, p2a.w).w;
107     dB = texture2DLod(NormalTex, p2b.xy, p2b.w).w;
108
109     dA = abs(p2a.z - dA);
110     dB = abs(p2b.z - dB);
111
112     p2 = mix(p2a.xyz, p2b.xyz, dA / (dA + dB));
113
114     p = p2;
115 }
116
117 float ray_intersect_QDM(vec2 dp, vec2 ds)
118 {
119     vec3 p = vec3( dp, 0.0 );
120     vec3 v = vec3( ds, 1.0 );
121     QDM( p, v );
122     return p.z;
123 }
124
125 float ray_intersect_relief(vec2 dp, vec2 ds)
126 {
127     float size = 1.0 / float(linear_search_steps);
128     float depth = 0.0;
129     float best_depth = 1.0;
130
131     for(int i = 0; i < linear_search_steps - 1; ++i)
132     {
133         depth += size;
134         float t = step(0.95, texture2D(NormalTex, dp + ds * depth).a);
135         if(best_depth > 0.996)
136             if(depth >= t)
137                 best_depth = depth;
138     }
139     depth = best_depth;
140
141     const int binary_search_steps = 5;
142
143     for(int i = 0; i < binary_search_steps; ++i)
144     {
145         size *= 0.5;
146         float t = step(0.95, texture2D(NormalTex, dp + ds * depth).a);
147         if(depth >= t)
148         {
149             best_depth = depth;
150             depth -= 2.0 * size;
151         }
152         depth += size;
153     }
154
155     return(best_depth);
156 }
157
158 float ray_intersect(vec2 dp, vec2 ds)
159 {
160     if ( random_buildings )
161         return 0.0;
162     else if ( quality_level >= 4.0 )
163         return ray_intersect_QDM( dp, ds );
164     else
165         return ray_intersect_relief( dp, ds );
166 }
167
168 void main (void)
169 {
170     if ( quality_level >= 3.0 ) {
171         linear_search_steps = 20;
172     }
173
174     float depthfactor = depth_factor;
175     if ( random_buildings ) depthfactor = 0.0;
176
177     vec3 normal = normalize(VNormal);
178     vec3 tangent = normalize(VTangent);
179     //vec3 binormal = normalize(VBinormal);
180     vec3 binormal = normalize(cross(normal, tangent));
181     vec3 ecPos3 = ecPosition.xyz / ecPosition.w;
182     vec3 V = normalize(ecPos3);
183     vec3 s = vec3(dot(V, tangent), dot(V, binormal), dot(normal, -V));
184     vec2 ds = s.xy * depthfactor / s.z;
185     vec2 dp = gl_TexCoord[0].st - ds;
186     float d = ray_intersect(dp, ds);
187
188     vec2 uv = dp + ds * d;
189     vec3 N = texture2D(NormalTex, uv).xyz * 2.0 - 1.0;
190
191
192     float emis = N.z;
193     N.z = sqrt(1.0 - min(1.0,dot(N.xy, N.xy)));
194     float Nz = N.z;
195     N = normalize(N.x * tangent + N.y * binormal + N.z * normal);
196
197     vec3 l = gl_LightSource[0].position.xyz;
198     vec3 diffuse = gl_Color.rgb * max(0.0, dot(N, l));
199     float shadow_factor = 1.0;
200
201     // Shadow
202     if ( quality_level >= 2.0 ) {
203         dp += ds * d;
204         vec3 sl = normalize( vec3( dot( l, tangent ), dot( l, binormal ), dot( -l, normal ) ) );
205         ds = sl.xy * depthfactor / sl.z;
206         dp -= ds * d;
207         float dl = ray_intersect(dp, ds);
208         if ( dl < d - 0.05 )
209             shadow_factor = dot( constantColor.xyz, vec3( 1.0, 1.0, 1.0 ) ) * 0.25;
210     }
211     // end shadow
212
213     vec4 ambient_light = constantColor + gl_LightSource[0].diffuse * vec4(diffuse, 1.0);
214     float reflectance = ambient_light.r * 0.3 + ambient_light.g * 0.59 + ambient_light.b * 0.11;
215     if ( shadow_factor < 1.0 )
216         ambient_light = constantColor + gl_LightSource[0].diffuse * shadow_factor * vec4(diffuse, 1.0);
217     float emission_factor = (1.0 - smoothstep(0.15, 0.25, reflectance)) * emis;
218     vec4 tc = texture2D(BaseTex, uv);
219     emission_factor *= 0.5*pow(tc.r+0.8*tc.g+0.2*tc.b, 2.0) -0.2;
220     ambient_light += (emission_factor * vec4(night_color, 0.0));
221
222     vec4 noisevec   = texture3D(NoiseTex, (rawpos.xyz)*0.01*scale);
223     vec4 nvL   = texture3D(NoiseTex, (rawpos.xyz)*0.00066*scale);
224
225     float n=0.06;
226     n += nvL[0]*0.4;
227     n += nvL[1]*0.6;
228     n += nvL[2]*2.0;
229     n += nvL[3]*4.0;
230     n += noisevec[0]*0.1;
231     n += noisevec[1]*0.4;
232
233     n += noisevec[2]*0.8;
234     n += noisevec[3]*2.1;
235     n = mix(0.6, n, length(ecPosition.xyz) );
236
237     vec4 finalColor = texture2D(BaseTex, uv);
238     finalColor = mix(finalColor, clamp(n+nvL[2]*4.1+vec4(0.1, 0.1, nvL[2]*2.2, 1.0), 0.7, 1.0),
239             step(0.8,Nz)*(1.0-emis)*smoothstep(snowlevel+300.0, snowlevel+360.0, (rawpos.z)+nvL[1]*3000.0));
240     finalColor *= ambient_light;
241
242     vec4 p = vec4( ecPos3 + tile_size * V * (d-1.0) * depthfactor / s.z, 1.0 );
243
244     finalColor.rgb = fog_Func(finalColor.rgb, fogType);
245     gl_FragColor = finalColor;
246
247     if (dot(normal,-V) > 0.1) {
248         vec4 iproj = gl_ProjectionMatrix * p;
249         iproj /= iproj.w;
250         gl_FragDepth = (iproj.z+1.0)/2.0;
251     } else {
252         gl_FragDepth = gl_FragCoord.z;
253     }
254 }