fixing bug 243668 - signon has incomplete doxygen config in debian/api
[accounts-sso:signon.git] / src / plugins / sasl / doc / doc.pri
1 #-----------------------------------------------------------------------------
2 # doc.pri
3 #-----------------------------------------------------------------------------
4
5 # list of documentation folders to install
6 DOC_FOLDERS = doc/html \
7               doc/qch
8
9 # files and folders listed in the installation target's .files section
10 # must exist _before_ qmake generates the Makefile...so, make sure our
11 # documentation target folders exist in the current build folder
12 for( folder, DOC_FOLDERS ) {
13     system( mkdir -p $$(PWD)/$${folder} )
14 }
15
16
17 #-----------------------------------------------------------------------------
18 # extra build targets for generating and cleaning documentation
19 #-----------------------------------------------------------------------------
20 DOC_INPUT += $${_PRO_FILE_PWD_}/doc/
21
22 # target for generating documentation
23 doctarget.target     = docs
24 doctarget.commands   = OUTPUT_DIRECTORY=doc \
25                        PROJECT_NAME=\"$${PROJECT_NAME}\" \
26                        PROJECT_NUMBER=\"$${PROJECT_VERSION}\" \
27                        STRIP_FROM_PATH=\"$${_PRO_FILE_PWD_}\" \
28                        INPUT=\"$${DOC_INPUT}\" \
29                        QHP_NAMESPACE=\"com.nokia.example.$${TARGET}\" \
30                        QHP_VIRTUAL_FOLDER=\"$${TARGET}\" \
31                        TAGFILES=\"$$system(pwd)/qt.tags\" \
32                        TAGFILE=\"doc/$${TARGET}.tags\" \
33                        doxygen $$system(pwd)/doxy.conf
34 doctarget.depends    = FORCE
35 QMAKE_EXTRA_TARGETS += doctarget
36
37
38 # target for cleaning generated documentation
39 doccleantarget.target = cleandocs
40 for( folder, DOC_FOLDERS ) {
41     doccleantarget.commands += rm -r -f $${folder};
42 }
43 doccleantarget.commands += rm -r -f doc/accounts.tags;
44 doccleantarget.depends   = FORCE
45 QMAKE_EXTRA_TARGETS     += doccleantarget
46
47
48 #-----------------------------------------------------------------------------
49 # Installation target setup for documentation
50 #-----------------------------------------------------------------------------
51 documentation.path = $${INSTALL_PREFIX}/share/doc/$${TARGET}
52 for( folder, DOC_FOLDERS ) {
53     documentation.files += $${folder}
54 }
55 # make sure docs are generated before trying to install anything
56 documentation.depends  = docs
57 INSTALLS              += documentation
58 message("====")
59 message("==== INSTALLS += documentation")
60
61
62 # End of File
63