Add mouse scroll support to session browser widget
[entangle:entangle.git] / m4 / warnings.m4
1 # -*- buffer-read-only: t -*- vi: set ro:
2 # DO NOT EDIT! GENERATED AUTOMATICALLY!
3 # warnings.m4 serial 5
4 dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
5 dnl This file is free software; the Free Software Foundation
6 dnl gives unlimited permission to copy and/or distribute it,
7 dnl with or without modifications, as long as this notice is preserved.
8
9 dnl From Simon Josefsson
10
11 # gl_AS_VAR_APPEND(VAR, VALUE)
12 # ----------------------------
13 # Provide the functionality of AS_VAR_APPEND if Autoconf does not have it.
14 m4_ifdef([AS_VAR_APPEND],
15 [m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])],
16 [m4_define([gl_AS_VAR_APPEND],
17 [AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])])
18
19 # gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS])
20 # ------------------------------------------------
21 # Adds parameter to WARN_CFLAGS if the compiler supports it.  For example,
22 # gl_WARN_ADD([-Wparentheses]).
23 AC_DEFUN([gl_WARN_ADD],
24 dnl FIXME: gl_Warn must be used unquoted until we can assume
25 dnl autoconf 2.64 or newer.
26 [AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl
27 AC_CACHE_CHECK([whether compiler handles $1], m4_defn([gl_Warn]), [
28   gl_save_CPPFLAGS="$CPPFLAGS"
29   CPPFLAGS="${CPPFLAGS} $1"
30   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])],
31                     [AS_VAR_SET(gl_Warn, [yes])],
32                     [AS_VAR_SET(gl_Warn, [no])])
33   CPPFLAGS="$gl_save_CPPFLAGS"
34 ])
35 AS_VAR_IF(gl_Warn, [yes],
36   [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])])
37 AS_VAR_POPDEF([gl_Warn])dnl
38 m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl
39 ])