SDL 1.2.13
[crawl:crawl-sdl.git] / acinclude.m4
1 ##############################################################################
2 dnl Configure Paths for Alsa
3 dnl Some modifications by Richard Boulton <richard-alsa@tartarus.org>
4 dnl Christopher Lansdown <lansdoct@cs.alfred.edu>
5 dnl Jaroslav Kysela <perex@suse.cz>
6 dnl Last modification: alsa.m4,v 1.23 2004/01/16 18:14:22 tiwai Exp
7 dnl AM_PATH_ALSA([MINIMUM-VERSION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
8 dnl Test for libasound, and define ALSA_CFLAGS and ALSA_LIBS as appropriate.
9 dnl enables arguments --with-alsa-prefix=
10 dnl                   --with-alsa-enc-prefix=
11 dnl                   --disable-alsatest
12 dnl
13 dnl For backwards compatibility, if ACTION_IF_NOT_FOUND is not specified,
14 dnl and the alsa libraries are not found, a fatal AC_MSG_ERROR() will result.
15 dnl
16 AC_DEFUN([AM_PATH_ALSA],
17 [dnl Save the original CFLAGS, LDFLAGS, and LIBS
18 alsa_save_CFLAGS="$CFLAGS"
19 alsa_save_LDFLAGS="$LDFLAGS"
20 alsa_save_LIBS="$LIBS"
21 alsa_found=yes
22
23 dnl
24 dnl Get the cflags and libraries for alsa
25 dnl
26 AC_ARG_WITH(alsa-prefix,
27 [  --with-alsa-prefix=PFX  Prefix where Alsa library is installed(optional)],
28 [alsa_prefix="$withval"], [alsa_prefix=""])
29
30 AC_ARG_WITH(alsa-inc-prefix,
31 [  --with-alsa-inc-prefix=PFX  Prefix where include libraries are (optional)],
32 [alsa_inc_prefix="$withval"], [alsa_inc_prefix=""])
33
34 dnl FIXME: this is not yet implemented
35 AC_ARG_ENABLE(alsatest,
36 [  --disable-alsatest      Do not try to compile and run a test Alsa program],
37 [enable_alsatest="$enableval"],
38 [enable_alsatest=yes])
39
40 dnl Add any special include directories
41 AC_MSG_CHECKING(for ALSA CFLAGS)
42 if test "$alsa_inc_prefix" != "" ; then
43         ALSA_CFLAGS="$ALSA_CFLAGS -I$alsa_inc_prefix"
44         CFLAGS="$CFLAGS -I$alsa_inc_prefix"
45 fi
46 AC_MSG_RESULT($ALSA_CFLAGS)
47
48 dnl add any special lib dirs
49 AC_MSG_CHECKING(for ALSA LDFLAGS)
50 if test "$alsa_prefix" != "" ; then
51         ALSA_LIBS="$ALSA_LIBS -L$alsa_prefix"
52         LDFLAGS="$LDFLAGS $ALSA_LIBS"
53 fi
54
55 dnl add the alsa library
56 ALSA_LIBS="$ALSA_LIBS -lasound -lm -ldl -lpthread"
57 LIBS=`echo $LIBS | sed 's/-lm//'`
58 LIBS=`echo $LIBS | sed 's/-ldl//'`
59 LIBS=`echo $LIBS | sed 's/-lpthread//'`
60 LIBS=`echo $LIBS | sed 's/  //'`
61 LIBS="$ALSA_LIBS $LIBS"
62 AC_MSG_RESULT($ALSA_LIBS)
63
64 dnl Check for a working version of libasound that is of the right version.
65 min_alsa_version=ifelse([$1], ,0.1.1,$1)
66 AC_MSG_CHECKING(for libasound headers version >= $min_alsa_version)
67 no_alsa=""
68     alsa_min_major_version=`echo $min_alsa_version | \
69            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
70     alsa_min_minor_version=`echo $min_alsa_version | \
71            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
72     alsa_min_micro_version=`echo $min_alsa_version | \
73            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
74
75 AC_LANG_SAVE
76 AC_LANG_C
77 AC_TRY_COMPILE([
78 #include <alsa/asoundlib.h>
79 ], [
80 /* ensure backward compatibility */
81 #if !defined(SND_LIB_MAJOR) && defined(SOUNDLIB_VERSION_MAJOR)
82 #define SND_LIB_MAJOR SOUNDLIB_VERSION_MAJOR
83 #endif
84 #if !defined(SND_LIB_MINOR) && defined(SOUNDLIB_VERSION_MINOR)
85 #define SND_LIB_MINOR SOUNDLIB_VERSION_MINOR
86 #endif
87 #if !defined(SND_LIB_SUBMINOR) && defined(SOUNDLIB_VERSION_SUBMINOR)
88 #define SND_LIB_SUBMINOR SOUNDLIB_VERSION_SUBMINOR
89 #endif
90
91 #  if(SND_LIB_MAJOR > $alsa_min_major_version)
92   exit(0);
93 #  else
94 #    if(SND_LIB_MAJOR < $alsa_min_major_version)
95 #       error not present
96 #    endif
97
98 #   if(SND_LIB_MINOR > $alsa_min_minor_version)
99   exit(0);
100 #   else
101 #     if(SND_LIB_MINOR < $alsa_min_minor_version)
102 #          error not present
103 #      endif
104
105 #      if(SND_LIB_SUBMINOR < $alsa_min_micro_version)
106 #        error not present
107 #      endif
108 #    endif
109 #  endif
110 exit(0);
111 ],
112   [AC_MSG_RESULT(found.)],
113   [AC_MSG_RESULT(not present.)
114    ifelse([$3], , [AC_MSG_ERROR(Sufficiently new version of libasound not found.)])
115    alsa_found=no]
116 )
117 AC_LANG_RESTORE
118
119 dnl Now that we know that we have the right version, let's see if we have the library and not just the headers.
120 if test "x$enable_alsatest" = "xyes"; then
121 AC_CHECK_LIB([asound], [snd_ctl_open],,
122         [ifelse([$3], , [AC_MSG_ERROR(No linkable libasound was found.)])
123          alsa_found=no]
124 )
125 fi
126
127 if test "x$alsa_found" = "xyes" ; then
128    ifelse([$2], , :, [$2])
129    LIBS=`echo $LIBS | sed 's/-lasound//g'`
130    LIBS=`echo $LIBS | sed 's/  //'`
131    LIBS="-lasound $LIBS"
132 fi
133 if test "x$alsa_found" = "xno" ; then
134    ifelse([$3], , :, [$3])
135    CFLAGS="$alsa_save_CFLAGS"
136    LDFLAGS="$alsa_save_LDFLAGS"
137    LIBS="$alsa_save_LIBS"
138    ALSA_CFLAGS=""
139    ALSA_LIBS=""
140 fi
141
142 dnl That should be it.  Now just export out symbols:
143 AC_SUBST(ALSA_CFLAGS)
144 AC_SUBST(ALSA_LIBS)
145 ])
146
147 ##############################################################################
148 #
149 # --- esd.m4 ---
150 #
151 # Configure paths for ESD
152 # Manish Singh    98-9-30
153 # stolen back from Frank Belew
154 # stolen from Manish Singh
155 # Shamelessly stolen from Owen Taylor
156
157 dnl AM_PATH_ESD([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
158 dnl Test for ESD, and define ESD_CFLAGS and ESD_LIBS
159 dnl
160 AC_DEFUN([AM_PATH_ESD],
161 [dnl 
162 dnl Get the cflags and libraries from the esd-config script
163 dnl
164 AC_ARG_WITH(esd-prefix,[  --with-esd-prefix=PFX   Prefix where ESD is installed (optional)],
165             esd_prefix="$withval", esd_prefix="")
166 AC_ARG_WITH(esd-exec-prefix,[  --with-esd-exec-prefix=PFX Exec prefix where ESD is installed (optional)],
167             esd_exec_prefix="$withval", esd_exec_prefix="")
168 AC_ARG_ENABLE(esdtest, [  --disable-esdtest       Do not try to compile and run a test ESD program],
169                     , enable_esdtest=yes)
170
171   if test x$esd_exec_prefix != x ; then
172      esd_args="$esd_args --exec-prefix=$esd_exec_prefix"
173      if test x${ESD_CONFIG+set} != xset ; then
174         ESD_CONFIG=$esd_exec_prefix/bin/esd-config
175      fi
176   fi
177   if test x$esd_prefix != x ; then
178      esd_args="$esd_args --prefix=$esd_prefix"
179      if test x${ESD_CONFIG+set} != xset ; then
180         ESD_CONFIG=$esd_prefix/bin/esd-config
181      fi
182   fi
183
184   AC_PATH_PROG(ESD_CONFIG, esd-config, no)
185   min_esd_version=ifelse([$1], ,0.2.7,$1)
186   AC_MSG_CHECKING(for ESD - version >= $min_esd_version)
187   no_esd=""
188   if test "$ESD_CONFIG" = "no" ; then
189     no_esd=yes
190   else
191     ESD_CFLAGS=`$ESD_CONFIG $esdconf_args --cflags`
192     ESD_LIBS=`$ESD_CONFIG $esdconf_args --libs`
193
194     esd_major_version=`$ESD_CONFIG $esd_args --version | \
195            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
196     esd_minor_version=`$ESD_CONFIG $esd_args --version | \
197            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
198     esd_micro_version=`$ESD_CONFIG $esd_config_args --version | \
199            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
200     if test "x$enable_esdtest" = "xyes" ; then
201       ac_save_CFLAGS="$CFLAGS"
202       ac_save_LIBS="$LIBS"
203       CFLAGS="$CFLAGS $ESD_CFLAGS"
204       LIBS="$LIBS $ESD_LIBS"
205 dnl
206 dnl Now check if the installed ESD is sufficiently new. (Also sanity
207 dnl checks the results of esd-config to some extent
208 dnl
209       rm -f conf.esdtest
210       AC_TRY_RUN([
211 #include <stdio.h>
212 #include <stdlib.h>
213 #include <string.h>
214 #include <esd.h>
215
216 char*
217 my_strdup (char *str)
218 {
219   char *new_str;
220   
221   if (str)
222     {
223       new_str = malloc ((strlen (str) + 1) * sizeof(char));
224       strcpy (new_str, str);
225     }
226   else
227     new_str = NULL;
228   
229   return new_str;
230 }
231
232 int main ()
233 {
234   int major, minor, micro;
235   char *tmp_version;
236
237   system ("touch conf.esdtest");
238
239   /* HP/UX 9 (%@#!) writes to sscanf strings */
240   tmp_version = my_strdup("$min_esd_version");
241   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
242      printf("%s, bad version string\n", "$min_esd_version");
243      exit(1);
244    }
245
246    if (($esd_major_version > major) ||
247       (($esd_major_version == major) && ($esd_minor_version > minor)) ||
248       (($esd_major_version == major) && ($esd_minor_version == minor) && ($esd_micro_version >= micro)))
249     {
250       return 0;
251     }
252   else
253     {
254       printf("\n*** 'esd-config --version' returned %d.%d.%d, but the minimum version\n", $esd_major_version, $esd_minor_version, $esd_micro_version);
255       printf("*** of ESD required is %d.%d.%d. If esd-config is correct, then it is\n", major, minor, micro);
256       printf("*** best to upgrade to the required version.\n");
257       printf("*** If esd-config was wrong, set the environment variable ESD_CONFIG\n");
258       printf("*** to point to the correct copy of esd-config, and remove the file\n");
259       printf("*** config.cache before re-running configure\n");
260       return 1;
261     }
262 }
263
264 ],, no_esd=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
265        CFLAGS="$ac_save_CFLAGS"
266        LIBS="$ac_save_LIBS"
267      fi
268   fi
269   if test "x$no_esd" = x ; then
270      AC_MSG_RESULT(yes)
271      ifelse([$2], , :, [$2])     
272   else
273      AC_MSG_RESULT(no)
274      if test "$ESD_CONFIG" = "no" ; then
275        echo "*** The esd-config script installed by ESD could not be found"
276        echo "*** If ESD was installed in PREFIX, make sure PREFIX/bin is in"
277        echo "*** your path, or set the ESD_CONFIG environment variable to the"
278        echo "*** full path to esd-config."
279      else
280        if test -f conf.esdtest ; then
281         :
282        else
283           echo "*** Could not run ESD test program, checking why..."
284           CFLAGS="$CFLAGS $ESD_CFLAGS"
285           LIBS="$LIBS $ESD_LIBS"
286           AC_TRY_LINK([
287 #include <stdio.h>
288 #include <esd.h>
289 ],      [ return 0; ],
290         [ echo "*** The test program compiled, but did not run. This usually means"
291           echo "*** that the run-time linker is not finding ESD or finding the wrong"
292           echo "*** version of ESD. If it is not finding ESD, you'll need to set your"
293           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
294           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
295           echo "*** is required on your system"
296           echo "***"
297           echo "*** If you have an old version installed, it is best to remove it, although"
298           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
299         [ echo "*** The test program failed to compile or link. See the file config.log for the"
300           echo "*** exact error that occured. This usually means ESD was incorrectly installed"
301           echo "*** or that you have moved ESD since it was installed. In the latter case, you"
302           echo "*** may want to edit the esd-config script: $ESD_CONFIG" ])
303           CFLAGS="$ac_save_CFLAGS"
304           LIBS="$ac_save_LIBS"
305        fi
306      fi
307      ESD_CFLAGS=""
308      ESD_LIBS=""
309      ifelse([$3], , :, [$3])
310   fi
311   AC_SUBST(ESD_CFLAGS)
312   AC_SUBST(ESD_LIBS)
313   rm -f conf.esdtest
314 ])
315
316 ##############################################################################
317 # Based on libtool-1.5.22
318 # libtool.m4 - Configure libtool for the host system. -*-Autoconf-*-
319 ## Copyright 1996, 1997, 1998, 1999, 2000, 2001, 2003, 2004, 2005
320 ## Free Software Foundation, Inc.
321 ## Originally by Gordon Matzigkeit <gord@gnu.ai.mit.edu>, 1996
322 ##
323 ## This file is free software; the Free Software Foundation gives
324 ## unlimited permission to copy and/or distribute it, with or without
325 ## modifications, as long as this notice is preserved.
326
327 # serial 48 AC_PROG_LIBTOOL
328
329
330 # AC_PROVIDE_IFELSE(MACRO-NAME, IF-PROVIDED, IF-NOT-PROVIDED)
331 # -----------------------------------------------------------
332 # If this macro is not defined by Autoconf, define it here.
333 m4_ifdef([AC_PROVIDE_IFELSE],
334          [],
335          [m4_define([AC_PROVIDE_IFELSE],
336                  [m4_ifdef([AC_PROVIDE_$1],
337                            [$2], [$3])])])
338
339
340 # AC_PROG_LIBTOOL
341 # ---------------
342 AC_DEFUN([AC_PROG_LIBTOOL],
343 [AC_REQUIRE([_AC_PROG_LIBTOOL])dnl
344 dnl If AC_PROG_CXX has already been expanded, run AC_LIBTOOL_CXX
345 dnl immediately, otherwise, hook it in at the end of AC_PROG_CXX.
346   AC_PROVIDE_IFELSE([AC_PROG_CXX],
347     [AC_LIBTOOL_CXX],
348     [define([AC_PROG_CXX], defn([AC_PROG_CXX])[AC_LIBTOOL_CXX
349   ])])
350 dnl And a similar setup for Fortran 77 support
351   AC_PROVIDE_IFELSE([AC_PROG_F77],
352     [AC_LIBTOOL_F77],
353     [define([AC_PROG_F77], defn([AC_PROG_F77])[AC_LIBTOOL_F77
354 ])])
355
356 dnl Quote A][M_PROG_GCJ so that aclocal doesn't bring it in needlessly.
357 dnl If either AC_PROG_GCJ or A][M_PROG_GCJ have already been expanded, run
358 dnl AC_LIBTOOL_GCJ immediately, otherwise, hook it in at the end of both.
359   AC_PROVIDE_IFELSE([AC_PROG_GCJ],
360     [AC_LIBTOOL_GCJ],
361     [AC_PROVIDE_IFELSE([A][M_PROG_GCJ],
362       [AC_LIBTOOL_GCJ],
363       [AC_PROVIDE_IFELSE([LT_AC_PROG_GCJ],
364         [AC_LIBTOOL_GCJ],
365       [ifdef([AC_PROG_GCJ],
366              [define([AC_PROG_GCJ], defn([AC_PROG_GCJ])[AC_LIBTOOL_GCJ])])
367        ifdef([A][M_PROG_GCJ],
368              [define([A][M_PROG_GCJ], defn([A][M_PROG_GCJ])[AC_LIBTOOL_GCJ])])
369        ifdef([LT_AC_PROG_GCJ],
370              [define([LT_AC_PROG_GCJ],
371                 defn([LT_AC_PROG_GCJ])[AC_LIBTOOL_GCJ])])])])
372 ])])# AC_PROG_LIBTOOL
373
374
375 # _AC_PROG_LIBTOOL
376 # ----------------
377 AC_DEFUN([_AC_PROG_LIBTOOL],
378 [AC_REQUIRE([AC_LIBTOOL_SETUP])dnl
379 AC_BEFORE([$0],[AC_LIBTOOL_CXX])dnl
380 AC_BEFORE([$0],[AC_LIBTOOL_F77])dnl
381 AC_BEFORE([$0],[AC_LIBTOOL_GCJ])dnl
382
383 # This can be used to rebuild libtool when needed
384 LIBTOOL_DEPS="$ac_aux_dir/ltmain.sh"
385
386 # Always use our own libtool.
387 LIBTOOL='$(SHELL) $(top_builddir)/libtool'
388 AC_SUBST(LIBTOOL)dnl
389
390 # Prevent multiple expansion
391 define([AC_PROG_LIBTOOL], [])
392 ])# _AC_PROG_LIBTOOL
393
394
395 # AC_LIBTOOL_SETUP
396 # ----------------
397 AC_DEFUN([AC_LIBTOOL_SETUP],
398 [AC_PREREQ(2.50)dnl
399 AC_REQUIRE([AC_ENABLE_SHARED])dnl
400 AC_REQUIRE([AC_ENABLE_STATIC])dnl
401 AC_REQUIRE([AC_ENABLE_FAST_INSTALL])dnl
402 AC_REQUIRE([AC_CANONICAL_HOST])dnl
403 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
404 AC_REQUIRE([AC_PROG_CC])dnl
405 AC_REQUIRE([AC_PROG_LD])dnl
406 AC_REQUIRE([AC_PROG_LD_RELOAD_FLAG])dnl
407 AC_REQUIRE([AC_PROG_NM])dnl
408
409 AC_REQUIRE([AC_PROG_LN_S])dnl
410 AC_REQUIRE([AC_DEPLIBS_CHECK_METHOD])dnl
411 # Autoconf 2.13's AC_OBJEXT and AC_EXEEXT macros only works for C compilers!
412 AC_REQUIRE([AC_OBJEXT])dnl
413 AC_REQUIRE([AC_EXEEXT])dnl
414 dnl
415
416 AC_LIBTOOL_SYS_MAX_CMD_LEN
417 AC_LIBTOOL_SYS_GLOBAL_SYMBOL_PIPE
418 AC_LIBTOOL_OBJDIR
419
420 AC_REQUIRE([_LT_AC_SYS_COMPILER])dnl
421 _LT_AC_PROG_ECHO_BACKSLASH
422
423 case $host_os in
424 aix3*)
425   # AIX sometimes has problems with the GCC collect2 program.  For some
426   # reason, if we set the COLLECT_NAMES environment variable, the problems
427   # vanish in a puff of smoke.
428   if test "X${COLLECT_NAMES+set}" != Xset; then
429     COLLECT_NAMES=
430     export COLLECT_NAMES
431   fi
432   ;;
433 esac
434
435 # Sed substitution that helps us do robust quoting.  It backslashifies
436 # metacharacters that are still active within double-quoted strings.
437 Xsed='sed -e 1s/^X//'
438 [sed_quote_subst='s/\([\\"\\`$\\\\]\)/\\\1/g']
439
440 # Same as above, but do not quote variable references.
441 [double_quote_subst='s/\([\\"\\`\\\\]\)/\\\1/g']
442
443 # Sed substitution to delay expansion of an escaped shell variable in a
444 # double_quote_subst'ed string.
445 delay_variable_subst='s/\\\\\\\\\\\$/\\\\\\$/g'
446
447 # Sed substitution to avoid accidental globbing in evaled expressions
448 no_glob_subst='s/\*/\\\*/g'
449
450 # Constants:
451 rm="rm -f"
452
453 # Global variables:
454 default_ofile=libtool
455 can_build_shared=yes
456
457 # All known linkers require a `.a' archive for static linking (except MSVC,
458 # which needs '.lib').
459 libext=a
460 ltmain="$ac_aux_dir/ltmain.sh"
461 ofile="$default_ofile"
462 with_gnu_ld="$lt_cv_prog_gnu_ld"
463
464 AC_CHECK_TOOL(AR, ar, false)
465 AC_CHECK_TOOL(RANLIB, ranlib, :)
466 AC_CHECK_TOOL(STRIP, strip, :)
467
468 old_CC="$CC"
469 old_CFLAGS="$CFLAGS"
470
471 # Set sane defaults for various variables
472 test -z "$AR" && AR=ar
473 test -z "$AR_FLAGS" && AR_FLAGS=cru
474 test -z "$AS" && AS=as
475 test -z "$CC" && CC=cc
476 test -z "$LTCC" && LTCC=$CC
477 test -z "$LTCFLAGS" && LTCFLAGS=$CFLAGS
478 test -z "$DLLTOOL" && DLLTOOL=dlltool
479 test -z "$LD" && LD=ld
480 test -z "$LN_S" && LN_S="ln -s"
481 test -z "$MAGIC_CMD" && MAGIC_CMD=file
482 test -z "$NM" && NM=nm
483 test -z "$SED" && SED=sed
484 test -z "$OBJDUMP" && OBJDUMP=objdump
485 test -z "$RANLIB" && RANLIB=:
486 test -z "$STRIP" && STRIP=:
487 test -z "$ac_objext" && ac_objext=o
488
489 # Determine commands to create old-style static archives.
490 old_archive_cmds='$AR $AR_FLAGS $oldlib$oldobjs$old_deplibs'
491 old_postinstall_cmds='chmod 644 $oldlib'
492 old_postuninstall_cmds=
493
494 if test -n "$RANLIB"; then
495   case $host_os in
496   openbsd*)
497     old_postinstall_cmds="$old_postinstall_cmds~\$RANLIB -t \$oldlib"
498     ;;
499   *)
500     old_postinstall_cmds="$old_postinstall_cmds~\$RANLIB \$oldlib"
501     ;;
502   esac
503   old_archive_cmds="$old_archive_cmds~\$RANLIB \$oldlib"
504 fi
505
506 _LT_CC_BASENAME([$compiler])
507
508 # Only perform the check for file, if the check method requires it
509 case $deplibs_check_method in
510 file_magic*)
511   if test "$file_magic_cmd" = '$MAGIC_CMD'; then
512     AC_PATH_MAGIC
513   fi
514   ;;
515 esac
516
517 AC_PROVIDE_IFELSE([AC_LIBTOOL_DLOPEN], enable_dlopen=yes, enable_dlopen=no)
518 AC_PROVIDE_IFELSE([AC_LIBTOOL_WIN32_DLL],
519 enable_win32_dll=yes, enable_win32_dll=no)
520
521 AC_ARG_ENABLE([libtool-lock],
522     [AC_HELP_STRING([--disable-libtool-lock],
523         [avoid locking (might break parallel builds)])])
524 test "x$enable_libtool_lock" != xno && enable_libtool_lock=yes
525
526 AC_ARG_WITH([pic],
527     [AC_HELP_STRING([--with-pic],
528         [try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
529     [pic_mode="$withval"],
530     [pic_mode=default])
531 test -z "$pic_mode" && pic_mode=default
532
533 # Use C for the default configuration in the libtool script
534 tagname=
535 AC_LIBTOOL_LANG_C_CONFIG
536 _LT_AC_TAGCONFIG
537 ])# AC_LIBTOOL_SETUP
538
539
540 # _LT_AC_SYS_COMPILER
541 # -------------------
542 AC_DEFUN([_LT_AC_SYS_COMPILER],
543 [AC_REQUIRE([AC_PROG_CC])dnl
544
545 # If no C compiler was specified, use CC.
546 LTCC=${LTCC-"$CC"}
547
548 # If no C compiler flags were specified, use CFLAGS.
549 LTCFLAGS=${LTCFLAGS-"$CFLAGS"}
550
551 # Allow CC to be a program name with arguments.
552 compiler=$CC
553 ])# _LT_AC_SYS_COMPILER
554
555
556 # _LT_CC_BASENAME(CC)
557 # -------------------
558 # Calculate cc_basename.  Skip known compiler wrappers and cross-prefix.
559 AC_DEFUN([_LT_CC_BASENAME],
560 [for cc_temp in $1""; do
561   case $cc_temp in
562     compile | *[[\\/]]compile | ccache | *[[\\/]]ccache ) ;;
563     distcc | *[[\\/]]distcc | purify | *[[\\/]]purify ) ;;
564     \-*) ;;
565     *) break;;
566   esac
567 done
568 cc_basename=`$echo "X$cc_temp" | $Xsed -e 's%.*/%%' -e "s%^$host_alias-%%"`
569 ])
570
571
572 # _LT_COMPILER_BOILERPLATE
573 # ------------------------
574 # Check for compiler boilerplate output or warnings with
575 # the simple compiler test code.
576 AC_DEFUN([_LT_COMPILER_BOILERPLATE],
577 [ac_outfile=conftest.$ac_objext
578 printf "$lt_simple_compile_test_code" >conftest.$ac_ext
579 eval "$ac_compile" 2>&1 >/dev/null | $SED '/^$/d; /^ *+/d' >conftest.err
580 _lt_compiler_boilerplate=`cat conftest.err`
581 $rm conftest*
582 ])# _LT_COMPILER_BOILERPLATE
583
584
585 # _LT_LINKER_BOILERPLATE
586 # ----------------------
587 # Check for linker boilerplate output or warnings with
588 # the simple link test code.
589 AC_DEFUN([_LT_LINKER_BOILERPLATE],
590 [ac_outfile=conftest.$ac_objext
591 printf "$lt_simple_link_test_code" >conftest.$ac_ext
592 eval "$ac_link" 2>&1 >/dev/null | $SED '/^$/d; /^ *+/d' >conftest.err
593 _lt_linker_boilerplate=`cat conftest.err`
594 $rm conftest*
595 ])# _LT_LINKER_BOILERPLATE
596
597
598 # _LT_AC_SYS_LIBPATH_AIX
599 # ----------------------
600 # Links a minimal program and checks the executable
601 # for the system default hardcoded library path. In most cases,
602 # this is /usr/lib:/lib, but when the MPI compilers are used
603 # the location of the communication and MPI libs are included too.
604 # If we don't find anything, use the default library path according
605 # to the aix ld manual.
606 AC_DEFUN([_LT_AC_SYS_LIBPATH_AIX],
607 [AC_LINK_IFELSE(AC_LANG_PROGRAM,[
608 aix_libpath=`dump -H conftest$ac_exeext 2>/dev/null | $SED -n -e '/Import File Strings/,/^$/ { /^0/ { s/^0  *\(.*\)$/\1/; p; }
609 }'`
610 # Check for a 64-bit object if we didn't find anything.
611 if test -z "$aix_libpath"; then aix_libpath=`dump -HX64 conftest$ac_exeext 2>/dev/null | $SED -n -e '/Import File Strings/,/^$/ { /^0/ { s/^0  *\(.*\)$/\1/; p; }
612 }'`; fi],[])
613 if test -z "$aix_libpath"; then aix_libpath="/usr/lib:/lib"; fi
614 ])# _LT_AC_SYS_LIBPATH_AIX
615
616
617 # _LT_AC_SHELL_INIT(ARG)
618 # ----------------------
619 AC_DEFUN([_LT_AC_SHELL_INIT],
620 [ifdef([AC_DIVERSION_NOTICE],
621              [AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)],
622          [AC_DIVERT_PUSH(NOTICE)])
623 $1
624 AC_DIVERT_POP
625 ])# _LT_AC_SHELL_INIT
626
627
628 # _LT_AC_PROG_ECHO_BACKSLASH
629 # --------------------------
630 # Add some code to the start of the generated configure script which
631 # will find an echo command which doesn't interpret backslashes.
632 AC_DEFUN([_LT_AC_PROG_ECHO_BACKSLASH],
633 [_LT_AC_SHELL_INIT([
634 # Check that we are running under the correct shell.
635 SHELL=${CONFIG_SHELL-/bin/sh}
636
637 case X$ECHO in
638 X*--fallback-echo)
639   # Remove one level of quotation (which was required for Make).
640   ECHO=`echo "$ECHO" | sed 's,\\\\\[$]\\[$]0,'[$]0','`
641   ;;
642 esac
643
644 echo=${ECHO-echo}
645 if test "X[$]1" = X--no-reexec; then
646   # Discard the --no-reexec flag, and continue.
647   shift
648 elif test "X[$]1" = X--fallback-echo; then
649   # Avoid inline document here, it may be left over
650   :
651 elif test "X`($echo '\t') 2>/dev/null`" = 'X\t' ; then
652   # Yippee, $echo works!
653   :
654 else
655   # Restart under the correct shell.
656   exec $SHELL "[$]0" --no-reexec ${1+"[$]@"}
657 fi
658
659 if test "X[$]1" = X--fallback-echo; then
660   # used as fallback echo
661   shift
662   cat <<EOF
663 [$]*
664 EOF
665   exit 0
666 fi
667
668 # The HP-UX ksh and POSIX shell print the target directory to stdout
669 # if CDPATH is set.
670 (unset CDPATH) >/dev/null 2>&1 && unset CDPATH
671
672 if test -z "$ECHO"; then
673 if test "X${echo_test_string+set}" != Xset; then
674 # find a string as large as possible, as long as the shell can cope with it
675   for cmd in 'sed 50q "[$]0"' 'sed 20q "[$]0"' 'sed 10q "[$]0"' 'sed 2q "[$]0"' 'echo test'; do
676     # expected sizes: less than 2Kb, 1Kb, 512 bytes, 16 bytes, ...
677     if (echo_test_string=`eval $cmd`) 2>/dev/null &&
678        echo_test_string=`eval $cmd` &&
679        (test "X$echo_test_string" = "X$echo_test_string") 2>/dev/null
680     then
681       break
682     fi
683   done
684 fi
685
686 if test "X`($echo '\t') 2>/dev/null`" = 'X\t' &&
687    echo_testing_string=`($echo "$echo_test_string") 2>/dev/null` &&
688    test "X$echo_testing_string" = "X$echo_test_string"; then
689   :
690 else
691   # The Solaris, AIX, and Digital Unix default echo programs unquote
692   # backslashes.  This makes it impossible to quote backslashes using
693   #   echo "$something" | sed 's/\\/\\\\/g'
694   #
695   # So, first we look for a working echo in the user's PATH.
696
697   lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
698   for dir in $PATH /usr/ucb; do
699     IFS="$lt_save_ifs"
700     if (test -f $dir/echo || test -f $dir/echo$ac_exeext) &&
701        test "X`($dir/echo '\t') 2>/dev/null`" = 'X\t' &&
702        echo_testing_string=`($dir/echo "$echo_test_string") 2>/dev/null` &&
703        test "X$echo_testing_string" = "X$echo_test_string"; then
704       echo="$dir/echo"
705       break
706     fi
707   done
708   IFS="$lt_save_ifs"
709
710   if test "X$echo" = Xecho; then
711     # We didn't find a better echo, so look for alternatives.
712     if test "X`(print -r '\t') 2>/dev/null`" = 'X\t' &&
713        echo_testing_string=`(print -r "$echo_test_string") 2>/dev/null` &&
714        test "X$echo_testing_string" = "X$echo_test_string"; then
715       # This shell has a builtin print -r that does the trick.
716       echo='print -r'
717     elif (test -f /bin/ksh || test -f /bin/ksh$ac_exeext) &&
718          test "X$CONFIG_SHELL" != X/bin/ksh; then
719       # If we have ksh, try running configure again with it.
720       ORIGINAL_CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
721       export ORIGINAL_CONFIG_SHELL
722       CONFIG_SHELL=/bin/ksh
723       export CONFIG_SHELL
724       exec $CONFIG_SHELL "[$]0" --no-reexec ${1+"[$]@"}
725     else
726       # Try using printf.
727       echo='printf %s\n'
728       if test "X`($echo '\t') 2>/dev/null`" = 'X\t' &&
729          echo_testing_string=`($echo "$echo_test_string") 2>/dev/null` &&
730          test "X$echo_testing_string" = "X$echo_test_string"; then
731         # Cool, printf works
732         :
733       elif echo_testing_string=`($ORIGINAL_CONFIG_SHELL "[$]0" --fallback-echo '\t') 2>/dev/null` &&
734            test "X$echo_testing_string" = 'X\t' &&
735            echo_testing_string=`($ORIGINAL_CONFIG_SHELL "[$]0" --fallback-echo "$echo_test_string") 2>/dev/null` &&
736            test "X$echo_testing_string" = "X$echo_test_string"; then
737         CONFIG_SHELL=$ORIGINAL_CONFIG_SHELL
738         export CONFIG_SHELL
739         SHELL="$CONFIG_SHELL"
740         export SHELL
741         echo="$CONFIG_SHELL [$]0 --fallback-echo"
742       elif echo_testing_string=`($CONFIG_SHELL "[$]0" --fallback-echo '\t') 2>/dev/null` &&
743            test "X$echo_testing_string" = 'X\t' &&
744            echo_testing_string=`($CONFIG_SHELL "[$]0" --fallback-echo "$echo_test_string") 2>/dev/null` &&
745            test "X$echo_testing_string" = "X$echo_test_string"; then
746         echo="$CONFIG_SHELL [$]0 --fallback-echo"
747       else
748         # maybe with a smaller string...
749         prev=:
750
751         for cmd in 'echo test' 'sed 2q "[$]0"' 'sed 10q "[$]0"' 'sed 20q "[$]0"' 'sed 50q "[$]0"'; do
752           if (test "X$echo_test_string" = "X`eval $cmd`") 2>/dev/null
753           then
754             break
755           fi
756           prev="$cmd"
757         done
758
759         if test "$prev" != 'sed 50q "[$]0"'; then
760           echo_test_string=`eval $prev`
761           export echo_test_string
762           exec ${ORIGINAL_CONFIG_SHELL-${CONFIG_SHELL-/bin/sh}} "[$]0" ${1+"[$]@"}
763         else
764           # Oops.  We lost completely, so just stick with echo.
765           echo=echo
766         fi
767       fi
768     fi
769   fi
770 fi
771 fi
772
773 # Copy echo and quote the copy suitably for passing to libtool from
774 # the Makefile, instead of quoting the original, which is used later.
775 ECHO=$echo
776 if test "X$ECHO" = "X$CONFIG_SHELL [$]0 --fallback-echo"; then
777    ECHO="$CONFIG_SHELL \\\$\[$]0 --fallback-echo"
778 fi
779
780 AC_SUBST(ECHO)
781 ])])# _LT_AC_PROG_ECHO_BACKSLASH
782
783
784 # _LT_AC_LOCK
785 # -----------
786 AC_DEFUN([_LT_AC_LOCK],
787 [AC_ARG_ENABLE([libtool-lock],
788     [AC_HELP_STRING([--disable-libtool-lock],
789         [avoid locking (might break parallel builds)])])
790 test "x$enable_libtool_lock" != xno && enable_libtool_lock=yes
791
792 # Some flags need to be propagated to the compiler or linker for good
793 # libtool support.
794 case $host in
795 ia64-*-hpux*)
796   # Find out which ABI we are using.
797   echo 'int i;' > conftest.$ac_ext
798   if AC_TRY_EVAL(ac_compile); then
799     case `/usr/bin/file conftest.$ac_objext` in
800     *ELF-32*)
801       HPUX_IA64_MODE="32"
802       ;;
803     *ELF-64*)
804       HPUX_IA64_MODE="64"
805       ;;
806     esac
807   fi
808   rm -rf conftest*
809   ;;
810 *-*-irix6*)
811   # Find out which ABI we are using.
812   echo '[#]line __oline__ "configure"' > conftest.$ac_ext
813   if AC_TRY_EVAL(ac_compile); then
814    if test "$lt_cv_prog_gnu_ld" = yes; then
815     case `/usr/bin/file conftest.$ac_objext` in
816     *32-bit*)
817       LD="${LD-ld} -melf32bsmip"
818       ;;
819     *N32*)
820       LD="${LD-ld} -melf32bmipn32"
821       ;;
822     *64-bit*)
823       LD="${LD-ld} -melf64bmip"
824       ;;
825     esac
826    else
827     case `/usr/bin/file conftest.$ac_objext` in
828     *32-bit*)
829       LD="${LD-ld} -32"
830       ;;
831     *N32*)
832       LD="${LD-ld} -n32"
833       ;;
834     *64-bit*)
835       LD="${LD-ld} -64"
836       ;;
837     esac
838    fi
839   fi
840   rm -rf conftest*
841   ;;
842
843 x86_64-*linux*|ppc*-*linux*|powerpc*-*linux*|s390*-*linux*|sparc*-*linux*)
844   # Find out which ABI we are using.
845   echo 'int i;' > conftest.$ac_ext
846   if AC_TRY_EVAL(ac_compile); then
847     case `/usr/bin/file conftest.o` in
848     *32-bit*)
849       case $host in
850         x86_64-*linux*)
851           LD="${LD-ld} -m elf_i386"
852           ;;
853         ppc64-*linux*|powerpc64-*linux*)
854           LD="${LD-ld} -m elf32ppclinux"
855           ;;
856         s390x-*linux*)
857           LD="${LD-ld} -m elf_s390"
858           ;;
859         sparc64-*linux*)
860           LD="${LD-ld} -m elf32_sparc"
861           ;;
862       esac
863       ;;
864     *64-bit*)
865       case $host in
866         x86_64-*linux*)
867           LD="${LD-ld} -m elf_x86_64"
868           ;;
869         ppc*-*linux*|powerpc*-*linux*)
870           LD="${LD-ld} -m elf64ppc"
871           ;;
872         s390*-*linux*)
873           LD="${LD-ld} -m elf64_s390"
874           ;;
875         sparc*-*linux*)
876           LD="${LD-ld} -m elf64_sparc"
877           ;;
878       esac
879       ;;
880     esac
881   fi
882   rm -rf conftest*
883   ;;
884
885 *-*-sco3.2v5*)
886   # On SCO OpenServer 5, we need -belf to get full-featured binaries.
887   SAVE_CFLAGS="$CFLAGS"
888   CFLAGS="$CFLAGS -belf"
889   AC_CACHE_CHECK([whether the C compiler needs -belf], lt_cv_cc_needs_belf,
890     [AC_LANG_PUSH(C)
891      AC_TRY_LINK([],[],[lt_cv_cc_needs_belf=yes],[lt_cv_cc_needs_belf=no])
892      AC_LANG_POP])
893   if test x"$lt_cv_cc_needs_belf" != x"yes"; then
894     # this is probably gcc 2.8.0, egcs 1.0 or newer; no need for -belf
895     CFLAGS="$SAVE_CFLAGS"
896   fi
897   ;;
898 sparc*-*solaris*)
899   # Find out which ABI we are using.
900   echo 'int i;' > conftest.$ac_ext
901   if AC_TRY_EVAL(ac_compile); then
902     case `/usr/bin/file conftest.o` in
903     *64-bit*)
904       case $lt_cv_prog_gnu_ld in
905       yes*) LD="${LD-ld} -m elf64_sparc" ;;
906       *)    LD="${LD-ld} -64" ;;
907       esac
908       ;;
909     esac
910   fi
911   rm -rf conftest*
912   ;;
913
914 AC_PROVIDE_IFELSE([AC_LIBTOOL_WIN32_DLL],
915 [*-*-cygwin* | *-*-mingw* | *-*-pw32*)
916   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
917   AC_CHECK_TOOL(AS, as, false)
918   AC_CHECK_TOOL(OBJDUMP, objdump, false)
919   ;;
920   ])
921 esac
922
923 need_locks="$enable_libtool_lock"
924
925 ])# _LT_AC_LOCK
926
927
928 # AC_LIBTOOL_COMPILER_OPTION(MESSAGE, VARIABLE-NAME, FLAGS,
929 #               [OUTPUT-FILE], [ACTION-SUCCESS], [ACTION-FAILURE])
930 # ----------------------------------------------------------------
931 # Check whether the given compiler option works
932 AC_DEFUN([AC_LIBTOOL_COMPILER_OPTION],
933 [AC_REQUIRE([LT_AC_PROG_SED])
934 AC_CACHE_CHECK([$1], [$2],
935   [$2=no
936   ifelse([$4], , [ac_outfile=conftest.$ac_objext], [ac_outfile=$4])
937    printf "$lt_simple_compile_test_code" > conftest.$ac_ext
938    lt_compiler_flag="$3"
939    # Insert the option either (1) after the last *FLAGS variable, or
940    # (2) before a word containing "conftest.", or (3) at the end.
941    # Note that $ac_compile itself does not contain backslashes and begins
942    # with a dollar sign (not a hyphen), so the echo should work correctly.
943    # The option is referenced via a variable to avoid confusing sed.
944    lt_compile=`echo "$ac_compile" | $SED \
945    -e 's:.*FLAGS}\{0,1\} :&$lt_compiler_flag :; t' \
946    -e 's: [[^ ]]*conftest\.: $lt_compiler_flag&:; t' \
947    -e 's:$: $lt_compiler_flag:'`
948    (eval echo "\"\$as_me:__oline__: $lt_compile\"" >&AS_MESSAGE_LOG_FD)
949    (eval "$lt_compile" 2>conftest.err)
950    ac_status=$?
951    cat conftest.err >&AS_MESSAGE_LOG_FD
952    echo "$as_me:__oline__: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
953    if (exit $ac_status) && test -s "$ac_outfile"; then
954      # The compiler can only warn and ignore the option if not recognized
955      # So say no if there are warnings other than the usual output.
956      $echo "X$_lt_compiler_boilerplate" | $Xsed -e '/^$/d' >conftest.exp
957      $SED '/^$/d; /^ *+/d' conftest.err >conftest.er2
958      if test ! -s conftest.er2 || diff conftest.exp conftest.er2 >/dev/null; then
959        $2=yes
960      fi
961    fi
962    $rm conftest*
963 ])
964
965 if test x"[$]$2" = xyes; then
966     ifelse([$5], , :, [$5])
967 else
968     ifelse([$6], , :, [$6])
969 fi
970 ])# AC_LIBTOOL_COMPILER_OPTION
971
972
973 # AC_LIBTOOL_LINKER_OPTION(MESSAGE, VARIABLE-NAME, FLAGS,
974 #                          [ACTION-SUCCESS], [ACTION-FAILURE])
975 # ------------------------------------------------------------
976 # Check whether the given compiler option works
977 AC_DEFUN([AC_LIBTOOL_LINKER_OPTION],
978 [AC_CACHE_CHECK([$1], [$2],
979   [$2=no
980    save_LDFLAGS="$LDFLAGS"
981    LDFLAGS="$LDFLAGS $3"
982    printf "$lt_simple_link_test_code" > conftest.$ac_ext
983    if (eval $ac_link 2>conftest.err) && test -s conftest$ac_exeext; then
984      # The linker can only warn and ignore the option if not recognized
985      # So say no if there are warnings
986      if test -s conftest.err; then
987        # Append any errors to the config.log.
988        cat conftest.err 1>&AS_MESSAGE_LOG_FD
989        $echo "X$_lt_linker_boilerplate" | $Xsed -e '/^$/d' > conftest.exp
990        $SED '/^$/d; /^ *+/d' conftest.err >conftest.er2
991        if diff conftest.exp conftest.er2 >/dev/null; then
992          $2=yes
993        fi
994      else
995        $2=yes
996      fi
997    fi
998    $rm conftest*
999    LDFLAGS="$save_LDFLAGS"
1000 ])
1001
1002 if test x"[$]$2" = xyes; then
1003     ifelse([$4], , :, [$4])
1004 else
1005     ifelse([$5], , :, [$5])
1006 fi
1007 ])# AC_LIBTOOL_LINKER_OPTION
1008
1009
1010 # AC_LIBTOOL_SYS_MAX_CMD_LEN
1011 # --------------------------
1012 AC_DEFUN([AC_LIBTOOL_SYS_MAX_CMD_LEN],
1013 [# find the maximum length of command line arguments
1014 AC_MSG_CHECKING([the maximum length of command line arguments])
1015 AC_CACHE_VAL([lt_cv_sys_max_cmd_len], [dnl
1016   i=0
1017   teststring="ABCD"
1018
1019   case $build_os in
1020   msdosdjgpp*)
1021     # On DJGPP, this test can blow up pretty badly due to problems in libc
1022     # (any single argument exceeding 2000 bytes causes a buffer overrun
1023     # during glob expansion).  Even if it were fixed, the result of this
1024     # check would be larger than it should be.
1025     lt_cv_sys_max_cmd_len=12288;    # 12K is about right
1026     ;;
1027
1028   gnu*)
1029     # Under GNU Hurd, this test is not required because there is
1030     # no limit to the length of command line arguments.
1031     # Libtool will interpret -1 as no limit whatsoever
1032     lt_cv_sys_max_cmd_len=-1;
1033     ;;
1034
1035   cygwin* | mingw*)
1036     # On Win9x/ME, this test blows up -- it succeeds, but takes
1037     # about 5 minutes as the teststring grows exponentially.
1038     # Worse, since 9x/ME are not pre-emptively multitasking,
1039     # you end up with a "frozen" computer, even though with patience
1040     # the test eventually succeeds (with a max line length of 256k).
1041     # Instead, let's just punt: use the minimum linelength reported by
1042     # all of the supported platforms: 8192 (on NT/2K/XP).
1043     lt_cv_sys_max_cmd_len=8192;
1044     ;;
1045
1046   beos*)
1047     # On BeOS, this test takes a really really long time.
1048     # So we just punt and use a minimum line length of 8192.
1049     lt_cv_sys_max_cmd_len=8192;
1050     ;;
1051
1052   amigaos*)
1053     # On AmigaOS with pdksh, this test takes hours, literally.
1054     # So we just punt and use a minimum line length of 8192.
1055     lt_cv_sys_max_cmd_len=8192;
1056     ;;
1057
1058   netbsd* | freebsd* | openbsd* | darwin* | dragonfly*)
1059     # This has been around since 386BSD, at least.  Likely further.
1060     if test -x /sbin/sysctl; then
1061       lt_cv_sys_max_cmd_len=`/sbin/sysctl -n kern.argmax`
1062     elif test -x /usr/sbin/sysctl; then
1063       lt_cv_sys_max_cmd_len=`/usr/sbin/sysctl -n kern.argmax`
1064     else
1065       lt_cv_sys_max_cmd_len=65536       # usable default for all BSDs
1066     fi
1067     # And add a safety zone
1068     lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \/ 4`
1069     lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \* 3`
1070     ;;
1071
1072   interix*)
1073     # We know the value 262144 and hardcode it with a safety zone (like BSD)
1074     lt_cv_sys_max_cmd_len=196608
1075     ;;
1076
1077   osf*)
1078     # Dr. Hans Ekkehard Plesser reports seeing a kernel panic running configure
1079     # due to this test when exec_disable_arg_limit is 1 on Tru64. It is not
1080     # nice to cause kernel panics so lets avoid the loop below.
1081     # First set a reasonable default.
1082     lt_cv_sys_max_cmd_len=16384
1083     #
1084     if test -x /sbin/sysconfig; then
1085       case `/sbin/sysconfig -q proc exec_disable_arg_limit` in
1086         *1*) lt_cv_sys_max_cmd_len=-1 ;;
1087       esac
1088     fi
1089     ;;
1090   sco3.2v5*)
1091     lt_cv_sys_max_cmd_len=102400
1092     ;;
1093   sysv5* | sco5v6* | sysv4.2uw2*)
1094     kargmax=`grep ARG_MAX /etc/conf/cf.d/stune 2>/dev/null`
1095     if test -n "$kargmax"; then
1096       lt_cv_sys_max_cmd_len=`echo $kargmax | sed 's/.*[[        ]]//'`
1097     else
1098       lt_cv_sys_max_cmd_len=32768
1099     fi
1100     ;;
1101   *)
1102     # If test is not a shell built-in, we'll probably end up computing a
1103     # maximum length that is only half of the actual maximum length, but
1104     # we can't tell.
1105     SHELL=${SHELL-${CONFIG_SHELL-/bin/sh}}
1106     while (test "X"`$SHELL [$]0 --fallback-echo "X$teststring" 2>/dev/null` \
1107                = "XX$teststring") >/dev/null 2>&1 &&
1108             new_result=`expr "X$teststring" : ".*" 2>&1` &&
1109             lt_cv_sys_max_cmd_len=$new_result &&
1110             test $i != 17 # 1/2 MB should be enough
1111     do
1112       i=`expr $i + 1`
1113       teststring=$teststring$teststring
1114     done
1115     teststring=
1116     # Add a significant safety factor because C++ compilers can tack on massive
1117     # amounts of additional arguments before passing them to the linker.
1118     # It appears as though 1/2 is a usable value.
1119     lt_cv_sys_max_cmd_len=`expr $lt_cv_sys_max_cmd_len \/ 2`
1120     ;;
1121   esac
1122 ])
1123 if test -n $lt_cv_sys_max_cmd_len ; then
1124   AC_MSG_RESULT($lt_cv_sys_max_cmd_len)
1125 else
1126   AC_MSG_RESULT(none)
1127 fi
1128 ])# AC_LIBTOOL_SYS_MAX_CMD_LEN
1129
1130
1131 # _LT_AC_CHECK_DLFCN
1132 # ------------------
1133 AC_DEFUN([_LT_AC_CHECK_DLFCN],
1134 [AC_CHECK_HEADERS(dlfcn.h)dnl
1135 ])# _LT_AC_CHECK_DLFCN
1136
1137
1138 # _LT_AC_TRY_DLOPEN_SELF (ACTION-IF-TRUE, ACTION-IF-TRUE-W-USCORE,
1139 #                           ACTION-IF-FALSE, ACTION-IF-CROSS-COMPILING)
1140 # ---------------------------------------------------------------------
1141 AC_DEFUN([_LT_AC_TRY_DLOPEN_SELF],
1142 [AC_REQUIRE([_LT_AC_CHECK_DLFCN])dnl
1143 if test "$cross_compiling" = yes; then :
1144   [$4]
1145 else
1146   lt_dlunknown=0; lt_dlno_uscore=1; lt_dlneed_uscore=2
1147   lt_status=$lt_dlunknown
1148   cat > conftest.$ac_ext <<EOF
1149 [#line __oline__ "configure"
1150 #include "confdefs.h"
1151
1152 #if HAVE_DLFCN_H
1153 #include <dlfcn.h>
1154 #endif
1155
1156 #include <stdio.h>
1157
1158 #ifdef RTLD_GLOBAL
1159 #  define LT_DLGLOBAL           RTLD_GLOBAL
1160 #else
1161 #  ifdef DL_GLOBAL
1162 #    define LT_DLGLOBAL         DL_GLOBAL
1163 #  else
1164 #    define LT_DLGLOBAL         0
1165 #  endif
1166 #endif
1167
1168 /* We may have to define LT_DLLAZY_OR_NOW in the command line if we
1169    find out it does not work in some platform. */
1170 #ifndef LT_DLLAZY_OR_NOW
1171 #  ifdef RTLD_LAZY
1172 #    define LT_DLLAZY_OR_NOW            RTLD_LAZY
1173 #  else
1174 #    ifdef DL_LAZY
1175 #      define LT_DLLAZY_OR_NOW          DL_LAZY
1176 #    else
1177 #      ifdef RTLD_NOW
1178 #        define LT_DLLAZY_OR_NOW        RTLD_NOW
1179 #      else
1180 #        ifdef DL_NOW
1181 #          define LT_DLLAZY_OR_NOW      DL_NOW
1182 #        else
1183 #          define LT_DLLAZY_OR_NOW      0
1184 #        endif
1185 #      endif
1186 #    endif
1187 #  endif
1188 #endif
1189
1190 #ifdef __cplusplus
1191 extern "C" void exit (int);
1192 #endif
1193
1194 void fnord() { int i=42;}
1195 int main ()
1196 {
1197   void *self = dlopen (0, LT_DLGLOBAL|LT_DLLAZY_OR_NOW);
1198   int status = $lt_dlunknown;
1199
1200   if (self)
1201     {
1202       if (dlsym (self,"fnord"))       status = $lt_dlno_uscore;
1203       else if (dlsym( self,"_fnord")) status = $lt_dlneed_uscore;
1204       /* dlclose (self); */
1205     }
1206   else
1207     puts (dlerror ());
1208
1209     exit (status);
1210 }]
1211 EOF
1212   if AC_TRY_EVAL(ac_link) && test -s conftest${ac_exeext} 2>/dev/null; then
1213     (./conftest; exit; ) >&AS_MESSAGE_LOG_FD 2>/dev/null
1214     lt_status=$?
1215     case x$lt_status in
1216       x$lt_dlno_uscore) $1 ;;
1217       x$lt_dlneed_uscore) $2 ;;
1218       x$lt_dlunknown|x*) $3 ;;
1219     esac
1220   else :
1221     # compilation failed
1222     $3
1223   fi
1224 fi
1225 rm -fr conftest*
1226 ])# _LT_AC_TRY_DLOPEN_SELF
1227
1228
1229 # AC_LIBTOOL_DLOPEN_SELF
1230 # ----------------------
1231 AC_DEFUN([AC_LIBTOOL_DLOPEN_SELF],
1232 [AC_REQUIRE([_LT_AC_CHECK_DLFCN])dnl
1233 if test "x$enable_dlopen" != xyes; then
1234   enable_dlopen=unknown
1235   enable_dlopen_self=unknown
1236   enable_dlopen_self_static=unknown
1237 else
1238   lt_cv_dlopen=no
1239   lt_cv_dlopen_libs=
1240
1241   case $host_os in
1242   beos*)
1243     lt_cv_dlopen="load_add_on"
1244     lt_cv_dlopen_libs=
1245     lt_cv_dlopen_self=yes
1246     ;;
1247
1248   mingw* | pw32*)
1249     lt_cv_dlopen="LoadLibrary"
1250     lt_cv_dlopen_libs=
1251    ;;
1252
1253   cygwin*)
1254     lt_cv_dlopen="dlopen"
1255     lt_cv_dlopen_libs=
1256    ;;
1257
1258   darwin*)
1259   # if libdl is installed we need to link against it
1260     AC_CHECK_LIB([dl], [dlopen],
1261                 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],[
1262     lt_cv_dlopen="dyld"
1263     lt_cv_dlopen_libs=
1264     lt_cv_dlopen_self=yes
1265     ])
1266    ;;
1267
1268   *)
1269     AC_CHECK_FUNC([shl_load],
1270           [lt_cv_dlopen="shl_load"],
1271       [AC_CHECK_LIB([dld], [shl_load],
1272             [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"],
1273         [AC_CHECK_FUNC([dlopen],
1274               [lt_cv_dlopen="dlopen"],
1275           [AC_CHECK_LIB([dl], [dlopen],
1276                 [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],
1277             [AC_CHECK_LIB([svld], [dlopen],
1278                   [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],
1279               [AC_CHECK_LIB([dld], [dld_link],
1280                     [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])
1281               ])
1282             ])
1283           ])
1284         ])
1285       ])
1286     ;;
1287   esac
1288
1289   if test "x$lt_cv_dlopen" != xno; then
1290     enable_dlopen=yes
1291   else
1292     enable_dlopen=no
1293   fi
1294
1295   case $lt_cv_dlopen in
1296   dlopen)
1297     save_CPPFLAGS="$CPPFLAGS"
1298     test "x$ac_cv_header_dlfcn_h" = xyes && CPPFLAGS="$CPPFLAGS -DHAVE_DLFCN_H"
1299
1300     save_LDFLAGS="$LDFLAGS"
1301     wl=$lt_prog_compiler_wl eval LDFLAGS=\"\$LDFLAGS $export_dynamic_flag_spec\"
1302
1303     save_LIBS="$LIBS"
1304     LIBS="$lt_cv_dlopen_libs $LIBS"
1305
1306     AC_CACHE_CHECK([whether a program can dlopen itself],
1307           lt_cv_dlopen_self, [dnl
1308           _LT_AC_TRY_DLOPEN_SELF(
1309             lt_cv_dlopen_self=yes, lt_cv_dlopen_self=yes,
1310             lt_cv_dlopen_self=no, lt_cv_dlopen_self=cross)
1311     ])
1312
1313     if test "x$lt_cv_dlopen_self" = xyes; then
1314       wl=$lt_prog_compiler_wl eval LDFLAGS=\"\$LDFLAGS $lt_prog_compiler_static\"
1315       AC_CACHE_CHECK([whether a statically linked program can dlopen itself],
1316           lt_cv_dlopen_self_static, [dnl
1317           _LT_AC_TRY_DLOPEN_SELF(
1318             lt_cv_dlopen_self_static=yes, lt_cv_dlopen_self_static=yes,
1319             lt_cv_dlopen_self_static=no,  lt_cv_dlopen_self_static=cross)
1320       ])
1321     fi
1322
1323     CPPFLAGS="$save_CPPFLAGS"
1324     LDFLAGS="$save_LDFLAGS"
1325     LIBS="$save_LIBS"
1326     ;;
1327   esac
1328
1329   case $lt_cv_dlopen_self in
1330   yes|no) enable_dlopen_self=$lt_cv_dlopen_self ;;
1331   *) enable_dlopen_self=unknown ;;
1332   esac
1333
1334   case $lt_cv_dlopen_self_static in
1335   yes|no) enable_dlopen_self_static=$lt_cv_dlopen_self_static ;;
1336   *) enable_dlopen_self_static=unknown ;;
1337   esac
1338 fi
1339 ])# AC_LIBTOOL_DLOPEN_SELF
1340
1341
1342 # AC_LIBTOOL_PROG_CC_C_O([TAGNAME])
1343 # ---------------------------------
1344 # Check to see if options -c and -o are simultaneously supported by compiler
1345 AC_DEFUN([AC_LIBTOOL_PROG_CC_C_O],
1346 [AC_REQUIRE([_LT_AC_SYS_COMPILER])dnl
1347 AC_CACHE_CHECK([if $compiler supports -c -o file.$ac_objext],
1348   [_LT_AC_TAGVAR(lt_cv_prog_compiler_c_o, $1)],
1349   [_LT_AC_TAGVAR(lt_cv_prog_compiler_c_o, $1)=no
1350    $rm -r conftest 2>/dev/null
1351    mkdir conftest
1352    cd conftest
1353    mkdir out
1354    printf "$lt_simple_compile_test_code" > conftest.$ac_ext
1355
1356    lt_compiler_flag="-o out/conftest2.$ac_objext"
1357    # Insert the option either (1) after the last *FLAGS variable, or
1358    # (2) before a word containing "conftest.", or (3) at the end.
1359    # Note that $ac_compile itself does not contain backslashes and begins
1360    # with a dollar sign (not a hyphen), so the echo should work correctly.
1361    lt_compile=`echo "$ac_compile" | $SED \
1362    -e 's:.*FLAGS}\{0,1\} :&$lt_compiler_flag :; t' \
1363    -e 's: [[^ ]]*conftest\.: $lt_compiler_flag&:; t' \
1364    -e 's:$: $lt_compiler_flag:'`
1365    (eval echo "\"\$as_me:__oline__: $lt_compile\"" >&AS_MESSAGE_LOG_FD)
1366    (eval "$lt_compile" 2>out/conftest.err)
1367    ac_status=$?
1368    cat out/conftest.err >&AS_MESSAGE_LOG_FD
1369    echo "$as_me:__oline__: \$? = $ac_status" >&AS_MESSAGE_LOG_FD
1370    if (exit $ac_status) && test -s out/conftest2.$ac_objext
1371    then
1372      # The compiler can only warn and ignore the option if not recognized
1373      # So say no if there are warnings
1374      $echo "X$_lt_compiler_boilerplate" | $Xsed -e '/^$/d' > out/conftest.exp
1375      $SED '/^$/d; /^ *+/d' out/conftest.err >out/conftest.er2
1376      if test ! -s out/conftest.er2 || diff out/conftest.exp out/conftest.er2 >/dev/null; then
1377        _LT_AC_TAGVAR(lt_cv_prog_compiler_c_o, $1)=yes
1378      fi
1379    fi
1380    chmod u+w . 2>&AS_MESSAGE_LOG_FD
1381    $rm conftest*
1382    # SGI C++ compiler will create directory out/ii_files/ for
1383    # template instantiation
1384    test -d out/ii_files && $rm out/ii_files/* && rmdir out/ii_files
1385    $rm out/* && rmdir out
1386    cd ..
1387    rmdir conftest
1388    $rm conftest*
1389 ])
1390 ])# AC_LIBTOOL_PROG_CC_C_O
1391
1392
1393 # AC_LIBTOOL_SYS_HARD_LINK_LOCKS([TAGNAME])
1394 # -----------------------------------------
1395 # Check to see if we can do hard links to lock some files if needed
1396 AC_DEFUN([AC_LIBTOOL_SYS_HARD_LINK_LOCKS],
1397 [AC_REQUIRE([_LT_AC_LOCK])dnl
1398
1399 hard_links="nottested"
1400 if test "$_LT_AC_TAGVAR(lt_cv_prog_compiler_c_o, $1)" = no && test "$need_locks" != no; then
1401   # do not overwrite the value of need_locks provided by the user
1402   AC_MSG_CHECKING([if we can lock with hard links])
1403   hard_links=yes
1404   $rm conftest*
1405   ln conftest.a conftest.b 2>/dev/null && hard_links=no
1406   touch conftest.a
1407   ln conftest.a conftest.b 2>&5 || hard_links=no
1408   ln conftest.a conftest.b 2>/dev/null && hard_links=no
1409   AC_MSG_RESULT([$hard_links])
1410   if test "$hard_links" = no; then
1411     AC_MSG_WARN([`$CC' does not support `-c -o', so `make -j' may be unsafe])
1412     need_locks=warn
1413   fi
1414 else
1415   need_locks=no
1416 fi
1417 ])# AC_LIBTOOL_SYS_HARD_LINK_LOCKS
1418
1419
1420 # AC_LIBTOOL_OBJDIR
1421 # -----------------
1422 AC_DEFUN([AC_LIBTOOL_OBJDIR],
1423 [AC_CACHE_CHECK([for objdir], [lt_cv_objdir],
1424 [rm -f .libs 2>/dev/null
1425 mkdir .libs 2>/dev/null
1426 if test -d .libs; then
1427   lt_cv_objdir=.libs
1428 else
1429   # MS-DOS does not allow filenames that begin with a dot.
1430   lt_cv_objdir=_libs
1431 fi
1432 rmdir .libs 2>/dev/null])
1433 objdir=$lt_cv_objdir
1434 ])# AC_LIBTOOL_OBJDIR
1435
1436
1437 # AC_LIBTOOL_PROG_LD_HARDCODE_LIBPATH([TAGNAME])
1438 # ----------------------------------------------
1439 # Check hardcoding attributes.
1440 AC_DEFUN([AC_LIBTOOL_PROG_LD_HARDCODE_LIBPATH],
1441 [AC_MSG_CHECKING([how to hardcode library paths into programs])
1442 _LT_AC_TAGVAR(hardcode_action, $1)=
1443 if test -n "$_LT_AC_TAGVAR(hardcode_libdir_flag_spec, $1)" || \
1444    test -n "$_LT_AC_TAGVAR(runpath_var, $1)" || \
1445    test "X$_LT_AC_TAGVAR(hardcode_automatic, $1)" = "Xyes" ; then
1446
1447   # We can hardcode non-existant directories.
1448   if test "$_LT_AC_TAGVAR(hardcode_direct, $1)" != no &&
1449      # If the only mechanism to avoid hardcoding is shlibpath_var, we
1450      # have to relink, otherwise we might link with an installed library
1451      # when we should be linking with a yet-to-be-installed one
1452      ## test "$_LT_AC_TAGVAR(hardcode_shlibpath_var, $1)" != no &&
1453      test "$_LT_AC_TAGVAR(hardcode_minus_L, $1)" != no; then
1454     # Linking always hardcodes the temporary library directory.
1455     _LT_AC_TAGVAR(hardcode_action, $1)=relink
1456   else
1457     # We can link without hardcoding, and we can hardcode nonexisting dirs.
1458     _LT_AC_TAGVAR(hardcode_action, $1)=immediate
1459   fi
1460 else
1461   # We cannot hardcode anything, or else we can only hardcode existing
1462   # directories.
1463   _LT_AC_TAGVAR(hardcode_action, $1)=unsupported
1464 fi
1465 AC_MSG_RESULT([$_LT_AC_TAGVAR(hardcode_action, $1)])
1466
1467 if test "$_LT_AC_TAGVAR(hardcode_action, $1)" = relink; then
1468   # Fast installation is not supported
1469   enable_fast_install=no
1470 elif test "$shlibpath_overrides_runpath" = yes ||
1471      test "$enable_shared" = no; then
1472   # Fast installation is not necessary
1473   enable_fast_install=needless
1474 fi
1475 ])# AC_LIBTOOL_PROG_LD_HARDCODE_LIBPATH
1476
1477
1478 # AC_LIBTOOL_SYS_LIB_STRIP
1479 # ------------------------
1480 AC_DEFUN([AC_LIBTOOL_SYS_LIB_STRIP],
1481 [striplib=
1482 old_striplib=
1483 AC_MSG_CHECKING([whether stripping libraries is possible])
1484 if test -n "$STRIP" && $STRIP -V 2>&1 | grep "GNU strip" >/dev/null; then
1485   test -z "$old_striplib" && old_striplib="$STRIP --strip-debug"
1486   test -z "$striplib" && striplib="$STRIP --strip-unneeded"
1487   AC_MSG_RESULT([yes])
1488 else
1489 # FIXME - insert some real tests, host_os isn't really good enough
1490   case $host_os in
1491    darwin*)
1492        if test -n "$STRIP" ; then
1493          striplib="$STRIP -x"
1494          AC_MSG_RESULT([yes])
1495        else
1496   AC_MSG_RESULT([no])
1497 fi
1498        ;;
1499    *)
1500   AC_MSG_RESULT([no])
1501     ;;
1502   esac
1503 fi
1504 ])# AC_LIBTOOL_SYS_LIB_STRIP
1505
1506
1507 # AC_LIBTOOL_SYS_DYNAMIC_LINKER
1508 # -----------------------------
1509 # PORTME Fill in your ld.so characteristics
1510 AC_DEFUN([AC_LIBTOOL_SYS_DYNAMIC_LINKER],
1511 [AC_MSG_CHECKING([dynamic linker characteristics])
1512 library_names_spec=
1513 libname_spec='lib$name'
1514 soname_spec=
1515 shrext_cmds=".so"
1516 postinstall_cmds=
1517 postuninstall_cmds=
1518 finish_cmds=
1519 finish_eval=
1520 shlibpath_var=
1521 shlibpath_overrides_runpath=unknown
1522 version_type=none
1523 dynamic_linker="$host_os ld.so"
1524 sys_lib_dlsearch_path_spec="/lib /usr/lib"
1525 if test "$GCC" = yes; then
1526   sys_lib_search_path_spec=`$CC -print-search-dirs | grep "^libraries:" | $SED -e "s/^libraries://" -e "s,=/,/,g"`
1527   if echo "$sys_lib_search_path_spec" | grep ';' >/dev/null ; then
1528     # if the path contains ";" then we assume it to be the separator
1529     # otherwise default to the standard path separator (i.e. ":") - it is
1530     # assumed that no part of a normal pathname contains ";" but that should
1531     # okay in the real world where ";" in dirpaths is itself problematic.
1532     sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | $SED -e 's/;/ /g'`
1533   else
1534     sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | $SED  -e "s/$PATH_SEPARATOR/ /g"`
1535   fi
1536 else
1537   sys_lib_search_path_spec="/lib /usr/lib /usr/local/lib"
1538 fi
1539 need_lib_prefix=unknown
1540 hardcode_into_libs=no
1541
1542 # when you set need_version to no, make sure it does not cause -set_version
1543 # flags to be left without arguments
1544 need_version=unknown
1545
1546 case $host_os in
1547 aix3*)
1548   version_type=linux
1549   library_names_spec='${libname}${release}${shared_ext}$versuffix $libname.a'
1550   shlibpath_var=LIBPATH
1551
1552   # AIX 3 has no versioning support, so we append a major version to the name.
1553   soname_spec='${libname}${release}${shared_ext}$major'
1554   ;;
1555
1556 aix4* | aix5*)
1557   version_type=linux
1558   need_lib_prefix=no
1559   need_version=no
1560   hardcode_into_libs=yes
1561   if test "$host_cpu" = ia64; then
1562     # AIX 5 supports IA64
1563     library_names_spec='${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext}$versuffix $libname${shared_ext}'
1564     shlibpath_var=LD_LIBRARY_PATH
1565   else
1566     # With GCC up to 2.95.x, collect2 would create an import file
1567     # for dependence libraries.  The import file would start with
1568     # the line `#! .'.  This would cause the generated library to
1569     # depend on `.', always an invalid library.  This was fixed in
1570     # development snapshots of GCC prior to 3.0.
1571     case $host_os in
1572       aix4 | aix4.[[01]] | aix4.[[01]].*)
1573       if { echo '#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 97)'
1574            echo ' yes '
1575            echo '#endif'; } | ${CC} -E - | grep yes > /dev/null; then
1576         :
1577       else
1578         can_build_shared=no
1579       fi
1580       ;;
1581     esac
1582     # AIX (on Power*) has no versioning support, so currently we can not hardcode correct
1583     # soname into executable. Probably we can add versioning support to
1584     # collect2, so additional links can be useful in future.
1585     if test "$aix_use_runtimelinking" = yes; then
1586       # If using run time linking (on AIX 4.2 or later) use lib<name>.so
1587       # instead of lib<name>.a to let people know that these are not
1588       # typical AIX shared libraries.
1589       library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1590     else
1591       # We preserve .a as extension for shared libraries through AIX4.2
1592       # and later when we are not doing run time linking.
1593       library_names_spec='${libname}${release}.a $libname.a'
1594       soname_spec='${libname}${release}${shared_ext}$major'
1595     fi
1596     shlibpath_var=LIBPATH
1597   fi
1598   ;;
1599
1600 amigaos*)
1601   library_names_spec='$libname.ixlibrary $libname.a'
1602   # Create ${libname}_ixlibrary.a entries in /sys/libs.
1603   finish_eval='for lib in `ls $libdir/*.ixlibrary 2>/dev/null`; do libname=`$echo "X$lib" | $Xsed -e '\''s%^.*/\([[^/]]*\)\.ixlibrary$%\1%'\''`; test $rm /sys/libs/${libname}_ixlibrary.a; $show "cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a"; cd /sys/libs && $LN_S $lib ${libname}_ixlibrary.a || exit 1; done'
1604   ;;
1605
1606 beos*)
1607   library_names_spec='${libname}${shared_ext}'
1608   dynamic_linker="$host_os ld.so"
1609   shlibpath_var=LIBRARY_PATH
1610   ;;
1611
1612 bsdi[[45]]*)
1613   version_type=linux
1614   need_version=no
1615   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1616   soname_spec='${libname}${release}${shared_ext}$major'
1617   finish_cmds='PATH="\$PATH:/sbin" ldconfig $libdir'
1618   shlibpath_var=LD_LIBRARY_PATH
1619   sys_lib_search_path_spec="/shlib /usr/lib /usr/X11/lib /usr/contrib/lib /lib /usr/local/lib"
1620   sys_lib_dlsearch_path_spec="/shlib /usr/lib /usr/local/lib"
1621   # the default ld.so.conf also contains /usr/contrib/lib and
1622   # /usr/X11R6/lib (/usr/X11 is a link to /usr/X11R6), but let us allow
1623   # libtool to hard-code these into programs
1624   ;;
1625
1626 cygwin* | mingw* | pw32*)
1627   version_type=windows
1628   shrext_cmds=".dll"
1629   need_version=no
1630   need_lib_prefix=no
1631
1632   case $GCC,$host_os in
1633   yes,cygwin* | yes,mingw* | yes,pw32*)
1634     library_names_spec='$libname.dll.a'
1635     # DLL is installed to $(libdir)/../bin by postinstall_cmds
1636     postinstall_cmds='base_file=`basename \${file}`~
1637       dlpath=`$SHELL 2>&1 -c '\''. $dir/'\''\${base_file}'\''i;echo \$dlname'\''`~
1638       dldir=$destdir/`dirname \$dlpath`~
1639       test -d \$dldir || mkdir -p \$dldir~
1640       $install_prog $dir/$dlname \$dldir/$dlname~
1641       chmod a+x \$dldir/$dlname'
1642     postuninstall_cmds='dldll=`$SHELL 2>&1 -c '\''. $file; echo \$dlname'\''`~
1643       dlpath=$dir/\$dldll~
1644        $rm \$dlpath'
1645     shlibpath_overrides_runpath=yes
1646
1647     case $host_os in
1648     cygwin*)
1649       # Cygwin DLLs use 'cyg' prefix rather than 'lib'
1650       #soname_spec='`echo ${libname} | sed -e 's/^lib/cyg/'``echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
1651       soname_spec='`echo ${libname} | sed -e 's/^lib//'`${shared_ext}'
1652       sys_lib_search_path_spec="/usr/lib /lib/w32api /lib /usr/local/lib"
1653       ;;
1654     mingw*)
1655       # MinGW DLLs use traditional 'lib' prefix
1656       #soname_spec='${libname}`echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
1657       soname_spec='`echo ${libname} | sed -e 's/^lib//'`${shared_ext}'
1658       sys_lib_search_path_spec=`$CC -print-search-dirs | grep "^libraries:" | $SED -e "s/^libraries://" -e "s,=/,/,g"`
1659       if echo "$sys_lib_search_path_spec" | [grep ';[c-zC-Z]:/' >/dev/null]; then
1660         # It is most probably a Windows format PATH printed by
1661         # mingw gcc, but we are running on Cygwin. Gcc prints its search
1662         # path with ; separators, and with drive letters. We can handle the
1663         # drive letters (cygwin fileutils understands them), so leave them,
1664         # especially as we might pass files found there to a mingw objdump,
1665         # which wouldn't understand a cygwinified path. Ahh.
1666         sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | $SED -e 's/;/ /g'`
1667       else
1668         sys_lib_search_path_spec=`echo "$sys_lib_search_path_spec" | $SED  -e "s/$PATH_SEPARATOR/ /g"`
1669       fi
1670       ;;
1671     pw32*)
1672       # pw32 DLLs use 'pw' prefix rather than 'lib'
1673       library_names_spec='`echo ${libname} | sed -e 's/^lib/pw/'``echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext}'
1674       ;;
1675     esac
1676     ;;
1677
1678   *)
1679     library_names_spec='${libname}`echo ${release} | $SED -e 's/[[.]]/-/g'`${versuffix}${shared_ext} $libname.lib'
1680     ;;
1681   esac
1682   dynamic_linker='Win32 ld.exe'
1683   # FIXME: first we should search . and the directory the executable is in
1684   shlibpath_var=PATH
1685   ;;
1686
1687 darwin* | rhapsody*)
1688   dynamic_linker="$host_os dyld"
1689   version_type=darwin
1690   need_lib_prefix=no
1691   need_version=no
1692   library_names_spec='${libname}${release}${versuffix}$shared_ext ${libname}${release}${major}$shared_ext ${libname}$shared_ext'
1693   soname_spec='${libname}${release}${major}$shared_ext'
1694   shlibpath_overrides_runpath=yes
1695   shlibpath_var=DYLD_LIBRARY_PATH
1696   shrext_cmds='`test .$module = .yes && echo .so || echo .dylib`'
1697   # Apple's gcc prints 'gcc -print-search-dirs' doesn't operate the same.
1698   if test "$GCC" = yes; then
1699     sys_lib_search_path_spec=`$CC -print-search-dirs | tr "\n" "$PATH_SEPARATOR" | sed -e 's/libraries:/@libraries:/' | tr "@" "\n" | grep "^libraries:" | sed -e "s/^libraries://" -e "s,=/,/,g" -e "s,$PATH_SEPARATOR, ,g" -e "s,.*,& /lib /usr/lib /usr/local/lib,g"`
1700   else
1701     sys_lib_search_path_spec='/lib /usr/lib /usr/local/lib'
1702   fi
1703   sys_lib_dlsearch_path_spec='/usr/local/lib /lib /usr/lib'
1704   ;;
1705
1706 dgux*)
1707   version_type=linux
1708   need_lib_prefix=no
1709   need_version=no
1710   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname$shared_ext'
1711   soname_spec='${libname}${release}${shared_ext}$major'
1712   shlibpath_var=LD_LIBRARY_PATH
1713   ;;
1714
1715 freebsd1*)
1716   dynamic_linker=no
1717   ;;
1718
1719 kfreebsd*-gnu)
1720   version_type=linux
1721   need_lib_prefix=no
1722   need_version=no
1723   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
1724   soname_spec='${libname}${release}${shared_ext}$major'
1725   shlibpath_var=LD_LIBRARY_PATH
1726   shlibpath_overrides_runpath=no
1727   hardcode_into_libs=yes
1728   dynamic_linker='GNU ld.so'
1729   ;;
1730
1731 freebsd* | dragonfly*)
1732   # DragonFly does not have aout.  When/if they implement a new
1733   # versioning mechanism, adjust this.
1734   if test -x /usr/bin/objformat; then
1735     objformat=`/usr/bin/objformat`
1736   else
1737     case $host_os in
1738     freebsd[[123]]*) objformat=aout ;;
1739     *) objformat=elf ;;
1740     esac
1741   fi
1742   version_type=freebsd-$objformat
1743   case $version_type in
1744     freebsd-elf*)
1745       library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext} $libname${shared_ext}'
1746       need_version=no
1747       need_lib_prefix=no
1748       ;;
1749     freebsd-*)
1750       library_names_spec='${libname}${release}${shared_ext}$versuffix $libname${shared_ext}$versuffix'
1751       need_version=yes
1752       ;;
1753   esac
1754   shlibpath_var=LD_LIBRARY_PATH
1755   case $host_os in
1756   freebsd2*)
1757     shlibpath_overrides_runpath=yes
1758     ;;
1759   freebsd3.[[01]]* | freebsdelf3.[[01]]*)
1760     shlibpath_overrides_runpath=yes
1761     hardcode_into_libs=yes
1762     ;;
1763   freebsd3.[[2-9]]* | freebsdelf3.[[2-9]]* | \
1764   freebsd4.[[0-5]] | freebsdelf4.[[0-5]] | freebsd4.1.1 | freebsdelf4.1.1)
1765     shlibpath_overrides_runpath=no
1766     hardcode_into_libs=yes
1767     ;;
1768   freebsd*) # from 4.6 on
1769     shlibpath_overrides_runpath=yes
1770     hardcode_into_libs=yes
1771     ;;
1772   esac
1773   ;;
1774
1775 gnu*)
1776   version_type=linux
1777   need_lib_prefix=no
1778   need_version=no
1779   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}${major} ${libname}${shared_ext}'
1780   soname_spec='${libname}${release}${shared_ext}$major'
1781   shlibpath_var=LD_LIBRARY_PATH
1782   hardcode_into_libs=yes
1783   ;;
1784
1785 hpux9* | hpux10* | hpux11*)
1786   # Give a soname corresponding to the major version so that dld.sl refuses to
1787   # link against other versions.
1788   version_type=sunos
1789   need_lib_prefix=no
1790   need_version=no
1791   case $host_cpu in
1792   ia64*)
1793     shrext_cmds='.so'
1794     hardcode_into_libs=yes
1795     dynamic_linker="$host_os dld.so"
1796     shlibpath_var=LD_LIBRARY_PATH
1797     shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
1798     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1799     soname_spec='${libname}${release}${shared_ext}$major'
1800     if test "X$HPUX_IA64_MODE" = X32; then
1801       sys_lib_search_path_spec="/usr/lib/hpux32 /usr/local/lib/hpux32 /usr/local/lib"
1802     else
1803       sys_lib_search_path_spec="/usr/lib/hpux64 /usr/local/lib/hpux64"
1804     fi
1805     sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
1806     ;;
1807    hppa*64*)
1808      shrext_cmds='.sl'
1809      hardcode_into_libs=yes
1810      dynamic_linker="$host_os dld.sl"
1811      shlibpath_var=LD_LIBRARY_PATH # How should we handle SHLIB_PATH
1812      shlibpath_overrides_runpath=yes # Unless +noenvvar is specified.
1813      library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1814      soname_spec='${libname}${release}${shared_ext}$major'
1815      sys_lib_search_path_spec="/usr/lib/pa20_64 /usr/ccs/lib/pa20_64"
1816      sys_lib_dlsearch_path_spec=$sys_lib_search_path_spec
1817      ;;
1818    *)
1819     shrext_cmds='.sl'
1820     dynamic_linker="$host_os dld.sl"
1821     shlibpath_var=SHLIB_PATH
1822     shlibpath_overrides_runpath=no # +s is required to enable SHLIB_PATH
1823     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1824     soname_spec='${libname}${release}${shared_ext}$major'
1825     ;;
1826   esac
1827   # HP-UX runs *really* slowly unless shared libraries are mode 555.
1828   postinstall_cmds='chmod 555 $lib'
1829   ;;
1830
1831 interix3*)
1832   version_type=linux
1833   need_lib_prefix=no
1834   need_version=no
1835   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
1836   soname_spec='${libname}${release}${shared_ext}$major'
1837   dynamic_linker='Interix 3.x ld.so.1 (PE, like ELF)'
1838   shlibpath_var=LD_LIBRARY_PATH
1839   shlibpath_overrides_runpath=no
1840   hardcode_into_libs=yes
1841   ;;
1842
1843 irix5* | irix6* | nonstopux*)
1844   case $host_os in
1845     nonstopux*) version_type=nonstopux ;;
1846     *)
1847         if test "$lt_cv_prog_gnu_ld" = yes; then
1848                 version_type=linux
1849         else
1850                 version_type=irix
1851         fi ;;
1852   esac
1853   need_lib_prefix=no
1854   need_version=no
1855   soname_spec='${libname}${release}${shared_ext}$major'
1856   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${release}${shared_ext} $libname${shared_ext}'
1857   case $host_os in
1858   irix5* | nonstopux*)
1859     libsuff= shlibsuff=
1860     ;;
1861   *)
1862     case $LD in # libtool.m4 will add one of these switches to LD
1863     *-32|*"-32 "|*-melf32bsmip|*"-melf32bsmip ")
1864       libsuff= shlibsuff= libmagic=32-bit;;
1865     *-n32|*"-n32 "|*-melf32bmipn32|*"-melf32bmipn32 ")
1866       libsuff=32 shlibsuff=N32 libmagic=N32;;
1867     *-64|*"-64 "|*-melf64bmip|*"-melf64bmip ")
1868       libsuff=64 shlibsuff=64 libmagic=64-bit;;
1869     *) libsuff= shlibsuff= libmagic=never-match;;
1870     esac
1871     ;;
1872   esac
1873   shlibpath_var=LD_LIBRARY${shlibsuff}_PATH
1874   shlibpath_overrides_runpath=no
1875   sys_lib_search_path_spec="/usr/lib${libsuff} /lib${libsuff} /usr/local/lib${libsuff}"
1876   sys_lib_dlsearch_path_spec="/usr/lib${libsuff} /lib${libsuff}"
1877   hardcode_into_libs=yes
1878   ;;
1879
1880 # No shared lib support for Linux oldld, aout, or coff.
1881 linux*oldld* | linux*aout* | linux*coff*)
1882   dynamic_linker=no
1883   ;;
1884
1885 # This must be Linux ELF.
1886 linux*)
1887   version_type=linux
1888   need_lib_prefix=no
1889   need_version=no
1890   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1891   soname_spec='${libname}${release}${shared_ext}$major'
1892   finish_cmds='PATH="\$PATH:/sbin" ldconfig -n $libdir'
1893   shlibpath_var=LD_LIBRARY_PATH
1894   shlibpath_overrides_runpath=no
1895   # This implies no fast_install, which is unacceptable.
1896   # Some rework will be needed to allow for fast_install
1897   # before this can be enabled.
1898   hardcode_into_libs=yes
1899
1900   # Append ld.so.conf contents to the search path
1901   if test -f /etc/ld.so.conf; then
1902     lt_ld_extra=`awk '/^include / { system(sprintf("cd /etc; cat %s", \[$]2)); skip = 1; } { if (!skip) print \[$]0; skip = 0; }' < /etc/ld.so.conf | $SED -e 's/#.*//;s/[:,    ]/ /g;s/=[^=]*$//;s/=[^= ]* / /g;/^$/d' | tr '\n' ' '`
1903     sys_lib_dlsearch_path_spec="/lib /usr/lib $lt_ld_extra"
1904   fi
1905
1906   # We used to test for /lib/ld.so.1 and disable shared libraries on
1907   # powerpc, because MkLinux only supported shared libraries with the
1908   # GNU dynamic linker.  Since this was broken with cross compilers,
1909   # most powerpc-linux boxes support dynamic linking these days and
1910   # people can always --disable-shared, the test was removed, and we
1911   # assume the GNU/Linux dynamic linker is in use.
1912   dynamic_linker='GNU/Linux ld.so'
1913   ;;
1914
1915 knetbsd*-gnu)
1916   version_type=linux
1917   need_lib_prefix=no
1918   need_version=no
1919   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
1920   soname_spec='${libname}${release}${shared_ext}$major'
1921   shlibpath_var=LD_LIBRARY_PATH
1922   shlibpath_overrides_runpath=no
1923   hardcode_into_libs=yes
1924   dynamic_linker='GNU ld.so'
1925   ;;
1926
1927 netbsd*)
1928   version_type=sunos
1929   need_lib_prefix=no
1930   need_version=no
1931   if echo __ELF__ | $CC -E - | grep __ELF__ >/dev/null; then
1932     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
1933     finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
1934     dynamic_linker='NetBSD (a.out) ld.so'
1935   else
1936     library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major ${libname}${shared_ext}'
1937     soname_spec='${libname}${release}${shared_ext}$major'
1938     dynamic_linker='NetBSD ld.elf_so'
1939   fi
1940   shlibpath_var=LD_LIBRARY_PATH
1941   shlibpath_overrides_runpath=yes
1942   hardcode_into_libs=yes
1943   ;;
1944
1945 newsos6)
1946   version_type=linux
1947   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1948   shlibpath_var=LD_LIBRARY_PATH
1949   shlibpath_overrides_runpath=yes
1950   ;;
1951
1952 nto-qnx*)
1953   version_type=linux
1954   need_lib_prefix=no
1955   need_version=no
1956   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
1957   soname_spec='${libname}${release}${shared_ext}$major'
1958   shlibpath_var=LD_LIBRARY_PATH
1959   shlibpath_overrides_runpath=yes
1960   ;;
1961
1962 openbsd*)
1963   version_type=sunos
1964   sys_lib_dlsearch_path_spec="/usr/lib"
1965   need_lib_prefix=no
1966   # Some older versions of OpenBSD (3.3 at least) *do* need versioned libs.
1967   case $host_os in
1968     openbsd3.3 | openbsd3.3.*) need_version=yes ;;
1969     *)                         need_version=no  ;;
1970   esac
1971   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
1972   finish_cmds='PATH="\$PATH:/sbin" ldconfig -m $libdir'
1973   shlibpath_var=LD_LIBRARY_PATH
1974   if test -z "`echo __ELF__ | $CC -E - | grep __ELF__`" || test "$host_os-$host_cpu" = "openbsd2.8-powerpc"; then
1975     case $host_os in
1976       openbsd2.[[89]] | openbsd2.[[89]].*)
1977         shlibpath_overrides_runpath=no
1978         ;;
1979       *)
1980         shlibpath_overrides_runpath=yes
1981         ;;
1982       esac
1983   else
1984     shlibpath_overrides_runpath=yes
1985   fi
1986   ;;
1987
1988 os2*)
1989   libname_spec='$name'
1990   shrext_cmds=".dll"
1991   need_lib_prefix=no
1992   library_names_spec='$libname${shared_ext} $libname.a'
1993   dynamic_linker='OS/2 ld.exe'
1994   shlibpath_var=LIBPATH
1995   ;;
1996
1997 osf3* | osf4* | osf5*)
1998   version_type=osf
1999   need_lib_prefix=no
2000   need_version=no
2001   soname_spec='${libname}${release}${shared_ext}$major'
2002   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2003   shlibpath_var=LD_LIBRARY_PATH
2004   sys_lib_search_path_spec="/usr/shlib /usr/ccs/lib /usr/lib/cmplrs/cc /usr/lib /usr/local/lib /var/shlib"
2005   sys_lib_dlsearch_path_spec="$sys_lib_search_path_spec"
2006   ;;
2007
2008 solaris*)
2009   version_type=linux
2010   need_lib_prefix=no
2011   need_version=no
2012   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2013   soname_spec='${libname}${release}${shared_ext}$major'
2014   shlibpath_var=LD_LIBRARY_PATH
2015   shlibpath_overrides_runpath=yes
2016   hardcode_into_libs=yes
2017   # ldd complains unless libraries are executable
2018   postinstall_cmds='chmod +x $lib'
2019   ;;
2020
2021 sunos4*)
2022   version_type=sunos
2023   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${shared_ext}$versuffix'
2024   finish_cmds='PATH="\$PATH:/usr/etc" ldconfig $libdir'
2025   shlibpath_var=LD_LIBRARY_PATH
2026   shlibpath_overrides_runpath=yes
2027   if test "$with_gnu_ld" = yes; then
2028     need_lib_prefix=no
2029   fi
2030   need_version=yes
2031   ;;
2032
2033 sysv4 | sysv4.3*)
2034   version_type=linux
2035   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2036   soname_spec='${libname}${release}${shared_ext}$major'
2037   shlibpath_var=LD_LIBRARY_PATH
2038   case $host_vendor in
2039     sni)
2040       shlibpath_overrides_runpath=no
2041       need_lib_prefix=no
2042       export_dynamic_flag_spec='${wl}-Blargedynsym'
2043       runpath_var=LD_RUN_PATH
2044       ;;
2045     siemens)
2046       need_lib_prefix=no
2047       ;;
2048     motorola)
2049       need_lib_prefix=no
2050       need_version=no
2051       shlibpath_overrides_runpath=no
2052       sys_lib_search_path_spec='/lib /usr/lib /usr/ccs/lib'
2053       ;;
2054   esac
2055   ;;
2056
2057 sysv4*MP*)
2058   if test -d /usr/nec ;then
2059     version_type=linux
2060     library_names_spec='$libname${shared_ext}.$versuffix $libname${shared_ext}.$major $libname${shared_ext}'
2061     soname_spec='$libname${shared_ext}.$major'
2062     shlibpath_var=LD_LIBRARY_PATH
2063   fi
2064   ;;
2065
2066 sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
2067   version_type=freebsd-elf
2068   need_lib_prefix=no
2069   need_version=no
2070   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext} $libname${shared_ext}'
2071   soname_spec='${libname}${release}${shared_ext}$major'
2072   shlibpath_var=LD_LIBRARY_PATH
2073   hardcode_into_libs=yes
2074   if test "$with_gnu_ld" = yes; then
2075     sys_lib_search_path_spec='/usr/local/lib /usr/gnu/lib /usr/ccs/lib /usr/lib /lib'
2076     shlibpath_overrides_runpath=no
2077   else
2078     sys_lib_search_path_spec='/usr/ccs/lib /usr/lib'
2079     shlibpath_overrides_runpath=yes
2080     case $host_os in
2081       sco3.2v5*)
2082         sys_lib_search_path_spec="$sys_lib_search_path_spec /lib"
2083         ;;
2084     esac
2085   fi
2086   sys_lib_dlsearch_path_spec='/usr/lib'
2087   ;;
2088
2089 uts4*)
2090   version_type=linux
2091   library_names_spec='${libname}${release}${shared_ext}$versuffix ${libname}${release}${shared_ext}$major $libname${shared_ext}'
2092   soname_spec='${libname}${release}${shared_ext}$major'
2093   shlibpath_var=LD_LIBRARY_PATH
2094   ;;
2095
2096 *)
2097   dynamic_linker=no
2098   ;;
2099 esac
2100 AC_MSG_RESULT([$dynamic_linker])
2101 test "$dynamic_linker" = no && can_build_shared=no
2102
2103 variables_saved_for_relink="PATH $shlibpath_var $runpath_var"
2104 if test "$GCC" = yes; then
2105   variables_saved_for_relink="$variables_saved_for_relink GCC_EXEC_PREFIX COMPILER_PATH LIBRARY_PATH"
2106 fi
2107 ])# AC_LIBTOOL_SYS_DYNAMIC_LINKER
2108
2109
2110 # _LT_AC_TAGCONFIG
2111 # ----------------
2112 AC_DEFUN([_LT_AC_TAGCONFIG],
2113 [AC_ARG_WITH([tags],
2114     [AC_HELP_STRING([--with-tags@<:@=TAGS@:>@],
2115         [include additional configurations @<:@automatic@:>@])],
2116     [tagnames="$withval"])
2117
2118 if test -f "$ltmain" && test -n "$tagnames"; then
2119   if test ! -f "${ofile}"; then
2120     AC_MSG_WARN([output file `$ofile' does not exist])
2121   fi
2122
2123   if test -z "$LTCC"; then
2124     eval "`$SHELL ${ofile} --config | grep '^LTCC='`"
2125     if test -z "$LTCC"; then
2126       AC_MSG_WARN([output file `$ofile' does not look like a libtool script])
2127     else
2128       AC_MSG_WARN([using `LTCC=$LTCC', extracted from `$ofile'])
2129     fi
2130   fi
2131   if test -z "$LTCFLAGS"; then
2132     eval "`$SHELL ${ofile} --config | grep '^LTCFLAGS='`"
2133   fi
2134
2135   # Extract list of available tagged configurations in $ofile.
2136   # Note that this assumes the entire list is on one line.
2137   available_tags=`grep "^available_tags=" "${ofile}" | $SED -e 's/available_tags=\(.*$\)/\1/' -e 's/\"//g'`
2138
2139   lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
2140   for tagname in $tagnames; do
2141     IFS="$lt_save_ifs"
2142     # Check whether tagname contains only valid characters
2143     case `$echo "X$tagname" | $Xsed -e 's:[[-_ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890,/]]::g'` in
2144     "") ;;
2145     *)  AC_MSG_ERROR([invalid tag name: $tagname])
2146         ;;
2147     esac
2148
2149     if grep "^# ### BEGIN LIBTOOL TAG CONFIG: $tagname$" < "${ofile}" > /dev/null
2150     then
2151       AC_MSG_ERROR([tag name \"$tagname\" already exists])
2152     fi
2153
2154     # Update the list of available tags.
2155     if test -n "$tagname"; then
2156       echo appending configuration tag \"$tagname\" to $ofile
2157
2158       case $tagname in
2159       CXX)
2160         if test -n "$CXX" && ( test "X$CXX" != "Xno" &&
2161             ( (test "X$CXX" = "Xg++" && `g++ -v >/dev/null 2>&1` ) ||
2162             (test "X$CXX" != "Xg++"))) ; then
2163           AC_LIBTOOL_LANG_CXX_CONFIG
2164         else
2165           tagname=""
2166         fi
2167         ;;
2168
2169       F77)
2170         if test -n "$F77" && test "X$F77" != "Xno"; then
2171           AC_LIBTOOL_LANG_F77_CONFIG
2172         else
2173           tagname=""
2174         fi
2175         ;;
2176
2177       GCJ)
2178         if test -n "$GCJ" && test "X$GCJ" != "Xno"; then
2179           AC_LIBTOOL_LANG_GCJ_CONFIG
2180         else
2181           tagname=""
2182         fi
2183         ;;
2184
2185       RC)
2186         AC_LIBTOOL_LANG_RC_CONFIG
2187         ;;
2188
2189       *)
2190         AC_MSG_ERROR([Unsupported tag name: $tagname])
2191         ;;
2192       esac
2193
2194       # Append the new tag name to the list of available tags.
2195       if test -n "$tagname" ; then
2196       available_tags="$available_tags $tagname"
2197     fi
2198     fi
2199   done
2200   IFS="$lt_save_ifs"
2201
2202   # Now substitute the updated list of available tags.
2203   if eval "sed -e 's/^available_tags=.*\$/available_tags=\"$available_tags\"/' \"$ofile\" > \"${ofile}T\""; then
2204     mv "${ofile}T" "$ofile"
2205     chmod +x "$ofile"
2206   else
2207     rm -f "${ofile}T"
2208     AC_MSG_ERROR([unable to update list of available tagged configurations.])
2209   fi
2210 fi
2211 ])# _LT_AC_TAGCONFIG
2212
2213
2214 # AC_LIBTOOL_DLOPEN
2215 # -----------------
2216 # enable checks for dlopen support
2217 AC_DEFUN([AC_LIBTOOL_DLOPEN],
2218  [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])
2219 ])# AC_LIBTOOL_DLOPEN
2220
2221
2222 # AC_LIBTOOL_WIN32_DLL
2223 # --------------------
2224 # declare package support for building win32 DLLs
2225 AC_DEFUN([AC_LIBTOOL_WIN32_DLL],
2226 [AC_BEFORE([$0], [AC_LIBTOOL_SETUP])
2227 ])# AC_LIBTOOL_WIN32_DLL
2228
2229
2230 # AC_ENABLE_SHARED([DEFAULT])
2231 # ---------------------------
2232 # implement the --enable-shared flag
2233 # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
2234 AC_DEFUN([AC_ENABLE_SHARED],
2235 [define([AC_ENABLE_SHARED_DEFAULT], ifelse($1, no, no, yes))dnl
2236 AC_ARG_ENABLE([shared],
2237     [AC_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
2238         [build shared libraries @<:@default=]AC_ENABLE_SHARED_DEFAULT[@:>@])],
2239     [p=${PACKAGE-default}
2240     case $enableval in
2241     yes) enable_shared=yes ;;
2242     no) enable_shared=no ;;
2243     *)
2244       enable_shared=no
2245       # Look at the argument we got.  We use all the common list separators.
2246       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
2247       for pkg in $enableval; do
2248         IFS="$lt_save_ifs"
2249         if test "X$pkg" = "X$p"; then
2250           enable_shared=yes
2251         fi
2252       done
2253       IFS="$lt_save_ifs"
2254       ;;
2255     esac],
2256     [enable_shared=]AC_ENABLE_SHARED_DEFAULT)
2257 ])# AC_ENABLE_SHARED
2258
2259
2260 # AC_DISABLE_SHARED
2261 # -----------------
2262 # set the default shared flag to --disable-shared
2263 AC_DEFUN([AC_DISABLE_SHARED],
2264 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2265 AC_ENABLE_SHARED(no)
2266 ])# AC_DISABLE_SHARED
2267
2268
2269 # AC_ENABLE_STATIC([DEFAULT])
2270 # ---------------------------
2271 # implement the --enable-static flag
2272 # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
2273 AC_DEFUN([AC_ENABLE_STATIC],
2274 [define([AC_ENABLE_STATIC_DEFAULT], ifelse($1, no, no, yes))dnl
2275 AC_ARG_ENABLE([static],
2276     [AC_HELP_STRING([--enable-static@<:@=PKGS@:>@],
2277         [build static libraries @<:@default=]AC_ENABLE_STATIC_DEFAULT[@:>@])],
2278     [p=${PACKAGE-default}
2279     case $enableval in
2280     yes) enable_static=yes ;;
2281     no) enable_static=no ;;
2282     *)
2283      enable_static=no
2284       # Look at the argument we got.  We use all the common list separators.
2285       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
2286       for pkg in $enableval; do
2287         IFS="$lt_save_ifs"
2288         if test "X$pkg" = "X$p"; then
2289           enable_static=yes
2290         fi
2291       done
2292       IFS="$lt_save_ifs"
2293       ;;
2294     esac],
2295     [enable_static=]AC_ENABLE_STATIC_DEFAULT)
2296 ])# AC_ENABLE_STATIC
2297
2298
2299 # AC_DISABLE_STATIC
2300 # -----------------
2301 # set the default static flag to --disable-static
2302 AC_DEFUN([AC_DISABLE_STATIC],
2303 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2304 AC_ENABLE_STATIC(no)
2305 ])# AC_DISABLE_STATIC
2306
2307
2308 # AC_ENABLE_FAST_INSTALL([DEFAULT])
2309 # ---------------------------------
2310 # implement the --enable-fast-install flag
2311 # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
2312 AC_DEFUN([AC_ENABLE_FAST_INSTALL],
2313 [define([AC_ENABLE_FAST_INSTALL_DEFAULT], ifelse($1, no, no, yes))dnl
2314 AC_ARG_ENABLE([fast-install],
2315     [AC_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
2316     [optimize for fast installation @<:@default=]AC_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
2317     [p=${PACKAGE-default}
2318     case $enableval in
2319     yes) enable_fast_install=yes ;;
2320     no) enable_fast_install=no ;;
2321     *)
2322       enable_fast_install=no
2323       # Look at the argument we got.  We use all the common list separators.
2324       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
2325       for pkg in $enableval; do
2326         IFS="$lt_save_ifs"
2327         if test "X$pkg" = "X$p"; then
2328           enable_fast_install=yes
2329         fi
2330       done
2331       IFS="$lt_save_ifs"
2332       ;;
2333     esac],
2334     [enable_fast_install=]AC_ENABLE_FAST_INSTALL_DEFAULT)
2335 ])# AC_ENABLE_FAST_INSTALL
2336
2337
2338 # AC_DISABLE_FAST_INSTALL
2339 # -----------------------
2340 # set the default to --disable-fast-install
2341 AC_DEFUN([AC_DISABLE_FAST_INSTALL],
2342 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2343 AC_ENABLE_FAST_INSTALL(no)
2344 ])# AC_DISABLE_FAST_INSTALL
2345
2346
2347 # AC_LIBTOOL_PICMODE([MODE])
2348 # --------------------------
2349 # implement the --with-pic flag
2350 # MODE is either `yes' or `no'.  If omitted, it defaults to `both'.
2351 AC_DEFUN([AC_LIBTOOL_PICMODE],
2352 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2353 pic_mode=ifelse($#,1,$1,default)
2354 ])# AC_LIBTOOL_PICMODE
2355
2356
2357 # AC_PROG_EGREP
2358 # -------------
2359 # This is predefined starting with Autoconf 2.54, so this conditional
2360 # definition can be removed once we require Autoconf 2.54 or later.
2361 m4_ifndef([AC_PROG_EGREP], [AC_DEFUN([AC_PROG_EGREP],
2362 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2363    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2364     then ac_cv_prog_egrep='grep -E'
2365     else ac_cv_prog_egrep='egrep'
2366     fi])
2367  EGREP=$ac_cv_prog_egrep
2368  AC_SUBST([EGREP])
2369 ])])
2370
2371
2372 # AC_PATH_TOOL_PREFIX
2373 # -------------------
2374 # find a file program which can recognise shared library
2375 AC_DEFUN([AC_PATH_TOOL_PREFIX],
2376 [AC_REQUIRE([AC_PROG_EGREP])dnl
2377 AC_MSG_CHECKING([for $1])
2378 AC_CACHE_VAL(lt_cv_path_MAGIC_CMD,
2379 [case $MAGIC_CMD in
2380 [[\\/*] |  ?:[\\/]*])
2381   lt_cv_path_MAGIC_CMD="$MAGIC_CMD" # Let the user override the test with a path.
2382   ;;
2383 *)
2384   lt_save_MAGIC_CMD="$MAGIC_CMD"
2385   lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
2386 dnl $ac_dummy forces splitting on constant user-supplied paths.
2387 dnl POSIX.2 word splitting is done only on the output of word expansions,
2388 dnl not every word.  This closes a longstanding sh security hole.
2389   ac_dummy="ifelse([$2], , $PATH, [$2])"
2390   for ac_dir in $ac_dummy; do
2391     IFS="$lt_save_ifs"
2392     test -z "$ac_dir" && ac_dir=.
2393     if test -f $ac_dir/$1; then
2394       lt_cv_path_MAGIC_CMD="$ac_dir/$1"
2395       if test -n "$file_magic_test_file"; then
2396         case $deplibs_check_method in
2397         "file_magic "*)
2398           file_magic_regex=`expr "$deplibs_check_method" : "file_magic \(.*\)"`
2399           MAGIC_CMD="$lt_cv_path_MAGIC_CMD"
2400           if eval $file_magic_cmd \$file_magic_test_file 2> /dev/null |
2401             $EGREP "$file_magic_regex" > /dev/null; then
2402             :
2403           else
2404             cat <<EOF 1>&2
2405
2406 *** Warning: the command libtool uses to detect shared libraries,
2407 *** $file_magic_cmd, produces output that libtool cannot recognize.
2408 *** The result is that libtool may fail to recognize shared libraries
2409 *** as such.  This will affect the creation of libtool libraries that
2410 *** depend on shared libraries, but programs linked with such libtool
2411 *** libraries will work regardless of this problem.  Nevertheless, you
2412 *** may want to report the problem to your system manager and/or to
2413 *** bug-libtool@gnu.org
2414
2415 EOF
2416           fi ;;
2417         esac
2418       fi
2419       break
2420     fi
2421   done
2422   IFS="$lt_save_ifs"
2423   MAGIC_CMD="$lt_save_MAGIC_CMD"
2424   ;;
2425 esac])
2426 MAGIC_CMD="$lt_cv_path_MAGIC_CMD"
2427 if test -n "$MAGIC_CMD"; then
2428   AC_MSG_RESULT($MAGIC_CMD)
2429 else
2430   AC_MSG_RESULT(no)
2431 fi
2432 ])# AC_PATH_TOOL_PREFIX
2433
2434
2435 # AC_PATH_MAGIC
2436 # -------------
2437 # find a file program which can recognise a shared library
2438 AC_DEFUN([AC_PATH_MAGIC],
2439 [AC_PATH_TOOL_PREFIX(${ac_tool_prefix}file, /usr/bin$PATH_SEPARATOR$PATH)
2440 if test -z "$lt_cv_path_MAGIC_CMD"; then
2441   if test -n "$ac_tool_prefix"; then
2442     AC_PATH_TOOL_PREFIX(file, /usr/bin$PATH_SEPARATOR$PATH)
2443   else
2444     MAGIC_CMD=:
2445   fi
2446 fi
2447 ])# AC_PATH_MAGIC
2448
2449
2450 # AC_PROG_LD
2451 # ----------
2452 # find the pathname to the GNU or non-GNU linker
2453 AC_DEFUN([AC_PROG_LD],
2454 [AC_ARG_WITH([gnu-ld],
2455     [AC_HELP_STRING([--with-gnu-ld],
2456         [assume the C compiler uses GNU ld @<:@default=no@:>@])],
2457     [test "$withval" = no || with_gnu_ld=yes],
2458     [with_gnu_ld=no])
2459 AC_REQUIRE([LT_AC_PROG_SED])dnl
2460 AC_REQUIRE([AC_PROG_CC])dnl
2461 AC_REQUIRE([AC_CANONICAL_HOST])dnl
2462 AC_REQUIRE([AC_CANONICAL_BUILD])dnl
2463 ac_prog=ld
2464 if test "$GCC" = yes; then
2465   # Check if gcc -print-prog-name=ld gives a path.
2466   AC_MSG_CHECKING([for ld used by $CC])
2467   case $host in
2468   *-*-mingw*)
2469     # gcc leaves a trailing carriage return which upsets mingw
2470     ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
2471   *)
2472     ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
2473   esac
2474   case $ac_prog in
2475     # Accept absolute paths.
2476     [[\\/]]* | ?:[[\\/]]*)
2477       re_direlt='/[[^/]][[^/]]*/\.\./'
2478       # Canonicalize the pathname of ld
2479       ac_prog=`echo $ac_prog| $SED 's%\\\\%/%g'`
2480       while echo $ac_prog | grep "$re_direlt" > /dev/null 2>&1; do
2481         ac_prog=`echo $ac_prog| $SED "s%$re_direlt%/%"`
2482       done
2483       test -z "$LD" && LD="$ac_prog"
2484       ;;
2485   "")
2486     # If it fails, then pretend we aren't using GCC.
2487     ac_prog=ld
2488     ;;
2489   *)
2490     # If it is relative, then search for the first ld in PATH.
2491     with_gnu_ld=unknown
2492     ;;
2493   esac
2494 elif test "$with_gnu_ld" = yes; then
2495   AC_MSG_CHECKING([for GNU ld])
2496 else
2497   AC_MSG_CHECKING([for non-GNU ld])
2498 fi
2499 AC_CACHE_VAL(lt_cv_path_LD,
2500 [if test -z "$LD"; then
2501   lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
2502   for ac_dir in $PATH; do
2503     IFS="$lt_save_ifs"
2504     test -z "$ac_dir" && ac_dir=.
2505     if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
2506       lt_cv_path_LD="$ac_dir/$ac_prog"
2507       # Check to see if the program is GNU ld.  I'd rather use --version,
2508       # but apparently some variants of GNU ld only accept -v.
2509       # Break only if it was the GNU/non-GNU ld that we prefer.
2510       case `"$lt_cv_path_LD" -v 2>&1 </dev/null` in
2511       *GNU* | *'with BFD'*)
2512         test "$with_gnu_ld" != no && break
2513         ;;
2514       *)
2515         test "$with_gnu_ld" != yes && break
2516         ;;
2517       esac
2518     fi
2519   done
2520   IFS="$lt_save_ifs"
2521 else
2522   lt_cv_path_LD="$LD" # Let the user override the test with a path.
2523 fi])
2524 LD="$lt_cv_path_LD"
2525 if test -n "$LD"; then
2526   AC_MSG_RESULT($LD)
2527 else
2528   AC_MSG_RESULT(no)
2529 fi
2530 test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
2531 AC_PROG_LD_GNU
2532 ])# AC_PROG_LD
2533
2534
2535 # AC_PROG_LD_GNU
2536 # --------------
2537 AC_DEFUN([AC_PROG_LD_GNU],
2538 [AC_REQUIRE([AC_PROG_EGREP])dnl
2539 AC_CACHE_CHECK([if the linker ($LD) is GNU ld], lt_cv_prog_gnu_ld,
2540 [# I'd rather use --version here, but apparently some GNU lds only accept -v.
2541 case `$LD -v 2>&1 </dev/null` in
2542 *GNU* | *'with BFD'*)
2543   lt_cv_prog_gnu_ld=yes
2544   ;;
2545 *)
2546   lt_cv_prog_gnu_ld=no
2547   ;;
2548 esac])
2549 with_gnu_ld=$lt_cv_prog_gnu_ld
2550 ])# AC_PROG_LD_GNU
2551
2552
2553 # AC_PROG_LD_RELOAD_FLAG
2554 # ----------------------
2555 # find reload flag for linker
2556 #   -- PORTME Some linkers may need a different reload flag.
2557 AC_DEFUN([AC_PROG_LD_RELOAD_FLAG],
2558 [AC_CACHE_CHECK([for $LD option to reload object files],
2559   lt_cv_ld_reload_flag,
2560   [lt_cv_ld_reload_flag='-r'])
2561 reload_flag=$lt_cv_ld_reload_flag
2562 case $reload_flag in
2563 "" | " "*) ;;
2564 *) reload_flag=" $reload_flag" ;;
2565 esac
2566 reload_cmds='$LD$reload_flag -o $output$reload_objs'
2567 case $host_os in
2568   darwin*)
2569     if test "$GCC" = yes; then
2570       reload_cmds='$LTCC $LTCFLAGS -nostdlib ${wl}-r -o $output$reload_objs'
2571     else
2572       reload_cmds='$LD$reload_flag -o $output$reload_objs'
2573     fi
2574     ;;
2575 esac
2576 ])# AC_PROG_LD_RELOAD_FLAG
2577
2578
2579 # AC_DEPLIBS_CHECK_METHOD
2580 # -----------------------
2581 # how to check for library dependencies
2582 #  -- PORTME fill in with the dynamic library characteristics
2583 AC_DEFUN([AC_DEPLIBS_CHECK_METHOD],
2584 [AC_CACHE_CHECK([how to recognise dependent libraries],
2585 lt_cv_deplibs_check_method,
2586 [lt_cv_file_magic_cmd='$MAGIC_CMD'
2587 lt_cv_file_magic_test_file=
2588 lt_cv_deplibs_check_method='unknown'
2589 # Need to set the preceding variable on all platforms that support
2590 # interlibrary dependencies.
2591 # 'none' -- dependencies not supported.
2592 # `unknown' -- same as none, but documents that we really don't know.
2593 # 'pass_all' -- all dependencies passed with no checks.
2594 # 'test_compile' -- check by making test program.
2595 # 'file_magic [[regex]]' -- check by looking for files in library path
2596 # which responds to the $file_magic_cmd with a given extended regex.
2597 # If you have `file' or equivalent on your system and you're not sure
2598 # whether `pass_all' will *always* work, you probably want this one.
2599
2600 case $host_os in
2601 aix4* | aix5*)
2602   lt_cv_deplibs_check_method=pass_all
2603   ;;
2604
2605 beos*)
2606   lt_cv_deplibs_check_method=pass_all
2607   ;;
2608
2609 bsdi[[45]]*)
2610   lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (shared object|dynamic lib)'
2611   lt_cv_file_magic_cmd='/usr/bin/file -L'
2612   lt_cv_file_magic_test_file=/shlib/libc.so
2613   ;;
2614
2615 cygwin*)
2616   # func_win32_libid is a shell function defined in ltmain.sh
2617   #lt_cv_deplibs_check_method='file_magic ^x86 archive import|^x86 DLL'
2618   lt_cv_deplibs_check_method=pass_all
2619   lt_cv_file_magic_cmd='func_win32_libid'
2620   ;;
2621
2622 mingw* | pw32*)
2623   # Base MSYS/MinGW do not provide the 'file' command needed by
2624   # func_win32_libid shell function, so use a weaker test based on 'objdump'.
2625   #lt_cv_deplibs_check_method='file_magic file format pei*-i386(.*architecture: i386)?'
2626   lt_cv_deplibs_check_method=pass_all
2627   lt_cv_file_magic_cmd='$OBJDUMP -f'
2628   ;;
2629
2630 darwin* | rhapsody*)
2631   lt_cv_deplibs_check_method=pass_all
2632   ;;
2633
2634 freebsd* | kfreebsd*-gnu | dragonfly*)
2635   if echo __ELF__ | $CC -E - | grep __ELF__ > /dev/null; then
2636     case $host_cpu in
2637     i*86 )
2638       # Not sure whether the presence of OpenBSD here was a mistake.
2639       # Let's accept both of them until this is cleared up.
2640       lt_cv_deplibs_check_method='file_magic (FreeBSD|OpenBSD|DragonFly)/i[[3-9]]86 (compact )?demand paged shared library'
2641       lt_cv_file_magic_cmd=/usr/bin/file
2642       lt_cv_file_magic_test_file=`echo /usr/lib/libc.so.*`
2643       ;;
2644     esac
2645   else
2646     lt_cv_deplibs_check_method=pass_all
2647   fi
2648   ;;
2649
2650 gnu*)
2651   lt_cv_deplibs_check_method=pass_all
2652   ;;
2653
2654 hpux10.20* | hpux11*)
2655   lt_cv_file_magic_cmd=/usr/bin/file
2656   case $host_cpu in
2657   ia64*)
2658     lt_cv_deplibs_check_method='file_magic (s[[0-9]][[0-9]][[0-9]]|ELF-[[0-9]][[0-9]]) shared object file - IA64'
2659     lt_cv_file_magic_test_file=/usr/lib/hpux32/libc.so
2660     ;;
2661   hppa*64*)
2662     [lt_cv_deplibs_check_method='file_magic (s[0-9][0-9][0-9]|ELF-[0-9][0-9]) shared object file - PA-RISC [0-9].[0-9]']
2663     lt_cv_file_magic_test_file=/usr/lib/pa20_64/libc.sl
2664     ;;
2665   *)
2666     lt_cv_deplibs_check_method='file_magic (s[[0-9]][[0-9]][[0-9]]|PA-RISC[[0-9]].[[0-9]]) shared library'
2667     lt_cv_file_magic_test_file=/usr/lib/libc.sl
2668     ;;
2669   esac
2670   ;;
2671
2672 interix3*)
2673   # PIC code is broken on Interix 3.x, that's why |\.a not |_pic\.a here
2674   lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so|\.a)$'
2675   ;;
2676
2677 irix5* | irix6* | nonstopux*)
2678   case $LD in
2679   *-32|*"-32 ") libmagic=32-bit;;
2680   *-n32|*"-n32 ") libmagic=N32;;
2681   *-64|*"-64 ") libmagic=64-bit;;
2682   *) libmagic=never-match;;
2683   esac
2684   lt_cv_deplibs_check_method=pass_all
2685   ;;
2686
2687 # This must be Linux ELF.
2688 linux*)
2689   lt_cv_deplibs_check_method=pass_all
2690   ;;
2691
2692 netbsd*)
2693   if echo __ELF__ | $CC -E - | grep __ELF__ > /dev/null; then
2694     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|_pic\.a)$'
2695   else
2696     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so|_pic\.a)$'
2697   fi
2698   ;;
2699
2700 newos6*)
2701   lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (executable|dynamic lib)'
2702   lt_cv_file_magic_cmd=/usr/bin/file
2703   lt_cv_file_magic_test_file=/usr/lib/libnls.so
2704   ;;
2705
2706 nto-qnx*)
2707   lt_cv_deplibs_check_method=unknown
2708   ;;
2709
2710 openbsd*)
2711   if test -z "`echo __ELF__ | $CC -E - | grep __ELF__`" || test "$host_os-$host_cpu" = "openbsd2.8-powerpc"; then
2712     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|\.so|_pic\.a)$'
2713   else
2714     lt_cv_deplibs_check_method='match_pattern /lib[[^/]]+(\.so\.[[0-9]]+\.[[0-9]]+|_pic\.a)$'
2715   fi
2716   ;;
2717
2718 osf3* | osf4* | osf5*)
2719   lt_cv_deplibs_check_method=pass_all
2720   ;;
2721
2722 solaris*)
2723   lt_cv_deplibs_check_method=pass_all
2724   ;;
2725
2726 sysv4 | sysv4.3*)
2727   case $host_vendor in
2728   motorola)
2729     lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[ML]]SB (shared object|dynamic lib) M[[0-9]][[0-9]]* Version [[0-9]]'
2730     lt_cv_file_magic_test_file=`echo /usr/lib/libc.so*`
2731     ;;
2732   ncr)
2733     lt_cv_deplibs_check_method=pass_all
2734     ;;
2735   sequent)
2736     lt_cv_file_magic_cmd='/bin/file'
2737     lt_cv_deplibs_check_method='file_magic ELF [[0-9]][[0-9]]*-bit [[LM]]SB (shared object|dynamic lib )'
2738     ;;
2739   sni)
2740     lt_cv_file_magic_cmd='/bin/file'
2741     lt_cv_deplibs_check_method="file_magic ELF [[0-9]][[0-9]]*-bit [[LM]]SB dynamic lib"
2742     lt_cv_file_magic_test_file=/lib/libc.so
2743     ;;
2744   siemens)
2745     lt_cv_deplibs_check_method=pass_all
2746     ;;
2747   pc)
2748     lt_cv_deplibs_check_method=pass_all
2749     ;;
2750   esac
2751   ;;
2752
2753 sysv5* | sco3.2v5* | sco5v6* | unixware* | OpenUNIX* | sysv4*uw2*)
2754   lt_cv_deplibs_check_method=pass_all
2755   ;;
2756 esac
2757 ])
2758 file_magic_cmd=$lt_cv_file_magic_cmd
2759 deplibs_check_method=$lt_cv_deplibs_check_method
2760 test -z "$deplibs_check_method" && deplibs_check_method=unknown
2761 ])# AC_DEPLIBS_CHECK_METHOD
2762
2763
2764 # AC_PROG_NM
2765 # ----------
2766 # find the pathname to a BSD-compatible name lister
2767 AC_DEFUN([AC_PROG_NM],
2768 [AC_CACHE_CHECK([for BSD-compatible nm], lt_cv_path_NM,
2769 [if test -n "$NM"; then
2770   # Let the user override the test.
2771   lt_cv_path_NM="$NM"
2772 else
2773   lt_nm_to_check="${ac_tool_prefix}nm"
2774   if test -n "$ac_tool_prefix" && test "$build" = "$host"; then 
2775     lt_nm_to_check="$lt_nm_to_check nm"
2776   fi
2777   for lt_tmp_nm in $lt_nm_to_check; do
2778     lt_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
2779     for ac_dir in $PATH /usr/ccs/bin/elf /usr/ccs/bin /usr/ucb /bin; do
2780       IFS="$lt_save_ifs"
2781       test -z "$ac_dir" && ac_dir=.
2782       tmp_nm="$ac_dir/$lt_tmp_nm"
2783       if test -f "$tmp_nm" || test -f "$tmp_nm$ac_exeext" ; then
2784         # Check to see if the nm accepts a BSD-compat flag.
2785         # Adding the `sed 1q' prevents false positives on HP-UX, which says:
2786         #   nm: unknown option "B" ignored
2787         # Tru64's nm complains that /dev/null is an invalid object file
2788         case `"$tmp_nm" -B /dev/null 2>&1 | sed '1q'` in
2789         */dev/null* | *'Invalid file or object type'*)
2790           lt_cv_path_NM="$tmp_nm -B"
2791           break
2792           ;;
2793         *)
2794           case `"$tmp_nm" -p /dev/null 2>&1 | sed '1q'` in
2795           */dev/null*)
2796             lt_cv_path_NM="$tmp_nm -p"
2797             break
2798             ;;
2799           *)
2800             lt_cv_path_NM=${lt_cv_path_NM="$tmp_nm"} # keep the first match, but
2801             continue # so that we can try to find one that supports BSD flags
2802             ;;
2803           esac
2804           ;;
2805         esac
2806       fi
2807     done
2808     IFS="$lt_save_ifs"
2809   done
2810   test -z "$lt_cv_path_NM" && lt_cv_path_NM=nm
2811 fi])
2812 NM="$lt_cv_path_NM"
2813 ])# AC_PROG_NM
2814
2815
2816 # AC_CHECK_LIBM
2817 # -------------
2818 # check for math library
2819 AC_DEFUN([AC_CHECK_LIBM],
2820 [AC_REQUIRE([AC_CANONICAL_HOST])dnl
2821 LIBM=
2822 case $host in
2823 *-*-beos* | *-*-cygwin* | *-*-pw32* | *-*-darwin*)
2824   # These system don't have libm, or don't need it
2825   ;;
2826 *-ncr-sysv4.3*)
2827   AC_CHECK_LIB(mw, _mwvalidcheckl, LIBM="-lmw")
2828   AC_CHECK_LIB(m, cos, LIBM="$LIBM -lm")
2829   ;;
2830 *)
2831   AC_CHECK_LIB(m, cos, LIBM="-lm")
2832   ;;
2833 esac
2834 ])# AC_CHECK_LIBM
2835
2836
2837 # AC_LIBLTDL_CONVENIENCE([DIRECTORY])
2838 # -----------------------------------
2839 # sets LIBLTDL to the link flags for the libltdl convenience library and
2840 # LTDLINCL to the include flags for the libltdl header and adds
2841 # --enable-ltdl-convenience to the configure arguments.  Note that
2842 # AC_CONFIG_SUBDIRS is not called here.  If DIRECTORY is not provided,
2843 # it is assumed to be `libltdl'.  LIBLTDL will be prefixed with
2844 # '${top_builddir}/' and LTDLINCL will be prefixed with '${top_srcdir}/'
2845 # (note the single quotes!).  If your package is not flat and you're not
2846 # using automake, define top_builddir and top_srcdir appropriately in
2847 # the Makefiles.
2848 AC_DEFUN([AC_LIBLTDL_CONVENIENCE],
2849 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2850   case $enable_ltdl_convenience in
2851   no) AC_MSG_ERROR([this package needs a convenience libltdl]) ;;
2852   "") enable_ltdl_convenience=yes
2853       ac_configure_args="$ac_configure_args --enable-ltdl-convenience" ;;
2854   esac
2855   LIBLTDL='${top_builddir}/'ifelse($#,1,[$1],['libltdl'])/libltdlc.la
2856   LTDLINCL='-I${top_srcdir}/'ifelse($#,1,[$1],['libltdl'])
2857   # For backwards non-gettext consistent compatibility...
2858   INCLTDL="$LTDLINCL"
2859 ])# AC_LIBLTDL_CONVENIENCE
2860
2861
2862 # AC_LIBLTDL_INSTALLABLE([DIRECTORY])
2863 # -----------------------------------
2864 # sets LIBLTDL to the link flags for the libltdl installable library and
2865 # LTDLINCL to the include flags for the libltdl header and adds
2866 # --enable-ltdl-install to the configure arguments.  Note that
2867 # AC_CONFIG_SUBDIRS is not called here.  If DIRECTORY is not provided,
2868 # and an installed libltdl is not found, it is assumed to be `libltdl'.
2869 # LIBLTDL will be prefixed with '${top_builddir}/'# and LTDLINCL with
2870 # '${top_srcdir}/' (note the single quotes!).  If your package is not
2871 # flat and you're not using automake, define top_builddir and top_srcdir
2872 # appropriately in the Makefiles.
2873 # In the future, this macro may have to be called after AC_PROG_LIBTOOL.
2874 AC_DEFUN([AC_LIBLTDL_INSTALLABLE],
2875 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
2876   AC_CHECK_LIB(ltdl, lt_dlinit,
2877   [test x"$enable_ltdl_install" != xyes && enable_ltdl_install=no],
2878   [if test x"$enable_ltdl_install" = xno; then
2879      AC_MSG_WARN([libltdl not installed, but installation disabled])
2880    else
2881      enable_ltdl_install=yes
2882    fi
2883   ])
2884   if test x"$enable_ltdl_install" = x"yes"; then
2885     ac_configure_args="$ac_configure_args --enable-ltdl-install"
2886     LIBLTDL='${top_builddir}/'ifelse($#,1,[$1],['libltdl'])/libltdl.la
2887     LTDLINCL='-I${top_srcdir}/'ifelse($#,1,[$1],['libltdl'])
2888   else
2889     ac_configure_args="$ac_configure_args --enable-ltdl-install=no"
2890     LIBLTDL="-lltdl"
2891     LTDLINCL=
2892   fi
2893   # For backwards non-gettext consistent compatibility...
2894   INCLTDL="$LTDLINCL"
2895 ])# AC_LIBLTDL_INSTALLABLE
2896
2897
2898 # AC_LIBTOOL_CXX
2899 # --------------
2900 # enable support for C++ libraries
2901 AC_DEFUN([AC_LIBTOOL_CXX],
2902 [AC_REQUIRE([_LT_AC_LANG_CXX])
2903 ])# AC_LIBTOOL_CXX
2904
2905
2906 # _LT_AC_LANG_CXX
2907 # ---------------
2908 AC_DEFUN([_LT_AC_LANG_CXX],
2909 [AC_REQUIRE([AC_PROG_CXX])
2910 AC_REQUIRE([_LT_AC_PROG_CXXCPP])
2911 _LT_AC_SHELL_INIT([tagnames=${tagnames+${tagnames},}CXX])
2912 ])# _LT_AC_LANG_CXX
2913
2914 # _LT_AC_PROG_CXXCPP
2915 # ------------------
2916 AC_DEFUN([_LT_AC_PROG_CXXCPP],
2917 [
2918 AC_REQUIRE([AC_PROG_CXX])
2919 if test -n "$CXX" && ( test "X$CXX" != "Xno" &&
2920     ( (test "X$CXX" = "Xg++" && `g++ -v >/dev/null 2>&1` ) ||
2921     (test "X$CXX" != "Xg++"))) ; then
2922   AC_PROG_CXXCPP
2923 fi
2924 ])# _LT_AC_PROG_CXXCPP
2925
2926 # AC_LIBTOOL_F77
2927 # --------------
2928 # enable support for Fortran 77 libraries
2929 AC_DEFUN([AC_LIBTOOL_F77],
2930 [AC_REQUIRE([_LT_AC_LANG_F77])
2931 ])# AC_LIBTOOL_F77
2932
2933
2934 # _LT_AC_LANG_F77
2935 # ---------------
2936 AC_DEFUN([_LT_AC_LANG_F77],
2937 [AC_REQUIRE([AC_PROG_F77])
2938 _LT_AC_SHELL_INIT([tagnames=${tagnames+${tagnames},}F77])
2939 ])# _LT_AC_LANG_F77
2940
2941
2942 # AC_LIBTOOL_GCJ
2943 # --------------
2944 # enable support for GCJ libraries
2945 AC_DEFUN([AC_LIBTOOL_GCJ],
2946 [AC_REQUIRE([_LT_AC_LANG_GCJ])
2947 ])# AC_LIBTOOL_GCJ
2948
2949
2950 # _LT_AC_LANG_GCJ
2951 # ---------------
2952 AC_DEFUN([_LT_AC_LANG_GCJ],
2953 [AC_PROVIDE_IFELSE([AC_PROG_GCJ],[],
2954   [AC_PROVIDE_IFELSE([A][M_PROG_GCJ],[],
2955     [AC_PROVIDE_IFELSE([LT_AC_PROG_GCJ],[],
2956       [ifdef([AC_PROG_GCJ],[AC_REQUIRE([AC_PROG_GCJ])],
2957          [ifdef([A][M_PROG_GCJ],[AC_REQUIRE([A][M_PROG_GCJ])],
2958            [AC_REQUIRE([A][C_PROG_GCJ_OR_A][M_PROG_GCJ])])])])])])
2959 _LT_AC_SHELL_INIT([tagnames=${tagnames+${tagnames},}GCJ])
2960 ])# _LT_AC_LANG_GCJ
2961
2962
2963 # AC_LIBTOOL_RC
2964 # -------------
2965 # enable support for Windows resource files
2966 AC_DEFUN([AC_LIBTOOL_RC],
2967 [AC_REQUIRE([LT_AC_PROG_RC])
2968 _LT_AC_SHELL_INIT([tagnames=${tagnames+${tagnames},}RC])
2969 ])# AC_LIBTOOL_RC
2970
2971
2972 # AC_LIBTOOL_LANG_C_CONFIG
2973 # ------------------------
2974 # Ensure that the configuration vars for the C compiler are
2975 # suitably defined.  Those variables are subsequently used by
2976 # AC_LIBTOOL_CONFIG to write the compiler configuration to `libtool'.
2977 AC_DEFUN([AC_LIBTOOL_LANG_C_CONFIG], [_LT_AC_LANG_C_CONFIG])
2978 AC_DEFUN([_LT_AC_LANG_C_CONFIG],
2979 [lt_save_CC="$CC"
2980 AC_LANG_PUSH(C)
2981
2982 # Source file extension for C test sources.
2983 ac_ext=c
2984
2985 # Object file extension for compiled C test sources.
2986 objext=o
2987 _LT_AC_TAGVAR(objext, $1)=$objext
2988
2989 # Code to be used in simple compile tests
2990 lt_simple_compile_test_code="int some_variable = 0;\n"
2991
2992 # Code to be used in simple link tests
2993 lt_simple_link_test_code='int main(){return(0);}\n'
2994
2995 _LT_AC_SYS_COMPILER
2996
2997 # save warnings/boilerplate of simple test code
2998 _LT_COMPILER_BOILERPLATE
2999 _LT_LINKER_BOILERPLATE
3000
3001 ## CAVEAT EMPTOR:
3002 ## There is no encapsulation within the following macros, do not change
3003 ## the running order or otherwise move them around unless you know exactly
3004 ## what you are doing...
3005 AC_LIBTOOL_PROG_COMPILER_NO_RTTI($1)
3006 AC_LIBTOOL_PROG_COMPILER_PIC($1)
3007 AC_LIBTOOL_PROG_CC_C_O($1)
3008 AC_LIBTOOL_SYS_HARD_LINK_LOCKS($1)
3009 AC_LIBTOOL_PROG_LD_SHLIBS($1)
3010 AC_LIBTOOL_SYS_DYNAMIC_LINKER($1)
3011 AC_LIBTOOL_PROG_LD_HARDCODE_LIBPATH($1)
3012 AC_LIBTOOL_SYS_LIB_STRIP
3013 AC_LIBTOOL_DLOPEN_SELF
3014
3015 # Report which library types will actually be built
3016 AC_MSG_CHECKING([if libtool supports shared libraries])
3017 AC_MSG_RESULT([$can_build_shared])
3018
3019 AC_MSG_CHECKING([whether to build shared libraries])
3020 test "$can_build_shared" = "no" && enable_shared=no
3021
3022 # On AIX, shared libraries and static libraries use the same namespace, and
3023 # are all built from PIC.
3024 case $host_os in
3025 aix3*)
3026   test "$enable_shared" = yes && enable_static=no
3027   if test -n "$RANLIB"; then
3028     archive_cmds="$archive_cmds~\$RANLIB \$lib"
3029     postinstall_cmds='$RANLIB $lib'
3030   fi
3031   ;;
3032
3033 aix4* | aix5*)
3034   if test "$host_cpu" != ia64 && test "$aix_use_runtimelinking" = no ; then
3035     test "$enable_shared" = yes && enable_static=no
3036   fi
3037     ;;
3038 esac
3039 AC_MSG_RESULT([$enable_shared])
3040
3041 AC_MSG_CHECKING([whether to build static libraries])
3042 # Make sure either enable_shared or enable_static is yes.
3043 test "$enable_shared" = yes || enable_static=yes
3044 AC_MSG_RESULT([$enable_static])
3045
3046 AC_LIBTOOL_CONFIG($1)
3047
3048 AC_LANG_POP
3049 CC="$lt_save_CC"
3050 ])# AC_LIBTOOL_LANG_C_CONFIG
3051
3052
3053 # AC_LIBTOOL_LANG_CXX_CONFIG
3054 # --------------------------
3055 # Ensure that the configuration vars for the C compiler are
3056 # suitably defined.  Those variables are subsequently used by
3057 # AC_LIBTOOL_CONFIG to write the compiler configuration to `libtool'.
3058 AC_DEFUN([AC_LIBTOOL_LANG_CXX_CONFIG], [_LT_AC_LANG_CXX_CONFIG(CXX)])
3059 AC_DEFUN([_LT_AC_LANG_CXX_CONFIG],
3060 [AC_LANG_PUSH(C++)
3061 AC_REQUIRE([AC_PROG_CXX])
3062 AC_REQUIRE([_LT_AC_PROG_CXXCPP])
3063
3064 _LT_AC_TAGVAR(archive_cmds_need_lc, $1)=no
3065 _LT_AC_TAGVAR(allow_undefined_flag, $1)=
3066 _LT_AC_TAGVAR(always_export_symbols, $1)=no
3067 _LT_AC_TAGVAR(archive_expsym_cmds, $1)=
3068 _LT_AC_TAGVAR(export_dynamic_flag_spec, $1)=
3069 _LT_AC_TAGVAR(hardcode_direct, $1)=no
3070 _LT_AC_TAGVAR(hardcode_libdir_flag_spec, $1)=
3071 _LT_AC_TAGVAR(hardcode_libdir_flag_spec_ld, $1)=
3072 _LT_AC_TAGVAR(hardcode_libdir_separator, $1)=
3073 _LT_AC_TAGVAR(hardcode_minus_L, $1)=no
3074 _LT_AC_TAGVAR(hardcode_shlibpath_var, $1)=unsupported
3075 _LT_AC_TAGVAR(hardcode_automatic, $1)=no
3076 _LT_AC_TAGVAR(module_cmds, $1)=
3077 _LT_AC_TAGVAR(module_expsym_cmds, $1)=
3078 _LT_AC_TAGVAR(link_all_deplibs, $1)=unknown
3079 _LT_AC_TAGVAR(old_archive_cmds, $1)=$old_archive_cmds
3080 _LT_AC_TAGVAR(no_undefined_flag, $1)=
3081 _LT_AC_TAGVAR(whole_archive_flag_spec, $1)=
3082 _LT_AC_TAGVAR(enable_shared_with_static_runtimes, $1)=no
3083
3084 # Dependencies to place before and after the object being linked:
3085 _LT_AC_TAGVAR(predep_objects, $1)=
3086 _LT_AC_TAGVAR(postdep_objects, $1)=
3087 _LT_AC_TAGVAR(predeps, $1)=
3088 _LT_AC_TAGVAR(postdeps, $1)=
3089 _LT_AC_TAGVAR(compiler_lib_search_path, $1)=
3090
3091 # Source file extension for C++ test sources.
3092 ac_ext=cpp
3093
3094 # Object file extension for compiled C++ test sources.
3095 objext=o
3096 _LT_AC_TAGVAR(objext, $1)=$objext
3097
3098 # Code to be used in simple compile tests
3099 lt_simple_compile_test_code="int some_variable = 0;\n"
3100
3101 # Code to be used in simple link tests
3102 lt_simple_link_test_code='int main(int, char *[[]]) { return(0); }\n'
3103
3104 # ltmain only uses $CC for tagged configurations so make sure $CC is set.
3105 _LT_AC_SYS_COMPILER
3106
3107 # save warnings/boilerplate of simple test code
3108 _LT_COMPILER_BOILERPLATE
3109 _LT_LINKER_BOILERPLATE
3110
3111 # Allow CC to be a program name with arguments.
3112 lt_save_CC=$CC
3113 lt_save_LD=$LD
3114 lt_save_GCC=$GCC
3115 GCC=$GXX
3116 lt_save_with_gnu_ld=$with_gnu_ld
3117 lt_save_path_LD=$lt_cv_path_LD
3118 if test -n "${lt_cv_prog_gnu_ldcxx+set}"; then
3119   lt_cv_prog_gnu_ld=$lt_cv_prog_gnu_ldcxx
3120 else
3121   $as_unset lt_cv_prog_gnu_ld
3122 fi
3123 if test -n "${lt_cv_path_LDCXX+set}"; then
3124   lt_cv_path_LD=$lt_cv_path_LDCXX
3125 else
3126   $as_unset lt_cv_path_LD
3127 fi
3128 test -z "${LDCXX+set}" || LD=$LDCXX
3129 CC=${CXX-"c++"}
3130 compiler=$CC
3131 _LT_AC_TAGVAR(compiler, $1)=$CC
3132 _LT_CC_BASENAME([$compiler])
3133
3134 # We don't want -fno-exception wen compiling C++ code, so set the
3135 # no_builtin_flag separately
3136 if test "$GXX" = yes; then
3137   _LT_AC_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)=' -fno-builtin'
3138 else
3139   _LT_AC_TAGVAR(lt_prog_compiler_no_builtin_flag, $1)=
3140 fi
3141
3142 if test "$GXX" = yes; then
3143   # Set up default GNU C++ configuration
3144
3145   AC_PROG_LD
3146
3147   # Check if GNU C++ uses GNU ld as the underlying linker, since the
3148   # archiving commands below assume that GNU ld is being used.
3149   if test "$with_gnu_ld" = yes; then
3150     _LT_AC_TAGVAR(archive_cmds, $1)='$CC -shared -nostdlib $predep_objects $libobjs $deplibs $postdep_objects $compiler_flags ${wl}-soname $wl$soname -o $lib'
3151     _LT_AC_TAGVAR(archive_expsym_cmds, $1)='$CC -shared -nostdlib $predep_objects $libobjs $deplibs $postdep_objects $compiler_flags ${wl}-soname $wl$soname ${wl}-retain-symbols-file $wl$export_symbols -o $lib'
3152
3153     _LT_AC_TAGVAR(hardcode_libdir_flag_spec, $1)='${wl}--rpath ${wl}$libdir'
3154     _LT_AC_TAGVAR(export_dynamic_flag_spec, $1)='${wl}--export-dynamic'
3155
3156     # If archive_cmds runs LD, not CC, wlarc should be empty
3157     # XXX I think wlarc can be eliminated in ltcf-cxx, but I need to
3158     #     investigate it a little bit more. (MM)
3159     wlarc='${wl}'
3160
3161     # ancient GNU ld didn't support --whole-archive et. al.
3162     if eval "`$CC -print-prog-name=ld` --help 2>&1" | \
3163         grep 'no-whole-archive' > /dev/null; then
3164       _LT_AC_TAGVAR(whole_archive_flag_spec, $1)="$wlarc"'--whole-archive$convenience '"$wlarc"'--no-whole-archive'
3165     else
3166       _LT_AC_TAGVAR(whole_archive_flag_spec, $1)=
3167     fi
3168   else
3169     with_gnu_ld=no
3170     wlarc=
3171
3172     # A generic and very simple default shared library creation
3173     # command for GNU C++ for the case where it uses the native
3174     # linker, instead of GNU ld.  If possible, this setting should
3175     # overridden to take advantage of the native linker features on
3176     # the platform it is being used on.
3177     _LT_AC_TAGVAR(archive_cmds, $1)='$CC -shared -nostdlib $predep_objects $libobjs $deplibs $postdep_objects $compiler_flags -o $lib'
3178   fi
3179
3180   # Commands to make compiler produce verbose output that lists
3181   # what "hidden" libraries, object files and flags are used when
3182   # linking a shared library.