Check for GNU/Hurd before setting the stack limit
[abe:zshrc.git] / zsh.d / 05-grml
1 # -*- sh -*-
2 # Filename:      /etc/zsh/zshrc
3 # Purpose:       config file for zsh (z shell)
4 # Authors:       grml-team (grml.org), (c) Michael Prokop <mika@grml.org>
5 # Bug-Reports:   see http://grml.org/bugs/
6 # License:       This file is licensed under the GPL v2.
7 ################################################################################
8 # This file is sourced only for interactive shells. It
9 # should contain commands to set up aliases, functions,
10 # options, key bindings, etc.
11 #
12 # Global Order: zshenv, zprofile, zshrc, zlogin
13 ################################################################################
14
15 # zsh-refcard-tag documentation: {{{
16 #   You may notice strange looking comments in this file.
17 #   These are there for a purpose. grml's zsh-refcard can now be
18 #   automatically generated from the contents of the actual configuration
19 #   file. However, we need a little extra information on which comments
20 #   and what lines of code to take into account (and for what purpose).
21 #
22 # Here is what they mean:
23 #
24 # List of tags (comment types) used:
25 #   #a#     Next line contains an important alias, that should
26 #           be included in the grml-zsh-refcard.
27 #           (placement tag: @@INSERT-aliases@@)
28 #   #f#     Next line contains the beginning of an important function.
29 #           (placement tag: @@INSERT-functions@@)
30 #   #v#     Next line contains an important variable.
31 #           (placement tag: @@INSERT-variables@@)
32 #   #k#     Next line contains an important keybinding.
33 #           (placement tag: @@INSERT-keybindings@@)
34 #   #d#     Hashed directories list generation:
35 #               start   denotes the start of a list of 'hash -d'
36 #                       definitions.
37 #               end     denotes its end.
38 #           (placement tag: @@INSERT-hasheddirs@@)
39 #   #A#     Abbreviation expansion list generation:
40 #               start   denotes the beginning of abbreviations.
41 #               end     denotes their end.
42 #           Lines within this section that end in '#d .*' provide
43 #           extra documentation to be included in the refcard.
44 #           (placement tag: @@INSERT-abbrev@@)
45 #   #m#     This tag allows you to manually generate refcard entries
46 #           for code lines that are hard/impossible to parse.
47 #               Example:
48 #                   #m# k ESC-h Call the run-help function
49 #               That would add a refcard entry in the keybindings table
50 #               for 'ESC-h' with the given comment.
51 #           So the syntax is: #m# <section> <argument> <comment>
52 #   #o#     This tag lets you insert entries to the 'other' hash.
53 #           Generally, this should not be used. It is there for
54 #           things that cannot be done easily in another way.
55 #           (placement tag: @@INSERT-other-foobar@@)
56 #
57 #   All of these tags (except for m and o) take two arguments, the first
58 #   within the tag, the other after the tag:
59 #
60 #   #<tag><section># <comment>
61 #
62 #   Where <section> is really just a number, which are defined by the
63 #   @secmap array on top of 'genrefcard.pl'. The reason for numbers
64 #   instead of names is, that for the reader, the tag should not differ
65 #   much from a regular comment. For zsh, it is a regular comment indeed.
66 #   The numbers have got the following meanings:
67 #         0 -> "default"
68 #         1 -> "system"
69 #         2 -> "user"
70 #         3 -> "debian"
71 #         4 -> "search"
72 #         5 -> "shortcuts"
73 #         6 -> "services"
74 #
75 #   So, the following will add an entry to the 'functions' table in the
76 #   'system' section, with a (hopefully) descriptive comment:
77 #       #f1# Edit an alias via zle
78 #       edalias() {
79 #
80 #   It will then show up in the @@INSERT-aliases-system@@ replacement tag
81 #   that can be found in 'grml-zsh-refcard.tex.in'.
82 #   If the section number is omitted, the 'default' section is assumed.
83 #   Furthermore, in 'grml-zsh-refcard.tex.in' @@INSERT-aliases@@ is
84 #   exactly the same as @@INSERT-aliases-default@@. If you want a list of
85 #   *all* aliases, for example, use @@INSERT-aliases-all@@.
86 #}}}
87
88 # zsh profiling {{{
89 # just execute 'ZSH_PROFILE_RC=1 zsh' and run 'zprof' to get the details
90 if [[ $ZSH_PROFILE_RC -gt 0 ]] ; then
91     zmodload zsh/zprof
92 fi
93 # }}}
94
95 # load .zshrc.pre to give the user the chance to overwrite the defaults
96 [[ -r ${HOME}/.zshrc.pre ]] && source ${HOME}/.zshrc.pre
97
98 # {{{ check for version/system
99 # check for versions (compatibility reasons)
100 is4(){
101     [[ $ZSH_VERSION == <4->* ]] && return 0
102     return 1
103 }
104
105 is41(){
106     [[ $ZSH_VERSION == 4.<1->* || $ZSH_VERSION == <5->* ]] && return 0
107     return 1
108 }
109
110 is42(){
111     [[ $ZSH_VERSION == 4.<2->* || $ZSH_VERSION == <5->* ]] && return 0
112     return 1
113 }
114
115 is425(){
116     [[ $ZSH_VERSION == 4.2.<5->* || $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
117     return 1
118 }
119
120 is43(){
121     [[ $ZSH_VERSION == 4.<3->* || $ZSH_VERSION == <5->* ]] && return 0
122     return 1
123 }
124
125 #f1# Checks whether or not you're running grml
126 isgrml(){
127     [[ -f /etc/grml_version ]] && return 0
128     return 1
129 }
130
131 #f1# Checks whether or not you're running a grml cd
132 isgrmlcd(){
133     [[ -f /etc/grml_cd ]] && return 0
134     return 1
135 }
136
137 if isgrml ; then
138 #f1# Checks whether or not you're running grml-small
139     isgrmlsmall() {
140         [[ ${${${(f)"$(</etc/grml_version)"}%% *}##*-} == 'small' ]] && return 0 ; return 1
141     }
142 else
143     isgrmlsmall() { return 1 }
144 fi
145
146 isdarwin(){
147     [[ $OSTYPE == darwin* ]] && return 0
148     return 1
149 }
150
151 #f1# are we running within an utf environment?
152 isutfenv() {
153     case "$LANG $CHARSET $LANGUAGE" in
154         *utf*) return 0 ;;
155         *UTF*) return 0 ;;
156         *)     return 1 ;;
157     esac
158 }
159
160 # check for user, if not running as root set $SUDO to sudo
161 (( EUID != 0 )) && SUDO='sudo' || SUDO=''
162
163 # change directory to home on first invocation of zsh
164 # important for rungetty -> autologin
165 # Thanks go to Bart Schaefer!
166 isgrml && checkhome() {
167     if [[ -z "$ALREADY_DID_CD_HOME" ]] ; then
168         export ALREADY_DID_CD_HOME=$HOME
169         cd
170     fi
171 }
172
173 # check for zsh v3.1.7+
174
175 if ! [[ ${ZSH_VERSION} == 3.1.<7->*      \
176      || ${ZSH_VERSION} == 3.<2->.<->*    \
177      || ${ZSH_VERSION} == <4->.<->*   ]] ; then
178
179     printf '-!-\n'
180     printf '-!- In this configuration we try to make use of features, that only\n'
181     printf '-!- require version 3.1.7 of the shell; That way this setup can be\n'
182     printf '-!- used with a wide range of zsh versions, while using fairly\n'
183     printf '-!- advanced features in all supported versions.\n'
184     printf '-!-\n'
185     printf '-!- However, you are running zsh version %s.\n' "$ZSH_VERSION"
186     printf '-!-\n'
187     printf '-!- While this *may* work, it might as well fail.\n'
188     printf '-!- Please consider updating to at least version 3.1.7 of zsh.\n'
189     printf '-!-\n'
190     printf '-!- DO NOT EXPECT THIS TO WORK FLAWLESSLY!\n'
191     printf '-!- If it does today, you'\''ve been lucky.\n'
192     printf '-!-\n'
193     printf '-!- Ye been warned!\n'
194     printf '-!-\n'
195
196     function zstyle() { : }
197 fi
198
199 # autoload wrapper - use this one instead of autoload directly
200 # We need to define this function as early as this, because autoloading
201 # 'is-at-least()' needs it.
202 function zrcautoload() {
203     setopt local_options extended_glob
204     local fdir ffile
205     local -i ffound
206
207     ffile=${1}
208     (( found = 0 ))
209     for fdir in ${fpath} ; do
210         [[ -e ${fdir}/${ffile} ]] && (( ffound = 1 ))
211     done
212
213     (( ffound == 0 )) && return 1
214     if [[ $ZSH_VERSION == 3.1.<6-> || $ZSH_VERSION == <4->* ]] ; then
215         autoload -U ${ffile} || return 1
216     else
217         autoload ${ffile} || return 1
218     fi
219     return 0
220 }
221
222 # Load is-at-least() for more precise version checks
223 # Note that this test will *always* fail, if the is-at-least
224 # function could not be marked for autoloading.
225 zrcautoload is-at-least || is-at-least() { return 1 }
226
227 # }}}
228
229 # setting some default values {{{
230
231 NOCOR=${NOCOR:-0}
232 NOMENU=${NOMENU:-0}
233 NOPRECMD=${NOPRECMD:-0}
234 COMMAND_NOT_FOUND=${COMMAND_NOT_FOUND:-0}
235 GRML_ZSH_CNF_HANDLER=${GRML_ZSH_CNF_HANDLER:-/usr/share/command-not-found/command-not-found}
236 BATTERY=${BATTERY:-0}
237 GRMLSMALL_SPECIFIC=${GRMLSMALL_SPECIFIC:-1}
238 GRML_ALWAYS_LOAD_ALL=${GRML_ALWAYS_LOAD_ALL:-0}
239
240 if isgrmlcd ; then
241     GRML_WARN_SKEL=${GRML_WARN_SKEL:-0}
242 else
243     GRML_WARN_SKEL=${GRML_WARN_SKEL:-1}
244 fi
245
246 if (( GRML_WARN_SKEL != 0 )) ; then
247
248 function grml_warn_skel_main() {
249     printf '
250 Dear user,
251
252 You updated grml'\''s zshrc which brings a major change.
253 The configuration is kept only in one file, being the global zshrc.
254 In the past, the configuration was split in two files, with the
255 second file being the .zshrc file from /etc/skel.
256
257 If you have a .zshrc file in your home directory that originally
258 came from the skel directory, please remove it. This is also the case
259 if you followed earlier instructions from the grml-zsh-refcard or
260 from <http://grml.org/console/> on non-grml systems.
261
262 Please see the current grml-zsh-refcard (available at
263 <http://grml.org/zsh/>) for updated installation information. In short,
264 you don'\''t want a .zshrc.global file. Install the global zshrc to
265 ~/.zshrc and be done.
266
267 If you need changes to the configuration, use ~/.zshrc.pre and
268 ~/.zshrc.local.
269
270 '
271 }
272
273 function grml_warn_skel_remove() {
274     printf 'To remove this warning execute '\''grml_do_not_warn_skel'\''.\n\n'
275 }
276
277 function grml_do_not_warn_skel() {
278     printf '# Do not warn about old skel dot-files anymore\n' >>! ~/.zshrc.pre
279     printf 'GRML_WARN_SKEL=0\n' >>! ~/.zshrc.pre
280 }
281
282 # let's try to guess how the user uses us.
283 if is-at-least 4.3.7 ; then
284     # funcsourcetrace requires at least version 4.3.7 of zsh.
285     GRML_SRC_FILE="${${funcsourcetrace[1]}%:*}"
286
287     grml_warn_skel_main
288     case ${GRML_SRC_FILE} in
289         (${HOME}/.zshrc.global)
290             grml_warn_skel_remove
291             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc.global'\''.\n'
292             printf 'Nowadays you just copy the global zshrc to '\''~/.zshrc'\'' to use\n'
293             printf 'it on a non-grml-system.\n'
294             ;;
295         (${HOME}/.zshrc)
296             printf '\nIt looks like you copied the grml zshrc to '\''~/.zshrc'\''.\n'
297             printf 'We'\''ll disable this warning automatically for later sessions.\n'
298             grml_do_not_warn_skel
299             ;;
300         (*)
301             grml_do_not_warn_skel
302             ;;
303     esac
304 else
305     grml_warn_skel_main
306     grml_warn_skel_remove
307 fi
308
309 unfunction grml_warn_skel_remove grml_warn_skel_main
310
311 fi # GRML_WARN_SKEL
312
313 # }}}
314
315 # utility functions {{{
316 # this function checks if a command exists and returns either true
317 # or false. This avoids using 'which' and 'whence', which will
318 # avoid problems with aliases for which on certain weird systems. :-)
319 check_com() {
320     local -i comonly
321
322     if [[ ${1} == '-c' ]] ; then
323         (( comonly = 1 ))
324         shift
325     else
326         (( comonly = 0 ))
327     fi
328
329     if (( ${#argv} != 1 )) ; then
330         printf 'usage: check_com [-c] <command>\n' >&2
331         return 1
332     fi
333
334     if (( comonly > 0 )) ; then
335         [[ -n ${commands[$1]}  ]] && return 0
336         return 1
337     fi
338
339     if   [[ -n ${commands[$1]}    ]] \
340       || [[ -n ${functions[$1]}   ]] \
341       || [[ -n ${aliases[$1]}     ]] \
342       || [[ -n ${reswords[(r)$1]} ]] ; then
343
344         return 0
345     fi
346
347     return 1
348 }
349
350 # creates an alias and precedes the command with
351 # sudo if $EUID is not zero.
352 salias() {
353     local only=0 ; local multi=0
354     while [[ ${1} == -* ]] ; do
355         case ${1} in
356             (-o) only=1 ;;
357             (-a) multi=1 ;;
358             (--) shift ; break ;;
359             (-h)
360                 printf 'usage: salias [-h|-o|-a] <alias-expression>\n'
361                 printf '  -h      shows this help text.\n'
362                 printf '  -a      replace '\'' ; '\'' sequences with '\'' ; sudo '\''.\n'
363                 printf '          be careful using this option.\n'
364                 printf '  -o      only sets an alias if a preceding sudo would be needed.\n'
365                 return 0
366                 ;;
367             (*) printf "unkown option: '%s'\n" "${1}" ; return 1 ;;
368         esac
369         shift
370     done
371
372     if (( ${#argv} > 1 )) ; then
373         printf 'Too many arguments %s\n' "${#argv}"
374         return 1
375     fi
376
377     key="${1%%\=*}" ;  val="${1#*\=}"
378     if (( EUID == 0 )) && (( only == 0 )); then
379         alias -- "${key}=${val}"
380     elif (( EUID > 0 )) ; then
381         (( multi > 0 )) && val="${val// ; / ; sudo }"
382         alias -- "${key}=sudo ${val}"
383     fi
384
385     return 0
386 }
387
388 # a "print -l ${(u)foo}"-workaround for pre-4.2.0 shells
389 # usage: uprint foo
390 #   Where foo is the *name* of the parameter you want printed.
391 #   Note that foo is no typo; $foo would be wrong here!
392 if ! is42 ; then
393     uprint () {
394         local -a u
395         local w
396         local parameter=${1}
397
398         if [[ -z ${parameter} ]] ; then
399             printf 'usage: uprint <parameter>\n'
400             return 1
401         fi
402
403         for w in ${(P)parameter} ; do
404             [[ -z ${(M)u:#${w}} ]] && u=( ${u} ${w} )
405         done
406
407         builtin print -l ${u}
408     }
409 fi
410
411 # Check if we can read given files and source those we can.
412 xsource() {
413     if (( ${#argv} < 1 )) ; then
414         printf 'usage: xsource FILE(s)...\n' >&2
415         return 1
416     fi
417
418     while (( ${#argv} > 0 )) ; do
419         [[ -r ${1} ]] && source ${1}
420         shift
421     done
422     return 0
423 }
424
425 # Check if we can read a given file and 'cat(1)' it.
426 xcat() {
427     if (( ${#argv} != 1 )) ; then
428         printf 'usage: xcat FILE\n' >&2
429         return 1
430     fi
431
432     [[ -r ${1} ]] && cat ${1}
433     return 0
434 }
435
436 # Remove these functions again, they are of use only in these
437 # setup files. This should be called at the end of .zshrc.
438 xunfunction() {
439     local -a funcs
440     funcs=(salias xcat xsource xunfunction zrcautoload)
441
442     for func in $funcs ; do
443         [[ -n ${functions[$func]} ]] \
444             && unfunction $func
445     done
446     return 0
447 }
448
449 # this allows us to stay in sync with grml's zshrc and put own
450 # modifications in ~/.zshrc.local
451 zrclocal() {
452     xsource "${HOME}/.zshrc.local"
453     return 0
454 }
455
456 #}}}
457
458 # locale setup {{{
459 xsource "/etc/default/locale"
460
461 export LANG=${LANG:-en_US.iso885915}
462 for var in LC_ALL LC_MESSAGES ; do
463     [[ -n ${(P)var} ]] && export $var
464 done
465
466 xsource "/etc/sysconfig/keyboard"
467
468 TZ=$(xcat /etc/timezone)
469 # }}}
470
471 # check for potentially old files in 'completion.d' {{{
472 setopt extendedglob
473 xof=($HOME/.zsh/completion.d/*~$HOME/.zsh/completion.d/_*(N))
474 if (( ${#xof} > 0 )) ; then
475     printf '\n -!- INFORMATION\n\n'
476     printf ' -!- %s file(s) not starting with an underscore (_) found in\n' ${#xof}
477     printf ' -!- $HOME/.zsh/completion.d/.\n\n'
478     printf ' -!- While this has been the case in old versions of grml-etc-core,\n'
479     printf ' -!- recent versions of the grml-zsh-setup have all these files rewritten\n'
480     printf ' -!- and renamed. Furthermore, the grml-zsh-setup will *only* add files\n'
481     printf ' -!- named _* to that directory.\n\n'
482     printf ' -!- If you added functions to completion.d yourself, please consider\n'
483     printf ' -!- moving them to $HOME/.zsh/functions.d/. Files in that directory, not\n'
484     printf ' -!- starting with an underscore are marked for automatic loading\n'
485     printf ' -!- by default (so that is quite convenient).\n\n'
486     printf ' -!- If there are files *not* starting with an underscore from an older\n'
487     printf ' -!- grml-etc-core in completion.d, you may safely remove them.\n\n'
488     printf ' -!- Delete the files for example via running:\n\n'
489     printf "      rm ${xof}\n\n"
490     printf ' -!- Note, that this message will *not* go away, unless you yourself\n'
491     printf ' -!- resolve the situation manually.\n\n'
492     BROKEN_COMPLETION_DIR=1
493 fi
494 unset xof
495 # }}}
496
497 # {{{ set some variables
498 if check_com -c vim ; then
499 #v#
500     export EDITOR=${EDITOR:-vim}
501 else
502     export EDITOR=${EDITOR:-vi}
503 fi
504
505 #v#
506 export PAGER=${PAGER:-less}
507
508 #v#
509 export MAIL=${MAIL:-/var/mail/$USER}
510
511 # if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
512 export SHELL='/bin/zsh'
513
514 # color setup for ls:
515 check_com -c dircolors && eval $(dircolors -b)
516 # color setup for ls on OS X:
517 isdarwin && export CLICOLOR=1
518
519 # do MacPorts setup on darwin
520 if isdarwin && [[ -d /opt/local ]]; then
521     # Note: PATH gets set in /etc/zprofile on Darwin, so this can't go into
522     # zshenv.
523     PATH="/opt/local/bin:/opt/local/sbin:$PATH"
524     MANPATH="/opt/local/share/man:$MANPATH"
525 fi
526 # do Fink setup on darwin
527 isdarwin && xsource /sw/bin/init.sh
528
529 # completion functions go to $HOME/.zsh/completion.d
530 # function files may be put into $HOME/.zsh/functions.d, from where they
531 # will be automatically autoloaded.
532 if [[ -n "$BROKEN_COMPLETION_DIR" ]] ; then
533     print 'Warning: not setting completion directories because broken files have been found.' >&2
534 else
535     [[ -d $HOME/.zsh/completion.d ]] && fpath=( $fpath $HOME/.zsh/completion.d )
536     if [[ -d $HOME/.zsh/functions.d ]] ; then
537         fdir="$HOME/.zsh/functions.d"
538         fpath=( ${fdir} ${fdir}/**/*(/N) ${fpath} )
539         for func in ${fdir}/**/[^_]*[^~](N.) ; do
540             zrcautoload ${func:t}
541         done
542         unset fdir
543     fi
544 fi
545
546 # automatically remove duplicates from these arrays
547 typeset -U path cdpath fpath manpath
548 # }}}
549
550 # {{{ keybindings
551 if [[ "$TERM" != emacs ]] ; then
552     [[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
553     [[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
554     [[ -z "$terminfo[kend]"  ]] || bindkey -M emacs "$terminfo[kend]"  end-of-line
555     [[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
556     [[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
557     [[ -z "$terminfo[kend]"  ]] || bindkey -M vicmd "$terminfo[kend]"  vi-end-of-line
558     [[ -z "$terminfo[cuu1]"  ]] || bindkey -M viins "$terminfo[cuu1]"  vi-up-line-or-history
559     [[ -z "$terminfo[cuf1]"  ]] || bindkey -M viins "$terminfo[cuf1]"  vi-forward-char
560     [[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
561     [[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
562     [[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
563     [[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char
564     # ncurses stuff:
565     [[ "$terminfo[kcuu1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
566     [[ "$terminfo[kcud1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
567     [[ "$terminfo[kcuf1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
568     [[ "$terminfo[kcub1]" == $'\eO'* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
569     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
570     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M viins "${terminfo[kend]/O/[}"  end-of-line
571     [[ "$terminfo[khome]" == $'\eO'* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
572     [[ "$terminfo[kend]"  == $'\eO'* ]] && bindkey -M emacs "${terminfo[kend]/O/[}"  end-of-line
573 fi
574
575 ## keybindings (run 'bindkeys' for details, more details via man zshzle)
576 # use emacs style per default:
577 bindkey -e
578 # use vi style:
579 # bindkey -v
580
581 #if [[ "$TERM" == screen ]] ; then
582 bindkey '\e[1~' beginning-of-line       # home
583 bindkey '\e[4~' end-of-line             # end
584 bindkey '\e[A'  up-line-or-search       # cursor up
585 bindkey '\e[B'  down-line-or-search     # <ESC>-
586
587 bindkey '^xp'   history-beginning-search-backward
588 bindkey '^xP'   history-beginning-search-forward
589 # bindkey -s '^L' "|less\n"             # ctrl-L pipes to less
590 # bindkey -s '^B' " &\n"                # ctrl-B runs it in the background
591 # if terminal type is set to 'rxvt':
592 bindkey '\e[7~' beginning-of-line       # home
593 bindkey '\e[8~' end-of-line             # end
594 #fi
595
596 # insert unicode character
597 # usage example: 'ctrl-x i' 00A7 'ctrl-x i' will give you an ยง
598 # See for example http://unicode.org/charts/ for unicode characters code
599 zrcautoload insert-unicode-char
600 zle -N insert-unicode-char
601 #k# Insert Unicode character
602 bindkey '^Xi' insert-unicode-char
603
604 # just type 'cd ...' to get 'cd ../..'
605 #  rationalise-dot() {
606 #  if [[ $LBUFFER == *.. ]] ; then
607 #    LBUFFER+=/..
608 #  else
609 #    LBUFFER+=.
610 #  fi
611 #  }
612 #  zle -N rationalise-dot
613 #  bindkey . rationalise-dot
614
615 #  bindkey '\eq' push-line-or-edit
616
617 ## toggle the ,. abbreviation feature on/off
618 # NOABBREVIATION: default abbreviation-state
619 #                 0 - enabled (default)
620 #                 1 - disabled
621 NOABBREVIATION=${NOABBREVIATION:-0}
622
623 grml_toggle_abbrev() {
624     if (( ${NOABBREVIATION} > 0 )) ; then
625         NOABBREVIATION=0
626     else
627         NOABBREVIATION=1
628     fi
629 }
630
631 zle -N grml_toggle_abbrev
632 bindkey '^xA' grml_toggle_abbrev
633
634 # add a command line to the shells history without executing it
635 commit-to-history() {
636     print -s ${(z)BUFFER}
637     zle send-break
638 }
639 zle -N commit-to-history
640 bindkey "^x^h" commit-to-history
641
642 # }}}
643
644 # a generic accept-line wrapper {{{
645
646 # This widget can prevent unwanted autocorrections from command-name
647 # to _command-name, rehash automatically on enter and call any number
648 # of builtin and user-defined widgets in different contexts.
649 #
650 # For a broader description, see:
651 # <http://bewatermyfriend.org/posts/2007/12-26.11-50-38-tooltime.html>
652 #
653 # The code is imported from the file 'zsh/functions/accept-line' from
654 # <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>, which
655 # distributed under the same terms as zsh itself.
656
657 # A newly added command will may not be found or will cause false
658 # correction attempts, if you got auto-correction set. By setting the
659 # following style, we force accept-line() to rehash, if it cannot
660 # find the first word on the command line in the $command[] hash.
661 zstyle ':acceptline:*' rehash true
662
663 function Accept-Line() {
664     setopt localoptions noksharrays
665     local -a subs
666     local -xi aldone
667     local sub
668
669     zstyle -a ":acceptline:${alcontext}" actions subs
670
671     (( ${#subs} < 1 )) && return 0
672
673     (( aldone = 0 ))
674     for sub in ${subs} ; do
675         [[ ${sub} == 'accept-line' ]] && sub='.accept-line'
676         zle ${sub}
677
678         (( aldone > 0 )) && break
679     done
680 }
681
682 function Accept-Line-getdefault() {
683     local default_action
684
685     zstyle -s ":acceptline:${alcontext}" default_action default_action
686     case ${default_action} in
687         ((accept-line|))
688             printf ".accept-line"
689             ;;
690         (*)
691             printf ${default_action}
692             ;;
693     esac
694 }
695
696 function accept-line() {
697     setopt localoptions noksharrays
698     local -a cmdline
699     local -x alcontext
700     local buf com fname format msg default_action
701
702     alcontext='default'
703     buf="${BUFFER}"
704     cmdline=(${(z)BUFFER})
705     com="${cmdline[1]}"
706     fname="_${com}"
707
708     zstyle -t ":acceptline:${alcontext}" rehash \
709         && [[ -z ${commands[$com]} ]]           \
710         && rehash
711
712     if    [[ -n ${reswords[(r)$com]} ]] \
713        || [[ -n ${aliases[$com]}     ]] \
714        || [[ -n ${functions[$com]}   ]] \
715        || [[ -n ${builtins[$com]}    ]] \
716        || [[ -n ${commands[$com]}    ]] ; then
717
718         # there is something sensible to execute, just do it.
719         alcontext='normal'
720         zle Accept-Line
721
722         default_action=$(Accept-Line-getdefault)
723         zstyle -T ":acceptline:${alcontext}" call_default \
724             && zle ${default_action}
725         return
726     fi
727
728     if    [[ -o correct              ]] \
729        || [[ -o correctall           ]] \
730        && [[ -n ${functions[$fname]} ]] ; then
731
732         # nothing there to execute but there is a function called
733         # _command_name; a completion widget. Makes no sense to
734         # call it on the commandline, but the correct{,all} options
735         # will ask for it nevertheless, so warn the user.
736         if [[ ${LASTWIDGET} == 'accept-line' ]] ; then
737             # Okay, we warned the user before, he called us again,
738             # so have it his way.
739             alcontext='force'
740             zle Accept-Line
741
742             default_action=$(Accept-Line-getdefault)
743             zstyle -T ":acceptline:${alcontext}" call_default \
744                 && zle ${default_action}
745             return
746         fi
747
748         # prepare warning message for the user, configurable via zstyle.
749         zstyle -s ":acceptline:${alcontext}" compwarnfmt msg
750
751         if [[ -z ${msg} ]] ; then
752             msg="%c will not execute and completion %f exists."
753         fi
754
755         zformat -f msg "${msg}" "c:${com}" "f:${fname}"
756
757         zle -M -- "${msg}"
758         return
759     elif [[ -n ${buf//[$' \t\n']##/} ]] ; then
760         # If we are here, the commandline contains something that is not
761         # executable, which is neither subject to _command_name correction
762         # and is not empty. might be a variable assignment
763         alcontext='misc'
764         zle Accept-Line
765
766         default_action=$(Accept-Line-getdefault)
767         zstyle -T ":acceptline:${alcontext}" call_default \
768             && zle ${default_action}
769         return
770     fi
771
772     # If we got this far, the commandline only contains whitespace, or is empty.
773     alcontext='empty'
774     zle Accept-Line
775
776     default_action=$(Accept-Line-getdefault)
777     zstyle -T ":acceptline:${alcontext}" call_default \
778         && zle ${default_action}
779 }
780
781 zle -N accept-line
782 zle -N Accept-Line
783
784 # }}}
785
786 # power completion - abbreviation expansion {{{
787 # power completion / abbreviation expansion / buffer expansion
788 # see http://zshwiki.org/home/examples/zleiab for details
789 # less risky than the global aliases but powerful as well
790 # just type the abbreviation key and afterwards ',.' to expand it
791 declare -A abk
792 setopt extendedglob
793 setopt interactivecomments
794 abk=(
795 #   key   # value                  (#d additional doc string)
796 #A# start
797     '...'  '../..'
798     '....' '../../..'
799     'BG'   '& exit'
800     'C'    '| wc -l'
801     'G'    '|& grep --color=auto '
802     'H'    '| head'
803     'Hl'   ' --help |& less -r'    #d (Display help in pager)
804     'L'    '| less'
805     'LL'   '|& less -r'
806     'M'    '| most'
807     'N'    '&>/dev/null'           #d (No Output)
808     'R'    '| tr A-z N-za-m'       #d (ROT13)
809     'SL'   '| sort | less'
810     'S'    '| sort -u'
811     'T'    '| tail'
812     'V'    '|& vim -'
813 #A# end
814     'co'   './configure && make && sudo make install'
815 )
816
817 globalias() {
818     local MATCH
819
820     if (( NOABBREVIATION > 0 )) ; then
821         LBUFFER="${LBUFFER},."
822         return 0
823     fi
824
825     matched_chars='[.-|_a-zA-Z0-9]#'
826     LBUFFER=${LBUFFER%%(#m)[.-|_a-zA-Z0-9]#}
827     LBUFFER+=${abk[$MATCH]:-$MATCH}
828 }
829
830 zle -N globalias
831 bindkey ",." globalias
832 # }}}
833
834 # {{{ autoloading
835 zrcautoload zmv    # who needs mmv or rename?
836 zrcautoload history-search-end
837
838 # we don't want to quote/espace URLs on our own...
839 # if autoload -U url-quote-magic ; then
840 #    zle -N self-insert url-quote-magic
841 #    zstyle ':url-quote-magic:*' url-metas '*?[]^()~#{}='
842 # else
843 #    print 'Notice: no url-quote-magic available :('
844 # fi
845 alias url-quote='autoload -U url-quote-magic ; zle -N self-insert url-quote-magic'
846
847 #m# k ESC-h Call \kbd{run-help} for the 1st word on the command line
848 alias run-help >&/dev/null && unalias run-help
849 zrcautoload run-help # use via 'esc-h'
850
851 # completion system
852 if zrcautoload compinit && compinit 2>/dev/null ; then
853     compinit 2>/dev/null || print 'Notice: no compinit available :('
854 else
855     print 'Notice: no compinit available :('
856     function zstyle { }
857     function compdef { }
858 fi
859
860 is4 && zrcautoload zed # use ZLE editor to edit a file or function
861
862 is4 && \
863 for mod in complist deltochar mathfunc ; do
864     zmodload -i zsh/${mod} 2>/dev/null || print "Notice: no ${mod} available :("
865 done
866
867 # autoload zsh modules when they are referenced
868 if is4 ; then
869     tmpargs=(
870         a   stat
871         a   zpty
872         ap  mapfile
873     )
874
875     while (( ${#tmpargs} > 0 )) ; do
876         zmodload -${tmpargs[1]} zsh/${tmpargs[2]} ${tmpargs[2]}
877         shift 2 tmpargs
878     done
879     unset tmpargs
880 fi
881
882 if is4 && zrcautoload insert-files && zle -N insert-files ; then
883     #k# Insert files
884     bindkey "^Xf" insert-files # C-x-f
885 fi
886
887 bindkey ' '   magic-space    # also do history expansion on space
888 #k# Trigger menu-complete
889 bindkey '\ei' menu-complete  # menu completion via esc-i
890
891 # press esc-e for editing command line in $EDITOR or $VISUAL
892 if is4 && zrcautoload edit-command-line && zle -N edit-command-line ; then
893     #k# Edit the current line in \kbd{\$EDITOR}
894     bindkey '\ee' edit-command-line
895 fi
896
897 if is4 && [[ -n ${(k)modules[zsh/complist]} ]] ; then
898     #k# menu selection: pick item but stay in the menu
899     bindkey -M menuselect '\e^M' accept-and-menu-complete
900
901     # accept a completion and try to complete again by using menu
902     # completion; very useful with completing directories
903     # by using 'undo' one's got a simple file browser
904     bindkey -M menuselect '^o' accept-and-infer-next-history
905 fi
906
907 # press "ctrl-e d" to insert the actual date in the form yyyy-mm-dd
908 _bkdate() { BUFFER="$BUFFER$(date '+%F')"; CURSOR=$#BUFFER; }
909 zle -N _bkdate
910
911 #k# Insert a timestamp on the command line (yyyy-mm-dd)
912 bindkey '^Ed' _bkdate
913
914 # press esc-m for inserting last typed word again (thanks to caphuso!)
915 insert-last-typed-word() { zle insert-last-word -- 0 -1 };
916 zle -N insert-last-typed-word;
917
918 #k# Insert last typed word
919 bindkey "\em" insert-last-typed-word
920
921 #k# Shortcut for \kbd{fg<enter>}
922 bindkey -s '^z' "fg\n"
923
924 # run command line as user root via sudo:
925 sudo-command-line() {
926     [[ -z $BUFFER ]] && zle up-history
927     [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
928 }
929 zle -N sudo-command-line
930
931 #k# Put the current command line into a \kbd{sudo} call
932 bindkey "^Os" sudo-command-line
933
934 ### jump behind the first word on the cmdline.
935 ### useful to add options.
936 function jump_after_first_word() {
937     local words
938     words=(${(z)BUFFER})
939
940     if (( ${#words} <= 1 )) ; then
941         CURSOR=${#BUFFER}
942     else
943         CURSOR=${#${words[1]}}
944     fi
945 }
946 zle -N jump_after_first_word
947
948 bindkey '^x1' jump_after_first_word
949
950 # }}}
951
952 # {{{ set some important options
953 # Please update these tags, if you change the umask settings below.
954 #o# r_umask     002
955 #o# r_umaskstr  rwxrwxr-x
956 #o# umask       022
957 #o# umaskstr    rwxr-xr-x
958 (( EUID != 0 )) && umask 002 || umask 022
959
960 # history:
961 setopt append_history       # append history list to the history file (important for multiple parallel zsh sessions!)
962 is4 && setopt SHARE_HISTORY # import new commands from the history file also in other zsh-session
963 setopt extended_history     # save each command's beginning timestamp and the duration to the history file
964 is4 && setopt histignorealldups # If  a  new  command  line being added to the history
965                             # list duplicates an older one, the older command is removed from the list
966 setopt histignorespace      # remove command lines from the history list when
967                             # the first character on the line is a space
968 setopt auto_cd              # if a command is issued that can't be executed as a normal command,
969                             # and the command is the name of a directory, perform the cd command to that directory
970 setopt extended_glob        # in order to use #, ~ and ^ for filename generation
971                             # grep word *~(*.gz|*.bz|*.bz2|*.zip|*.Z) ->
972                             # -> searches for word not in compressed files
973                             # don't forget to quote '^', '~' and '#'!
974 setopt longlistjobs         # display PID when suspending processes as well
975 setopt notify               # report the status of backgrounds jobs immediately
976 setopt hash_list_all        # Whenever a command completion is attempted, make sure \
977                             # the entire command path is hashed first.
978 setopt completeinword       # not just at the end
979 setopt nohup                # and don't kill them, either
980 setopt auto_pushd           # make cd push the old directory onto the directory stack.
981 setopt nonomatch            # try to avoid the 'zsh: no matches found...'
982 setopt nobeep               # avoid "beep"ing
983 setopt pushd_ignore_dups    # don't push the same dir twice.
984 setopt noglobdots           # * shouldn't match dotfiles. ever.
985
986 MAILCHECK=30       # mailchecks
987 REPORTTIME=5       # report about cpu-/system-/user-time of command if running longer than 5 seconds
988 watch=(notme root) # watch for everyone but me and root
989
990 # only slash should be considered as a word separator:
991 slash-backward-kill-word() {
992     local WORDCHARS="${WORDCHARS:s@/@}"
993     # zle backward-word
994     zle backward-kill-word
995 }
996 zle -N slash-backward-kill-word
997
998 #k# Kill everything in a word up to its last \kbd{/}
999 bindkey '\ev' slash-backward-kill-word
1000
1001 # }}}
1002
1003 # {{{ history
1004
1005 ZSHDIR=$HOME/.zsh
1006
1007 #v#
1008 HISTFILE=$HOME/.zsh_history
1009 isgrmlcd && HISTSIZE=500  || HISTSIZE=5000
1010 isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000 # useful for setopt append_history
1011
1012 # }}}
1013
1014 # dirstack handling {{{
1015
1016 DIRSTACKSIZE=${DIRSTACKSIZE:-20}
1017 DIRSTACKFILE=${DIRSTACKFILE:-${HOME}/.zdirs}
1018
1019 if [[ -f ${DIRSTACKFILE} ]] && [[ ${#dirstack[*]} -eq 0 ]] ; then
1020     dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
1021     # "cd -" won't work after login by just setting $OLDPWD, so
1022     [[ -d $dirstack[0] ]] && cd $dirstack[0] && cd $OLDPWD
1023 fi
1024
1025 chpwd() {
1026     if is42 ; then
1027         builtin print -l ${(u)dirstack} >! ${DIRSTACKFILE}
1028     else
1029         uprint dirstack >! ${DIRSTACKFILE}
1030     fi
1031 }
1032
1033 # }}}
1034
1035 # {{{ display battery status on right side of prompt via running 'BATTERY=1 zsh'
1036 if [[ $BATTERY -gt 0 ]] ; then
1037     if ! check_com -c acpi ; then
1038         BATTERY=0
1039     fi
1040 fi
1041
1042 battery() {
1043 if [[ $BATTERY -gt 0 ]] ; then
1044     PERCENT="${${"$(acpi 2>/dev/null)"}/(#b)[[:space:]]#Battery <->: [^0-9]##, (<->)%*/${match[1]}}"
1045     if [[ -z "$PERCENT" ]] ; then
1046         PERCENT='acpi not present'
1047     else
1048         if [[ "$PERCENT" -lt 20 ]] ; then
1049             PERCENT="warning: ${PERCENT}%%"
1050         else
1051             PERCENT="${PERCENT}%%"
1052         fi
1053     fi
1054 fi
1055 }
1056 # }}}
1057
1058 # set colors for use in prompts {{{
1059 if zrcautoload colors && colors 2>/dev/null ; then
1060     BLUE="%{${fg[blue]}%}"
1061     RED="%{${fg_bold[red]}%}"
1062     GREEN="%{${fg[green]}%}"
1063     CYAN="%{${fg[cyan]}%}"
1064     MAGENTA="%{${fg[magenta]}%}"
1065     YELLOW="%{${fg[yellow]}%}"
1066     WHITE="%{${fg[white]}%}"
1067     NO_COLOUR="%{${reset_color}%}"
1068 else
1069     BLUE=$'%{\e[1;34m%}'
1070     RED=$'%{\e[1;31m%}'
1071     GREEN=$'%{\e[1;32m%}'
1072     CYAN=$'%{\e[1;36m%}'
1073     WHITE=$'%{\e[1;37m%}'
1074     MAGENTA=$'%{\e[1;35m%}'
1075     YELLOW=$'%{\e[1;33m%}'
1076     NO_COLOUR=$'%{\e[0m%}'
1077 fi
1078
1079 # }}}
1080
1081 # gather version control information for inclusion in a prompt {{{
1082
1083 if ! is41 ; then
1084     # Be quiet about version problems in grml's zshrc as the user cannot disable
1085     # loading vcs_info() as it is *in* the zshrc - as you can see. :-)
1086     # Just unset most probable variables and disable vcs_info altogether.
1087     local -i i
1088     for i in {0..9} ; do
1089         unset VCS_INFO_message_${i}_
1090     done
1091     zstyle ':vcs_info:*' enable false
1092 fi
1093
1094 # The following code is imported from the file 'zsh/functions/vcs_info'
1095 # from <http://ft.bewatermyfriend.org/comp/zsh/zsh-dotfiles.tar.bz2>,
1096 # which distributed under the same terms as zsh itself.
1097
1098 # we will be using two variables, so let the code know now.
1099 zstyle ':vcs_info:*' max-exports 2
1100
1101 # vcs_info() documentation:
1102 #{{{
1103 # REQUIREMENTS:
1104 #{{{
1105 #     This functionality requires zsh version >= 4.1.*.
1106 #}}}
1107 #
1108 # LOADING:
1109 #{{{
1110 # To load vcs_info(), copy this file to your $fpath[] and do:
1111 #   % autoload -Uz vcs_info && vcs_info
1112 #
1113 # To work, vcs_info() needs 'setopt prompt_subst' in your setup.
1114 #}}}
1115 #
1116 # QUICKSTART:
1117 #{{{
1118 # To get vcs_info() working quickly (including colors), you can do the
1119 # following (assuming, you loaded vcs_info() properly - see above):
1120 #
1121 # % RED=$'%{\e[31m%}'
1122 # % GR=$'%{\e[32m%}'
1123 # % MA=$'%{\e[35m%}'
1124 # % YE=$'%{\e[33m%}'
1125 # % NC=$'%{\e[0m%}'
1126 #
1127 # % zstyle ':vcs_info:*' actionformats \
1128 #       "${MA}(${NC}%s${MA})${YE}-${MA}[${GR}%b${YE}|${RED}%a${MA}]${NC} "
1129 #
1130 # % zstyle ':vcs_info:*' formats       \
1131 #       "${MA}(${NC}%s${MA})${Y}-${MA}[${GR}%b${MA}]${NC}%} "
1132 #
1133 # % zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YE}%r"
1134 #
1135 # % precmd () { vcs_info }
1136 # % PS1='${MA}[${GR}%n${MA}] ${MA}(${RED}%!${MA}) ${YE}%3~ ${VCS_INFO_message_0_}${NC}%# '
1137 #
1138 # Obviously, the las two lines are there for demonstration: You need to
1139 # call vcs_info() from your precmd() function (see 'SPECIAL FUNCTIONS' in
1140 # 'man zshmisc'). Once that is done you need a *single* quoted
1141 # '${VCS_INFO_message_0_}' in your prompt.
1142 #
1143 # Now call the 'vcs_info_printsys' utility from the command line:
1144 #
1145 # % vcs_info_printsys
1146 # # list of supported version control backends:
1147 # # disabled systems are prefixed by a hash sign (#)
1148 # git
1149 # hg
1150 # bzr
1151 # darcs
1152 # svk
1153 # mtn
1154 # svn
1155 # cvs
1156 # cdv
1157 # tla
1158 # # flavours (cannot be used in the disable style; they
1159 # # are disabled with their master [git-svn -> git]):
1160 # git-p4
1161 # git-svn
1162 #
1163 # Ten version control backends as you can see. You may not want all
1164 # of these. Because there is no point in running the code to detect
1165 # systems you do not use. ever. So, there is a way to disable some
1166 # backends altogether:
1167 #
1168 # % zstyle ':vcs_info:*' disable bzr cdv darcs mtn svk tla
1169 #
1170 # If you rerun 'vcs_info_printsys' now, you will see the backends listed
1171 # in the 'disable' style marked as diabled by a hash sign. That means the
1172 # detection of these systems is skipped *completely*. No wasted time there.
1173 #
1174 # For more control, read the reference below.
1175 #}}}
1176 #
1177 # CONFIGURATION:
1178 #{{{
1179 # The vcs_info() feature can be configured via zstyle.
1180 #
1181 # First, the context in which we are working:
1182 #       :vcs_info:<vcs-string>:<user-context>
1183 #
1184 # ...where <vcs-string> is one of:
1185 #   - git, git-svn, git-p4, hg, darcs, bzr, cdv, mtn, svn, cvs, svk or tla.
1186 #
1187 # ...and <user-context> is a freely configurable string, assignable by the
1188 # user as the first argument to vcs_info() (see its description below).
1189 #
1190 # There is are three special values for <vcs-string>: The first is named
1191 # 'init', that is in effect as long as there was no decision what vcs
1192 # backend to use. The second is 'preinit; it is used *before* vcs_info()
1193 # is run, when initializing the data exporting variables. The third
1194 # special value is 'formats' and is used by the 'vcs_info_lastmsg' for
1195 # looking up its styles.
1196 #
1197 # There are two pre-defined values for <user-context>:
1198 #   default  - the one used if none is specified
1199 #   command  - used by vcs_info_lastmsg to lookup its styles.
1200 #
1201 # You may *not* use 'print_systems_' as a user-context string, because it
1202 # is used internally.
1203 #
1204 # You can of course use ':vcs_info:*' to match all VCSs in all
1205 # user-contexts at once.
1206 #
1207 # Another special context is 'formats', which is used by the
1208 # vcs_info_lastmsg() utility function (see below).
1209 #
1210 #
1211 # This is a description of all styles, that are looked up:
1212 #   formats             - A list of formats, used when actionformats is not
1213 #                         used (which is most of the time).
1214 #   actionformats       - A list of formats, used if a there is a special
1215 #                         action going on in your current repository;
1216 #                         (like an interactive rebase or a merge conflict)
1217 #   branchformat        - Some backends replace %b in the formats and
1218 #                         actionformats styles above, not only by a branch
1219 #                         name but also by a revision number. This style
1220 #                         let's you modify how that string should look like.
1221 #   nvcsformats         - These "formats" are exported, when we didn't detect
1222 #                         a version control system for the current directory.
1223 #                         This is useful, if you want vcs_info() to completely
1224 #                         take over the generation of your prompt.
1225 #                         You would do something like
1226 #                           PS1='${VCS_INFO_message_0_}'
1227 #                         to accomplish that.
1228 #   max-exports         - Defines the maximum number if VCS_INFO_message_*_
1229 #                         variables vcs_info() will export.
1230 #   enable              - Checked in the 'init' context. If set to false,
1231 #                         vcs_info() will do nothing.
1232 #   disable             - Provide a list of systems, you don't want
1233 #                         the vcs_info() to check for repositories
1234 #                         (checked in the 'init' context, too).
1235 #   disable-patterns    - A list of patterns that are checked against $PWD.
1236 #                         If the pattern matches, vcs_info will be disabled.
1237 #                         Say, ~/.zsh is a directory under version control,
1238 #                         in which you do not want vcs_info to be active, do:
1239 #                         zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh+(|/*)"
1240 #   use-simple          - If there are two different ways of gathering
1241 #                         information, you can select the simpler one
1242 #                         by setting this style to true; the default
1243 #                         is to use the not-that-simple code, which is
1244 #                         potentially a lot slower but might be more
1245 #                         accurate in all possible cases.
1246 #   use-prompt-escapes  - determines if we assume that the assembled
1247 #                         string from vcs_info() includes prompt escapes.
1248 #                         (Used by vcs_info_lastmsg().
1249 #
1250 # The use-simple style is only available for the bzr backend.
1251 #
1252 # The default values for these in all contexts are:
1253 #   formats             " (%s)-[%b|%a]-"
1254 #   actionformats       " (%s)-[%b]-"
1255 #   branchformat        "%b:%r" (for bzr, svn and svk)
1256 #   nvcsformats         ""
1257 #   max-exports         2
1258 #   enable              true
1259 #   disable             (empty list)
1260 #   disable-patterns    (empty list)
1261 #   use-simple          false
1262 #   use-prompt-escapes  true
1263 #
1264 #
1265 # In normal formats and actionformats, the following replacements
1266 # are done:
1267 #   %s  - The vcs in use (git, hg, svn etc.)
1268 #   %b  - Information about the current branch.
1269 #   %a  - An identifier, that describes the action.
1270 #         Only makes sense in actionformats.
1271 #   %R  - base directory of the repository.
1272 #   %r  - repository name
1273 #         If %R is '/foo/bar/repoXY', %r is 'repoXY'.
1274 #   %S  - subdirectory within a repository. if $PWD is
1275 #         '/foo/bar/reposXY/beer/tasty', %S is 'beer/tasty'.
1276 #
1277 #
1278 # In branchformat these replacements are done:
1279 #   %b  - the branch name
1280 #   %r  - the current revision number
1281 #
1282 # Not all vcs backends have to support all replacements.
1283 # nvcsformat does not perform *any* replacements. It is just a string.
1284 #}}}
1285 #
1286 # ODDITIES:
1287 #{{{
1288 # If you want to use the %b (bold off) prompt expansion in 'formats', which
1289 # expands %b itself, use %%b. That will cause the vcs_info() expansion to
1290 # replace %%b with %b. So zsh's prompt expansion mechanism can handle it.
1291 # Similarly, to hand down %b from branchformat, use %%%%b. Sorry for this
1292 # inconvenience, but it cannot be easily avoided. Luckily we do not clash
1293 # with a lot of prompt expansions and this only needs to be done for those.
1294 # See 'man zshmisc' for details about EXPANSION OF PROMPT SEQUENCES.
1295 #}}}
1296 #
1297 # FUNCTION DESCRIPTIONS (public API):
1298 #{{{
1299 #   vcs_info()
1300 #       The main function, that runs all backends and assembles
1301 #       all data into ${VCS_INFO_message_*_}. This is the function
1302 #       you want to call from precmd() if you want to include
1303 #       up-to-date information in your prompt (see VARIABLE
1304 #       DESCRIPTION below).
1305 #
1306 #   vcs_info_printsys()
1307 #       Prints a list of all supported version control systems.
1308 #       Useful to find out possible contexts (and which of them are enabled)
1309 #       or values for the 'disable' style.
1310 #
1311 #   vcs_info_lastmsg()
1312 #       Outputs the last ${VCS_INFO_message_*_} value. Takes into account
1313 #       the value of the use-prompt-escapes style in ':vcs_info:formats'.
1314 #       It also only prints max-exports values.
1315 #
1316 # All functions named VCS_INFO_* are for internal use only.
1317 #}}}
1318 #
1319 # VARIABLE DESCRIPTION:
1320 #{{{
1321 #   ${VCS_INFO_message_N_}    (Note the trailing underscore)
1322 #       Where 'N' is an integer, eg: VCS_INFO_message_0_
1323 #       These variables are the storage for the informational message the
1324 #       last vcs_info() call has assembled. These are strongly connected
1325 #       to the formats, actionformats and nvcsformats styles described
1326 #       above. Those styles are lists. the first member of that list gets
1327 #       expanded into ${VCS_INFO_message_0_}, the second into
1328 #       ${VCS_INFO_message_1_} and the Nth into ${VCS_INFO_message_N-1_}.
1329 #       These parameters are exported into the environment.
1330 #       (See the max-exports style above.)
1331 #}}}
1332 #
1333 # EXAMPLES:
1334 #{{{
1335 #   Don't use vcs_info at all (even though it's in your prompt):
1336 #   % zstyle ':vcs_info:*' enable false
1337 #
1338 #   Disable the backends for bzr and svk:
1339 #   % zstyle ':vcs_info:*' disable bzr svk
1340 #
1341 #   Provide a special formats for git:
1342 #   % zstyle ':vcs_info:git:*' formats       ' GIT, BABY! [%b]'
1343 #   % zstyle ':vcs_info:git:*' actionformats ' GIT ACTION! [%b|%a]'
1344 #
1345 #   Use the quicker bzr backend (if you do, please report if it does
1346 #   the-right-thing[tm] - thanks):
1347 #   % zstyle ':vcs_info:bzr:*' use-simple true
1348 #
1349 #   Display the revision number in yellow for bzr and svn:
1350 #   % zstyle ':vcs_info:(svn|bzr):*' branchformat '%b%{'${fg[yellow]}'%}:%r'
1351 #
1352 # If you want colors, make sure you enclose the color codes in %{...%},
1353 # if you want to use the string provided by vcs_info() in prompts.
1354 #
1355 # Here is how to print the vcs infomation as a command:
1356 #   % alias vcsi='vcs_info command; vcs_info_lastmsg'
1357 #
1358 #   This way, you can even define different formats for output via
1359 #   vcs_info_lastmsg() in the ':vcs_info:command:*' namespace.
1360 #}}}
1361 #}}}
1362 # utilities
1363 VCS_INFO_adjust () { #{{{
1364     [[ -n ${vcs_comm[overwrite_name]} ]] && vcs=${vcs_comm[overwrite_name]}
1365     return 0
1366 }
1367 # }}}
1368 VCS_INFO_check_com () { #{{{
1369     (( ${+commands[$1]} )) && [[ -x ${commands[$1]} ]] && return 0
1370     return 1
1371 }
1372 # }}}
1373 VCS_INFO_formats () { # {{{
1374     setopt localoptions noksharrays
1375     local action=$1 branch=$2 base=$3
1376     local msg
1377     local -i i
1378
1379     if [[ -n ${action} ]] ; then
1380         zstyle -a ":vcs_info:${vcs}:${usercontext}" actionformats msgs
1381         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b|%a]-'
1382     else
1383         zstyle -a ":vcs_info:${vcs}:${usercontext}" formats msgs
1384         (( ${#msgs} < 1 )) && msgs[1]=' (%s)-[%b]-'
1385     fi
1386
1387     (( ${#msgs} > maxexports )) && msgs[$(( maxexports + 1 )),-1]=()
1388     for i in {1..${#msgs}} ; do
1389         zformat -f msg ${msgs[$i]}                      \
1390                         a:${action}                     \
1391                         b:${branch}                     \
1392                         r:${base:t}                     \
1393                         s:${vcs}                        \
1394                         R:${base}                       \
1395                         S:"$(VCS_INFO_reposub ${base})"
1396         msgs[$i]=${msg}
1397     done
1398     return 0
1399 }
1400 # }}}
1401 VCS_INFO_maxexports () { #{{{
1402     zstyle -s ":vcs_info:${vcs}:${usercontext}" "max-exports" maxexports || maxexports=2
1403     if [[ ${maxexports} != <-> ]] || (( maxexports < 1 )); then
1404         printf 'vcs_info(): expecting numeric arg >= 1 for max-exports (got %s).\n' ${maxexports}
1405         printf 'Defaulting to 2.\n'
1406         maxexports=2
1407     fi
1408 }
1409 # }}}
1410 VCS_INFO_nvcsformats () { #{{{
1411     setopt localoptions noksharrays
1412     local c v
1413
1414     if [[ $1 == 'preinit' ]] ; then
1415         c=default
1416         v=preinit
1417     fi
1418     zstyle -a ":vcs_info:${v:-$vcs}:${c:-$usercontext}" nvcsformats msgs
1419     (( ${#msgs} > maxexports )) && msgs[${maxexports},-1]=()
1420 }
1421 # }}}
1422 VCS_INFO_realpath () { #{{{
1423     # a portable 'readlink -f'
1424     # forcing a subshell, to ensure chpwd() is not removed
1425     # from the calling shell (if VCS_INFO_realpath() is called
1426     # manually).
1427     (
1428         (( ${+functions[chpwd]} )) && unfunction chpwd
1429         setopt chaselinks
1430         cd $1 2>/dev/null && pwd
1431     )
1432 }
1433 # }}}
1434 VCS_INFO_reposub () { #{{{
1435     setopt localoptions extendedglob
1436     local base=${1%%/##}
1437
1438     [[ ${PWD} == ${base}/* ]] || {
1439         printf '.'
1440         return 1
1441     }
1442     printf '%s' ${PWD#$base/}
1443     return 0
1444 }
1445 # }}}
1446 VCS_INFO_set () { #{{{
1447     setopt localoptions noksharrays
1448     local -i i j
1449
1450     if [[ $1 == '--clear' ]] ; then
1451         for i in {0..9} ; do
1452             unset VCS_INFO_message_${i}_
1453         done
1454     fi
1455     if [[ $1 == '--nvcs' ]] ; then
1456         [[ $2 == 'preinit' ]] && (( maxexports == 0 )) && (( maxexports = 1 ))
1457         for i in {0..$((maxexports - 1))} ; do
1458             typeset -gx VCS_INFO_message_${i}_=
1459         done
1460         VCS_INFO_nvcsformats $2
1461     fi
1462
1463     (( ${#msgs} - 1 < 0 )) && return 0
1464     for i in {0..$(( ${#msgs} - 1 ))} ; do
1465         (( j = i + 1 ))
1466         typeset -gx VCS_INFO_message_${i}_=${msgs[$j]}
1467     done
1468     return 0
1469 }
1470 # }}}
1471 # information gathering
1472 VCS_INFO_bzr_get_data () { # {{{
1473     setopt localoptions noksharrays
1474     local bzrbase bzrbr
1475     local -a bzrinfo
1476
1477     if zstyle -t ":vcs_info:${vcs}:${usercontext}" "use-simple" ; then
1478         bzrbase=${vcs_comm[basedir]}
1479         bzrinfo[2]=${bzrbase:t}
1480         if [[ -f ${bzrbase}/.bzr/branch/last-revision ]] ; then
1481             bzrinfo[1]=$(< ${bzrbase}/.bzr/branch/last-revision)
1482             bzrinfo[1]=${${bzrinfo[1]}%% *}
1483         fi
1484     else
1485         bzrbase=${${(M)${(f)"$( bzr info )"}:# ##branch\ root:*}/*: ##/}
1486         bzrinfo=( ${${${(M)${(f)"$( bzr version-info )"}:#(#s)(revno|branch-nick)*}/*: /}/*\//} )
1487         bzrbase="$(VCS_INFO_realpath ${bzrbase})"
1488     fi
1489
1490     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat bzrbr || bzrbr="%b:%r"
1491     zformat -f bzrbr "${bzrbr}" "b:${bzrinfo[2]}" "r:${bzrinfo[1]}"
1492     VCS_INFO_formats '' "${bzrbr}" "${bzrbase}"
1493     return 0
1494 }
1495 # }}}
1496 VCS_INFO_cdv_get_data () { # {{{
1497     local cdvbase
1498
1499     cdvbase=${vcs_comm[basedir]}
1500     VCS_INFO_formats '' "${cdvbase:t}" "${cdvbase}"
1501     return 0
1502 }
1503 # }}}
1504 VCS_INFO_cvs_get_data () { # {{{
1505     local cvsbranch cvsbase basename
1506
1507     cvsbase="."
1508     while [[ -d "${cvsbase}/../CVS" ]]; do
1509         cvsbase="${cvsbase}/.."
1510     done
1511     cvsbase="$(VCS_INFO_realpath ${cvsbase})"
1512     cvsbranch=$(< ./CVS/Repository)
1513     basename=${cvsbase:t}
1514     cvsbranch=${cvsbranch##${basename}/}
1515     [[ -z ${cvsbranch} ]] && cvsbranch=${basename}
1516     VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}"
1517     return 0
1518 }
1519 # }}}
1520 VCS_INFO_darcs_get_data () { # {{{
1521     local darcsbase
1522
1523     darcsbase=${vcs_comm[basedir]}
1524     VCS_INFO_formats '' "${darcsbase:t}" "${darcsbase}"
1525     return 0
1526 }
1527 # }}}
1528 VCS_INFO_git_getaction () { #{{{
1529     local gitaction='' gitdir=$1
1530     local tmp
1531
1532     for tmp in "${gitdir}/rebase-apply" \
1533                "${gitdir}/rebase"       \
1534                "${gitdir}/../.dotest" ; do
1535         if [[ -d ${tmp} ]] ; then
1536             if   [[ -f "${tmp}/rebasing" ]] ; then
1537                 gitaction="rebase"
1538             elif [[ -f "${tmp}/applying" ]] ; then
1539                 gitaction="am"
1540             else
1541                 gitaction="am/rebase"
1542             fi
1543             printf '%s' ${gitaction}
1544             return 0
1545         fi
1546     done
1547
1548     for tmp in "${gitdir}/rebase-merge/interactive" \
1549                "${gitdir}/.dotest-merge/interactive" ; do
1550         if [[ -f "${tmp}" ]] ; then
1551             printf '%s' "rebase-i"
1552             return 0
1553         fi
1554     done
1555
1556     for tmp in "${gitdir}/rebase-merge" \
1557                "${gitdir}/.dotest-merge" ; do
1558         if [[ -d "${tmp}" ]] ; then
1559             printf '%s' "rebase-m"
1560             return 0
1561         fi
1562     done
1563
1564     if [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1565         printf '%s' "merge"
1566         return 0
1567     fi
1568
1569     if [[ -f "${gitdir}/BISECT_LOG" ]] ; then
1570         printf '%s' "bisect"
1571         return 0
1572     fi
1573     return 1
1574 }
1575 # }}}
1576 VCS_INFO_git_getbranch () { #{{{
1577     local gitbranch gitdir=$1
1578     local gitsymref='git symbolic-ref HEAD'
1579
1580     if    [[ -d "${gitdir}/rebase-apply" ]] \
1581        || [[ -d "${gitdir}/rebase" ]]       \
1582        || [[ -d "${gitdir}/../.dotest" ]]   \
1583        || [[ -f "${gitdir}/MERGE_HEAD" ]] ; then
1584         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1585         [[ -z ${gitbranch} ]] && [[ -r ${gitdir}/rebase-apply/head-name ]] \
1586             && gitbranch="$(< ${gitdir}/rebase-apply/head-name)"
1587
1588     elif   [[ -f "${gitdir}/rebase-merge/interactive" ]] \
1589         || [[ -d "${gitdir}/rebase-merge" ]] ; then
1590         gitbranch="$(< ${gitdir}/rebase-merge/head-name)"
1591
1592     elif   [[ -f "${gitdir}/.dotest-merge/interactive" ]] \
1593         || [[ -d "${gitdir}/.dotest-merge" ]] ; then
1594         gitbranch="$(< ${gitdir}/.dotest-merge/head-name)"
1595
1596     else
1597         gitbranch="$(${(z)gitsymref} 2> /dev/null)"
1598
1599         if [[ $? -ne 0 ]] ; then
1600             gitbranch="$(git describe --exact-match HEAD 2>/dev/null)"
1601
1602             if [[ $? -ne 0 ]] ; then
1603                 gitbranch="${${"$(< $gitdir/HEAD)"}[1,7]}..."
1604             fi
1605         fi
1606     fi
1607
1608     printf '%s' "${gitbranch##refs/heads/}"
1609     return 0
1610 }
1611 # }}}
1612 VCS_INFO_git_get_data () { # {{{
1613     setopt localoptions extendedglob
1614     local gitdir gitbase gitbranch gitaction
1615
1616     gitdir=${vcs_comm[gitdir]}
1617     gitbranch="$(VCS_INFO_git_getbranch ${gitdir})"
1618
1619     if [[ -z ${gitdir} ]] || [[ -z ${gitbranch} ]] ; then
1620         return 1
1621     fi
1622
1623     VCS_INFO_adjust
1624     gitaction="$(VCS_INFO_git_getaction ${gitdir})"
1625     gitbase=${PWD%/${$( git rev-parse --show-prefix )%/##}}
1626     VCS_INFO_formats "${gitaction}" "${gitbranch}" "${gitbase}"
1627     return 0
1628 }
1629 # }}}
1630 VCS_INFO_hg_get_data () { # {{{
1631     local hgbranch hgbase file
1632
1633     hgbase=${vcs_comm[basedir]}
1634
1635     file="${hgbase}/.hg/branch"
1636     if [[ -r ${file} ]] ; then
1637         hgbranch=$(< ${file})
1638     else
1639         hgbranch='default'
1640     fi
1641
1642     VCS_INFO_formats '' "${hgbranch}" "${hgbase}"
1643     return 0
1644 }
1645 # }}}
1646 VCS_INFO_mtn_get_data () { # {{{
1647     local mtnbranch mtnbase
1648
1649     mtnbase=${vcs_comm[basedir]}
1650     mtnbranch=${${(M)${(f)"$( mtn status )"}:#(#s)Current branch:*}/*: /}
1651     VCS_INFO_formats '' "${mtnbranch}" "${mtnbase}"
1652     return 0
1653 }
1654 # }}}
1655 VCS_INFO_svk_get_data () { # {{{
1656     local svkbranch svkbase
1657
1658     svkbase=${vcs_comm[basedir]}
1659     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svkbranch || svkbranch="%b:%r"
1660     zformat -f svkbranch "${svkbranch}" "b:${vcs_comm[branch]}" "r:${vcs_comm[revision]}"
1661     VCS_INFO_formats '' "${svkbranch}" "${svkbase}"
1662     return 0
1663 }
1664 # }}}
1665 VCS_INFO_svn_get_data () { # {{{
1666     setopt localoptions noksharrays
1667     local svnbase svnbranch
1668     local -a svninfo
1669
1670     svnbase="."
1671     while [[ -d "${svnbase}/../.svn" ]]; do
1672         svnbase="${svnbase}/.."
1673     done
1674     svnbase="$(VCS_INFO_realpath ${svnbase})"
1675     svninfo=( ${${${(M)${(f)"$( svn info )"}:#(#s)(URL|Revision)*}/*: /}/*\//} )
1676
1677     zstyle -s ":vcs_info:${vcs}:${usercontext}" branchformat svnbranch || svnbranch="%b:%r"
1678     zformat -f svnbranch "${svnbranch}" "b:${svninfo[1]}" "r:${svninfo[2]}"
1679     VCS_INFO_formats '' "${svnbranch}" "${svnbase}"
1680     return 0
1681 }
1682 # }}}
1683 VCS_INFO_tla_get_data () { # {{{
1684     local tlabase tlabranch
1685
1686     tlabase="$(VCS_INFO_realpath ${vcs_comm[basedir]})"
1687     # tree-id gives us something like 'foo@example.com/demo--1.0--patch-4', so:
1688     tlabranch=${${"$( tla tree-id )"}/*\//}
1689     VCS_INFO_formats '' "${tlabranch}" "${tlabase}"
1690     return 0
1691 }
1692 # }}}
1693 # detection
1694 VCS_INFO_detect_by_dir() { #{{{
1695     local dirname=$1
1696     local basedir="." realbasedir
1697
1698     realbasedir="$(VCS_INFO_realpath ${basedir})"
1699     while [[ ${realbasedir} != '/' ]]; do
1700         if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
1701             [[ -d ${basedir}/${dirname} ]] && \
1702             [[ -e ${basedir}/${dirname}/${vcs_comm[detect_need_file]} ]] && \
1703                 break
1704         else
1705             [[ -d ${basedir}/${dirname} ]] && break
1706         fi
1707
1708         basedir=${basedir}/..
1709         realbasedir="$(VCS_INFO_realpath ${basedir})"
1710     done
1711
1712     [[ ${realbasedir} == "/" ]] && return 1
1713     vcs_comm[basedir]=${realbasedir}
1714     return 0
1715 }
1716 # }}}
1717 VCS_INFO_bzr_detect() { #{{{
1718     VCS_INFO_check_com bzr || return 1
1719     vcs_comm[detect_need_file]=branch/format
1720     VCS_INFO_detect_by_dir '.bzr'
1721     return $?
1722 }
1723 # }}}
1724 VCS_INFO_cdv_detect() { #{{{
1725     VCS_INFO_check_com cdv || return 1
1726     vcs_comm[detect_need_file]=format
1727     VCS_INFO_detect_by_dir '.cdv'
1728     return $?
1729 }
1730 # }}}
1731 VCS_INFO_cvs_detect() { #{{{
1732     VCS_INFO_check_com svn || return 1
1733     [[ -d "./CVS" ]] && [[ -r "./CVS/Repository" ]] && return 0
1734     return 1
1735 }
1736 # }}}
1737 VCS_INFO_darcs_detect() { #{{{
1738     VCS_INFO_check_com darcs || return 1
1739     vcs_comm[detect_need_file]=format
1740     VCS_INFO_detect_by_dir '_darcs'
1741     return $?
1742 }
1743 # }}}
1744 VCS_INFO_git_detect() { #{{{
1745     if VCS_INFO_check_com git && git rev-parse --is-inside-work-tree &> /dev/null ; then
1746         vcs_comm[gitdir]="$(git rev-parse --git-dir 2> /dev/null)" || return 1
1747         if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
1748         elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
1749         return 0
1750     fi
1751     return 1
1752 }
1753 # }}}
1754 VCS_INFO_hg_detect() { #{{{
1755     VCS_INFO_check_com hg || return 1
1756     vcs_comm[detect_need_file]=store
1757     VCS_INFO_detect_by_dir '.hg'
1758     return $?
1759 }
1760 # }}}
1761 VCS_INFO_mtn_detect() { #{{{
1762     VCS_INFO_check_com mtn || return 1
1763     vcs_comm[detect_need_file]=revision
1764     VCS_INFO_detect_by_dir '_MTN'
1765     return $?
1766 }
1767 # }}}
1768 VCS_INFO_svk_detect() { #{{{
1769     setopt localoptions noksharrays extendedglob
1770     local -a info
1771     local -i fhash
1772     fhash=0
1773
1774     VCS_INFO_check_com svk || return 1
1775     [[ -f ~/.svk/config ]] || return 1
1776
1777     # This detection function is a bit different from the others.
1778     # We need to read svk's config file to detect a svk repository
1779     # in the first place. Therefore, we'll just proceed and read
1780     # the other information, too. This is more then any of the
1781     # other detections do but this takes only one file open for
1782     # svk at most. VCS_INFO_svk_get_data() get simpler, too. :-)
1783     while IFS= read -r line ; do
1784         if [[ -n ${vcs_comm[basedir]} ]] ; then
1785             line=${line## ##}
1786             [[ ${line} == depotpath:* ]] && vcs_comm[branch]=${line##*/}
1787             [[ ${line} == revision:* ]] && vcs_comm[revision]=${line##*[[:space:]]##}
1788             [[ -n ${vcs_comm[branch]} ]] && [[ -n ${vcs_comm[revision]} ]] && break
1789             continue
1790         fi
1791         (( fhash > 0 )) && [[ ${line} == '  '[^[:space:]]*:* ]] && break
1792         [[ ${line} == '  hash:'* ]] && fhash=1 && continue
1793         (( fhash == 0 )) && continue
1794         [[ ${PWD}/ == ${${line## ##}%:*}/* ]] && vcs_comm[basedir]=${${line## ##}%:*}
1795     done < ~/.svk/config
1796
1797     [[ -n ${vcs_comm[basedir]} ]]  && \
1798     [[ -n ${vcs_comm[branch]} ]]   && \
1799     [[ -n ${vcs_comm[revision]} ]] && return 0
1800     return 1
1801 }
1802 # }}}
1803 VCS_INFO_svn_detect() { #{{{
1804     VCS_INFO_check_com svn || return 1
1805     [[ -d ".svn" ]] && return 0
1806     return 1
1807 }
1808 # }}}
1809 VCS_INFO_tla_detect() { #{{{
1810     VCS_INFO_check_com tla || return 1
1811     vcs_comm[basedir]="$(tla tree-root 2> /dev/null)" && return 0
1812     return 1
1813 }
1814 # }}}
1815 # public API
1816 vcs_info_printsys () { # {{{
1817     vcs_info print_systems_
1818 }
1819 # }}}
1820 vcs_info_lastmsg () { # {{{
1821     local -i i
1822
1823     VCS_INFO_maxexports
1824     for i in {0..$((maxexports - 1))} ; do
1825         printf '$VCS_INFO_message_%d_: "' $i
1826         if zstyle -T ':vcs_info:formats:command' use-prompt-escapes ; then
1827             print -nP ${(P)${:-VCS_INFO_message_${i}_}}
1828         else
1829             print -n ${(P)${:-VCS_INFO_message_${i}_}}
1830         fi
1831         printf '"\n'
1832     done
1833 }
1834 # }}}
1835 vcs_info () { # {{{
1836     local pat
1837     local -i found
1838     local -a VCSs disabled dps
1839     local -x vcs usercontext
1840     local -ix maxexports
1841     local -ax msgs
1842     local -Ax vcs_comm
1843
1844     vcs="init"
1845     VCSs=(git hg bzr darcs svk mtn svn cvs cdv tla)
1846     case $1 in
1847         (print_systems_)
1848             zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1849             print -l '# list of supported version control backends:' \
1850                      '# disabled systems are prefixed by a hash sign (#)'
1851             for vcs in ${VCSs} ; do
1852                 [[ -n ${(M)disabled:#${vcs}} ]] && printf '#'
1853                 printf '%s\n' ${vcs}
1854             done
1855             print -l '# flavours (cannot be used in the disable style; they' \
1856                      '# are disabled with their master [git-svn -> git]):'   \
1857                      git-{p4,svn}
1858             return 0
1859             ;;
1860         ('')
1861             [[ -z ${usercontext} ]] && usercontext=default
1862             ;;
1863         (*) [[ -z ${usercontext} ]] && usercontext=$1
1864             ;;
1865     esac
1866
1867     zstyle -T ":vcs_info:${vcs}:${usercontext}" "enable" || {
1868         [[ -n ${VCS_INFO_message_0_} ]] && VCS_INFO_set --clear
1869         return 0
1870     }
1871     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable" disabled
1872
1873     zstyle -a ":vcs_info:${vcs}:${usercontext}" "disable-patterns" dps
1874     for pat in ${dps} ; do
1875         if [[ ${PWD} == ${~pat} ]] ; then
1876             [[ -n ${vcs_info_msg_0_} ]] && VCS_INFO_set --clear
1877             return 0
1878         fi
1879     done
1880
1881     VCS_INFO_maxexports
1882
1883     (( found = 0 ))
1884     for vcs in ${VCSs} ; do
1885         [[ -n ${(M)disabled:#${vcs}} ]] && continue
1886         vcs_comm=()
1887         VCS_INFO_${vcs}_detect && (( found = 1 )) && break
1888     done
1889
1890     (( found == 0 )) && {
1891         VCS_INFO_set --nvcs
1892         return 0
1893     }
1894
1895     VCS_INFO_${vcs}_get_data || {
1896         VCS_INFO_set --nvcs
1897         return 1
1898     }
1899
1900     VCS_INFO_set
1901     return 0
1902 }
1903
1904 VCS_INFO_set --nvcs preinit
1905 # }}}
1906
1907 # Change vcs_info formats for the grml prompt. The 2nd format sets up
1908 # $vcs_info_msg_1_ to contain "zsh: repo-name" used to set our screen title.
1909 # TODO: The included vcs_info() version still uses $VCS_INFO_message_N_.
1910 #       That needs to be the use of $VCS_INFO_message_N_ needs to be changed
1911 #       to $vcs_info_msg_N_ as soon as we use the included version.
1912 if [[ "$TERM" == dumb ]] ; then
1913     zstyle ':vcs_info:*' actionformats "(%s%)-[%b|%a] " "zsh: %r"
1914     zstyle ':vcs_info:*' formats       "(%s%)-[%b] "    "zsh: %r"
1915 else
1916     # these are the same, just with a lot of colours:
1917     zstyle ':vcs_info:*' actionformats "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${YELLOW}|${RED}%a${MAGENTA}]${NO_COLOUR} " \
1918                                        "zsh: %r"
1919     zstyle ':vcs_info:*' formats       "${MAGENTA}(${NO_COLOUR}%s${MAGENTA})${YELLOW}-${MAGENTA}[${GREEN}%b${MAGENTA}]${NO_COLOUR}%} " \
1920                                        "zsh: %r"
1921     zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat "%b${RED}:${YELLOW}%r"
1922 fi
1923
1924 # }}}
1925
1926 # command not found handling {{{
1927
1928 (( ${COMMAND_NOT_FOUND} == 1 )) &&
1929 function command_not_found_handler() {
1930     setopt localoptions no_sh_wordsplit
1931     if [[ -x ${GRML_ZSH_CNF_HANDLER} ]] ; then
1932         ${GRML_ZSH_CNF_HANDLER} $1
1933     fi
1934     return 1
1935 }
1936
1937 # }}}
1938
1939 # {{{ set prompt
1940 if zrcautoload promptinit && promptinit 2>/dev/null ; then
1941     promptinit # people should be able to use their favourite prompt
1942 else
1943     print 'Notice: no promptinit available :('
1944 fi
1945
1946 setopt prompt_subst
1947
1948 # make sure to use right prompt only when not running a command
1949 is41 && setopt transient_rprompt
1950
1951 # TODO: revise all these NO* variables and especially their documentation
1952 #       in zsh-help() below.
1953 is4 && [[ $NOPRECMD -eq 0 ]] && precmd () {
1954     [[ $NOPRECMD -gt 0 ]] && return 0
1955     # update VCS information
1956     vcs_info
1957
1958     if [[ $TERM == screen* ]] ; then
1959         if [[ -n ${VCS_INFO_message_1_} ]] ; then
1960             print -nP "\ek${VCS_INFO_message_1_}\e\\"
1961         else
1962             print -nP "\ekzsh\e\\"
1963         fi
1964     fi
1965     # just use DONTSETRPROMPT=1 to be able to overwrite RPROMPT
1966     if [[ $DONTSETRPROMPT -eq 0 ]] ; then
1967         if [[ $BATTERY -gt 0 ]] ; then
1968             # update battery (dropped into $PERCENT) information
1969             battery
1970             RPROMPT="%(?..:() ${PERCENT}"
1971         else
1972             RPROMPT="%(?..:() "
1973         fi
1974     fi
1975     # adjust title of xterm
1976     # see http://www.faqs.org/docs/Linux-mini/Xterm-Title.html
1977     [[ ${NOTITLE} -gt 0 ]] && return 0
1978     case $TERM in
1979         (xterm*|rxvt*)
1980             print -Pn "\e]0;%n@%m: %~\a"
1981             ;;
1982     esac
1983 }
1984
1985 # preexec() => a function running before every command
1986 is4 && [[ $NOPRECMD -eq 0 ]] && \
1987 preexec () {
1988     [[ $NOPRECMD -gt 0 ]] && return 0
1989 # set hostname if not running on host with name 'grml'
1990     if [[ -n "$HOSTNAME" ]] && [[ "$HOSTNAME" != $(hostname) ]] ; then
1991        NAME="@$HOSTNAME"
1992     fi
1993 # get the name of the program currently running and hostname of local machine
1994 # set screen window title if running in a screen
1995     if [[ "$TERM" == screen* ]] ; then
1996         # local CMD=${1[(wr)^(*=*|sudo|ssh|-*)]}       # don't use hostname
1997         local CMD="${1[(wr)^(*=*|sudo|ssh|-*)]}$NAME" # use hostname
1998         echo -ne "\ek$CMD\e\\"
1999     fi
2000 # adjust title of xterm
2001     [[ ${NOTITLE} -gt 0 ]] && return 0
2002     case $TERM in
2003         (xterm*|rxvt)
2004             print -Pn "\e]0;%n@%m: $1\a"
2005             ;;
2006     esac
2007 }
2008
2009 EXITCODE="%(?..%?%1v )"
2010 PS2='\`%_> '      # secondary prompt, printed when the shell needs more information to complete a command.
2011 PS3='?# '         # selection prompt used within a select loop.
2012 PS4='+%N:%i:%_> ' # the execution trace prompt (setopt xtrace). default: '+%N:%i>'
2013
2014 # set variable debian_chroot if running in a chroot with /etc/debian_chroot
2015 if [[ -z "$debian_chroot" ]] && [[ -r /etc/debian_chroot ]] ; then
2016     debian_chroot=$(cat /etc/debian_chroot)
2017 fi
2018
2019 # don't use colors on dumb terminals (like emacs):
2020 if [[ "$TERM" == dumb ]] ; then
2021     PROMPT="${EXITCODE}${debian_chroot:+($debian_chroot)}%n@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2022 else
2023     # only if $GRMLPROMPT is set (e.g. via 'GRMLPROMPT=1 zsh') use the extended prompt
2024     # set variable identifying the chroot you work in (used in the prompt below)
2025     if [[ $GRMLPROMPT -gt 0 ]] ; then
2026         PROMPT="${RED}${EXITCODE}${CYAN}[%j running job(s)] ${GREEN}{history#%!} ${RED}%(3L.+.) ${BLUE}%* %D
2027 ${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< %# "
2028     else
2029         # This assembles the primary prompt string
2030         if (( EUID != 0 )); then
2031             PROMPT="${RED}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${BLUE}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2032         else
2033             PROMPT="${BLUE}${EXITCODE}${WHITE}${debian_chroot:+($debian_chroot)}${RED}%n${NO_COLOUR}@%m %40<...<%B%~%b%<< "'${VCS_INFO_message_0_}'"%# "
2034         fi
2035     fi
2036 fi
2037
2038 # if we are inside a grml-chroot set a specific prompt theme
2039 if [[ -n "$GRML_CHROOT" ]] ; then
2040     PROMPT="%{$fg[red]%}(CHROOT) %{$fg_bold[red]%}%n%{$fg_no_bold[white]%}@%m %40<...<%B%~%b%<< %\# "
2041 fi
2042 # }}}
2043
2044 # {{{ 'hash' some often used directories
2045 #d# start
2046 hash -d deb=/var/cache/apt/archives
2047 hash -d doc=/usr/share/doc
2048 hash -d linux=/lib/modules/$(command uname -r)/build/
2049 hash -d log=/var/log
2050 hash -d slog=/var/log/syslog
2051 hash -d src=/usr/src
2052 hash -d templ=/usr/share/doc/grml-templates
2053 hash -d tt=/usr/share/doc/texttools-doc
2054 hash -d www=/var/www
2055 #d# end
2056 # }}}
2057
2058 # {{{ some aliases
2059 if check_com -c screen ; then
2060     if [[ $UID -eq 0 ]] ; then
2061         [[ -r /etc/grml/screenrc ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc"
2062     elif [[ -r $HOME/.screenrc ]] ; then
2063         alias screen="${commands[screen]} -c $HOME/.screenrc"
2064     else
2065         [[ -r /etc/grml/screenrc_grml ]] && alias screen="${commands[screen]} -c /etc/grml/screenrc_grml"
2066     fi
2067 fi
2068
2069 # do we have GNU ls with color-support?
2070 if ls --help 2>/dev/null | grep -- --color= >/dev/null && [[ "$TERM" != dumb ]] ; then
2071     #a1# execute \kbd{@a@}:\quad ls with colors
2072     alias ls='ls -b -CF --color=auto'
2073     #a1# execute \kbd{@a@}:\quad list all files, with colors
2074     alias la='ls -la --color=auto'
2075     #a1# long colored list, without dotfiles (@a@)
2076     alias ll='ls -l --color=auto'
2077     #a1# long colored list, human readable sizes (@a@)
2078     alias lh='ls -hAl --color=auto'
2079     #a1# List files, append qualifier to filenames \\&\quad(\kbd{/} for directories, \kbd{@} for symlinks ...)
2080     alias l='ls -lF --color=auto'
2081 else
2082     alias ls='ls -b -CF'
2083     alias la='ls -la'
2084     alias ll='ls -l'
2085     alias lh='ls -hAl'
2086     alias l='ls -lF'
2087 fi
2088
2089 alias mdstat='cat /proc/mdstat'
2090 alias ...='cd ../../'
2091
2092 # generate alias named "$KERNELVERSION-reboot" so you can use boot with kexec:
2093 if [[ -x /sbin/kexec ]] && [[ -r /proc/cmdline ]] ; then
2094     alias "$(uname -r)-reboot"="kexec -l --initrd=/boot/initrd.img-"$(uname -r)" --command-line=\"$(cat /proc/cmdline)\" /boot/vmlinuz-"$(uname -r)""
2095 fi
2096
2097 alias cp='nocorrect cp'         # no spelling correction on cp
2098 alias mkdir='nocorrect mkdir'   # no spelling correction on mkdir
2099 alias mv='nocorrect mv'         # no spelling correction on mv
2100 alias rm='nocorrect rm'         # no spelling correction on rm
2101
2102 #a1# Execute \kbd{rmdir}
2103 alias rd='rmdir'
2104 #a1# Execute \kbd{rmdir}
2105 alias md='mkdir'
2106
2107 # see http://www.cl.cam.ac.uk/~mgk25/unicode.html#term for details
2108 alias term2iso="echo 'Setting terminal to iso mode' ; print -n '\e%@'"
2109 alias term2utf="echo 'Setting terminal to utf-8 mode'; print -n '\e%G'"
2110
2111 # make sure it is not assigned yet
2112 [[ $(whence -w utf2iso &>/dev/null) == 'utf2iso: alias' ]] && unalias utf2iso
2113
2114 utf2iso() {
2115     if isutfenv ; then
2116         for ENV in $(env | command grep -i '.utf') ; do
2117             eval export "$(echo $ENV | sed 's/UTF-8/iso885915/ ; s/utf8/iso885915/')"
2118         done
2119     fi
2120 }
2121
2122 # make sure it is not assigned yet
2123 [[ $(whence -w iso2utf &>/dev/null) == 'iso2utf: alias' ]] && unalias iso2utf
2124 iso2utf() {
2125     if ! isutfenv ; then
2126         for ENV in $(env | command grep -i '\.iso') ; do
2127             eval export "$(echo $ENV | sed 's/iso.*/UTF-8/ ; s/ISO.*/UTF-8/')"
2128         done
2129     fi
2130 }
2131
2132 # set up software synthesizer via speakup
2133 swspeak() {
2134     if [ -x /usr/sbin/swspeak-setup ] ; then
2135        setopt singlelinezle
2136        unsetopt prompt_cr
2137        export PS1="%m%# "
2138        /usr/sbin/swspeak-setup $@
2139      else # old version:
2140         aumix -w 90 -v 90 -p 90 -m 90
2141         if ! [[ -r /dev/softsynth ]] ; then
2142             flite -o play -t "Sorry, software synthesizer not available. Did you boot with swspeak bootoption?"
2143             return 1
2144         else
2145            setopt singlelinezle
2146            unsetopt prompt_cr
2147            export PS1="%m%# "
2148             nice -n -20 speechd-up
2149             sleep 2
2150             flite -o play -t "Finished setting up software synthesizer"
2151         fi
2152      fi
2153 }
2154
2155 # I like clean prompt, so provide simple way to get that
2156 check_com 0 || alias 0='return 0'
2157
2158 # for really lazy people like mika:
2159 check_com S &>/dev/null || alias S='screen'
2160 check_com s &>/dev/null || alias s='ssh'
2161
2162 # get top 10 shell commands:
2163 alias top10='print -l ? ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
2164
2165 # truecrypt; use e.g. via 'truec /dev/ice /mnt/ice' or 'truec -i'
2166 if check_com -c truecrypt ; then
2167     if isutfenv ; then
2168         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077,utf8" '
2169     else
2170         alias truec='truecrypt --mount-options "rw,sync,dirsync,users,uid=1000,gid=users,umask=077" '
2171     fi
2172 fi
2173
2174 #f1# Hints for the use of zsh on grml
2175 zsh-help() {
2176     print "$bg[white]$fg[black]
2177 zsh-help - hints for use of zsh on grml
2178 =======================================$reset_color"
2179
2180     print '
2181 Main configuration of zsh happens in /etc/zsh/zshrc.
2182 That file is part of the package grml-etc-core, if you want to
2183 use them on a non-grml-system just get the tar.gz from
2184 http://deb.grml.org/ or (preferably) get it from the git repository:
2185
2186   http://git.grml.org/f/grml-etc-core/etc/zsh/zshrc
2187
2188 This version of grml'\''s zsh setup does not use skel/.zshrc anymore.
2189 The file is still there, but it is empty for backwards compatibility.
2190
2191 For your own changes use these two files:
2192     $HOME/.zshrc.pre
2193     $HOME/.zshrc.local
2194
2195 The former is sourced very early in our zshrc, the latter is sourced
2196 very lately.
2197
2198 System wide configuration without touching configuration files of grml
2199 can take place in /etc/zsh/zshrc.local.
2200
2201 Normally, the root user (EUID == 0) does not get the whole grml setup.
2202 If you want to force the whole setup for that user, too, set
2203 GRML_ALWAYS_LOAD_ALL=1 in .zshrc.pre in root'\''s home directory.
2204
2205 For information regarding zsh start at http://grml.org/zsh/
2206
2207 Take a look at grml'\''s zsh refcard:
2208 % xpdf =(zcat /usr/share/doc/grml-docs/zsh/grml-zsh-refcard.pdf.gz)
2209
2210 Check out the main zsh refcard:
2211 % '$BROWSER' http://www.bash2zsh.com/zsh_refcard/refcard.pdf
2212
2213 And of course visit the zsh-lovers:
2214 % man zsh-lovers
2215
2216 You can adjust some options through environment variables when
2217 invoking zsh without having to edit configuration files.
2218 Basically meant for bash users who are not used to the power of
2219 the zsh yet. :)
2220
2221   "NOCOR=1    zsh" => deactivate automatic correction
2222   "NOMENU=1   zsh" => do not use auto menu completion (note: use ctrl-d for completion instead!)
2223   "NOPRECMD=1 zsh" => disable the precmd + preexec commands (set GNU screen title)
2224   "NOTITLE=1  zsh" => disable setting the title of xterms without disabling
2225                       preexec() and precmd() completely
2226   "BATTERY=1  zsh" => activate battery status (via acpi) on right side of prompt
2227   "COMMAND_NOT_FOUND=1 zsh"
2228                    => Enable a handler if an external command was not found
2229                       The command called in the handler can be altered by setting
2230                       the GRML_ZSH_CNF_HANDLER variable, the default is:
2231                       "/usr/share/command-not-found/command-not-found"
2232
2233 A value greater than 0 is enables a feature; a value equal to zero
2234 disables it. If you like one or the other of these settings, you can
2235 add them to ~/.zshrc.pre to ensure they are set when sourcing grml'\''s
2236 zshrc.'
2237
2238     print "
2239 $bg[white]$fg[black]
2240 Please report wishes + bugs to the grml-team: http://grml.org/bugs/
2241 Enjoy your grml system with the zsh!$reset_color"
2242 }
2243
2244 # debian stuff
2245 if [[ -r /etc/debian_version ]] ; then
2246     #a3# Execute \kbd{apt-cache search}
2247     alias acs='apt-cache search'
2248     #a3# Execute \kbd{apt-cache show}
2249     alias acsh='apt-cache show'
2250     #a3# Execute \kbd{apt-cache policy}
2251     alias acp='apt-cache policy'
2252     #a3# Execute \kbd{apt-get dist-upgrade}
2253     salias adg="apt-get dist-upgrade"
2254     #a3# Execute \kbd{apt-get install}
2255     salias agi="apt-get install"
2256     #a3# Execute \kbd{aptitude install}
2257     salias ati="aptitude install"
2258     #a3# Execute \kbd{apt-get upgrade}
2259     salias ag="apt-get upgrade"
2260     #a3# Execute \kbd{apt-get update}
2261     salias au="apt-get update"
2262     #a3# Execute \kbd{aptitude update ; aptitude safe-upgrade}
2263     salias -a up="aptitude update ; aptitude safe-upgrade"
2264     #a3# Execute \kbd{dpkg-buildpackage}
2265     alias dbp='dpkg-buildpackage'
2266     #a3# Execute \kbd{grep-excuses}
2267     alias ge='grep-excuses'
2268
2269     # debian upgrade
2270     #f3# Execute \kbd{apt-get update \&\& }\\&\quad \kbd{apt-get dist-upgrade}
2271     upgrade() {
2272         if [[ -z "$1" ]] ; then
2273             $SUDO apt-get update
2274             $SUDO apt-get -u upgrade
2275         else
2276             ssh $1 $SUDO apt-get update
2277             # ask before the upgrade
2278             local dummy
2279             ssh $1 $SUDO apt-get --no-act upgrade
2280             echo -n 'Process the upgrade?'
2281             read -q dummy
2282             if [[ $dummy == "y" ]] ; then
2283                 ssh $1 $SUDO apt-get -u upgrade --yes
2284             fi
2285         fi
2286     }
2287
2288     # get a root shell as normal user in live-cd mode:
2289     if isgrmlcd && [[ $UID -ne 0 ]] ; then
2290        alias su="sudo su"
2291      fi
2292
2293     #a1# Take a look at the syslog: \kbd{\$PAGER /var/log/syslog}
2294     alias llog="$PAGER /var/log/syslog"     # take a look at the syslog
2295     #a1# Take a look at the syslog: \kbd{tail -f /var/log/syslog}
2296     alias tlog="tail -f /var/log/syslog"    # follow the syslog
2297 fi
2298
2299 # sort installed Debian-packages by size
2300 if check_com -c grep-status ; then
2301     #a3# List installed Debian-packages sorted by size
2302     alias debs-by-size='grep-status -FStatus -sInstalled-Size,Package -n "install ok installed" | paste -sd "  \n" | sort -rn'
2303 fi
2304
2305 # if cdrecord is a symlink (to wodim) or isn't present at all warn:
2306 if [[ -L /usr/bin/cdrecord ]] || ! check_com -c cdrecord ; then
2307     if check_com -c wodim ; then
2308         alias cdrecord="echo 'cdrecord is not provided under its original name by Debian anymore.
2309 See #377109 in the BTS of Debian for more details.
2310
2311 Please use the wodim binary instead' ; return 1"
2312     fi
2313 fi
2314
2315 # get_tw_cli has been renamed into get_3ware
2316 if check_com -c get_3ware ; then
2317     get_tw_cli() {
2318         echo 'Warning: get_tw_cli has been renamed into get_3ware. Invoking get_3ware for you.'>&2
2319         get_3ware
2320     }
2321 fi
2322
2323 # I hate lacking backward compatibility, so provide an alternative therefore
2324 if ! check_com -c apache2-ssl-certificate ; then
2325
2326     apache2-ssl-certificate() {
2327
2328     print 'Debian does not ship apache2-ssl-certificate anymore (see #398520). :('
2329     print 'You might want to take a look at Debian the package ssl-cert as well.'
2330     print 'To generate a certificate for use with apache2 follow the instructions:'
2331
2332     echo '
2333
2334 export RANDFILE=/dev/random
2335 mkdir /etc/apache2/ssl/
2336 openssl req $@ -new -x509 -days 365 -nodes -out /etc/apache2/ssl/apache.pem -keyout /etc/apache2/ssl/apache.pem
2337 chmod 600 /etc/apache2/ssl/apache.pem
2338
2339 Run "grml-tips ssl-certificate" if you need further instructions.
2340 '
2341     }
2342 fi
2343 # }}}
2344
2345 # {{{ Use hard limits, except for a smaller stack and no core dumps
2346 unlimit
2347 test "`uname -s`" '!=' 'GNU' && is425 && limit stack 2048
2348 isgrmlcd && limit core 0 # important for a live-cd-system
2349 limit -s
2350 # }}}
2351
2352 # {{{ completion system
2353
2354 # called later (via is4 && grmlcomp)
2355 # note: use 'zstyle' for getting current settings
2356 #         press ^Xh (control-x h) for getting tags in context; ^X? (control-x ?) to run complete_debug with trace output
2357 grmlcomp() {
2358     # TODO: This could use some additional information
2359
2360     # allow one error for every three characters typed in approximate completer
2361     zstyle ':completion:*:approximate:'    max-errors 'reply=( $((($#PREFIX+$#SUFFIX)/3 )) numeric )'
2362
2363     # don't complete backup files as executables
2364     zstyle ':completion:*:complete:-command-::commands' ignored-patterns '(aptitude-*|*\~)'
2365
2366     # start menu completion only if it could find no unambiguous initial string
2367     zstyle ':completion:*:correct:*'       insert-unambiguous true
2368     zstyle ':completion:*:corrections'     format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
2369     zstyle ':completion:*:correct:*'       original true
2370
2371     # activate color-completion
2372     zstyle ':completion:*:default'         list-colors ${(s.:.)LS_COLORS}
2373
2374     # format on completion
2375     zstyle ':completion:*:descriptions'    format $'%{\e[0;31m%}completing %B%d%b%{\e[0m%}'
2376
2377     # complete 'cd -<tab>' with menu
2378     zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
2379
2380     # insert all expansions for expand completer
2381     zstyle ':completion:*:expand:*'        tag-order all-expansions
2382     zstyle ':completion:*:history-words'   list false
2383
2384     # activate menu
2385     zstyle ':completion:*:history-words'   menu yes
2386
2387     # ignore duplicate entries
2388     zstyle ':completion:*:history-words'   remove-all-dups yes
2389     zstyle ':completion:*:history-words'   stop yes
2390
2391     # match uppercase from lowercase
2392     zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'
2393
2394     # separate matches into groups
2395     zstyle ':completion:*:matches'         group 'yes'
2396     zstyle ':completion:*'                 group-name ''
2397
2398     if [[ "$NOMENU" -eq 0 ]] ; then
2399         # if there are more than 5 options allow selecting from a menu
2400         zstyle ':completion:*'               menu select=5
2401     else
2402         # don't use any menus at all
2403         setopt no_auto_menu
2404     fi
2405
2406     zstyle ':completion:*:messages'        format '%d'
2407     zstyle ':completion:*:options'         auto-description '%d'
2408
2409     # describe options in full
2410     zstyle ':completion:*:options'         description 'yes'
2411
2412     # on processes completion complete all user processes
2413     zstyle ':completion:*:processes'       command 'ps -au$USER'
2414
2415     # offer indexes before parameters in subscripts
2416     zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters
2417
2418     # provide verbose completion information
2419     zstyle ':completion:*'                 verbose true
2420
2421     # recent (as of Dec 2007) zsh versions are able to provide descriptions
2422     # for commands (read: 1st word in the line) that it will list for the user
2423     # to choose from. The following disables that, because it's not exactly fast.
2424     zstyle ':completion:*:-command-:*:'    verbose false
2425
2426     # set format for warnings
2427     zstyle ':completion:*:warnings'        format $'%{\e[0;31m%}No matches for:%{\e[0m%} %d'
2428
2429     # define files to ignore for zcompile
2430     zstyle ':completion:*:*:zcompile:*'    ignored-patterns '(*~|*.zwc)'
2431     zstyle ':completion:correct:'          prompt 'correct to: %e'
2432
2433     # Ignore completion functions for commands you don't have:
2434     zstyle ':completion::(^approximate*):*:functions' ignored-patterns '_*'
2435
2436     # Provide more processes in completion of programs like killall:
2437     zstyle ':completion:*:processes-names' command 'ps c -u ${USER} -o command | uniq'
2438
2439     # complete manual by their section
2440     zstyle ':completion:*:manuals'    separate-sections true
2441     zstyle ':completion:*:manuals.*'  insert-sections   true
2442     zstyle ':completion:*:man:*'      menu yes select
2443
2444     # provide .. as a completion
2445     zstyle ':completion:*' special-dirs ..
2446
2447     # run rehash on completion so new installed program are found automatically:
2448     _force_rehash() {
2449         (( CURRENT == 1 )) && rehash
2450         return 1
2451     }
2452
2453     ## correction
2454     # some people don't like the automatic correction - so run 'NOCOR=1 zsh' to deactivate it
2455     if [[ "$NOCOR" -gt 0 ]] ; then
2456         zstyle ':completion:*' completer _oldlist _expand _force_rehash _complete _files _ignored
2457         setopt nocorrect
2458     else
2459         # try to be smart about when to use what completer...
2460         setopt correct
2461         zstyle -e ':completion:*' completer '
2462             if [[ $_last_try != "$HISTNO$BUFFER$CURSOR" ]] ; then
2463                 _last_try="$HISTNO$BUFFER$CURSOR"
2464                 reply=(_complete _match _ignored _prefix _files)
2465             else
2466                 if [[ $words[1] == (rm|mv) ]] ; then
2467                     reply=(_complete _files)
2468                 else
2469                     reply=(_oldlist _expand _force_rehash _complete _ignored _correct _approximate _files)
2470                 fi
2471             fi'
2472     fi
2473
2474     # command for process lists, the local web server details and host completion
2475     zstyle ':completion:*:urls' local 'www' '/var/www/' 'public_html'
2476
2477     # caching
2478     [[ -d $ZSHDIR/cache ]] && zstyle ':completion:*' use-cache yes && \
2479                             zstyle ':completion::complete:*' cache-path $ZSHDIR/cache/
2480
2481     # host completion /* add brackets as vim can't parse zsh's complex cmdlines 8-) {{{ */
2482     if is42 ; then
2483         [[ -r ~/.ssh/known_hosts ]] && _ssh_hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[\|]*}%%\ *}%%,*}) || _ssh_hosts=()
2484         [[ -r /etc/hosts ]] && : ${(A)_etc_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}} || _etc_hosts=()
2485     else
2486         _ssh_hosts=()
2487         _etc_hosts=()
2488     fi
2489     hosts=(
2490         $(hostname)
2491         "$_ssh_hosts[@]"
2492         "$_etc_hosts[@]"
2493         grml.org
2494         localhost
2495     )
2496     zstyle ':completion:*:hosts' hosts $hosts
2497     # TODO: so, why is this here?
2498     #  zstyle '*' hosts $hosts
2499
2500     # use generic completion system for programs not yet defined; (_gnu_generic works
2501     # with commands that provide a --help option with "standard" gnu-like output.)
2502     for compcom in tail head feh cp mv df stow uname ipacsum fetchipac; do
2503         [[ -z ${_comps[$compcom]} ]] && compdef _gnu_generic ${compcom}
2504     done; unset compcom
2505
2506     # see upgrade function in this file
2507     compdef _hosts upgrade
2508 }
2509 # }}}
2510
2511 # {{{ grmlstuff
2512 grmlstuff() {
2513 # people should use 'grml-x'!
2514     startx() {
2515         if [[ -e /etc/X11/xorg.conf ]] ; then
2516             [[ -x /usr/bin/startx ]] && /usr/bin/startx "$@" || /usr/X11R6/bin/startx "$@"
2517         else
2518             echo "Please use the script \"grml-x\" for starting the X Window System
2519 because there does not exist /etc/X11/xorg.conf yet.
2520 If you want to use startx anyway please call \"/usr/bin/startx\"."
2521             return -1
2522         fi
2523     }
2524
2525     xinit() {
2526         if [[ -e /etc/X11/xorg.conf ]] ; then
2527             [[ -x /usr/bin/xinit ]] && /usr/bin/xinit || /usr/X11R6/bin/xinit
2528         else
2529             echo "Please use the script \"grml-x\" for starting the X Window System.
2530 because there does not exist /etc/X11/xorg.conf yet.
2531 If you want to use xinit anyway please call \"/usr/bin/xinit\"."
2532             return -1
2533         fi
2534     }
2535
2536     if check_com -c 915resolution ; then
2537         alias 855resolution='echo -e "Please use 915resolution as resolution modify tool for Intel graphic chipset."; return -1'
2538     fi
2539
2540     #a1# Output version of running grml
2541     alias grml-version='cat /etc/grml_version'
2542
2543     if check_com -c rebuildfstab ; then
2544         #a1# Rebuild /etc/fstab
2545         alias grml-rebuildfstab='rebuildfstab -v -r -config'
2546     fi
2547
2548     if check_com -c grml-debootstrap ; then
2549         alias debian2hd='print "Installing debian to harddisk is possible via using grml-debootstrap." ; return 1'
2550     fi
2551 }
2552 # }}}
2553
2554 # {{{ now run the functions
2555 isgrml && checkhome
2556 is4    && isgrml    && grmlstuff
2557 is4    && grmlcomp
2558 # }}}
2559
2560 # {{{ keephack
2561 is4 && xsource "/etc/zsh/keephack"
2562 # }}}
2563
2564 # {{{ wonderful idea of using "e" glob qualifier by Peter Stephenson
2565 # You use it as follows:
2566 # $ NTREF=/reference/file
2567 # $ ls -l *(e:nt:)
2568 # This lists all the files in the current directory newer than the reference file.
2569 # You can also specify the reference file inline; note quotes:
2570 # $ ls -l *(e:'nt ~/.zshenv':)
2571 is4 && nt() {
2572     if [[ -n $1 ]] ; then
2573         local NTREF=${~1}
2574     fi
2575     [[ $REPLY -nt $NTREF ]]
2576 }
2577 # }}}
2578
2579 # shell functions {{{
2580
2581 #f1# Provide csh compatibility
2582 setenv()  { typeset -x "${1}${1:+=}${(@)argv[2,$#]}" }  # csh compatibility
2583
2584 #f1# Reload an autoloadable function
2585 freload() { while (( $# )); do; unfunction $1; autoload -U $1; shift; done }
2586
2587 #f1# Reload zsh setup
2588 reload() {
2589     if [[ "$#*" -eq 0 ]] ; then
2590         [[ -r ~/.zshrc ]] && . ~/.zshrc
2591     else
2592         local fn
2593         for fn in "$@"; do
2594             unfunction $fn
2595             autoload -U $fn
2596         done
2597     fi
2598 }
2599 compdef _functions reload freload
2600
2601 #f1# List symlinks in detail (more detailed version of 'readlink -f' and 'whence -s')
2602 sll() {
2603     [[ -z "$1" ]] && printf 'Usage: %s <file(s)>\n' "$0" && return 1
2604     for i in "$@" ; do
2605         file=$i
2606         while [[ -h "$file" ]] ; do
2607             ls -l $file
2608             file=$(readlink "$file")
2609         done
2610     done
2611 }
2612
2613 # fast manual access
2614 if check_com qma ; then
2615     #f1# View the zsh manual
2616     manzsh()  { qma zshall "$1" }
2617     compdef _man qma
2618 else
2619     manzsh()  { /usr/bin/man zshall |  vim -c "se ft=man| se hlsearch" +/"$1" - ; }
2620 fi
2621
2622 if check_com -c $PAGER ; then
2623     #f1# View Debian's changelog of a given package
2624     dchange() {
2625         if [[ -r /usr/share/doc/${1}/changelog.Debian.gz ]] ; then
2626             $PAGER /usr/share/doc/${1}/changelog.Debian.gz
2627         elif [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2628             $PAGER /usr/share/doc/${1}/changelog.gz
2629         else
2630             if check_com -c aptitude ; then
2631                 echo "No changelog for package $1 found, using aptitude to retrieve it."
2632                 if isgrml ; then
2633                     aptitude -t unstable changelog ${1}
2634                 else
2635                     aptitude changelog ${1}
2636                 fi
2637             else
2638                 echo "No changelog for package $1 found, sorry."
2639                 return 1
2640             fi
2641         fi
2642     }
2643     _dchange() { _files -W /usr/share/doc -/ }
2644     compdef _dchange dchange
2645
2646     #f1# View Debian's NEWS of a given package
2647     dnews() {
2648         if [[ -r /usr/share/doc/${1}/NEWS.Debian.gz ]] ; then
2649             $PAGER /usr/share/doc/${1}/NEWS.Debian.gz
2650         else
2651             if [[ -r /usr/share/doc/${1}/NEWS.gz ]] ; then
2652                 $PAGER /usr/share/doc/${1}/NEWS.gz
2653             else
2654                 echo "No NEWS file for package $1 found, sorry."
2655                 return 1
2656             fi
2657         fi
2658     }
2659     _dnews() { _files -W /usr/share/doc -/ }
2660     compdef _dnews dnews
2661
2662     #f1# View upstream's changelog of a given package
2663     uchange() {
2664         if [[ -r /usr/share/doc/${1}/changelog.gz ]] ; then
2665             $PAGER /usr/share/doc/${1}/changelog.gz
2666         else
2667             echo "No changelog for package $1 found, sorry."
2668             return 1
2669         fi
2670     }
2671     _uchange() { _files -W /usr/share/doc -/ }
2672     compdef _uchange uchange
2673 fi
2674
2675 # zsh profiling
2676 profile() {
2677     ZSH_PROFILE_RC=1 $SHELL "$@"
2678 }
2679
2680 #f1# Edit an alias via zle
2681 edalias() {
2682     [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
2683 }
2684 compdef _aliases edalias
2685
2686 #f1# Edit a function via zle
2687 edfunc() {
2688     [[ -z "$1" ]] && { echo "Usage: edfun <function_to_edit>" ; return 1 } || zed -f "$1" ;
2689 }
2690 compdef _functions edfunc
2691
2692 # use it e.g. via 'Restart apache2'
2693 #m# f6 Start() \kbd{/etc/init.d/\em{process}}\quad\kbd{start}
2694 #m# f6 Restart() \kbd{/etc/init.d/\em{process}}\quad\kbd{restart}
2695 #m# f6 Stop() \kbd{/etc/init.d/\em{process}}\quad\kbd{stop}
2696 #m# f6 Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{reload}
2697 #m# f6 Force-Reload() \kbd{/etc/init.d/\em{process}}\quad\kbd{force-reload}
2698 if [[ -d /etc/init.d || -d /etc/service ]] ; then
2699     __start_stop() {
2700         local action_="${1:l}"  # e.g Start/Stop/Restart
2701         local service_="$2"
2702         local param_="$3"
2703
2704         local service_target_="$(readlink /etc/init.d/$service_)"
2705         if [[ $service_target_ == "/usr/bin/sv" ]]; then
2706             # runit
2707             case "${action_}" in
2708                 start) if [[ ! -e /etc/service/$service_ ]]; then
2709                            $SUDO ln -s "/etc/sv/$service_" "/etc/service/"
2710                        else
2711                            $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2712                        fi ;;
2713                 # there is no reload in runits sysv emulation
2714                 reload) $SUDO "/etc/init.d/$service_" "force-reload" "$param_" ;;
2715                 *) $SUDO "/etc/init.d/$service_" "${action_}" "$param_" ;;
2716             esac
2717         else
2718             # sysvinit
2719             $SUDO "/etc/init.d/$service_" "${action_}" "$param_"
2720         fi
2721     }
2722
2723     for i in Start Restart Stop Force-Reload Reload ; do
2724         eval "$i() { __start_stop $i \"\$1\" \"\$2\" ; }"
2725     done
2726 fi
2727
2728 #f1# Provides useful information on globbing
2729 H-Glob() {
2730     echo -e "
2731     /      directories
2732     .      plain files
2733     @      symbolic links
2734     =      sockets
2735     p      named pipes (FIFOs)
2736     *      executable plain files (0100)
2737     %      device files (character or block special)
2738     %b     block special files
2739     %c     character special files
2740     r      owner-readable files (0400)
2741     w      owner-writable files (0200)
2742     x      owner-executable files (0100)
2743     A      group-readable files (0040)
2744     I      group-writable files (0020)
2745     E      group-executable files (0010)
2746     R      world-readable files (0004)
2747     W      world-writable files (0002)
2748     X      world-executable files (0001)
2749     s      setuid files (04000)
2750     S      setgid files (02000)
2751     t      files with the sticky bit (01000)
2752
2753   print *(m-1)          # Files modified up to a day ago
2754   print *(a1)           # Files accessed a day ago
2755   print *(@)            # Just symlinks
2756   print *(Lk+50)        # Files bigger than 50 kilobytes
2757   print *(Lk-50)        # Files smaller than 50 kilobytes
2758   print **/*.c          # All *.c files recursively starting in \$PWD
2759   print **/*.c~file.c   # Same as above, but excluding 'file.c'
2760   print (foo|bar).*     # Files starting with 'foo' or 'bar'
2761   print *~*.*           # All Files that do not contain a dot
2762   chmod 644 *(.^x)      # make all plain non-executable files publically readable
2763   print -l *(.c|.h)     # Lists *.c and *.h
2764   print **/*(g:users:)  # Recursively match all files that are owned by group 'users'
2765   echo /proc/*/cwd(:h:t:s/self//) # Analogous to >ps ax | awk '{print $1}'<"
2766 }
2767 alias help-zshglob=H-Glob
2768
2769 check_com -c qma && alias ?='qma zshall'
2770
2771 # grep for running process, like: 'any vim'
2772 any() {
2773     if [[ -z "$1" ]] ; then
2774         echo "any - grep for process(es) by keyword" >&2
2775         echo "Usage: any <keyword>" >&2 ; return 1
2776     else
2777         local STRING=$1
2778         local LENGTH=$(expr length $STRING)
2779         local FIRSCHAR=$(echo $(expr substr $STRING 1 1))
2780         local REST=$(echo $(expr substr $STRING 2 $LENGTH))
2781         ps xauwww| grep "[$FIRSCHAR]$REST"
2782     fi
2783 }
2784
2785 # After resuming from suspend, system is paging heavily, leading to very bad interactivity.
2786 # taken from $LINUX-KERNELSOURCE/Documentation/power/swsusp.txt
2787 [[ -r /proc/1/maps ]] && \
2788 deswap() {
2789     print 'Reading /proc/[0-9]*/maps and sending output to /dev/null, this might take a while.'
2790     cat $(sed -ne 's:.* /:/:p' /proc/[0-9]*/maps | sort -u | grep -v '^/dev/')  > /dev/null
2791     print 'Finished, running "swapoff -a; swapon -a" may also be useful.'
2792 }
2793
2794 # print hex value of a number
2795 hex() {
2796     [[ -n "$1" ]] && printf "%x\n" $1 || { print 'Usage: hex <number-to-convert>' ; return 1 }
2797 }
2798
2799 # calculate (or eval at all ;-)) with perl => p[erl-]eval
2800 # hint: also take a look at zcalc -> 'autoload zcalc' -> 'man zshmodules | less -p MATHFUNC'
2801 peval() {
2802     [[ -n "$1" ]] && CALC="$*" || print "Usage: calc [expression]"
2803     perl -e "print eval($CALC),\"\n\";"
2804 }
2805 functions peval &>/dev/null && alias calc=peval
2806
2807 # brltty seems to have problems with utf8 environment and/or font Uni3-Terminus16 under
2808 # certain circumstances, so work around it, no matter which environment we have
2809 brltty() {
2810     if [[ -z "$DISPLAY" ]] ; then
2811         consolechars -f /usr/share/consolefonts/default8x16.psf.gz
2812         command brltty "$@"
2813     else
2814         command brltty "$@"
2815     fi
2816 }
2817
2818 # just press 'asdf' keys to toggle between dvorak and us keyboard layout
2819 aoeu() {
2820     echo -n 'Switching to us keyboard layout: '
2821     [[ -z "$DISPLAY" ]] && $SUDO loadkeys us &>/dev/null || setxkbmap us &>/dev/null
2822     echo 'Done'
2823 }
2824 asdf() {
2825     echo -n 'Switching to dvorak keyboard layout: '
2826     [[ -z "$DISPLAY" ]] && $SUDO loadkeys dvorak &>/dev/null || setxkbmap dvorak &>/dev/null
2827     echo 'Done'
2828 }
2829 # just press 'asdf' key to toggle from neon layout to us keyboard layout
2830 uiae() {
2831     echo -n 'Switching to us keyboard layout: '
2832     setxkbmap us && echo 'Done' || echo 'Failed'
2833 }
2834
2835 # set up an ipv6 tunnel
2836 ipv6-tunnel() {
2837     case $1 in
2838         start)
2839             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2840                 print 'ipv6 tunnel already set up, nothing to be done.'
2841                 print 'execute: "ifconfig sit1 down ; ifconfig sit0 down" to remove ipv6-tunnel.' ; return 1
2842             else
2843                 [[ -n "$PUBLIC_IP" ]] || \
2844                     local PUBLIC_IP=$(ifconfig $(route -n | awk '/^0\.0\.0\.0/{print $8; exit}') | \
2845                                       awk '/inet addr:/ {print $2}' | tr -d 'addr:')
2846
2847                 [[ -n "$PUBLIC_IP" ]] || { print 'No $PUBLIC_IP set and could not determine default one.' ; return 1 }
2848                 local IPV6ADDR=$(printf "2002:%02x%02x:%02x%02x:1::1" $(print ${PUBLIC_IP//./ }))
2849                 print -n "Setting up ipv6 tunnel $IPV6ADDR via ${PUBLIC_IP}: "
2850                 ifconfig sit0 tunnel ::192.88.99.1 up
2851                 ifconfig sit1 add "$IPV6ADDR" && print done || print failed
2852             fi
2853             ;;
2854         status)
2855             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2856                 print 'ipv6 tunnel available' ; return 0
2857             else
2858                 print 'ipv6 tunnel not available' ; return 1
2859             fi
2860             ;;
2861         stop)
2862             if ifconfig sit1 2>/dev/null | grep -q 'inet6 addr: 2002:.*:1::1' ; then
2863                 print -n 'Stopping ipv6 tunnel (sit0 + sit1): '
2864                 ifconfig sit1 down ; ifconfig sit0 down && print done || print failed
2865             else
2866                 print 'No ipv6 tunnel found, nothing to be done.' ; return 1
2867             fi
2868             ;;
2869         *)
2870             print "Usage: ipv6-tunnel [start|stop|status]">&2 ; return 1
2871             ;;
2872     esac
2873 }
2874
2875 # run dhclient for wireless device
2876 iwclient() {
2877     salias dhclient "$(wavemon -d | awk '/device/{print $2}')"
2878 }
2879
2880 # spawn a minimally set up ksh - useful if you want to umount /usr/.
2881 minimal-shell() {
2882     exec env -i ENV="/etc/minimal-shellrc" HOME="$HOME" TERM="$TERM" ksh
2883 }
2884
2885 # a wrapper for vim, that deals with title setting
2886 #   VIM_OPTIONS
2887 #       set this array to a set of options to vim you always want
2888 #       to have set when calling vim (in .zshrc.local), like:
2889 #           VIM_OPTIONS=( -p )
2890 #       This will cause vim to send every file given on the
2891 #       commandline to be send to it's own tab (needs vim7).
2892 vim() {
2893     VIM_PLEASE_SET_TITLE='yes' command vim ${VIM_OPTIONS} "$@"
2894 }
2895
2896 # make a backup of a file
2897 bk() {
2898     cp -a "$1" "${1}_$(date --iso-8601=seconds)"
2899 }
2900
2901 #f1# grep for patterns in grml's zsh setup
2902 zg() {
2903 #{{{
2904     LANG=C perl -e '
2905
2906 sub usage {
2907     print "usage: zg -[anr] <pattern>\n";
2908     print " Search for patterns in grml'\''s zshrc.\n";
2909     print " zg takes no or exactly one option plus a non empty pattern.\n\n";
2910     print "   options:\n";
2911     print "     --  no options (use if your pattern starts in with a dash.\n";
2912     print "     -a  search for the pattern in all code regions\n";
2913     print "     -n  search for the pattern in non-root code only\n";
2914     print "     -r  search in code for everyone (also root) only\n\n";
2915     print "   The default is -a for non-root users and -r for root.\n\n";
2916     print " If you installed the zshrc to a non-default locations (ie *NOT*\n";
2917     print " in /etc/zsh/zshrc) do: export GRML_ZSHRC=\$HOME/.zshrc\n";
2918     print " ...in case you copied the file to that location.\n\n";
2919     exit 1;
2920 }
2921
2922 if ($ENV{GRML_ZSHRC} ne "") {
2923     $RC = $ENV{GRML_ZSHRC};
2924 } else {
2925     $RC = "/etc/zsh/zshrc";
2926 }
2927
2928 usage if ($#ARGV < 0 || $#ARGV > 1);
2929 if ($> == 0) { $mode = "allonly"; }
2930 else { $mode = "all"; }
2931
2932 $opt = $ARGV[0];
2933 if ($opt eq "--")     { shift; }
2934 elsif ($opt eq "-a")  { $mode = "all"; shift; }
2935 elsif ($opt eq "-n")  { $mode = "nonroot"; shift; }
2936 elsif ($opt eq "-r" ) { $mode = "allonly"; shift; }
2937 elsif ($opt =~ m/^-/ || $#ARGV > 0) { usage(); }
2938
2939 $pattern = $ARGV[0];
2940 usage() if ($pattern eq "");
2941
2942 open FH, "<$RC" or die "zg: Could not open $RC: $!\n";
2943 while ($line = <FH>) {
2944     chomp $line;
2945     if ($line =~ m/^#:grep:marker:for:mika:/) { $markerfound = 1; next; }
2946     next if ($mode eq "nonroot" && markerfound == 0);
2947     break if ($mode eq "allonly" && markerfound == 1);
2948     print $line, "\n" if ($line =~ /$pattern/);
2949 }
2950 close FH;
2951 exit 0;
2952
2953     ' -- "$@"
2954 #}}}
2955     return $?
2956 }
2957
2958 # }}}
2959
2960 # {{{ make sure our environment is clean regarding colors
2961 for color in BLUE RED GREEN CYAN YELLOW MAGENTA WHITE ; unset $color
2962 # }}}
2963
2964 # source another config file if present {{{
2965 xsource "/etc/zsh/zshrc.local"
2966 # }}}
2967
2968 # "persistent history" {{{
2969 # just write important commands you always need to ~/.important_commands
2970 if [[ -r ~/.important_commands ]] ; then
2971     fc -R ~/.important_commands
2972 fi
2973 # }}}
2974
2975 #:grep:marker:for:mika: :-)
2976 ### non-root (EUID != 0) code below
2977 ###
2978
2979 if (( GRML_ALWAYS_LOAD_ALL == 0 )) && (( $EUID == 0 )) ; then
2980     zrclocal
2981     return 0
2982 fi
2983
2984
2985 # variables {{{
2986
2987 # set terminal property (used e.g. by msgid-chooser)
2988 export COLORTERM="yes"
2989
2990 # set default browser
2991 if [[ -z "$BROWSER" ]] ; then
2992     if [[ -n "$DISPLAY" ]] ; then
2993         #v# If X11 is running
2994         check_com -c firefox && export BROWSER=firefox
2995     else
2996         #v# If no X11 is running
2997         check_com -c w3m && export BROWSER=w3m
2998     fi
2999 fi
3000
3001 #m# v QTDIR \kbd{/usr/share/qt[34]}\quad [for non-root only]
3002 [[ -d /usr/share/qt3 ]] && export QTDIR=/usr/share/qt3
3003 [[ -d /usr/share/qt4 ]] && export QTDIR=/usr/share/qt4
3004
3005 # support running 'jikes *.java && jamvm HelloWorld' OOTB:
3006 #v# [for non-root only]
3007 [[ -f /usr/share/classpath/glibj.zip ]] && export JIKESPATH=/usr/share/classpath/glibj.zip
3008 # }}}
3009
3010 # aliases {{{
3011
3012 # Xterm resizing-fu.
3013 # Based on http://svn.kitenet.net/trunk/home-full/.zshrc?rev=11710&view=log (by Joey Hess)
3014 alias hide='echo -en "\033]50;nil2\007"'
3015 alias tiny='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-80-*-*-c-*-iso8859-15\007"'
3016 alias small='echo -en "\033]50;6x10\007"'
3017 alias medium='echo -en "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-80-iso8859-15\007"'
3018 alias default='echo -e "\033]50;-misc-fixed-medium-r-normal-*-*-140-*-*-c-*-iso8859-15\007"'
3019 alias large='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-150-*-*-c-*-iso8859-15\007"'
3020 alias huge='echo -en "\033]50;-misc-fixed-medium-r-normal-*-*-210-*-*-c-*-iso8859-15\007"'
3021 alias smartfont='echo -en "\033]50;-artwiz-smoothansi-*-*-*-*-*-*-*-*-*-*-*-*\007"'
3022 alias semifont='echo -en "\033]50;-misc-fixed-medium-r-semicondensed-*-*-120-*-*-*-*-iso8859-15\007"'
3023
3024 # general
3025 #a2# Execute \kbd{du -sch}
3026 alias da='du -sch'
3027 #a2# Execute \kbd{jobs -l}
3028 alias j='jobs -l'
3029
3030 # compile stuff
3031 #a2# Execute \kbd{./configure}
3032 alias CO="./configure"
3033 #a2# Execute \kbd{./configure --help}
3034 alias CH="./configure --help"
3035
3036 # arch/tla stuff
3037 if check_com -c tla ; then
3038     #a2# Execute \kbd{tla what-changed --diffs | less}
3039     alias tdi='tla what-changed --diffs | less'
3040     #a2# Execute \kbd{tla-buildpackage}
3041     alias tbp='tla-buildpackage'
3042     #a2# Execute \kbd{tla archive-mirror}
3043     alias tmi='tla archive-mirror'
3044     #a2# Execute \kbd{tla commit}
3045     alias tco='tla commit'
3046     #a2# Execute \kbd{tla star-merge}
3047     alias tme='tla star-merge'
3048 fi
3049
3050 # listing stuff
3051 #a2# Execute \kbd{ls -lSrah}
3052 alias dir="ls -lSrah"
3053 #a2# Only show dot-directories
3054 alias lad='ls -d .*(/)'                # only show dot-directories
3055 #a2# Only show dot-files
3056 alias lsa='ls -a .*(.)'                # only show dot-files
3057 #a2# Only files with setgid/setuid/sticky flag
3058 alias lss='ls -l *(s,S,t)'             # only files with setgid/setuid/sticky flag
3059 #a2# Only show 1st ten symlinks
3060 alias lsl='ls -l *(@[1,10])'           # only symlinks
3061 #a2# Display only executables
3062 alias lsx='ls -l *(*[1,10])'           # only executables
3063 #a2# Display world-{readable,writable,executable} files
3064 alias lsw='ls -ld *(R,W,X.^ND/)'       # world-{readable,writable,executable} files
3065 #a2# Display the ten biggest files
3066 alias lsbig="ls -flh *(.OL[1,10])"     # display the biggest files
3067 #a2# Only show directories
3068 alias lsd='ls -d *(/)'                 # only show directories
3069 #a2# Only show empty directories
3070 alias lse='ls -d *(/^F)'               # only show empty directories
3071 #a2# Display the ten newest files
3072 alias lsnew="ls -rl *(D.om[1,10])"     # display the newest files
3073 #a2# Display the ten oldest files
3074 alias lsold="ls -rtlh *(D.om[1,10])"   # display the oldest files
3075 #a2# Display the ten smallest files
3076 alias lssmall="ls -Srl *(.oL[1,10])"   # display the smallest files
3077
3078 # chmod
3079 #a2# Execute \kbd{chmod 600}
3080 alias rw-='chmod 600'
3081 #a2# Execute \kbd{chmod 700}
3082 alias rwx='chmod 700'
3083 #m# a2 r-{}- Execute \kbd{chmod 644}
3084 alias r--='chmod 644'
3085 #a2# Execute \kbd{chmod 755}
3086 alias r-x='chmod 755'
3087
3088 # some useful aliases
3089 #a2# Execute \kbd{mkdir -o}
3090 alias md='mkdir -p'
3091
3092 check_com -c ipython && alias ips='ipython -p sh'
3093
3094 # console stuff
3095 #a2# Execute \kbd{mplayer -vo fbdev}
3096 alias cmplayer='mplayer -vo fbdev'
3097 #a2# Execute \kbd{mplayer -vo fbdev -fs -zoom}
3098 alias fbmplayer='mplayer -vo fbdev -fs -zoom'
3099 #a2# Execute \kbd{links2 -driver fb}
3100 alias fblinks='links2 -driver fb'
3101
3102 #a2# ssh with StrictHostKeyChecking=no \\&\quad and UserKnownHostsFile unset
3103 alias insecssh='ssh -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3104 alias insecscp='scp -o "StrictHostKeyChecking=no" -o "UserKnownHostsFile=/dev/null"'
3105
3106 # simple webserver
3107 check_com -c python && alias http="python -m SimpleHTTPServer"
3108
3109 # Use 'g' instead of 'git':
3110 check_com g || alias g='git'
3111
3112 # use colors when browsing man pages, but only if not using LESS_TERMCAP_* from /etc/zsh/zshenv:
3113 if [[ -z "$LESS_TERMCAP_md" ]] ; then
3114     [[ -d ~/.terminfo/ ]] && alias man='TERMINFO=~/.terminfo/ LESS=C TERM=mostlike PAGER=less man'
3115 fi
3116
3117 # check whether Debian's package management (dpkg) is running
3118 if check_com salias ; then
3119     #a2# Check whether a dpkg instance is currently running
3120     salias check_dpkg_running="dpkg_running"
3121 fi
3122
3123 # work around non utf8 capable software in utf environment via $LANG and luit
3124 if check_com isutfenv && check_com luit ; then
3125     if check_com -c mrxvt ; then
3126         isutfenv && [[ -n "$LANG" ]] && \
3127             alias mrxvt="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit mrxvt"
3128     fi
3129
3130     if check_com -c aterm ; then
3131         isutfenv && [[ -n "$LANG" ]] && \
3132             alias aterm="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit aterm"
3133     fi
3134
3135     if check_com -c centericq ; then
3136         isutfenv && [[ -n "$LANG" ]] && \
3137             alias centericq="LANG=${LANG/(#b)(*)[.@]*/$match[1].iso885915} luit centericq"
3138     fi
3139 fi
3140 # }}}
3141
3142 # useful functions {{{
3143
3144 # searching
3145 #f4# Search for newspostings from authors
3146 agoogle() { ${=BROWSER} "http://groups.google.com/groups?as_uauthors=$*" ; }
3147 #f4# Search Debian Bug Tracking System
3148 debbug()  {
3149     setopt localoptions extendedglob
3150     if [[ $# -eq 1 ]]; then
3151         case "$1" in
3152             ([0-9]##)
3153             ${=BROWSER} "http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=$1"
3154             ;;
3155             (*@*)
3156             ${=BROWSER} "http://bugs.debian.org/cgi-bin/pkgreport.cgi?submitter=$1"
3157             ;;
3158             (*)
3159             ${=BROWSER} "http://bugs.debian.org/$*"
3160             ;;
3161         esac
3162     else
3163         print "$0 needs one argument"
3164         return 1
3165     fi
3166 }
3167 #f4# Search Debian Bug Tracking System in mbox format
3168 debbugm() { bts show --mbox $1 } # provide bugnummer as "$1"
3169 #f4# Search DMOZ
3170 dmoz()    { ${=BROWSER} http://search.dmoz.org/cgi-bin/search\?search=${1// /_} }
3171 #f4# Search German   Wiktionary
3172 dwicti()  { ${=BROWSER} http://de.wiktionary.org/wiki/${(C)1// /_} }
3173 #f4# Search English  Wiktionary
3174 ewicti()  { ${=BROWSER} http://en.wiktionary.org/wiki/${(C)1// /_} }
3175 #f4# Search Google Groups
3176 ggogle()  { ${=BROWSER} "http://groups.google.com/groups?q=$*" }
3177 #f4# Search Google
3178 google()  { ${=BROWSER} "http://www.google.com/search?&num=100&q=$*" }
3179 #f4# Search Google Groups for MsgID
3180 mggogle() { ${=BROWSER} "http://groups.google.com/groups?selm=$*" }
3181 #f4# Search Netcraft
3182 netcraft(){ ${=BROWSER} "http://toolbar.netcraft.com/site_report?url=$1" }
3183 #f4# Use German Wikipedia's full text search
3184 swiki()   { ${=BROWSER} http://de.wikipedia.org/wiki/Spezial:Search/${(C)1} }
3185 #f4# search \kbd{dict.leo.org}
3186 oleo()    { ${=BROWSER} "http://dict.leo.org/?search=$*" }
3187 #f4# Search German   Wikipedia
3188 wikide()  { ${=BROWSER} http://de.wikipedia.org/wiki/"${(C)*}" }
3189 #f4# Search English  Wikipedia
3190 wikien()  { ${=BROWSER} http://en.wikipedia.org/wiki/"${(C)*}" }
3191 #f4# Search official debs
3192 wodeb()   { ${=BROWSER} "http://packages.debian.org/search?keywords=$1&searchon=contents&suite=${2:=unstable}&section=all" }
3193
3194 #m# f4 gex() Exact search via Google
3195 check_com google && gex () { google "\"[ $1]\" $*" } # exact search at google
3196
3197 # misc
3198 #f5# Backup \kbd{file {\rm to} file\_timestamp}
3199 bk()      { cp -b ${1} ${1}_`date --iso-8601=m` }
3200 #f5# Copied diff
3201 cdiff()   { diff -crd "$*" | egrep -v "^Only in |^Binary files " }
3202 #f5# cd to directoy and list files
3203 cl()      { cd $1 && ls -a }        # cd && ls
3204 #f5# Cvs add
3205 cvsa()    { cvs add $* && cvs com -m 'initial checkin' $* }
3206 #f5# Cvs diff
3207 cvsd()    { cvs diff -N $* |& $PAGER }
3208 #f5# Cvs log
3209 cvsl()    { cvs log $* |& $PAGER }
3210 #f5# Cvs update
3211 cvsq()    { cvs -nq update }
3212 #f5# Rcs2log
3213 cvsr()    { rcs2log $* | $PAGER }
3214 #f5# Cvs status
3215 cvss()    { cvs status -v $* }
3216 #f5# Disassemble source files using gcc and as
3217 disassemble(){ gcc -pipe -S -o - -O -g $* | as -aldh -o /dev/null }
3218 #f5# Firefox remote control - open given URL
3219 fir()     { firefox -a firefox -remote "openURL($1)" }
3220 #f5# Create Directoy and \kbd{cd} to it
3221 mcd()     { mkdir -p "$@"; cd "$@" } # mkdir && cd
3222 #f5# Unified diff to timestamped outputfile
3223 mdiff()   { diff -udrP "$1" "$2" > diff.`date "+%Y-%m-%d"`."$1" }
3224 #f5# Memory overview
3225 memusage(){ ps aux | awk '{if (NR > 1) print $5; if (NR > 2) print "+"} END { print "p" }' | dc }
3226 #f5# Show contents of tar file
3227 shtar()   { gunzip -c $1 | tar -tf - -- | $PAGER }
3228 #f5# Show contents of tgz file
3229 shtgz()   { tar -ztf $1 | $PAGER }
3230 #f5# Show contents of zip file
3231 shzip()   { unzip -l $1 | $PAGER }
3232 #f5# Greps signature from file
3233 sig()     { agrep -d '^-- $' "$*" ~/.Signature }
3234 #f5# Unified diff
3235 udiff()   { diff -urd $* | egrep -v "^Only in |^Binary files " }
3236 #f5# (Mis)use \kbd{vim} as \kbd{less}
3237 viless()  { vim --cmd 'let no_plugin_maps = 1' -c "so \$VIMRUNTIME/macros/less.vim" "${@:--}" }
3238
3239 # download video from youtube
3240 ytdl() {
3241     if ! [[ -n "$2" ]] ; then
3242         print "Usage: ydtl http://youtube.com/watch?v=.... outputfile.flv">&2
3243         return 1
3244     else
3245         wget -O${2} "http://youtube.com/get_video?"${${${"$(wget -o/dev/null -O- "${1}" | grep -e watch_fullscreen)"}##*watch_fullscreen\?}%%\&fs=*}
3246     fi
3247 }
3248
3249 # Function Usage: uopen $URL/$file
3250 #f5# Download a file and display it locally
3251 uopen() {
3252     if ! [[ -n "$1" ]] ; then
3253         print "Usage: uopen \$URL/\$file">&2
3254         return 1
3255     else
3256         FILE=$1
3257         MIME=$(curl --head $FILE | grep Content-Type | cut -d ' ' -f 2 | cut -d\; -f 1)
3258         MIME=${MIME%$'\r'}
3259         curl $FILE | see ${MIME}:-
3260     fi
3261 }
3262
3263 # Function Usage: doc packagename
3264 #f5# \kbd{cd} to /usr/share/doc/\textit{package}
3265 doc() { cd /usr/share/doc/$1 && ls }
3266 _doc() { _files -W /usr/share/doc -/ }
3267 check_com compdef && compdef _doc doc
3268
3269 #f5# Make screenshot
3270 sshot() {
3271     [[ ! -d ~/shots  ]] && mkdir ~/shots
3272     #cd ~/shots ; sleep 5 ; import -window root -depth 8 -quality 80 `date "+%Y-%m-%d--%H:%M:%S"`.png
3273     cd ~/shots ; sleep 5; import -window root shot_`date --iso-8601=m`.jpg
3274 }
3275
3276 # list images only
3277 limg() {
3278     local -a images
3279     images=( *.{jpg,gif,png}(.N) )
3280
3281     if [[ $#images -eq 0 ]] ; then
3282         print "No image files found"
3283     else
3284         ls "$@" "$images[@]"
3285     fi
3286 }
3287
3288 #f5# Create PDF file from source code
3289 makereadable() {
3290     output=$1
3291     shift
3292     a2ps --medium A4dj -E -o $output $*
3293     ps2pdf $output
3294 }
3295
3296 # zsh with perl-regex - use it e.g. via:
3297 # regcheck '\s\d\.\d{3}\.\d{3} Euro' ' 1.000.000 Euro'
3298 #f5# Checks whether a regex matches or not.\\&\quad Example: \kbd{regcheck '.\{3\} EUR' '500 EUR'}
3299 regcheck() {
3300     zmodload -i zsh/pcre
3301     pcre_compile $1 && \
3302     pcre_match $2 && echo "regex matches" || echo "regex does not match"
3303 }
3304
3305 #f5# List files which have been modified within the last {\it n} days
3306 new() { print -l *(m-$1) }
3307
3308 #f5# Grep in history
3309 greph() { history 0 | grep $1 }
3310 # use colors when GNU grep with color-support
3311 #a2# Execute \kbd{grep -{}-color=auto}
3312 (grep --help 2>/dev/null |grep -- --color) >/dev/null && alias grep='grep --color=auto'
3313 #a2# Execute \kbd{grep -i -{}-color=auto}
3314 alias GREP='grep -i --color=auto'
3315
3316 # one blank line between each line
3317 if [[ -r ~/.terminfo/m/mostlike ]] ; then
3318     #f5# Watch manpages in a stretched style
3319     man2() { PAGER='dash -c "sed G | /usr/bin/less"' TERM=mostlike /usr/bin/man "$@" ; }
3320 fi
3321
3322 # d():Copyright 2005 Nikolai Weibull <nikolai@bitwi.se>
3323 # note: option AUTO_PUSHD has to be set
3324 #f5# Jump between directories
3325 d() {
3326     emulate -L zsh
3327     autoload -U colors
3328     local color=$fg_bold[blue]
3329     integer i=0
3330     dirs -p | while read dir; do
3331         local num="${$(printf "%-4d " $i)/ /.}"
3332         printf " %s  $color%s$reset_color\n" $num $dir
3333         (( i++ ))
3334     done
3335     integer dir=-1
3336     read -r 'dir?Jump to directory: ' || return
3337     (( dir == -1 )) && return
3338     if (( dir < 0 || dir >= i )); then
3339         echo d: no such directory stack entry: $dir
3340         return 1
3341     fi
3342     cd ~$dir
3343 }
3344
3345 # usage example: 'lcheck strcpy'
3346 #f5# Find out which libs define a symbol
3347 lcheck() {
3348     if [[ -n "$1" ]] ; then
3349         nm -go /usr/lib/lib*.a 2>/dev/null | grep ":[[:xdigit:]]\{8\} . .*$1"
3350     else
3351         echo "Usage: lcheck <function>" >&2
3352     fi
3353 }
3354
3355 #f5# Clean up directory - remove well known tempfiles
3356 purge() {
3357     FILES=(*~(N) .*~(N) \#*\#(N) *.o(N) a.out(N) *.core(N) *.cmo(N) *.cmi(N) .*.swp(N))
3358     NBFILES=${#FILES}
3359     if [[ $NBFILES > 0 ]] ; then
3360         print $FILES
3361         local ans
3362         echo -n "Remove these files? [y/n] "
3363         read -q ans
3364         if [[ $ans == "y" ]] ; then
3365             rm ${FILES}
3366             echo ">> $PWD purged, $NBFILES files removed"
3367         else
3368             echo "Ok. .. than not.."
3369         fi
3370     fi
3371 }
3372
3373 # Translate DE<=>EN
3374 # 'translate' looks up fot a word in a file with language-to-language
3375 # translations (field separator should be " : "). A typical wordlist looks
3376 # like at follows:
3377 #  | english-word : german-transmission
3378 # It's also only possible to translate english to german but not reciprocal.
3379 # Use the following oneliner to turn back the sort order:
3380 #  $ awk -F ':' '{ print $2" : "$1" "$3 }' \
3381 #    /usr/local/lib/words/en-de.ISO-8859-1.vok > ~/.translate/de-en.ISO-8859-1.vok
3382 #f5# Translates a word
3383 trans() {
3384     case "$1" in
3385         -[dD]*)
3386             translate -l de-en $2
3387             ;;
3388         -[eE]*)
3389             translate -l en-de $2
3390             ;;
3391         *)
3392             echo "Usage: $0 { -D | -E }"
3393             echo "         -D == German to English"
3394             echo "         -E == English to German"
3395     esac
3396 }
3397
3398 #f5# List all occurrences of programm in current PATH
3399 plap() {
3400     if [[ $# = 0 ]] ; then
3401         echo "Usage:    $0 program"
3402         echo "Example:  $0 zsh"
3403         echo "Lists all occurrences of program in the current PATH."
3404     else
3405         ls -l ${^path}/*$1*(*N)
3406     fi
3407 }
3408
3409 # Found in the mailinglistarchive from Zsh (IIRC ~1996)
3410 #f5# Select items for specific command(s) from history
3411 selhist() {
3412     emulate -L zsh
3413     local TAB=$'\t';
3414     (( $# < 1 )) && {
3415         echo "Usage: $0 command"
3416         return 1
3417     };
3418     cmd=(${(f)"$(grep -w $1 $HISTFILE | sort | uniq | pr -tn)"})
3419     print -l $cmd | less -F
3420     echo -n "enter number of desired command [1 - $(( ${#cmd[@]} - 1 ))]: "
3421     local answer
3422     read answer
3423     print -z "${cmd[$answer]#*$TAB}"
3424 }
3425
3426 # Use vim to convert plaintext to HTML
3427 #f5# Transform files to html with highlighting
3428 2html() { vim -u NONE -n -c ':syntax on' -c ':so $VIMRUNTIME/syntax/2html.vim' -c ':wqa' $1 &>/dev/null }
3429
3430 # Usage: simple-extract <file>
3431 #f5# Smart archive extractor
3432 simple-extract () {
3433     if [[ -f $1 ]] ; then
3434         case $1 in
3435             *.tar.bz2)  bzip2 -v -d $1      ;;
3436             *.tar.gz)   tar -xvzf $1        ;;
3437             *.rar)      unrar $1            ;;
3438             *.deb)      ar -x $1            ;;
3439             *.bz2)      bzip2 -d $1         ;;
3440             *.lzh)      lha x $1            ;;
3441             *.gz)       gunzip -d $1        ;;
3442             *.tar)      tar -xvf $1         ;;
3443             *.tgz)      gunzip -d $1        ;;
3444             *.tbz2)     tar -jxvf $1        ;;
3445             *.zip)      unzip $1            ;;
3446             *.Z)        uncompress $1       ;;
3447             *)          echo "'$1' Error. Please go away" ;;
3448         esac
3449     else
3450         echo "'$1' is not a valid file"
3451     fi
3452 }
3453
3454 # Usage: smartcompress <file> (<type>)
3455 #f5# Smart archive creator
3456 smartcompress() {
3457     if [[ -n $2 ]] ; then
3458         case $2 in
3459             tgz | tar.gz)   tar -zcvf$1.$2 $1 ;;
3460             tbz2 | tar.bz2) tar -jcvf$1.$2 $1 ;;
3461             tar.Z)          tar -Zcvf$1.$2 $1 ;;
3462             tar)            tar -cvf$1.$2  $1 ;;
3463             gz | gzip)      gzip           $1 ;;
3464             bz2 | bzip2)    bzip2          $1 ;;
3465             *)
3466                 echo "Error: $2 is not a valid compression type"
3467                 ;;
3468         esac
3469     else
3470         smartcompress $1 tar.gz
3471     fi
3472 }
3473
3474 # Usage: show-archive <archive>
3475 #f5# List an archive's content
3476 show-archive() {
3477     if [[ -f $1 ]] ; then
3478         case $1 in
3479             *.tar.gz)      gunzip -c $1 | tar -tf - -- ;;
3480             *.tar)         tar -tf $1 ;;
3481             *.tgz)         tar -ztf $1 ;;
3482             *.zip)         unzip -l $1 ;;
3483             *.bz2)         bzless $1 ;;
3484             *.deb)         dpkg-deb --fsys-tarfile $1 | tar -tf - -- ;;
3485             *)             echo "'$1' Error. Please go away" ;;
3486         esac
3487     else
3488         echo "'$1' is not a valid archive"
3489     fi
3490 }
3491
3492 # It's shameless stolen from <http://www.vim.org/tips/tip.php?tip_id=167>
3493 #f5# Use \kbd{vim} as your manpage reader
3494 vman() { man $* | col -b | view -c 'set ft=man nomod nolist' - }
3495
3496 # function readme() { $PAGER -- (#ia3)readme* }
3497 #f5# View all README-like files in current directory in pager
3498 readme() {
3499     local files
3500     files=(./(#i)*(read*me|lue*m(in|)ut)*(ND))
3501     if (($#files)) ; then
3502         $PAGER $files
3503     else
3504         print 'No README files.'
3505     fi
3506 }
3507
3508 # function ansi-colors()
3509 #f5# Display ANSI colors
3510 ansi-colors() {
3511     typeset esc="\033[" line1 line2
3512     echo " _ _ _40 _ _ _41_ _ _ _42 _ _ 43_ _ _ 44_ _ _45 _ _ _ 46_ _ _ 47_ _ _ 49_ _"
3513     for fore in 30 31 32 33 34 35 36 37; do
3514         line1="$fore "
3515         line2="   "
3516         for back in 40 41 42 43 44 45 46 47 49; do
3517             line1="${line1}${esc}${back};${fore}m Normal ${esc}0m"
3518             line2="${line2}${esc}${back};${fore};1m Bold   ${esc}0m"
3519         done
3520         echo -e "$line1\n$line2"
3521     done
3522 }
3523
3524 # suidfind() { ls -latg $path | grep '^...s' }
3525 #f5# Find all files in \$PATH with setuid bit set
3526 suidfind() { ls -latg $path/*(sN) }
3527
3528 # See above but this is /better/ ... anywise ..
3529 findsuid() {
3530     print 'Output will be written to ~/suid_* ...'
3531     $SUDO find / -type f \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suidfiles.`date "+%Y-%m-%d"`.out 2>&1
3532     $SUDO find / -type d \( -perm -4000 -o -perm -2000 \) -ls > ~/suid_suiddirs.`date "+%Y-%m-%d"`.out 2>&1
3533     $SUDO find / -type f \( -perm -2 -o -perm -20 \) -ls > ~/suid_writefiles.`date "+%Y-%m-%d"`.out 2>&1
3534     $SUDO find / -type d \( -perm -2 -o -perm -20 \) -ls > ~/suid_writedirs.`date "+%Y-%m-%d"`.out 2>&1
3535     print 'Finished'
3536 }
3537
3538 #f5# Reload given functions
3539 refunc() {
3540     for func in $argv ; do
3541         unfunction $func
3542         autoload $func
3543     done
3544 }
3545
3546 # a small check to see which DIR is located on which server/partition.
3547 # stolen and modified from Sven's zshrc.forall
3548 #f5# Report diskusage of a directory
3549 dirspace() {
3550     if [[ -n "$1" ]] ; then
3551         for dir in $* ; do
3552             if [[ -d "$dir" ]] ; then
3553                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3554             else
3555                 echo "warning: $dir does not exist" >&2
3556             fi
3557         done
3558     else
3559         for dir in $path; do
3560             if [[ -d "$dir" ]] ; then
3561                 ( cd $dir; echo "-<$dir>"; du -shx .; echo);
3562             else
3563                 echo "warning: $dir does not exist" >&2
3564             fi
3565         done
3566     fi
3567 }
3568
3569 # % slow_print `cat /etc/passwd`
3570 #f5# Slowly print out parameters
3571 slow_print() {
3572     for argument in "${@}" ; do
3573         for ((i = 1; i <= ${#1} ;i++)) ; do
3574             print -n "${argument[i]}"
3575             sleep 0.08
3576         done
3577         print -n " "
3578     done
3579     print ""
3580 }
3581
3582 #f5# Show some status info
3583 status() {
3584     print ""
3585     print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
3586     print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
3587     print "Term..: $TTY ($TERM), ${BAUD:+$BAUD bauds, }$COLUMNS x $LINES cars"
3588     print "Login.: $LOGNAME (UID = $EUID) on $HOST"
3589     print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
3590     print "Uptime:$(uptime)"
3591     print ""
3592 }
3593
3594 # Rip an audio CD
3595 #f5# Rip an audio CD
3596 audiorip() {
3597     mkdir -p ~/ripps
3598     cd ~/ripps
3599     cdrdao read-cd --device $DEVICE --driver generic-mmc audiocd.toc
3600     cdrdao read-cddb --device $DEVICE --driver generic-mmc audiocd.toc
3601     echo " * Would you like to burn the cd now? (yes/no)"
3602     read input
3603     if [[ "$input" = "yes" ]] ; then
3604         echo " ! Burning Audio CD"
3605         audioburn
3606         echo " * done."
3607     else
3608         echo " ! Invalid response."
3609     fi
3610 }
3611
3612 # and burn it
3613 #f5# Burn an audio CD (in combination with audiorip)
3614 audioburn() {
3615     cd ~/ripps
3616     cdrdao write --device $DEVICE --driver generic-mmc audiocd.toc
3617     echo " * Should I remove the temporary files? (yes/no)"
3618     read input
3619     if [[ "$input" = "yes" ]] ; then
3620         echo " ! Removing Temporary Files."
3621         cd ~
3622         rm -rf ~/ripps
3623         echo " * done."
3624     else
3625         echo " ! Invalid response."
3626     fi
3627 }
3628
3629 #f5# Make an audio CD from all mp3 files
3630 mkaudiocd() {
3631     # TODO: do the renaming more zshish, possibly with zmv()
3632     cd ~/ripps
3633     for i in *.[Mm][Pp]3; do mv "$i" `echo $i | tr '[A-Z]' '[a-z]'`; done
3634     for i in *.mp3; do mv "$i" `echo $i | tr ' ' '_'`; done
3635     for i in *.mp3; do mpg123 -w `basename $i .mp3`.wav $i; done
3636     normalize -m *.wav
3637     for i in *.wav; do sox $i.wav -r 44100 $i.wav resample; done
3638 }
3639
3640 #f5# Create an ISO image. You are prompted for\\&\quad volume name, filename and directory
3641 mkiso() {
3642     echo " * Volume name "
3643     read volume
3644     echo " * ISO Name (ie. tmp.iso)"
3645     read iso
3646     echo " * Directory or File"
3647     read files
3648     mkisofs -o ~/$iso -A $volume -allow-multidot -J -R -iso-level 3 -V $volume -R $files
3649 }
3650
3651 #f5# Simple thumbnails generator
3652 genthumbs() {
3653     rm -rf thumb-* index.html
3654     echo "
3655 <html>
3656   <head>
3657     <title>Images</title>
3658   </head>
3659   <body>" > index.html
3660     for f in *.(gif|jpeg|jpg|png) ; do
3661         convert -size 100x200 "$f" -resize 100x200 thumb-"$f"
3662         echo "    <a href=\"$f\"><img src=\"thumb-$f\"></a>" >> index.html
3663     done
3664     echo "
3665   </body>
3666 </html>" >> index.html
3667 }
3668
3669 #f5# Set all ulimit parameters to \kbd{unlimited}
3670 allulimit() {
3671     ulimit -c unlimited
3672     ulimit -d unlimited
3673     ulimit -f unlimited
3674     ulimit -l unlimited
3675     ulimit -n unlimited
3676     ulimit -s unlimited
3677     ulimit -t unlimited
3678 }
3679
3680 # ogg2mp3 with bitrate of 192
3681 ogg2mp3_192() {
3682     oggdec -o - ${1} | lame -b 192 - ${1:r}.mp3
3683 }
3684
3685 #f5# RFC 2396 URL encoding in Z-Shell
3686 urlencode() {
3687     setopt localoptions extendedglob
3688     input=( ${(s::)1} )
3689     print ${(j::)input/(#b)([^A-Za-z0-9_.!~*\'\(\)-])/%${(l:2::0:)$(([##16]#match))}}
3690 }
3691
3692 #f5# Install x-lite (VoIP software)
3693 getxlite() {
3694     setopt local_options
3695     setopt errreturn
3696     [[ -d ~/tmp ]] || mkdir ~/tmp
3697     cd ~/tmp
3698
3699     echo "Downloading http://www.counterpath.com/download/X-Lite_Install.tar.gz and storing it in ~/tmp:"
3700     if wget http://www.counterpath.com/download/X-Lite_Install.tar.gz ; then
3701         unp X-Lite_Install.tar.gz && echo done || echo failed
3702     else
3703         echo "Error while downloading." ; return 1
3704     fi
3705
3706     if [[ -x xten-xlite/xtensoftphone ]] ; then
3707         echo "Execute xten-xlite/xtensoftphone to start xlite."
3708     fi
3709 }
3710
3711 #f5# Install skype
3712 getskype() {
3713     setopt local_options
3714     setopt errreturn
3715     echo "Downloading debian package of skype."
3716     echo "Notice: If you want to use a more recent skype version run 'getskypebeta'."
3717     wget http://www.skype.com/go/getskype-linux-deb
3718     $SUDO dpkg -i skype*.deb && echo "skype installed."
3719 }
3720
3721 #f5# Install beta-version of skype
3722 getskypebeta() {
3723     setopt local_options
3724     setopt errreturn
3725     echo "Downloading debian package of skype (beta version)."
3726     wget http://www.skype.com/go/getskype-linux-beta-deb
3727     $SUDO dpkg -i skype-beta*.deb && echo "skype installed."
3728 }
3729
3730 #f5# Install gizmo (VoIP software)
3731 getgizmo() {
3732     setopt local_options
3733     setopt errreturn
3734     echo "libgtk2.0-0, gconf2, libstdc++6, libasound2 and zlib1g have to be available. Installing."
3735     $SUDO apt-get update
3736     $SUDO apt-get install libgtk2.0-0 gconf2 libstdc++6 libasound2 zlib1g
3737     wget "$(lynx --dump http://gizmo5.com/pc/download/linux/ | awk '/libstdc\+\+6.*\.deb/ {print $2}')"
3738     $SUDO dpkg -i gizmo-project*.deb && echo "gizmo installed."
3739 }
3740
3741 #f5# Get and run AIR (Automated Image and Restore)
3742 getair() {
3743     setopt local_options
3744     setopt errreturn
3745     [[ -w . ]] || { echo 'Error: you do not have write permissions in this directory. Exiting.' ; return 1 }
3746     local VER='1.2.8'
3747     wget http://puzzle.dl.sourceforge.net/sourceforge/air-imager/air-$VER.tar.gz
3748     tar zxf air-$VER.tar.gz
3749     cd air-$VER
3750     INTERACTIVE=no $SUDO ./install-air-1.2.8
3751     [[ -x /usr/local/bin/air ]] && [[ -n "$DISPLAY" ]] && $SUDO air
3752 }
3753
3754 #f5# Get specific git commitdiff
3755 git-get-diff() {
3756     if [[ -z $GITTREE ]] ; then
3757         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3758     fi
3759     if ! [[ -z $1 ]] ; then
3760         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commitdiff;h=$1"
3761     else
3762         echo "Usage: git-get-diff <commit>"
3763     fi
3764 }
3765
3766 #f5# Get specific git commit
3767 git-get-commit() {
3768     if [[ -z $GITTREE ]] ; then
3769         GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3770     fi
3771     if ! [[ -z $1 ]] ; then
3772         ${=BROWSER} "http://kernel.org/git/?p=$GITTREE;a=commit;h=$1"
3773     else
3774         echo "Usage: git-get-commit <commit>"
3775     fi
3776 }
3777
3778 #f5# Get specific git diff
3779 git-get-plaindiff () {
3780     if [[ -z $GITTREE ]] ; then
3781        GITTREE='linux/kernel/git/torvalds/linux-2.6.git'
3782     fi
3783     if [[ -z $1 ]] ; then
3784        echo 'Usage: git-get-plaindiff '
3785     else
3786        echo -n "Downloading $1.diff ... "
3787        # avoid "generating ..." stuff from kernel.org server:
3788        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O /dev/null
3789        wget --quiet "http://kernel.org/git/?p=$GITTREE;a=commitdiff_plain;h=$1" -O $1.diff \
3790             && echo done || echo failed
3791     fi
3792 }
3793
3794
3795 # http://strcat.de/blog/index.php?/archives/335-Software-sauber-deinstallieren...html
3796 #f5# Log 'make install' output
3797 mmake() {
3798     [[ ! -d ~/.errorlogs ]] && mkdir ~/.errorlogs
3799     make -n install > ~/.errorlogs/${PWD##*/}-makelog
3800 }
3801
3802 #f5# Indent source code
3803 smart-indent() {
3804     indent -npro -kr -i8 -ts8 -sob -l80 -ss -ncs $*
3805 }
3806
3807 # highlight important stuff in diff output, usage example: hg diff | hidiff
3808 #m# a2 hidiff \kbd{histring} oneliner for diffs
3809 check_com -c histring && \
3810     alias hidiff="histring -fE '^Comparing files .*|^diff .*' | histring -c yellow -fE '^\-.*' | histring -c green -fE '^\+.*'"
3811
3812 # rename pictures based on information found in exif headers
3813 #f5# Rename pictures based on information found in exif headers
3814 exirename() {
3815     if [[ $# -lt 1 ]] ; then
3816         echo 'Usage: jpgrename $FILES' >& 2
3817         return 1
3818     else
3819         echo -n 'Checking for jhead with version newer than 1.9: '
3820         jhead_version=`jhead -h | grep 'used by most Digital Cameras.  v.*' | awk '{print $6}' | tr -d v`
3821         if [[ $jhead_version > '1.9' ]]; then
3822             echo 'success - now running jhead.'
3823             jhead -n%Y-%m-%d_%Hh%M_%f $*
3824         else
3825             echo 'failed - exiting.'
3826         fi
3827     fi
3828 }
3829
3830 # open file in vim and jump to line
3831 # http://www.downgra.de/archives/2007/05/08/T19_21_11/
3832 j2v() {
3833     local -a params
3834     params=(${*//(#m):[0-9]*:/\\n+${MATCH//:/}}) # replace ':23:' to '\n+23'
3835     params=(${(s|\n|)${(j|\n|)params}}) # join array using '\n', then split on all '\n'
3836     vim ${params}
3837 }
3838
3839 # get_ic() - queries imap servers for capabilities; real simple. no imaps
3840 ic_get() {
3841     local port
3842     if [[ ! -z $1 ]] ; then
3843         port=${2:-143}
3844         print "querying imap server on $1:${port}...\n";
3845         print "a1 capability\na2 logout\n" | nc $1 ${port}
3846     else
3847         print "usage:\n  $0 <imap-server> [port]"
3848     fi
3849 }
3850
3851 # creates a Maildir/ with its {new,cur,tmp} subdirs
3852 mkmaildir() {
3853     local root subdir
3854     root=${MAILDIR_ROOT:-${HOME}/Mail}
3855     if [[ -z ${1} ]] ; then print "Usage:\n $0 <dirname>" ; return 1 ; fi
3856     subdir=${1}
3857     mkdir -p ${root}/${subdir}/{cur,new,tmp}
3858 }
3859
3860 #f5# Change the xterm title from within GNU-screen
3861 xtrename() {
3862     if [[ ${1} != "-f" ]] ; then
3863         if [[ -z ${DISPLAY} ]] ; then
3864             printf 'xtrename only makes sense in X11.\n'
3865             return 1
3866         fi
3867     else
3868         shift
3869     fi
3870     if [[ -z ${1} ]] ; then
3871         printf 'usage: xtrename [-f] "title for xterm"\n'
3872         printf '  renames the title of xterm from _within_ screen.\n'
3873         printf '  also works without screen.\n'
3874         printf '  will not work if DISPLAY is unset, use -f to override.\n'
3875         return 0
3876     fi
3877     print -n "\eP\e]0;${1}\C-G\e\\"
3878     return 0
3879 }
3880
3881 # hl() highlighted less
3882 # http://ft.bewatermyfriend.org/comp/data/zsh/zfunct.html
3883 if check_com -c highlight ; then
3884     function hl() {
3885         local theme lang
3886         theme=${HL_THEME:-""}
3887         case ${1} in
3888             (-l|--list)
3889                 ( printf 'available languages (syntax parameter):\n\n' ;
3890                     highlight --list-langs ; ) | less -SMr
3891                 ;;
3892             (-t|--themes)
3893                 ( printf 'available themes (style parameter):\n\n' ;
3894                     highlight --list-themes ; ) | less -SMr
3895                 ;;
3896             (-h|--help)
3897                 printf 'usage: hl <syntax[:theme]> <file>\n'
3898                 printf '    available options: --list (-l), --themes (-t), --help (-h)\n\n'
3899                 printf '  Example: hl c main.c\n'
3900                 ;;
3901             (*)
3902                 if [[ -z ${2} ]] || (( ${#argv} > 2 )) ; then
3903                     printf 'usage: hl <syntax[:theme]> <file>\n'
3904                     printf '    available options: --list (-l), --themes (-t), --help (-h)\n'
3905                     (( ${#argv} > 2 )) && printf '  Too many arguments.\n'
3906                     return 1
3907                 fi
3908                 lang=${1%:*}
3909                 [[ ${1} == *:* ]] && [[ -n ${1#*:} ]] && theme=${1#*:}
3910                 if [[ -n ${theme} ]] ; then
3911                     highlight --xterm256 --syntax ${lang} --style ${theme} ${2} | less -SMr
3912                 else
3913                     highlight --ansi --syntax ${lang} ${2} | less -SMr
3914                 fi
3915                 ;;
3916         esac
3917         return 0
3918     }
3919     # ... and a proper completion for hl()
3920     # needs 'highlight' as well, so it fits fine in here.
3921     function _hl_genarg()  {
3922         local expl
3923         if [[ -prefix 1 *: ]] ; then
3924             local themes
3925             themes=(${${${(f)"$(LC_ALL=C highlight --list-themes)"}/ #/}:#*(Installed|Use name)*})
3926             compset -P 1 '*:'
3927             _wanted -C list themes expl theme compadd ${themes}
3928         else
3929             local langs
3930             langs=(${${${(f)"$(LC_ALL=C highlight --list-langs)"}/ #/}:#*(Installed|Use name)*})
3931             _wanted -C list languages expl languages compadd -S ':' -q ${langs}
3932         fi
3933     }
3934     function _hl_complete() {
3935         _arguments -s '1: :_hl_genarg' '2:files:_path_files'
3936     }
3937     compdef _hl_complete hl
3938 fi
3939
3940 # Create small urls via http://tinyurl.com using wget(1).
3941 function zurl() {
3942     [[ -z ${1} ]] && { print "USAGE: zurl <URL>" ; return 1 }
3943
3944     local PN url tiny grabber search result preview
3945     PN=${0}
3946     url=${1}
3947 #   Check existence of given URL with the help of ping(1).
3948 #   N.B. ping(1) only works without an eventual given protocol.
3949     ping -c 1 ${${url#(ftp|http)://}%%/*} >& /dev/null || \
3950         read -q "?Given host ${${url#http://*/}%/*} is not reachable by pinging. Proceed anyway? [y|n] "
3951
3952     if (( $? == 0 )) ; then
3953 #           Prepend 'http://' to given URL where necessary for later output.
3954             [[ ${url} != http(s|)://* ]] && url='http://'${url}
3955             tiny='http://tinyurl.com/create.php?url='
3956             if check_com -c wget ; then
3957                 grabber='wget -O- -o/dev/null'
3958             else
3959                 print "wget is not available, but mandatory for ${PN}. Aborting."
3960             fi
3961 #           Looking for i.e.`copy('http://tinyurl.com/7efkze')' in TinyURL's HTML code.
3962             search='copy\(?http://tinyurl.com/[[:alnum:]]##*'
3963             result=${(M)${${${(f)"$(${=grabber} ${tiny}${url})"}[(fr)${search}*]}//[()\';]/}%%http:*}
3964 #           TinyURL provides the rather new feature preview for more confidence. <http://tinyurl.com/preview.php>
3965             preview='http://preview.'${result#http://}
3966
3967             printf '%s\n\n' "${PN} - Shrinking long URLs via webservice TinyURL <http://tinyurl.com>."
3968             printf '%s\t%s\n\n' 'Given URL:' ${url}
3969             printf '%s\t%s\n\t\t%s\n' 'TinyURL:' ${result} ${preview}
3970     else
3971         return 1
3972     fi
3973 }
3974
3975 #f2# Print a specific line of file(s).
3976 linenr () {
3977 # {{{
3978     if [ $# -lt 2 ] ; then
3979        print "Usage: linenr <number>[,<number>] <file>" ; return 1
3980     elif [ $# -eq 2 ] ; then
3981          local number=$1
3982          local file=$2
3983          command ed -s $file <<< "${number}n"
3984     else
3985          local number=$1
3986          shift
3987          for file in "$@" ; do
3988              if [ ! -d $file ] ; then
3989                 echo "${file}:"
3990                 command ed -s $file <<< "${number}n" 2> /dev/null
3991              else
3992                 continue
3993              fi
3994          done | less
3995     fi
3996 # }}}
3997 }
3998
3999 #f2# Find history events by search pattern and list them by date.
4000 whatwhen()  {
4001 # {{{
4002     local usage help ident format_l format_s first_char remain first last
4003     usage='USAGE: whatwhen [options] <searchstring> <search range>'
4004     help='Use' \`'whatwhen -h'\'' for further explanations.'
4005     ident=${(l,${#${:-Usage: }},, ,)}
4006     format_l="${ident}%s\t\t\t%s\n"
4007     format_s="${format_l//(\\t)##/\\t}"
4008     # Make the first char of the word to search for case
4009     # insensitive; e.g. [aA]
4010     first_char=[${(L)1[1]}${(U)1[1]}]
4011     remain=${1[2,-1]}
4012     # Default search range is `-100'.
4013     first=${2:-\-100}
4014     # Optional, just used for `<first> <last>' given.
4015     last=$3
4016     case $1 in
4017         ("")
4018             printf '%s\n\n' 'ERROR: No search string specified. Aborting.'
4019             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4020         ;;
4021         (-h)
4022             printf '%s\n\n' ${usage}
4023             print 'OPTIONS:'
4024             printf $format_l '-h' 'show help text'
4025             print '\f'
4026             print 'SEARCH RANGE:'
4027             printf $format_l "'0'" 'the whole history,'
4028             printf $format_l '-<n>' 'offset to the current history number; (default: -100)'
4029             printf $format_s '<[-]first> [<last>]' 'just searching within a give range'
4030             printf '\n%s\n' 'EXAMPLES:'
4031             printf ${format_l/(\\t)/} 'whatwhen grml' '# Range is set to -100 by default.'
4032             printf $format_l 'whatwhen zsh -250'
4033             printf $format_l 'whatwhen foo 1 99'
4034         ;;
4035         (\?)
4036             printf '%s\n%s\n\n' ${usage} ${help} && return 1
4037         ;;
4038         (*)
4039             # -l list results on stout rather than invoking $EDITOR.
4040             # -i Print dates as in YYYY-MM-DD.
4041             # -m Search for a - quoted - pattern within the history.
4042             fc -li -m "*${first_char}${remain}*" $first $last
4043         ;;
4044     esac
4045 # }}}
4046 }
4047
4048 # change fluxbox keys from 'Alt-#' to 'Alt-F#' and vice versa
4049 fluxkey-change() {
4050     [[ -n "$FLUXKEYS" ]] || local FLUXKEYS="$HOME/.fluxbox/keys"
4051     if ! [[ -r "$FLUXKEYS" ]] ; then
4052         echo "Sorry, \$FLUXKEYS file $FLUXKEYS could not be read - nothing to be done."
4053         return 1
4054     else
4055         if grep -q 'Mod1 F[0-9] :Workspace [0-9]' $FLUXKEYS ; then
4056             echo -n 'Switching to Alt-# mode in ~/.fluxbox/keys: '
4057             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)F\([0-9]\+[: space :]\+:Workspace.*\)|\1\2|' $FLUXKEYS && echo done || echo failed
4058         elif grep -q 'Mod1 [0-9] :Workspace [0-9]' $FLUXKEYS ; then
4059             echo -n 'Switching to Alt-F# mode in ~/.fluxbox/keys: '
4060             sed -i -e 's|^\(Mod[0-9]\+[: space :]\+\)\([0-9]\+[: space :]\+:Workspace.*\)|\1F\2|' $FLUXKEYS && echo done || echo failed
4061         else
4062             echo 'Sorry, do not know what to do.'
4063             return 1
4064         fi
4065     fi
4066 }
4067
4068 # retrieve weather information on the console
4069 # Usage example: 'weather LOWG'
4070 weather() {
4071     [[ -n "$1" ]] || {
4072         print 'Usage: weather <station_id>' >&2
4073         print 'List of stations: http://en.wikipedia.org/wiki/List_of_airports_by_ICAO_code'>&2
4074         return 1
4075     }
4076
4077     local PLACE="${1:u}"
4078     local FILE="$HOME/.weather/$PLACE"
4079     local LOG="$HOME/.weather/log"
4080
4081     [[ -d $HOME/.weather ]] || {
4082         print -n "Creating $HOME/.weather: "
4083         mkdir $HOME/.weather
4084         print 'done'
4085     }
4086
4087     print "Retrieving information for ${PLACE}:"
4088     print
4089     wget -T 10 --no-verbose --output-file=$LOG --output-document=$FILE --timestamping http://weather.noaa.gov/pub/data/observations/metar/decoded/$PLACE.TXT
4090
4091     if [[ $? -eq 0 ]] ; then
4092         if [[ -n "$VERBOSE" ]] ; then
4093             cat $FILE
4094         else
4095             DATE=$(grep 'UTC' $FILE | sed 's#.* /##')
4096             TEMPERATURE=$(awk '/Temperature/ { print $4" degree Celcius / " $2" degree Fahrenheit" }' $FILE| tr -d '(')
4097             echo "date: $DATE"
4098             echo "temp:  $TEMPERATURE"
4099         fi
4100     else
4101         print "There was an error retrieving the weather information for $PLACE" >&2
4102         cat $LOG
4103         return 1
4104     fi
4105 }
4106 # }}}
4107
4108 # mercurial related stuff {{{
4109 if check_com -c hg ; then
4110     # gnu like diff for mercurial
4111     # http://www.selenic.com/mercurial/wiki/index.cgi/TipsAndTricks
4112     #f5# GNU like diff for mercurial
4113     hgdi() {
4114         for i in $(hg status -marn "$@") ; diff -ubwd <(hg cat "$i") "$i"
4115     }
4116
4117     # build debian package
4118     #a2# Alias for \kbd{hg-buildpackage}
4119     alias hbp='hg-buildpackage'
4120
4121     # execute commands on the versioned patch-queue from the current repos
4122     alias mq='hg -R $(readlink -f $(hg root)/.hg/patches)'
4123
4124     # diffstat for specific version of a mercurial repository
4125     #   hgstat      => display diffstat between last revision and tip
4126     #   hgstat 1234 => display diffstat between revision 1234 and tip
4127     #f5# Diffstat for specific version of a mercurial repos
4128     hgstat() {
4129         [[ -n "$1" ]] && hg diff -r $1 -r tip | diffstat || hg export tip | diffstat
4130     }
4131
4132     #f5# Get current mercurial tip via hg itself
4133     gethgclone() {
4134         setopt local_options
4135         setopt errreturn
4136         if [[ -f mercurial-tree/.hg ]] ; then
4137             cd mercurial-tree
4138             echo "Running hg pull for retreiving latest version..."
4139             hg pull
4140             echo "Finished update. Building mercurial"
4141             make local
4142             echo "Setting \$PATH to $PWD:\$PATH..."
4143             export PATH="$PWD:$PATH"
4144         else
4145             echo "Downloading mercurial via hg"
4146             hg clone http://selenic.com/repo/hg mercurial-tree
4147             cd mercurial-tree
4148             echo "Building mercurial"
4149             make local
4150             echo "Setting \$PATH to $PWD:\$PATH..."
4151             export PATH="$PWD:$PATH"
4152             echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4153             # echo "Setting \$PYTHONPATH to PYTHONPATH=\${HOME}/lib/python,"
4154             # export PYTHONPATH=${HOME}/lib/python
4155         fi
4156     }
4157
4158 fi # end of check whether we have the 'hg'-executable
4159
4160 # get current mercurial snapshot
4161 #f5# Get current mercurial snapshot
4162 gethgsnap() {
4163     setopt local_options
4164     setopt errreturn
4165     if [[ -f mercurial-snapshot.tar.gz ]] ; then
4166          echo "mercurial-snapshot.tar.gz exists already, skipping download."
4167     else
4168         echo "Downloading mercurial snapshot"
4169         wget http://www.selenic.com/mercurial/mercurial-snapshot.tar.gz
4170     fi
4171     echo "Unpacking mercurial-snapshot.tar.gz"
4172     tar zxf mercurial-snapshot.tar.gz
4173     cd mercurial-snapshot/
4174     echo "Installing required build-dependencies"
4175     $SUDO apt-get update
4176     $SUDO apt-get install python2.4-dev
4177     echo "Building mercurial"
4178     make local
4179     echo "Setting \$PATH to $PWD:\$PATH..."
4180     export PATH="$PWD:$PATH"
4181     echo "make sure you set it permanent via ~/.zshrc if you plan to use it permanently."
4182 }
4183 # }}}
4184
4185 # some useful commands often hard to remember - let's grep for them {{{
4186 # actually use our zg() function now. :)
4187
4188 # Work around ion/xterm resize bug.
4189 #if [[ "$SHLVL" -eq 1 ]]; then
4190 #       if check_com -c resize ; then
4191 #               eval `resize </dev/null`
4192 #       fi
4193 #fi
4194
4195 # enable jackd:
4196 #  /usr/bin/jackd -dalsa -dhw:0 -r48000 -p1024 -n2
4197 # now play audio file:
4198 #  alsaplayer -o jack foobar.mp3
4199
4200 # send files via netcat
4201 # on sending side:
4202 #  send() {j=$*; tar cpz ${j/%${!#}/}|nc -w 1 ${!#} 51330;}
4203 #  send dir* $HOST
4204 #  alias receive='nc -vlp 51330 | tar xzvp'
4205
4206 # debian stuff:
4207 # dh_make -e foo@localhost -f $1
4208 # dpkg-buildpackage -rfakeroot
4209 # lintian *.deb
4210 # dpkg-scanpackages ./ /dev/null | gzip > Packages.gz
4211 # dpkg-scansources . | gzip > Sources.gz
4212 # grep-dctrl --field Maintainer $* /var/lib/apt/lists/*
4213
4214 # other stuff:
4215 # convert -geometry 200x200 -interlace LINE -verbose
4216 # ldapsearch -x -b "OU=Bedienstete,O=tug" -h ldap.tugraz.at sn=$1
4217 # ps -ao user,pcpu,start,command
4218 # gpg --keyserver blackhole.pca.dfn.de --recv-keys
4219 # xterm -bg black -fg yellow -fn -misc-fixed-medium-r-normal--14-140-75-75-c-90-iso8859-15 -ah
4220 # nc -vz $1 1-1024   # portscan via netcat
4221 # wget --mirror --no-parent --convert-links
4222 # pal -d `date +%d`
4223 # autoload -U tetris; zle -N tetris; bindkey '...' ; echo "press ... for playing tennis"
4224 #
4225 # modify console cursor
4226 # see http://www.tldp.org/HOWTO/Framebuffer-HOWTO-5.html
4227 # print $'\e[?96;0;64c'
4228 # }}}
4229
4230 # grml-small cleanups {{{
4231
4232 # The following is used to remove zsh-config-items that do not work
4233 # in grml-small by default.
4234 # If you do not want these adjustments (for whatever reason), set
4235 # $GRMLSMALL_SPECIFIC to 0 in your .zshrc.pre file (which this configuration
4236 # sources if it is there).
4237
4238 if (( GRMLSMALL_SPECIFIC > 0 )) && isgrmlsmall ; then
4239
4240     unset abk[V]
4241     unalias    'V'      &> /dev/null
4242     unfunction vman     &> /dev/null
4243     unfunction vimpm    &> /dev/null
4244     unfunction vimhelp  &> /dev/null
4245     unfunction viless   &> /dev/null
4246     unfunction 2html    &> /dev/null
4247
4248     # manpages are not in grmlsmall
4249     unfunction manzsh   &> /dev/null
4250     unalias    man2     &> /dev/null
4251     unalias    man      &> /dev/null
4252     unfunction man2     &> /dev/null
4253
4254 fi
4255
4256 #}}}
4257
4258 zrclocal
4259
4260 ## genrefcard.pl settings {{{
4261
4262 ### doc strings for external functions from files
4263 #m# f5 grml-wallpaper() Sets a wallpaper (try completion for possible values)
4264
4265 ### example: split functions-search 8,16,24,32
4266 #@# split functions-search 8
4267
4268 ## }}}
4269
4270 ## END OF FILE #################################################################
4271 # vim:filetype=zsh foldmethod=marker autoindent expandtab shiftwidth=4