Merge branch 'master' into harmattan
[accounts-sso:signon.git] / src / plugins / sasl / doc / doc.pri
1 #-----------------------------------------------------------------------------
2 # doc.pri
3 #-----------------------------------------------------------------------------
4
5 # list of documentation folders to install
6 DOC_FOLDERS = doc/html \
7               doc/qch
8
9 # files and folders listed in the installation target's .files section
10 # must exist _before_ qmake generates the Makefile...so, make sure our
11 # documentation target folders exist in the current build folder
12 for( folder, DOC_FOLDERS ) {
13     system( mkdir -p $$(PWD)/$${folder} )
14 }
15
16
17 #-----------------------------------------------------------------------------
18 # extra build targets for generating and cleaning documentation
19 #-----------------------------------------------------------------------------
20 DOC_INPUT += $${_PRO_FILE_PWD_}
21 DOC_INPUT += doc/src
22
23 # target for generating documentation
24 doctarget.target     = docs
25 doctarget.commands   = OUTPUT_DIRECTORY=doc \
26                        PROJECT_NAME=\"$${PROJECT_NAME}\" \
27                        PROJECT_NUMBER=\"$${PROJECT_VERSION}\" \
28                        STRIP_FROM_PATH=\"$${_PRO_FILE_PWD_}\" \
29                        INPUT=\"$${DOC_INPUT}\" \
30                        QHP_NAMESPACE=\"com.nokia.example.$${TARGET}\" \
31                        QHP_VIRTUAL_FOLDER=\"$${TARGET}\" \
32                        TAGFILES=\"$$system(pwd)/qt.tags\" \
33                        TAGFILE=\"doc/$${TARGET}.tags\" \
34                        doxygen $$system(pwd)/doxy.conf
35 doctarget.depends    = FORCE
36 QMAKE_EXTRA_TARGETS += doctarget
37
38
39 # target for cleaning generated documentation
40 doccleantarget.target = cleandocs
41 for( folder, DOC_FOLDERS ) {
42     doccleantarget.commands += rm -r -f $${folder};
43 }
44 doccleantarget.commands += rm -r -f doc/accounts.tags;
45 doccleantarget.depends   = FORCE
46 QMAKE_EXTRA_TARGETS     += doccleantarget
47
48
49 #-----------------------------------------------------------------------------
50 # Installation target setup for documentation
51 #-----------------------------------------------------------------------------
52 documentation.path = $${INSTALL_PREFIX}/share/doc/$${TARGET}
53 for( folder, DOC_FOLDERS ) {
54     documentation.files += $${folder}
55 }
56 # make sure docs are generated before trying to install anything
57 documentation.depends  = docs
58 INSTALLS              += documentation
59 message("====")
60 message("==== INSTALLS += documentation")
61
62
63 # End of File
64