Improve memory and instantiation time of random buildings.
[fg:toms-fgdata.git] / Shaders / building-haze.vert
1 // -*-C++-*-
2
3 // Shader that uses OpenGL state values to do per-pixel lighting
4 //
5 // The only light used is gl_LightSource[0], which is assumed to be
6 // directional.
7 //
8 // Diffuse colors come from the gl_Color, ambient from the material. This is
9 // equivalent to osg::Material::DIFFUSE.
10 // Haze part added by Thorsten Renk, Oct. 2011
11
12
13 #define MODE_OFF 0
14 #define MODE_DIFFUSE 1
15 #define MODE_AMBIENT_AND_DIFFUSE 2
16
17 // The constant term of the lighting equation that doesn't depend on
18 // the surface normal is passed in gl_{Front,Back}Color. The alpha
19 // component is set to 1 for front, 0 for back in order to work around
20 // bugs with gl_FrontFacing in the fragment shader.
21 varying vec4 diffuse_term;
22 varying vec3 normal;
23 varying vec3 relPos;
24
25 //varying float earthShade;
26 //varying float yprime;
27 //varying float vertex_alt;
28 varying float yprime_alt;
29 varying float mie_angle;
30
31
32
33
34 uniform int colorMode;
35 uniform float hazeLayerAltitude;
36 uniform float terminator;
37 uniform float terrain_alt; 
38 uniform float avisibility;
39 uniform float visibility;
40 uniform float overcast;
41 //uniform float scattering;
42 uniform float ground_scattering;
43
44
45 // This is the value used in the skydome scattering shader - use the same here for consistency?
46 const float EarthRadius = 5800000.0;
47 const float terminator_width = 200000.0;
48
49
50 float earthShade;
51
52 float light_func (in float x, in float a, in float b, in float c, in float d, in float e)
53 {
54 //x = x - 0.5;
55
56 // use the asymptotics to shorten computations
57 if (x < -15.0) {return 0.0;}
58
59 return e / pow((1.0 + a * exp(-b * (x-c)) ),(1.0/d));
60 }
61
62
63 void main()
64 {
65
66   vec4 light_diffuse;
67   vec4 light_ambient;
68
69   //float yprime_alt;
70   float yprime;
71   float lightArg;
72   float intensity;
73   float vertex_alt;
74   float scattering;
75
76 // this code is copied from default.vert
77
78     //vec4 ecPosition = gl_ModelViewMatrix * gl_Vertex;
79     // Determine the rotation for the building.  The Color alpha value provides rotation information
80     float sr = sin(6.28 * gl_Color.a);
81     float cr = cos(6.28 * gl_Color.a);
82     
83     vec3 position = gl_Vertex.xyz;
84     
85     // Rotation of the building and movement into position
86     position.xy = vec2(dot(position.xy, vec2(cr, sr)), dot(position.xy, vec2(-sr, cr)));
87     position = position + gl_Color.xyz;
88     
89     gl_Position  = gl_ModelViewProjectionMatrix * vec4(position,1.0);
90     gl_TexCoord[0] = gl_TextureMatrix[0] * gl_MultiTexCoord0;
91     
92     // Rotate the normal.
93     normal = gl_Normal;
94     normal.xy = vec2(dot(normal.xy, vec2(cr, sr)), dot(normal.xy, vec2(-sr, cr)));
95     normal = gl_NormalMatrix * normal;
96     
97     vec4 ambient_color, diffuse_color;
98     if (colorMode == MODE_DIFFUSE) {
99         diffuse_color = vec4(1.0,1.0,1.0,1.0);
100         ambient_color = gl_FrontMaterial.ambient;
101     } else if (colorMode == MODE_AMBIENT_AND_DIFFUSE) {
102         diffuse_color = vec4(1.0,1.0,1.0,1.0);
103         ambient_color = vec4(1.0,1.0,1.0,1.0);
104     } else {
105         diffuse_color = gl_FrontMaterial.diffuse;
106         ambient_color = gl_FrontMaterial.ambient;
107     }
108    
109     // here start computations for the haze layer
110     // we need several geometrical quantities
111
112     // first current altitude of eye position in model space
113     vec4 ep = gl_ModelViewMatrixInverse * vec4(0.0,0.0,0.0,1.0);
114     
115     // and relative position to vector
116     relPos = gl_Vertex.xyz + gl_Color.xyz - ep.xyz;
117
118     // unfortunately, we need the distance in the vertex shader, although the more accurate version
119     // is later computed in the fragment shader again
120     float dist = length(relPos);
121
122     // altitude of the vertex in question, somehow zero leads to artefacts, so ensure it is at least 100m
123     vertex_alt = max(gl_Vertex.z + gl_Color.z,100.0);
124     scattering = ground_scattering + (1.0 - ground_scattering) * smoothstep(hazeLayerAltitude -100.0, hazeLayerAltitude + 100.0, vertex_alt); 
125
126     // branch dependent on daytime
127
128 if (terminator < 1000000.0) // the full, sunrise and sunset computation
129 {
130     
131
132     // establish coordinates relative to sun position
133
134     vec3 lightFull = (gl_ModelViewMatrixInverse * gl_LightSource[0].position).xyz;
135     vec3 lightHorizon = normalize(vec3(lightFull.x,lightFull.y, 0.0));
136   
137
138     
139     // yprime is the distance of the vertex into sun direction
140     yprime = -dot(relPos, lightHorizon);
141
142     // this gets an altitude correction, higher terrain gets to see the sun earlier
143     yprime_alt = yprime - sqrt(2.0 * EarthRadius * vertex_alt);
144
145     // two times terminator width governs how quickly light fades into shadow
146     // now the light-dimming factor
147     earthShade = 0.6 * (1.0 - smoothstep(-terminator_width+ terminator, terminator_width + terminator, yprime_alt)) + 0.4;
148   
149    // parametrized version of the Flightgear ground lighting function
150     lightArg = (terminator-yprime_alt)/100000.0;
151
152     // directional scattering for low sun
153     if (lightArg < 10.0)
154         {mie_angle = (0.5 *  dot(normalize(relPos), normalize(lightFull)) ) + 0.5;}
155     else 
156         {mie_angle = 1.0;}
157
158
159
160
161    light_diffuse.b = light_func(lightArg, 1.330e-05, 0.264, 3.827, 1.08e-05, 1.0);
162    light_diffuse.g = light_func(lightArg, 3.931e-06, 0.264, 3.827, 7.93e-06, 1.0);
163    light_diffuse.r = light_func(lightArg, 8.305e-06, 0.161, 3.827, 3.04e-05, 1.0);
164    light_diffuse.a = 0.0;
165    light_diffuse = light_diffuse * scattering;
166
167    light_ambient.b = light_func(lightArg, 0.000506, 0.131, -3.315, 0.000457, 0.5);
168    light_ambient.g = light_func(lightArg, 2.264e-05, 0.134, 0.967, 3.66e-05, 0.4);
169    light_ambient.r = light_func(lightArg, 0.236, 0.253, 1.073, 0.572, 0.33);
170    light_ambient.a = 0.0;
171
172
173
174
175 // correct ambient light intensity and hue before sunrise
176 if (earthShade < 0.5)
177         {
178         light_ambient = light_ambient * (0.7 + 0.3 * smoothstep(0.2, 0.5, earthShade));
179         intensity = length(light_ambient.xyz); 
180
181         light_ambient.xyz = intensity * normalize(mix(light_ambient.xyz,  vec3 (0.45, 0.6, 0.8), 1.0 -smoothstep(0.1, 0.8,earthShade) ));
182
183         intensity = length(light_diffuse.xyz); 
184         light_diffuse.xyz = intensity * normalize(mix(light_diffuse.xyz,  vec3 (0.45, 0.6, 0.8), 1.0 -smoothstep(0.1, 0.7,earthShade) ));
185         }
186
187
188 // the haze gets the light at the altitude of the haze top if the vertex in view is below
189 // but the light at the vertex if the vertex is above
190
191 vertex_alt = max(vertex_alt,hazeLayerAltitude);
192
193 if (vertex_alt > hazeLayerAltitude)
194         {
195         if (dist > 0.8 * avisibility)
196                 {
197                 vertex_alt = mix(vertex_alt, hazeLayerAltitude, smoothstep(0.8*avisibility, avisibility, dist));
198                 yprime_alt = yprime -sqrt(2.0 * EarthRadius * vertex_alt);
199                 }
200         }
201 else
202         {
203         vertex_alt = hazeLayerAltitude;
204         yprime_alt = yprime -sqrt(2.0 * EarthRadius * vertex_alt);
205         }
206
207 }
208 else // the faster, full-day version without lightfields
209 {
210     //vertex_alt = max(gl_Vertex.z,100.0);
211  
212     earthShade = 1.0;
213     mie_angle = 1.0;
214     
215     if (terminator > 3000000.0)
216         {light_diffuse = vec4 (1.0, 1.0, 1.0, 0.0);
217         light_ambient = vec4 (0.33, 0.4, 0.5, 0.0); }
218     else
219         {
220
221         lightArg = (terminator/100000.0 - 10.0)/20.0;
222         light_diffuse.b = 0.78  + lightArg * 0.21;
223         light_diffuse.g = 0.907 + lightArg * 0.091;
224         light_diffuse.r = 0.904 + lightArg * 0.092;
225         light_diffuse.a = 0.0;
226
227         light_ambient.b = 0.41 + lightArg * 0.08;
228         light_ambient.g = 0.333 + lightArg * 0.06;
229         light_ambient.r = 0.316 + lightArg * 0.016;
230         light_ambient.a = 0.0;
231         }  
232     
233     light_diffuse = light_diffuse * scattering;
234     yprime_alt = -sqrt(2.0 * EarthRadius * hazeLayerAltitude);
235 }
236  
237
238 // default lighting based on texture and material using the light we have just computed
239
240  diffuse_term = diffuse_color* light_diffuse;
241     vec4 constant_term = gl_FrontMaterial.emission + ambient_color *
242         (gl_LightModel.ambient +  light_ambient);
243     // Super hack: if diffuse material alpha is less than 1, assume a
244     // transparency animation is at work
245     if (gl_FrontMaterial.diffuse.a < 1.0)
246         diffuse_term.a = gl_FrontMaterial.diffuse.a;
247     else
248         diffuse_term.a = 1.0;
249     // Another hack for supporting two-sided lighting without using
250     // gl_FrontFacing in the fragment shader.
251     gl_FrontColor.rgb = constant_term.rgb;  gl_FrontColor.a = 1.0;
252     gl_BackColor.rgb = constant_term.rgb; gl_BackColor.a = 0.0;
253 }
254