remove README.Protocol and add a README that refers to the "real"
[fg:toms-fgdata.git] / Nasal / io.nas
1 # Reads and returns a complete file as a string
2 var readfile = func(file) {
3     if((var st = stat(file)) == nil) die("Cannot stat file: " ~ file);
4     var sz = st[7];
5     var buf = bits.buf(sz);
6     read(open(file), buf, sz);
7     return buf;
8 }
9
10 # Generates a stat() test routine that is passed the "mode" field
11 # (stat(...)[2]) from a stat() call (index 2), extracts the IFMT
12 # subfield and compares it with the given type, assumes S_IFMT ==
13 # 0xf000.
14 var _gen_ifmt_test = func(ifmt) {
15     func(stat_mode) {
16         var buf = bits.buf(2);
17         bits.setfld(buf, 0, 16, stat_mode);
18         return ifmt == bits.fld(buf, 12, 4);
19     }
20 }
21
22 # Generate file type test predicates isdir(), isreg(), islnk(), etc.
23 # Usage: var s = io.stat(filename); # nil -> doesn't exist, broken link
24 #        if (s != nil and io.isdir(s[2])) { ... }
25 var ifmts = {dir:4, reg:8, lnk:10, sock:12, fifo:1, blk:6, chr:2};
26 foreach(fmt; keys(ifmts))
27     caller(0)[0]["is" ~ fmt] = _gen_ifmt_test(ifmts[fmt]);
28
29 # The following two functions are for reading generic XML files into
30 # the property tree and for writing them from there to the disk. The
31 # built-in fgcommands (load, save, loadxml, savexml) are for FlightGear's
32 # own <PropertyList> XML files only, as they only handle a limited
33 # number of very specific attributes. The io.readxml() loader turns
34 # attributes into regular children with a configurable prefix prepended
35 # to their name, while io.writexml() turns such nodes back into
36 # attributes. The two functions have their own limitations, but can
37 # easily get extended to whichever needs. The underlying parsexml()
38 # command will handle any XML file.
39
40 # Reads an XML file from an absolute path and returns it as property
41 # tree. All nodes will be of type STRING. Data are only written to
42 # leafs. Attributes are written as regular nodes with the optional
43 # prefix prepended to the name. If the prefix is nil, then attributes
44 # are ignored. Returns nil on error.
45 #
46 var readxml = func(file, prefix = "___") {
47     var stack = [[{}, ""]];
48     var node = props.Node.new();
49     var tree = node;           # prevent GC
50     var start = func(name, attr) {
51         var index = stack[-1][0];
52         if(!contains(index, name))
53             index[name] = 0;
54
55         node = node.getChild(name, index[name], 1);
56         if(prefix != nil)
57             foreach(var n; keys(attr))
58                 node.getNode(prefix ~ n, 1).setValue(attr[n]);
59
60         index[name] += 1;
61         append(stack, [{}, ""]);
62     }
63     var end = func(name) {
64         var buf = pop(stack);
65         if(!size(buf[0]) and size(buf[1]))
66             node.setValue(buf[1]);
67         node = node.getParent();
68     }
69     var data = func(d) {
70         stack[-1][1] ~= d;
71     }
72     return parsexml(file, start, end, data) == nil ? nil : tree;
73 }
74
75 # Writes a property tree as returned by readxml() to a file. Children
76 # with name starting with <prefix> are again turned into attributes of
77 # their parent. <node> must contain exactly one child, which will
78 # become the XML file's outermost element.
79 #
80 var writexml = func(file, node, indent = "\t", prefix = "___") {
81     var root = node.getChildren();
82     if(!size(root))
83         die("writexml(): tree doesn't have a root node");
84     if(substr(file, -4) != ".xml")
85         file ~= ".xml";
86     var fh = open(file, "w");
87     var pre = size(prefix);
88     write(fh, "<?xml version=\"1.0\"?>\n\n");
89     var writenode = func(n, ind = "") {
90         var name = n.getName();
91         var name_attr = name;
92         var children = [];
93         foreach(var c; n.getChildren()) {
94             var aname = c.getName();
95             if(substr(aname, 0, pre) == prefix)
96                 name_attr ~= " " ~ substr(aname, pre) ~ '="' ~  c.getValue() ~ '"';
97             else
98                 append(children, c);
99         }
100         if(size(children)) {
101             write(fh, ind ~ "<" ~ name_attr ~ ">\n");
102             foreach(var c; children)
103                 writenode(c, ind ~ indent);
104             write(fh, ind ~ "</" ~ name ~ ">\n");
105         } elsif((var value = n.getValue()) != nil) {
106             write(fh, ind ~ "<" ~ name_attr ~ ">" ~ value ~ "</" ~ name ~ ">\n");
107         } else {
108             write(fh, ind ~ "<" ~ name_attr ~ "/>\n");
109         }
110     }
111     writenode(root[0]);
112     close(fh);
113     if(size(root) != 1)
114         die("writexml(): tree has more than one root node");
115 }
116
117