Add a variant of the tanker request function that produces a tanker with
[fg:toms-fgdata.git] / Nasal / tanker.nas
1 if (globals["tanker"] != nil) {
2         # reload with io.load_nasal(getprop("/sim/fg-root") ~ "/Nasal/tanker.nas");
3         print("reloading " ~ caller(0)[2]);
4         var _setlistener = reinit;
5         reinit();
6 }
7 #--------------------------------------------------------------------------------------------------
8
9
10 var boom_tanker = "Models/Geometry/KC135/KC135.xml";
11 var probe_tanker = "Models/Geometry/KA6-D/KA6-D.xml";
12
13
14 var oclock = func(bearing) int(0.5 + geo.normdeg(bearing) / 30) or 12;
15
16
17 var tanker_msg = func setprop("sim/messages/ai-plane", call(sprintf, arg));
18 var pilot_msg = func setprop("/sim/messages/pilot", call(sprintf, arg));
19 var atc_msg = func setprop("sim/messages/atc", call(sprintf, arg));
20
21
22 var skip_cloud_layer = func(alt) {
23         var c = [];
24         foreach (var layer; props.globals.getNode("/environment/clouds").getChildren("layer")) {
25                 var elev = (layer.getNode("elevation-ft", 1).getValue() or -9999) * FT2M;
26                 var thck = (layer.getNode("thickness-ft", 1).getValue() or 0) * FT2M;
27                 if (elev > -1000)
28                         append(c, { bottom: elev - thck * 0.5 - 100, top: elev + thck * 0.5 + 100 });
29         }
30         while (check; 1) {
31                 foreach (var layer; c) {
32                         if (alt > layer.bottom and alt < layer.top) {
33                                 alt += 1000;
34                                 continue check;
35                         }
36                 }
37                 return alt;
38         }
39 }
40
41
42 var identity = {
43         get: func {
44                 # return free AI id number and least used, free callsign/channel pair
45                 var data = {};     # copy of me.pool
46                 var revdata = {};  # channel->callsign
47                 foreach (var k; keys(me.pool)) {
48                         data[k] = me.pool[k];
49                         revdata[me.pool[k][0]] = k;
50                 }
51                 var id_used = {};
52                 foreach (var t; props.globals.getNode("ai/models", 1).getChildren()) {
53                         if ((var c = t.getNode("callsign")) != nil)
54                                 delete(data, c.getValue() or "");
55                         if ((var c = t.getNode("navaids/tacan/channel-ID")) != nil)
56                                 delete(data, revdata[c.getValue() or ""]);
57                         if ((var c = t.getNode("id")) != nil)
58                                 id_used[c.getValue()] = 1;
59                 }
60                 for (var aiid = -2; aiid; aiid -= 1)
61                         if (!id_used[aiid])
62                                 break;
63                 if (!size(data))
64                         return [aiid, "MOBIL3", "062X"];
65                 var d = sort(keys(data), func(a, b) data[a][1] - data[b][1])[0];
66                 me.pool[d][1] += 1;
67                 return [aiid, d, data[d][0]];
68         },
69         pool: {
70                 ESSO1: ["040X", rand()], ESSO2: ["041X", rand()], ESSO3: ["042X", rand()],
71                 TEXACO1: ["050X", rand()], TEXACO2: ["051X", rand()], TEXACO3: ["052X", rand()],
72                 MOBIL1: ["060X", rand()], MOBIL2: ["061X", rand()], MOBIL3: ["062X", rand()],
73         },
74 };
75
76
77 var Tanker = {
78         new: func(aiid, callsign, tacan, type, kias, heading, coord) {
79                 var m = { parents: [Tanker] };
80                 m.callsign = callsign;
81                 m.tacan = tacan;
82                 m.kias = kias;
83                 m.heading = m.course = m.track_course = heading;
84                 m.out_of_range_time = 0;
85                 m.interval = 10;
86                 m.length = (getprop("tanker/pattern-length-nm") or 50) * NM2M;
87                 m.roll = 0;
88                 m.coord = geo.Coord.new(coord);
89                 m.anchor = geo.Coord.new(coord).apply_course_distance(m.track_course, m.length); # ARCP
90                 m.goal = [nil, m.anchor];
91                 m.lastmode = "none";
92                 m.mode = "leg";
93                 m.rollrate = 2; # deg/s
94                 m.maxbank = 25;
95
96                 var n = props.globals.getNode("models", 1);
97                 for (var i = 0; 1; i += 1)
98                         if (n.getChild("model", i, 0) == nil)
99                                 break;
100                 m.model = n.getChild("model", i, 1);
101
102                 var n = props.globals.getNode("ai/models", 1);
103                 for (var i = 0; 1; i += 1)
104                         if (n.getChild("tanker", i, 0) == nil)
105                                 break;
106                 m.ai = n.getChild("tanker", i, 1);
107
108                 m.ai.getNode("id", 1).setIntValue(aiid);
109                 m.ai.getNode("callsign", 1).setValue(m.callsign ~ "");
110                 m.ai.getNode("tanker", 1).setBoolValue(1);
111                 m.ai.getNode("valid", 1).setBoolValue(1);
112                 m.ai.getNode("navaids/tacan/channel-ID", 1).setValue(m.tacan);
113                 m.ai.getNode("refuel/type", 1).setValue(type);
114                 m.ai.getNode("refuel/contact", 1).setBoolValue(0);
115
116                 m.latN = m.ai.getNode("position/latitude-deg", 1);
117                 m.lonN = m.ai.getNode("position/longitude-deg", 1);
118                 m.altN = m.ai.getNode("position/altitude-ft", 1);
119                 m.hdgN = m.ai.getNode("orientation/true-heading-deg", 1);
120                 m.pitchN = m.ai.getNode("orientation/pitch-deg", 1);
121                 m.rollN = m.ai.getNode("orientation/roll-deg", 1);
122                 m.ktasN = m.ai.getNode("velocities/true-airspeed-kt", 1);
123                 m.vertN = m.ai.getNode("velocities/vertical-speed-fps", 1);
124                 m.rangeN = m.ai.getNode("radar/range-nm", 1);
125                 m.brgN = m.ai.getNode("radar/bearing-deg", 1);
126                 m.elevN = m.ai.getNode("radar/elevation-deg", 1);
127                 m.contactN = m.ai.getNode("refuel/contact", 1);
128
129                 m.update();
130                 m.model.getNode("path", 1).setValue(type == "boom" ? boom_tanker : probe_tanker);
131                 m.model.getNode("latitude-deg-prop", 1).setValue(m.latN.getPath());
132                 m.model.getNode("longitude-deg-prop", 1).setValue(m.lonN.getPath());
133                 m.model.getNode("elevation-ft-prop", 1).setValue(m.altN.getPath());
134                 m.model.getNode("heading-deg-prop", 1).setValue(m.hdgN.getPath());
135                 m.model.getNode("pitch-deg-prop", 1).setValue(m.pitchN.getPath());
136                 m.model.getNode("roll-deg-prop", 1).setValue(m.rollN.getPath());
137                 m.model.getNode("load", 1).remove();
138                 m.identify();
139                 return Tanker.active[m.callsign] = m;
140         },
141         del: func {
142                 tanker_msg(me.callsign ~ " returns to base");
143                 me.model.remove();
144                 me.ai.remove();
145                 delete(Tanker.active, me.callsign);
146         },
147         update: func {
148                 var dt = getprop("sim/time/delta-sec");
149                 var alt = me.coord.alt();
150
151                 if ((me.interval += dt) >= 5) {
152                         me.interval -= 5;
153                         me.headwind = aircraft.wind_speed_from(me.course);
154                         me.ktas = aircraft.kias_to_ktas(me.kias, alt);
155                 }
156
157                 var distance = dt * (me.ktas - me.headwind) * NM2M / 3600;
158                 var deviation = me.roll ? 0.5 * dt * 1085.941 * math.tan(me.roll * D2R) / me.ktas : 0;
159
160                 if (me.mode == "leg") {
161                         if (me.lastmode != "leg") {
162                                 me.lastmode = "leg";
163                                 # swap ARCP anchor and tanker exit point as leg end points
164                                 var g = me.goal[0];
165                                 me.goal[0] = me.goal[1];
166                                 me.goal[1] = g;
167
168                                 me.course = me.coord.course_to(me.goal[0]);
169                                 me.leg_remaining = me.coord.distance_to(me.goal[0]);
170                                 me.roll_target = 0;
171                                 me.leg_warning = 0;
172                         }
173                         if ((me.leg_remaining -= distance) < 0)
174                                 me.mode = "turn";
175
176                 } else { # me.mode == "turn"
177                         if (me.lastmode != "turn") {
178                                 me.lastmode = "turn";
179                                 me.full_bank_turn_angle = 0;
180                                 me.turn_remaining = 180;
181                                 me.roll_target = 25;
182                         }
183                         if (!me.full_bank_turn_angle and me.roll >= me.roll_target)
184                                 me.full_bank_turn_angle = geo.normdeg(180 - me.turn_remaining);
185
186                         if (me.turn_remaining < me.full_bank_turn_angle)
187                                 me.roll_target = 0;
188
189                         if ((me.turn_remaining -= deviation) < 0) {
190                                 if (me.goal[1] == nil)  # define tanker exit point (opposite of anchor point/ARCP)
191                                         me.goal[1] = geo.Coord.new(me.coord).apply_course_distance(me.track_course - 180,
192                                                         me.length);
193                                 me.mode = "leg";
194                         }
195                 }
196
197                 me.coord.apply_course_distance(me.course -= deviation, distance);
198
199                 me.ac = geo.aircraft_position();
200                 me.distance = me.ac.distance_to(me.coord);
201                 me.bearing = me.ac.course_to(me.coord);
202
203                 var dalt = alt - me.ac.alt();
204                 var ac_hdg = getprop("/orientation/heading-deg");
205
206                 me.latN.setDoubleValue(me.coord.lat());
207                 me.lonN.setDoubleValue(me.coord.lon());
208                 me.altN.setDoubleValue(alt * M2FT);
209                 me.hdgN.setDoubleValue(me.heading = me.course);
210                 me.pitchN.setDoubleValue(0);
211                 me.rollN.setDoubleValue(-me.roll);
212                 me.ktasN.setDoubleValue(me.ktas);
213                 me.vertN.setDoubleValue(0);
214                 me.rangeN.setDoubleValue(me.distance * M2NM);
215                 me.brgN.setDoubleValue(me.bearing);
216                 me.elevN.setDoubleValue(math.atan2(dalt, me.distance) * R2D);
217                 me.contactN.setBoolValue(me.distance < 76 and dalt > 0  # 250 ft
218                                 and abs(view.normdeg(me.bearing - ac_hdg)) < 20);
219
220                 var droll = me.roll_target - me.roll;
221                 if (droll > 0) {
222                         me.roll += me.rollrate * dt;
223                         if (me.roll > me.roll_target)
224                                 me.roll = me.roll_target;
225                 } elsif (droll < 0) {
226                         me.roll -= me.rollrate * dt;
227                         if (me.roll < me.roll_target)
228                                 me.roll = me.roll_target;
229                 }
230
231                 if (!me.leg_warning and me.leg_remaining < NM2M) {
232                         tanker_msg(me.callsign ~ ", turn in one mile");
233                         me.leg_warning = 1;
234                 }
235
236                 me.now = getprop("/sim/time/elapsed-sec");
237                 if (me.distance < 90000)
238                         me.out_of_range_time = me.now;
239                 elsif (me.now - me.out_of_range_time > 600)
240                         return me.del();
241                 settimer(func me.update(), 0);
242         },
243         identify: func {
244                 me.out_of_range_time = me.now;
245                 var alt = int((me.coord.alt() * M2FT + 50) / 100) * 100;
246                 tanker_msg("%s at %.0f, heading %.0f with %.0f knots, TACAN %s",
247                                 me.callsign, alt, me.course, me.kias, me.tacan);
248         },
249         report: func {
250                 me.out_of_range_time = me.now;
251                 var dist = int(me.distance * M2NM);
252                 var hdg = getprop("orientation/heading-deg");
253                 var diff = (me.coord.alt() - me.ac.alt()) * M2FT;
254                 var qual = diff > 3000 ? " well" : abs(diff) > 1000 ? " slightly" : "";
255                 var rel = diff > 1000 ? " above" : diff < -1000 ? " below" : "";
256                 atc_msg("Tanker %s is at %s o'clock%s",
257                                 me.callsign, oclock(me.ac.course_to(me.coord) - hdg),
258                                 qual ~ rel);
259         },
260         active: {},
261 };
262
263
264
265 var request = func {
266         var tanker = values(Tanker.active);
267         if (size(tanker))
268                 return tanker[0].identify();
269
270         var type = props.globals.getNode("systems/refuel", 1).getChildren("type");
271         if (!size(type))
272                 return;
273         type = type[rand() * size(type)].getValue();
274
275         var (aiid, callsign, tacanid) =_= identity.get();
276         var hdg = getprop("orientation/heading-deg");
277         var course = hdg + (rand() - 0.5) * 60;
278         var dist = 6000 + rand() * 4000;
279         var alt = int(10 + rand() * 15) * 1000;  # FL100--FL250
280         alt = skip_cloud_layer(alt * FT2M);
281         var coord = geo.aircraft_position().apply_course_distance(course, dist).set_alt(alt);
282         Tanker.new(aiid, callsign, tacanid, type, 250, hdg, coord);
283 }
284
285
286 var request_random = func {
287         var tanker = values(Tanker.active);
288         if (size(tanker))
289                 return tanker[0].identify();
290
291         var type = props.globals.getNode("systems/refuel", 1).getChildren("type");
292         if (!size(type))
293                 return;
294         type = type[rand() * size(type)].getValue();
295
296         var (aiid, callsign, tacanid) =_= identity.get();
297         var hdg = rand() * 360;
298         var course = rand() * 360;
299         var dist = 6000 + rand() * 4000;
300         var alt = int(10 + rand() * 15) * 1000;  # FL100--FL250
301         alt = skip_cloud_layer(alt * FT2M);
302         var coord = geo.aircraft_position().apply_course_distance(course, dist).set_alt(alt);
303         Tanker.new(aiid, callsign, tacanid, type, 250, hdg, coord);
304 }
305
306
307 var report = func {
308         var tanker = values(Tanker.active);
309         if (size(tanker))
310                 tanker[0].report();
311 }
312
313
314 var reinit = func {
315         foreach (var t; values(Tanker.active))
316                 t.del();
317 }
318
319
320 _setlistener("/sim/signals/nasal-dir-initialized", func {
321         var aar_capable = size(props.globals.getNode("systems/refuel", 1).getChildren("type"));
322         gui.menuEnable("tanker", aar_capable);
323         if (!aar_capable)
324                 request = func { atc_msg("no tanker in range") }; # braces mandatory
325
326         setlistener("/sim/signals/reinit", reinit, 1);
327 });
328