[U] amarok-git, kwebkitpart-git
[arch-linux-greece:arch-linux-greece.git] / list-of-sources / adslgr64 / mkvmerge-gui / PKGBUILD
1 pkgname=mkvmerge-gui
2 _pkgname=mkvtoolnix
3 pkgver=5.0.1
4 pkgrel=1
5 pkgdesc="user interface for mkvmerge (mmg) from mkvtoolnix"
6 arch=('i686' 'x86_64')
7 license=('GPL')
8 url="http://www.bunkus.org/videotools/mkvtoolnix/index.html"
9 depends=('mkvtoolnix' 'wxgtk' 'hicolor-icon-theme' 'desktop-file-utils')
10 makedepends=('boost' 'ruby')
11 install=$pkgname.install
12 source=("http://www.bunkus.org/videotools/${_pkgname}/sources/${_pkgname}-${pkgver}.tar.bz2")
13
14 build() {
15         cd "${srcdir}/${_pkgname}-${pkgver}"
16
17         # Disable automagic curl dep used for online update checking
18         sed -i -e '/curl/d' configure.in
19         export CURL_CFLAGS="" CURL_LIBS=""
20         
21         export CFLAGS="${CFLAGS} -DBOOST_FILESYSTEM_VERSION=2"
22         export CXXFLAGS="${CXXFLAGS} -DBOOST_FILESYSTEM_VERSION=2"
23
24         autoreconf
25         
26         ./configure --prefix=/usr --with-boost-libdir=/usr/lib --enable-gui
27         ./drake apps:mmg
28 }
29
30 package () {
31         # install binary file
32         install -Dm755 "${srcdir}/${_pkgname}-${pkgver}/src/mmg/mmg" "${pkgdir}/usr/bin/mmg"
33         # install all manpages
34         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/doc/man/mmg.1" "${pkgdir}/usr/share/man/man1/mmg.1"
35         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/doc/man/ja/mmg.1" "${pkgdir}/usr/share/man/ja/man1/mmg.1"
36         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/doc/man/nl/mmg.1" "${pkgdir}/usr/share/man/nl/man1/mmg.1"
37         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/doc/man/zh_CN/mmg.1" "${pkgdir}/usr/share/man/zh_CN/man1/mmg.1"
38         # install desktop file
39         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/share/desktop/mkvmergeGUI.desktop" "${pkgdir}/usr/share/applications/mkvmergeGUI.desktop"
40         # install icons
41         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/share/icons/32x32/mkvmergeGUI.png" "${pkgdir}/usr/share/icons/hicolor/32x32/apps/mkvmergeGUI.png"
42         install -Dm644 "${srcdir}/${_pkgname}-${pkgver}/share/icons/64x64/mkvmergeGUI.png" "${pkgdir}/usr/share/icons/hicolor/64x64/apps/mkvmergeGUI.png"
43 }
44
45 md5sums=('93fbbe946de6013eca699c0c2a93a4e9')